git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.Object
  11   alias Pleroma.Object.Containment
  12   alias Pleroma.Repo
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15   alias Pleroma.Web.ActivityPub.Utils
  16   alias Pleroma.Web.ActivityPub.Visibility
  17   alias Pleroma.Web.Federator
  18   alias Pleroma.Workers.TransmogrifierWorker
  19
  20   import Ecto.Query
  21
  22   require Logger
  23   require Pleroma.Constants
  24
  25   @doc """
  26   Modifies an incoming AP object (mastodon format) to our internal format.
  27   """
  28   def fix_object(object, options \\ []) do
  29     object
  30     |> strip_internal_fields
  31     |> fix_actor
  32     |> fix_url
  33     |> fix_attachments
  34     |> fix_context
  35     |> fix_in_reply_to(options)
  36     |> fix_emoji
  37     |> fix_tag
  38     |> fix_content_map
  39     |> fix_addressing
  40     |> fix_summary
  41     |> fix_type(options)
  42   end
  43
  44   def fix_summary(%{"summary" => nil} = object) do
  45     Map.put(object, "summary", "")
  46   end
  47
  48   def fix_summary(%{"summary" => _} = object) do
  49     # summary is present, nothing to do
  50     object
  51   end
  52
  53   def fix_summary(object), do: Map.put(object, "summary", "")
  54
  55   def fix_addressing_list(map, field) do
  56     cond do
  57       is_binary(map[field]) ->
  58         Map.put(map, field, [map[field]])
  59
  60       is_nil(map[field]) ->
  61         Map.put(map, field, [])
  62
  63       true ->
  64         map
  65     end
  66   end
  67
  68   def fix_explicit_addressing(
  69         %{"to" => to, "cc" => cc} = object,
  70         explicit_mentions,
  71         follower_collection
  72       ) do
  73     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  74
  75     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  76
  77     final_cc =
  78       (cc ++ explicit_cc)
  79       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  80       |> Enum.uniq()
  81
  82     object
  83     |> Map.put("to", explicit_to)
  84     |> Map.put("cc", final_cc)
  85   end
  86
  87   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  88
  89   # if directMessage flag is set to true, leave the addressing alone
  90   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  91
  92   def fix_explicit_addressing(object) do
  93     explicit_mentions = Utils.determine_explicit_mentions(object)
  94
  95     %User{follower_address: follower_collection} =
  96       object
  97       |> Containment.get_actor()
  98       |> User.get_cached_by_ap_id()
  99
 100     explicit_mentions =
 101       explicit_mentions ++
 102         [
 103           Pleroma.Constants.as_public(),
 104           follower_collection
 105         ]
 106
 107     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 108   end
 109
 110   # if as:Public is addressed, then make sure the followers collection is also addressed
 111   # so that the activities will be delivered to local users.
 112   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 113     recipients = to ++ cc
 114
 115     if followers_collection not in recipients do
 116       cond do
 117         Pleroma.Constants.as_public() in cc ->
 118           to = to ++ [followers_collection]
 119           Map.put(object, "to", to)
 120
 121         Pleroma.Constants.as_public() in to ->
 122           cc = cc ++ [followers_collection]
 123           Map.put(object, "cc", cc)
 124
 125         true ->
 126           object
 127       end
 128     else
 129       object
 130     end
 131   end
 132
 133   def fix_implicit_addressing(object, _), do: object
 134
 135   def fix_addressing(object) do
 136     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 137     followers_collection = User.ap_followers(user)
 138
 139     object
 140     |> fix_addressing_list("to")
 141     |> fix_addressing_list("cc")
 142     |> fix_addressing_list("bto")
 143     |> fix_addressing_list("bcc")
 144     |> fix_explicit_addressing()
 145     |> fix_implicit_addressing(followers_collection)
 146   end
 147
 148   def fix_actor(%{"attributedTo" => actor} = object) do
 149     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 150   end
 151
 152   def fix_in_reply_to(object, options \\ [])
 153
 154   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 155       when not is_nil(in_reply_to) do
 156     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 157     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 158
 159     if Federator.allowed_incoming_reply_depth?(options[:depth]) do
 160       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 161            %Activity{} = _ <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 162         object
 163         |> Map.put("inReplyTo", replied_object.data["id"])
 164         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 165         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 166         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 167       else
 168         e ->
 169           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 170           object
 171       end
 172     else
 173       object
 174     end
 175   end
 176
 177   def fix_in_reply_to(object, _options), do: object
 178
 179   defp prepare_in_reply_to(in_reply_to) do
 180     cond do
 181       is_bitstring(in_reply_to) ->
 182         in_reply_to
 183
 184       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 185         in_reply_to["id"]
 186
 187       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 188         Enum.at(in_reply_to, 0)
 189
 190       true ->
 191         ""
 192     end
 193   end
 194
 195   def fix_context(object) do
 196     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 197
 198     object
 199     |> Map.put("context", context)
 200     |> Map.put("conversation", context)
 201   end
 202
 203   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 204     attachments =
 205       Enum.map(attachment, fn data ->
 206         media_type = data["mediaType"] || data["mimeType"]
 207         href = data["url"] || data["href"]
 208         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 209
 210         data
 211         |> Map.put("mediaType", media_type)
 212         |> Map.put("url", url)
 213       end)
 214
 215     Map.put(object, "attachment", attachments)
 216   end
 217
 218   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 219     object
 220     |> Map.put("attachment", [attachment])
 221     |> fix_attachments()
 222   end
 223
 224   def fix_attachments(object), do: object
 225
 226   def fix_url(%{"url" => url} = object) when is_map(url) do
 227     Map.put(object, "url", url["href"])
 228   end
 229
 230   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 231     first_element = Enum.at(url, 0)
 232
 233     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 234
 235     object
 236     |> Map.put("attachment", [first_element])
 237     |> Map.put("url", link_element["href"])
 238   end
 239
 240   def fix_url(%{"type" => object_type, "url" => url} = object)
 241       when object_type != "Video" and is_list(url) do
 242     first_element = Enum.at(url, 0)
 243
 244     url_string =
 245       cond do
 246         is_bitstring(first_element) -> first_element
 247         is_map(first_element) -> first_element["href"] || ""
 248         true -> ""
 249       end
 250
 251     Map.put(object, "url", url_string)
 252   end
 253
 254   def fix_url(object), do: object
 255
 256   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 257     emoji =
 258       tags
 259       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 260       |> Enum.reduce(%{}, fn data, mapping ->
 261         name = String.trim(data["name"], ":")
 262
 263         Map.put(mapping, name, data["icon"]["url"])
 264       end)
 265
 266     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 267     emoji = Map.merge(object["emoji"] || %{}, emoji)
 268
 269     Map.put(object, "emoji", emoji)
 270   end
 271
 272   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 273     name = String.trim(tag["name"], ":")
 274     emoji = %{name => tag["icon"]["url"]}
 275
 276     Map.put(object, "emoji", emoji)
 277   end
 278
 279   def fix_emoji(object), do: object
 280
 281   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 282     tags =
 283       tag
 284       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 285       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 286
 287     Map.put(object, "tag", tag ++ tags)
 288   end
 289
 290   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 291     combined = [tag, String.slice(hashtag, 1..-1)]
 292
 293     Map.put(object, "tag", combined)
 294   end
 295
 296   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 297
 298   def fix_tag(object), do: object
 299
 300   # content map usually only has one language so this will do for now.
 301   def fix_content_map(%{"contentMap" => content_map} = object) do
 302     content_groups = Map.to_list(content_map)
 303     {_, content} = Enum.at(content_groups, 0)
 304
 305     Map.put(object, "content", content)
 306   end
 307
 308   def fix_content_map(object), do: object
 309
 310   def fix_type(object, options \\ [])
 311
 312   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 313       when is_binary(reply_id) do
 314     with true <- Federator.allowed_incoming_reply_depth?(options[:depth]),
 315          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 316       Map.put(object, "type", "Answer")
 317     else
 318       _ -> object
 319     end
 320   end
 321
 322   def fix_type(object, _), do: object
 323
 324   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 325     with true <- id =~ "follows",
 326          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 327          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 328       {:ok, activity}
 329     else
 330       _ -> {:error, nil}
 331     end
 332   end
 333
 334   defp mastodon_follow_hack(_, _), do: {:error, nil}
 335
 336   defp get_follow_activity(follow_object, followed) do
 337     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 338          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 339       {:ok, activity}
 340     else
 341       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 342       {:activity, nil} ->
 343         mastodon_follow_hack(follow_object, followed)
 344
 345       _ ->
 346         {:error, nil}
 347     end
 348   end
 349
 350   # Reduce the object list to find the reported user.
 351   defp get_reported(objects) do
 352     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 353       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 354         {:halt, user}
 355       else
 356         _ -> {:cont, nil}
 357       end
 358     end)
 359   end
 360
 361   def handle_incoming(data, options \\ [])
 362
 363   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 364   # with nil ID.
 365   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 366     with context <- data["context"] || Utils.generate_context_id(),
 367          content <- data["content"] || "",
 368          %User{} = actor <- User.get_cached_by_ap_id(actor),
 369          # Reduce the object list to find the reported user.
 370          %User{} = account <- get_reported(objects),
 371          # Remove the reported user from the object list.
 372          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 373       %{
 374         actor: actor,
 375         context: context,
 376         account: account,
 377         statuses: statuses,
 378         content: content,
 379         additional: %{"cc" => [account.ap_id]}
 380       }
 381       |> ActivityPub.flag()
 382     end
 383   end
 384
 385   # disallow objects with bogus IDs
 386   def handle_incoming(%{"id" => nil}, _options), do: :error
 387   def handle_incoming(%{"id" => ""}, _options), do: :error
 388   # length of https:// = 8, should validate better, but good enough for now.
 389   def handle_incoming(%{"id" => id}, _options) when not (is_binary(id) and length(id) > 8),
 390     do: :error
 391
 392   # TODO: validate those with a Ecto scheme
 393   # - tags
 394   # - emoji
 395   def handle_incoming(
 396         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 397         options
 398       )
 399       when objtype in ["Article", "Note", "Video", "Page", "Question", "Answer"] do
 400     actor = Containment.get_actor(data)
 401
 402     data =
 403       Map.put(data, "actor", actor)
 404       |> fix_addressing
 405
 406     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 407          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 408       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 409       object = fix_object(data["object"], options)
 410
 411       params = %{
 412         to: data["to"],
 413         object: object,
 414         actor: user,
 415         context: object["conversation"],
 416         local: false,
 417         published: data["published"],
 418         additional:
 419           Map.take(data, [
 420             "cc",
 421             "directMessage",
 422             "id"
 423           ])
 424       }
 425
 426       ActivityPub.create(params)
 427     else
 428       %Activity{} = activity -> {:ok, activity}
 429       _e -> :error
 430     end
 431   end
 432
 433   def handle_incoming(
 434         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 435         options
 436       ) do
 437     actor = Containment.get_actor(data)
 438
 439     data =
 440       Map.put(data, "actor", actor)
 441       |> fix_addressing
 442
 443     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 444       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 445       object = fix_object(object, options)
 446
 447       params = %{
 448         to: data["to"],
 449         object: object,
 450         actor: user,
 451         context: nil,
 452         local: false,
 453         published: data["published"],
 454         additional: Map.take(data, ["cc", "id"])
 455       }
 456
 457       ActivityPub.listen(params)
 458     else
 459       _e -> :error
 460     end
 461   end
 462
 463   def handle_incoming(
 464         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 465         _options
 466       ) do
 467     with %User{local: true} = followed <-
 468            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 469          {:ok, %User{} = follower} <-
 470            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 471          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 472       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 473            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 474            {_, false} <- {:user_locked, User.locked?(followed)},
 475            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 476            {_, {:ok, _}} <-
 477              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")} do
 478         ActivityPub.accept(%{
 479           to: [follower.ap_id],
 480           actor: followed,
 481           object: data,
 482           local: true
 483         })
 484       else
 485         {:user_blocked, true} ->
 486           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 487
 488           ActivityPub.reject(%{
 489             to: [follower.ap_id],
 490             actor: followed,
 491             object: data,
 492             local: true
 493           })
 494
 495         {:follow, {:error, _}} ->
 496           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 497
 498           ActivityPub.reject(%{
 499             to: [follower.ap_id],
 500             actor: followed,
 501             object: data,
 502             local: true
 503           })
 504
 505         {:user_locked, true} ->
 506           :noop
 507       end
 508
 509       {:ok, activity}
 510     else
 511       _e ->
 512         :error
 513     end
 514   end
 515
 516   def handle_incoming(
 517         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 518         _options
 519       ) do
 520     with actor <- Containment.get_actor(data),
 521          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 522          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 523          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 524          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 525          {:ok, _follower} = User.follow(follower, followed) do
 526       ActivityPub.accept(%{
 527         to: follow_activity.data["to"],
 528         type: "Accept",
 529         actor: followed,
 530         object: follow_activity.data["id"],
 531         local: false,
 532         activity_id: id
 533       })
 534     else
 535       _e -> :error
 536     end
 537   end
 538
 539   def handle_incoming(
 540         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 541         _options
 542       ) do
 543     with actor <- Containment.get_actor(data),
 544          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 545          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 546          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 547          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 548          {:ok, activity} <-
 549            ActivityPub.reject(%{
 550              to: follow_activity.data["to"],
 551              type: "Reject",
 552              actor: followed,
 553              object: follow_activity.data["id"],
 554              local: false,
 555              activity_id: id
 556            }) do
 557       User.unfollow(follower, followed)
 558
 559       {:ok, activity}
 560     else
 561       _e -> :error
 562     end
 563   end
 564
 565   def handle_incoming(
 566         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data,
 567         _options
 568       ) do
 569     with actor <- Containment.get_actor(data),
 570          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 571          {:ok, object} <- get_obj_helper(object_id),
 572          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 573       {:ok, activity}
 574     else
 575       _e -> :error
 576     end
 577   end
 578
 579   def handle_incoming(
 580         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 581         _options
 582       ) do
 583     with actor <- Containment.get_actor(data),
 584          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 585          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 586          public <- Visibility.is_public?(data),
 587          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 588       {:ok, activity}
 589     else
 590       _e -> :error
 591     end
 592   end
 593
 594   def handle_incoming(
 595         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 596           data,
 597         _options
 598       )
 599       when object_type in ["Person", "Application", "Service", "Organization"] do
 600     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 601       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 602
 603       banner = new_user_data[:info][:banner]
 604       locked = new_user_data[:info][:locked] || false
 605       attachment = get_in(new_user_data, [:info, :source_data, "attachment"]) || []
 606
 607       fields =
 608         attachment
 609         |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 610         |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 611
 612       update_data =
 613         new_user_data
 614         |> Map.take([:name, :bio, :avatar])
 615         |> Map.put(:info, %{banner: banner, locked: locked, fields: fields})
 616
 617       actor
 618       |> User.upgrade_changeset(update_data, true)
 619       |> User.update_and_set_cache()
 620
 621       ActivityPub.update(%{
 622         local: false,
 623         to: data["to"] || [],
 624         cc: data["cc"] || [],
 625         object: object,
 626         actor: actor_id,
 627         activity_id: data["id"]
 628       })
 629     else
 630       e ->
 631         Logger.error(e)
 632         :error
 633     end
 634   end
 635
 636   # TODO: We presently assume that any actor on the same origin domain as the object being
 637   # deleted has the rights to delete that object.  A better way to validate whether or not
 638   # the object should be deleted is to refetch the object URI, which should return either
 639   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 640   # place.
 641   def handle_incoming(
 642         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 643         _options
 644       ) do
 645     object_id = Utils.get_ap_id(object_id)
 646
 647     with actor <- Containment.get_actor(data),
 648          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 649          {:ok, object} <- get_obj_helper(object_id),
 650          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 651          {:ok, activity} <-
 652            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 653       {:ok, activity}
 654     else
 655       nil ->
 656         case User.get_cached_by_ap_id(object_id) do
 657           %User{ap_id: ^actor} = user ->
 658             User.delete(user)
 659
 660           nil ->
 661             :error
 662         end
 663
 664       _e ->
 665         :error
 666     end
 667   end
 668
 669   def handle_incoming(
 670         %{
 671           "type" => "Undo",
 672           "object" => %{"type" => "Announce", "object" => object_id},
 673           "actor" => _actor,
 674           "id" => id
 675         } = data,
 676         _options
 677       ) do
 678     with actor <- Containment.get_actor(data),
 679          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 680          {:ok, object} <- get_obj_helper(object_id),
 681          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 682       {:ok, activity}
 683     else
 684       _e -> :error
 685     end
 686   end
 687
 688   def handle_incoming(
 689         %{
 690           "type" => "Undo",
 691           "object" => %{"type" => "Follow", "object" => followed},
 692           "actor" => follower,
 693           "id" => id
 694         } = _data,
 695         _options
 696       ) do
 697     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 698          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 699          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 700       User.unfollow(follower, followed)
 701       {:ok, activity}
 702     else
 703       _e -> :error
 704     end
 705   end
 706
 707   def handle_incoming(
 708         %{
 709           "type" => "Undo",
 710           "object" => %{"type" => "Block", "object" => blocked},
 711           "actor" => blocker,
 712           "id" => id
 713         } = _data,
 714         _options
 715       ) do
 716     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 717          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 718          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 719       User.unblock(blocker, blocked)
 720       {:ok, activity}
 721     else
 722       _e -> :error
 723     end
 724   end
 725
 726   def handle_incoming(
 727         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 728         _options
 729       ) do
 730     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 731          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 732          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 733       User.unfollow(blocker, blocked)
 734       User.block(blocker, blocked)
 735       {:ok, activity}
 736     else
 737       _e -> :error
 738     end
 739   end
 740
 741   def handle_incoming(
 742         %{
 743           "type" => "Undo",
 744           "object" => %{"type" => "Like", "object" => object_id},
 745           "actor" => _actor,
 746           "id" => id
 747         } = data,
 748         _options
 749       ) do
 750     with actor <- Containment.get_actor(data),
 751          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 752          {:ok, object} <- get_obj_helper(object_id),
 753          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 754       {:ok, activity}
 755     else
 756       _e -> :error
 757     end
 758   end
 759
 760   # For Undos that don't have the complete object attached, try to find it in our database.
 761   def handle_incoming(
 762         %{
 763           "type" => "Undo",
 764           "object" => object
 765         } = activity,
 766         options
 767       )
 768       when is_binary(object) do
 769     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 770       activity
 771       |> Map.put("object", data)
 772       |> handle_incoming(options)
 773     else
 774       _e -> :error
 775     end
 776   end
 777
 778   def handle_incoming(_, _), do: :error
 779
 780   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 781   def get_obj_helper(id, options \\ []) do
 782     case Object.normalize(id, true, options) do
 783       %Object{} = object -> {:ok, object}
 784       _ -> nil
 785     end
 786   end
 787
 788   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 789   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 790         ap_id: ap_id
 791       })
 792       when attributed_to == ap_id do
 793     with {:ok, activity} <-
 794            handle_incoming(%{
 795              "type" => "Create",
 796              "to" => data["to"],
 797              "cc" => data["cc"],
 798              "actor" => attributed_to,
 799              "object" => data
 800            }) do
 801       {:ok, Object.normalize(activity)}
 802     else
 803       _ -> get_obj_helper(object_id)
 804     end
 805   end
 806
 807   def get_embedded_obj_helper(object_id, _) do
 808     get_obj_helper(object_id)
 809   end
 810
 811   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 812     with false <- String.starts_with?(in_reply_to, "http"),
 813          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 814       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 815     else
 816       _e -> object
 817     end
 818   end
 819
 820   def set_reply_to_uri(obj), do: obj
 821
 822   # Prepares the object of an outgoing create activity.
 823   def prepare_object(object) do
 824     object
 825     |> set_sensitive
 826     |> add_hashtags
 827     |> add_mention_tags
 828     |> add_emoji_tags
 829     |> add_attributed_to
 830     |> prepare_attachments
 831     |> set_conversation
 832     |> set_reply_to_uri
 833     |> strip_internal_fields
 834     |> strip_internal_tags
 835     |> set_type
 836   end
 837
 838   #  @doc
 839   #  """
 840   #  internal -> Mastodon
 841   #  """
 842
 843   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 844       when activity_type in ["Create", "Listen"] do
 845     object =
 846       object_id
 847       |> Object.normalize()
 848       |> Map.get(:data)
 849       |> prepare_object
 850
 851     data =
 852       data
 853       |> Map.put("object", object)
 854       |> Map.merge(Utils.make_json_ld_header())
 855       |> Map.delete("bcc")
 856
 857     {:ok, data}
 858   end
 859
 860   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 861     object =
 862       object_id
 863       |> Object.normalize()
 864
 865     data =
 866       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 867         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 868       else
 869         data |> maybe_fix_object_url
 870       end
 871
 872     data =
 873       data
 874       |> strip_internal_fields
 875       |> Map.merge(Utils.make_json_ld_header())
 876       |> Map.delete("bcc")
 877
 878     {:ok, data}
 879   end
 880
 881   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 882   # because of course it does.
 883   def prepare_outgoing(%{"type" => "Accept"} = data) do
 884     with follow_activity <- Activity.normalize(data["object"]) do
 885       object = %{
 886         "actor" => follow_activity.actor,
 887         "object" => follow_activity.data["object"],
 888         "id" => follow_activity.data["id"],
 889         "type" => "Follow"
 890       }
 891
 892       data =
 893         data
 894         |> Map.put("object", object)
 895         |> Map.merge(Utils.make_json_ld_header())
 896
 897       {:ok, data}
 898     end
 899   end
 900
 901   def prepare_outgoing(%{"type" => "Reject"} = data) do
 902     with follow_activity <- Activity.normalize(data["object"]) do
 903       object = %{
 904         "actor" => follow_activity.actor,
 905         "object" => follow_activity.data["object"],
 906         "id" => follow_activity.data["id"],
 907         "type" => "Follow"
 908       }
 909
 910       data =
 911         data
 912         |> Map.put("object", object)
 913         |> Map.merge(Utils.make_json_ld_header())
 914
 915       {:ok, data}
 916     end
 917   end
 918
 919   def prepare_outgoing(%{"type" => _type} = data) do
 920     data =
 921       data
 922       |> strip_internal_fields
 923       |> maybe_fix_object_url
 924       |> Map.merge(Utils.make_json_ld_header())
 925
 926     {:ok, data}
 927   end
 928
 929   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
 930     with false <- String.starts_with?(object, "http"),
 931          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
 932          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
 933            relative_object do
 934       Map.put(data, "object", external_url)
 935     else
 936       {:fetch, e} ->
 937         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
 938         data
 939
 940       _ ->
 941         data
 942     end
 943   end
 944
 945   def maybe_fix_object_url(data), do: data
 946
 947   def add_hashtags(object) do
 948     tags =
 949       (object["tag"] || [])
 950       |> Enum.map(fn
 951         # Expand internal representation tags into AS2 tags.
 952         tag when is_binary(tag) ->
 953           %{
 954             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 955             "name" => "##{tag}",
 956             "type" => "Hashtag"
 957           }
 958
 959         # Do not process tags which are already AS2 tag objects.
 960         tag when is_map(tag) ->
 961           tag
 962       end)
 963
 964     Map.put(object, "tag", tags)
 965   end
 966
 967   def add_mention_tags(object) do
 968     mentions =
 969       object
 970       |> Utils.get_notified_from_object()
 971       |> Enum.map(&build_mention_tag/1)
 972
 973     tags = object["tag"] || []
 974
 975     Map.put(object, "tag", tags ++ mentions)
 976   end
 977
 978   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
 979     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
 980   end
 981
 982   def take_emoji_tags(%User{info: %{emoji: emoji} = _user_info} = _user) do
 983     emoji
 984     |> Enum.flat_map(&Map.to_list/1)
 985     |> Enum.map(&build_emoji_tag/1)
 986   end
 987
 988   # TODO: we should probably send mtime instead of unix epoch time for updated
 989   def add_emoji_tags(%{"emoji" => emoji} = object) do
 990     tags = object["tag"] || []
 991
 992     out = Enum.map(emoji, &build_emoji_tag/1)
 993
 994     Map.put(object, "tag", tags ++ out)
 995   end
 996
 997   def add_emoji_tags(object), do: object
 998
 999   defp build_emoji_tag({name, url}) do
