git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/object_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.{Object, Activity}
   8   alias Pleroma.Web.ActivityPub.Transmogrifier
   9
  10   def render("object.json", %{object: %Object{} = object}) do
  11     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  12
  13     additional = Transmogrifier.prepare_object(object.data)
  14     Map.merge(base, additional)
  15   end
  16
  17   def render("object.json", %{object: %Activity{data: %{"type" => "Create"}} = activity}) do
  18     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  19     object = Object.normalize(activity.data["object"])
  20
  21     additional =
  22       Transmogrifier.prepare_object(activity.data)
  23       |> Map.put("object", Transmogrifier.prepare_object(object.data))
  24
  25     Map.merge(base, additional)
  26   end
  27
  28   def render("object.json", %{object: %Activity{} = activity}) do
  29     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  30     object = Object.normalize(activity.data["object"])
  31
  32     additional =
  33       Transmogrifier.prepare_object(activity.data)
  34       |> Map.put("object", object.data["id"])
  35
  36     Map.merge(base, additional)
  37   end
  38
  39   def render("likes.json", ap_id, likes, page) do
  40     collection(likes, "#{ap_id}/likes", page)
  41     |> Map.merge(Pleroma.Web.ActivityPub.Utils.make_json_ld_header())
  42   end
  43
  44   def render("likes.json", ap_id, likes) do
  45     %{
  46       "id" => "#{ap_id}/likes",
  47       "type" => "OrderedCollection",
  48       "totalItems" => length(likes),
  49       "first" => collection(likes, "#{ap_id}/likes", 1)
  50     }
  51     |> Map.merge(Pleroma.Web.ActivityPub.Utils.make_json_ld_header())
  52   end
  53
  54   def collection(collection, iri, page) do
  55     offset = (page - 1) * 10
  56     items = Enum.slice(collection, offset, 10)
  57     items = Enum.map(items, fn object -> Transmogrifier.prepare_object(object.data) end)
  58     total = length(collection)
  59
  60     map = %{
  61       "id" => "#{iri}?page=#{page}",
  62       "type" => "OrderedCollectionPage",
  63       "partOf" => iri,
  64       "totalItems" => total,
  65       "orderedItems" => items
  66     }
  67
  68     if offset < total do
  69       Map.put(map, "next", "#{iri}?page=#{page + 1}")
  70     end
  71   end
  72 end