git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   @doc """
  17   Modifies an incoming AP object (mastodon format) to our internal format.
  18   """
  19   def fix_object(object) do
  20     object
  21     |> Map.put("actor", object["attributedTo"])
  22     |> fix_attachments
  23     |> fix_context
  24     |> fix_in_reply_to
  25     |> fix_emoji
  26     |> fix_tag
  27   end
  28
  29   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  30       when not is_nil(in_reply_to_id) do
  31     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  32       {:ok, replied_object} ->
  33         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  34
  35         object
  36         |> Map.put("inReplyTo", replied_object.data["id"])
  37         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  38         |> Map.put("inReplyToStatusId", activity.id)
  39         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  40         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  41
  42       e ->
  43         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  44         object
  45     end
  46   end
  47
  48   def fix_in_reply_to(object), do: object
  49
  50   def fix_context(object) do
  51     object
  52     |> Map.put("context", object["conversation"])
  53   end
  54
  55   def fix_attachments(object) do
  56     attachments =
  57       (object["attachment"] || [])
  58       |> Enum.map(fn data ->
  59         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  60         Map.put(data, "url", url)
  61       end)
  62
  63     object
  64     |> Map.put("attachment", attachments)
  65   end
  66
  67   def fix_emoji(object) do
  68     tags = object["tag"] || []
  69     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  70
  71     emoji =
  72       emoji
  73       |> Enum.reduce(%{}, fn data, mapping ->
  74         name = data["name"]
  75
  76         name =
  77           if String.starts_with?(name, ":") do
  78             name |> String.slice(1..-2)
  79           else
  80             name
  81           end
  82
  83         mapping |> Map.put(name, data["icon"]["url"])
  84       end)
  85
  86     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  87     emoji = Map.merge(object["emoji"] || %{}, emoji)
  88
  89     object
  90     |> Map.put("emoji", emoji)
  91   end
  92
  93   def fix_tag(object) do
  94     tags =
  95       (object["tag"] || [])
  96       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  97       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  98
  99     combined = (object["tag"] || []) ++ tags
 100
 101     object
 102     |> Map.put("tag", combined)
 103   end
 104
 105   # TODO: validate those with a Ecto scheme
 106   # - tags
 107   # - emoji
 108   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 109     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 110          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 111       object = fix_object(data["object"])
 112
 113       params = %{
 114         to: data["to"],
 115         object: object,
 116         actor: user,
 117         context: object["conversation"],
 118         local: false,
 119         published: data["published"],
 120         additional:
 121           Map.take(data, [
 122             "cc",
 123             "id"
 124           ])
 125       }
 126
 127       ActivityPub.create(params)
 128     else
 129       %Activity{} = activity -> {:ok, activity}
 130       _e -> :error
 131     end
 132   end
 133
 134   def handle_incoming(
 135         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 136       ) do
 137     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 138          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 139          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 140       if not User.locked?(followed) do
 141         ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 142         User.follow(follower, followed)
 143       end
 144
 145       {:ok, activity}
 146     else
 147       _e -> :error
 148     end
 149   end
 150
 151   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 152     with true <- id =~ "follows",
 153          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 154          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 155       {:ok, activity}
 156     else
 157       _ -> {:error, nil}
 158     end
 159   end
 160
 161   defp mastodon_follow_hack(_), do: {:error, nil}
 162
 163   defp get_follow_activity(follow_object, followed) do
 164     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 165          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 166       {:ok, activity}
 167     else
 168       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 169       {:activity, nil} ->
 170         mastodon_follow_hack(follow_object, followed)
 171
 172       _ ->
 173         {:error, nil}
 174     end
 175   end
 176
 177   def handle_incoming(
 178         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 179       ) do
 180     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 181          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 182          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 183          {:ok, activity} <-
 184            ActivityPub.accept(%{
 185              to: follow_activity.data["to"],
 186              type: "Accept",
 187              actor: followed.ap_id,
 188              object: follow_activity.data["id"],
 189              local: false
 190            }) do
 191       if not User.following?(follower, followed) do
 192         {:ok, follower} = User.follow(follower, followed)
 193       end
 194
 195       {:ok, activity}
 196     else
 197       _e -> :error
 198     end
 199   end
 200
 201   def handle_incoming(
 202         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 203       ) do
 204     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 205          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 206          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 207          {:ok, activity} <-
 208            ActivityPub.accept(%{
 209              to: follow_activity.data["to"],
 210              type: "Accept",
 211              actor: followed.ap_id,
 212              object: follow_activity.data["id"],
 213              local: false
 214            }) do
 215       User.unfollow(follower, followed)
 216
 217       {:ok, activity}
 218     else
 219       _e -> :error
 220     end
 221   end
 222
 223   def handle_incoming(
 224         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 225       ) do
 226     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 227          {:ok, object} <-
 228            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 229          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 230       {:ok, activity}
 231     else
 232       _e -> :error
 233     end
 234   end
 235
 236   def handle_incoming(
 237         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 238       ) do
 239     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 240          {:ok, object} <-
 241            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 242          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 243       {:ok, activity}
 244     else
 245       _e -> :error
 246     end
 247   end
 248
 249   def handle_incoming(
 250         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 251           data
 252       ) do
 253     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 254       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 255
 256       banner = new_user_data[:info]["banner"]
 257       locked = new_user_data[:info]["locked"]
 258
 259       update_data =
 260         new_user_data
 261         |> Map.take([:name, :bio, :avatar])
 262         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 263
 264       actor
 265       |> User.upgrade_changeset(update_data)
 266       |> User.update_and_set_cache()
 267
 268       ActivityPub.update(%{
 269         local: false,
 270         to: data["to"] || [],
 271         cc: data["cc"] || [],
 272         object: object,
 273         actor: actor_id
 274       })
 275     else
 276       e ->
 277         Logger.error(e)
 278         :error
 279     end
 280   end
 281
 282   # TODO: Make secure.
 283   def handle_incoming(
 284         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 285       ) do
 286     object_id = Utils.get_ap_id(object_id)
 287
 288     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 289          {:ok, object} <-
 290            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 291          {:ok, activity} <- ActivityPub.delete(object, false) do
 292       {:ok, activity}
 293     else
 294       _e -> :error
 295     end
 296   end
 297
 298   def handle_incoming(
 299         %{
 300           "type" => "Undo",
 301           "object" => %{"type" => "Announce", "object" => object_id},
 302           "actor" => actor,
 303           "id" => id
 304         } = _data
 305       ) do
 306     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 307          {:ok, object} <-
 308            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 309          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 310       {:ok, activity}
 311     else
 312       _e -> :error
 313     end
 314   end
 315
 316   def handle_incoming(
 317         %{
 318           "type" => "Undo",
 319           "object" => %{"type" => "Follow", "object" => followed},
 320           "actor" => follower,
 321           "id" => id
 322         } = _data
 323       ) do
 324     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 325          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 326          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 327       User.unfollow(follower, followed)
 328       {:ok, activity}
 329     else
 330       e -> :error
 331     end
 332   end
 333
 334   @ap_config Application.get_env(:pleroma, :activitypub)
 335   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 336
 337   def handle_incoming(
 338         %{
 339           "type" => "Undo",
 340           "object" => %{"type" => "Block", "object" => blocked},
 341           "actor" => blocker,
 342           "id" => id
 343         } = _data
 344       ) do
 345     with true <- @accept_blocks,
 346          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 347          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 348          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 349       User.unblock(blocker, blocked)
 350       {:ok, activity}
 351     else
 352       e -> :error
 353     end
 354   end
 355
 356   def handle_incoming(
 357         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 358       ) do
 359     with true <- @accept_blocks,
 360          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 361          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 362          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 363       User.unfollow(blocker, blocked)
 364       User.block(blocker, blocked)
 365       {:ok, activity}
 366     else
 367       e -> :error
 368     end
 369   end
 370
 371   def handle_incoming(
 372         %{
 373           "type" => "Undo",
 374           "object" => %{"type" => "Like", "object" => object_id},
 375           "actor" => actor,
 376           "id" => id
 377         } = _data
 378       ) do
 379     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 380          {:ok, object} <-
 381            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 382          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 383       {:ok, activity}
 384     else
 385       _e -> :error
 386     end
 387   end
 388
 389   def handle_incoming(_), do: :error
 390
 391   def get_obj_helper(id) do
 392     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 393   end
 394
 395   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 396     with false <- String.starts_with?(inReplyTo, "http"),
 397          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 398       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 399     else
 400       _e -> object
 401     end
 402   end
 403
 404   def set_reply_to_uri(obj), do: obj
 405
 406   # Prepares the object of an outgoing create activity.
 407   def prepare_object(object) do
 408     object
 409     |> set_sensitive
 410     |> add_hashtags
 411     |> add_mention_tags
 412     |> add_emoji_tags
 413     |> add_attributed_to
 414     |> prepare_attachments
 415     |> set_conversation
 416     |> set_reply_to_uri
 417   end
 418
 419   #  @doc
 420   #  """
 421   #  internal -> Mastodon
 422   #  """
 423
 424   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 425     object =
 426       object
 427       |> prepare_object
 428
 429     data =
 430       data
 431       |> Map.put("object", object)
 432       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 433
 434     {:ok, data}
 435   end
 436
 437   def prepare_outgoing(%{"type" => _type} = data) do
 438     data =
 439       data
 440       |> maybe_fix_object_url
 441       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 442
 443     {:ok, data}
 444   end
 445
 446   def maybe_fix_object_url(data) do
 447     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 448       case ActivityPub.fetch_object_from_id(data["object"]) do
 449         {:ok, relative_object} ->
 450           if relative_object.data["external_url"] do
 451             _data =
 452               data
 453               |> Map.put("object", relative_object.data["external_url"])
 454           else
 455             data
 456           end
 457
 458         e ->
 459           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 460           data
 461       end
 462     else
 463       data
 464     end
 465   end
 466
 467   def add_hashtags(object) do
 468     tags =
 469       (object["tag"] || [])
 470       |> Enum.map(fn tag ->
 471         %{
 472           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 473           "name" => "##{tag}",
 474           "type" => "Hashtag"
 475         }
 476       end)
 477
 478     object
 479     |> Map.put("tag", tags)
 480   end
 481
 482   def add_mention_tags(object) do
 483     recipients = object["to"] ++ (object["cc"] || [])
 484
 485     mentions =
 486       recipients
 487       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 488       |> Enum.filter(& &1)
 489       |> Enum.map(fn user ->
 490         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 491       end)
 492
 493     tags = object["tag"] || []
 494
 495     object
 496     |> Map.put("tag", tags ++ mentions)
 497   end
 498
 499   # TODO: we should probably send mtime instead of unix epoch time for updated
 500   def add_emoji_tags(object) do
 501     tags = object["tag"] || []
 502     emoji = object["emoji"] || []
 503
 504     out =
 505       emoji
 506       |> Enum.map(fn {name, url} ->
 507         %{
 508           "icon" => %{"url" => url, "type" => "Image"},
 509           "name" => ":" <> name <> ":",
 510           "type" => "Emoji",
 511           "updated" => "1970-01-01T00:00:00Z",
 512           "id" => url
 513         }
 514       end)
 515
 516     object
 517     |> Map.put("tag", tags ++ out)
 518   end
 519
 520   def set_conversation(object) do
 521     Map.put(object, "conversation", object["context"])
 522   end
 523
 524   def set_sensitive(object) do
 525     tags = object["tag"] || []
 526     Map.put(object, "sensitive", "nsfw" in tags)
 527   end
 528
 529   def add_attributed_to(object) do
 530     attributedTo = object["attributedTo"] || object["actor"]
 531
 532     object
 533     |> Map.put("attributedTo", attributedTo)
 534   end
 535
 536   def prepare_attachments(object) do
 537     attachments =
 538       (object["attachment"] || [])
 539       |> Enum.map(fn data ->
 540         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 541         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 542       end)
 543
 544     object
 545     |> Map.put("attachment", attachments)
 546   end
 547
 548   defp user_upgrade_task(user) do
 549     old_follower_address = User.ap_followers(user)
 550
 551     q =
 552       from(
 553         u in User,
 554         where: ^old_follower_address in u.following,
 555         update: [
 556           set: [
 557             following:
 558               fragment(
 559                 "array_replace(?,?,?)",
 560                 u.following,
 561                 ^old_follower_address,
 562                 ^user.follower_address
 563               )
 564           ]
 565         ]
 566       )
 567
 568     Repo.update_all(q, [])
 569
 570     maybe_retire_websub(user.ap_id)
 571
 572     # Only do this for recent activties, don't go through the whole db.
 573     # Only look at the last 1000 activities.
 574     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 575
 576     q =
 577       from(
 578         a in Activity,
 579         where: ^old_follower_address in a.recipients,
 580         where: a.id > ^since,
 581         update: [
 582           set: [
 583             recipients:
 584               fragment(
 585                 "array_replace(?,?,?)",
 586                 a.recipients,
 587                 ^old_follower_address,
 588                 ^user.follower_address
 589               )
 590           ]
 591         ]
 592       )
 593
 594     Repo.update_all(q, [])
 595   end
 596
 597   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 598     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 599          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 600       data =
 601         data
 602         |> Map.put(:info, Map.merge(user.info, data[:info]))
 603
 604       already_ap = User.ap_enabled?(user)
 605
 606       {:ok, user} =
 607         User.upgrade_changeset(user, data)
 608         |> Repo.update()
 609
 610       if !already_ap do
 611         # This could potentially take a long time, do it in the background
 612         if async do
 613           Task.start(fn ->
 614             user_upgrade_task(user)
 615           end)
 616         else
 617           user_upgrade_task(user)
 618         end
 619       end
 620
 621       {:ok, user}
 622     else
 623       e -> e
 624     end
 625   end
 626
 627   def maybe_retire_websub(ap_id) do
 628     # some sanity checks
 629     if is_binary(ap_id) && String.length(ap_id) > 8 do
 630       q =
 631         from(
 632           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 633           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 634         )
 635
 636       Repo.delete_all(q)
 637     end
 638   end
 639
 640   def maybe_fix_user_url(data) do
 641     if is_map(data["url"]) do
 642       Map.put(data, "url", data["url"]["href"])
 643     else
 644       data
 645     end
 646   end
 647
 648   def maybe_fix_user_object(data) do
 649     data
 650     |> maybe_fix_user_url
 651   end
 652 end