1000     %{
1001       "icon" => %{"url" => url, "type" => "Image"},
1002       "name" => ":" <> name <> ":",
1003       "type" => "Emoji",
1004       "updated" => "1970-01-01T00:00:00Z",
1005       "id" => url
1006     }
1007   end
1008
1009   def set_conversation(object) do
1010     Map.put(object, "conversation", object["context"])
1011   end
1012
1013   def set_sensitive(object) do
1014     tags = object["tag"] || []
1015     Map.put(object, "sensitive", "nsfw" in tags)
1016   end
1017
1018   def set_type(%{"type" => "Answer"} = object) do
1019     Map.put(object, "type", "Note")
1020   end
1021
1022   def set_type(object), do: object
1023
1024   def add_attributed_to(object) do
1025     attributed_to = object["attributedTo"] || object["actor"]
1026     Map.put(object, "attributedTo", attributed_to)
1027   end
1028
1029   def prepare_attachments(object) do
1030     attachments =
1031       (object["attachment"] || [])
1032       |> Enum.map(fn data ->
1033         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1034         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1035       end)
1036
1037     Map.put(object, "attachment", attachments)
1038   end
1039
1040   defp strip_internal_fields(object) do
1041     object
1042     |> Map.drop(Pleroma.Constants.object_internal_fields())
1043   end
1044
1045   defp strip_internal_tags(%{"tag" => tags} = object) do
1046     tags = Enum.filter(tags, fn x -> is_map(x) end)
1047
1048     Map.put(object, "tag", tags)
1049   end
1050
1051   defp strip_internal_tags(object), do: object
1052
1053   def perform(:user_upgrade, user) do
1054     # we pass a fake user so that the followers collection is stripped away
1055     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1056
1057     q =
1058       from(
1059         u in User,
1060         where: ^old_follower_address in u.following,
1061         update: [
1062           set: [
1063             following:
1064               fragment(
1065                 "array_replace(?,?,?)",
1066                 u.following,
1067                 ^old_follower_address,
1068                 ^user.follower_address
1069               )
1070           ]
1071         ]
1072       )
1073
1074     Repo.update_all(q, [])
1075
1076     q =
1077       from(
1078         a in Activity,
1079         where: ^old_follower_address in a.recipients,
1080         update: [
1081           set: [
1082             recipients:
1083               fragment(
1084                 "array_replace(?,?,?)",
1085                 a.recipients,
1086                 ^old_follower_address,
1087                 ^user.follower_address
1088               )
1089           ]
1090         ]
1091       )
1092
1093     Repo.update_all(q, [])
1094   end
1095
1096   def upgrade_user_from_ap_id(ap_id) do
1097     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1098          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1099          already_ap <- User.ap_enabled?(user),
1100          {:ok, user} <- upgrade_user(user, data) do
1101       if not already_ap do
1102         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1103       end
1104
1105       {:ok, user}
1106     else
1107       %User{} = user -> {:ok, user}
1108       e -> e
1109     end
1110   end
1111
1112   defp upgrade_user(user, data) do
1113     user
1114     |> User.upgrade_changeset(data, true)
1115     |> User.update_and_set_cache()
1116   end
1117
1118   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1119     Map.put(data, "url", url["href"])
1120   end
1121
1122   def maybe_fix_user_url(data), do: data
1123
1124   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1125 end