git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  30     id
  31   end
  32
  33   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  34     get_actor(%{"actor" => actor})
  35   end
  36
  37   @doc """
  38   Checks that an imported AP object's actor matches the domain it came from.
  39   """
  40   def contain_origin(id, %{"actor" => nil}), do: :error
  41
  42   def contain_origin(id, %{"actor" => actor} = params) do
  43     id_uri = URI.parse(id)
  44     actor_uri = URI.parse(get_actor(params))
  45
  46     if id_uri.host == actor_uri.host do
  47       :ok
  48     else
  49       :error
  50     end
  51   end
  52
  53   def contain_origin_from_id(id, %{"id" => nil}), do: :error
  54
  55   def contain_origin_from_id(id, %{"id" => other_id} = params) do
  56     id_uri = URI.parse(id)
  57     other_uri = URI.parse(other_id)
  58
  59     if id_uri.host == other_uri.host do
  60       :ok
  61     else
  62       :error
  63     end
  64   end
  65
  66   @doc """
  67   Modifies an incoming AP object (mastodon format) to our internal format.
  68   """
  69   def fix_object(object) do
  70     object
  71     |> fix_actor
  72     |> fix_attachments
  73     |> fix_url
  74     |> fix_context
  75     |> fix_in_reply_to
  76     |> fix_emoji
  77     |> fix_tag
  78     |> fix_content_map
  79     |> fix_likes
  80     |> fix_addressing
  81   end
  82
  83   def fix_addressing_list(map, field) do
  84     if is_binary(map[field]) do
  85       map
  86       |> Map.put(field, [map[field]])
  87     else
  88       map
  89     end
  90   end
  91
  92   def fix_addressing(map) do
  93     map
  94     |> fix_addressing_list("to")
  95     |> fix_addressing_list("cc")
  96     |> fix_addressing_list("bto")
  97     |> fix_addressing_list("bcc")
  98   end
  99
 100   def fix_actor(%{"attributedTo" => actor} = object) do
 101     object
 102     |> Map.put("actor", get_actor(%{"actor" => actor}))
 103   end
 104
 105   def fix_likes(%{"likes" => likes} = object)
 106       when is_bitstring(likes) do
 107     # Check for standardisation
 108     # This is what Peertube does
 109     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
 110     object
 111     |> Map.put("likes", [])
 112     |> Map.put("like_count", 0)
 113   end
 114
 115   def fix_likes(object) do
 116     object
 117   end
 118
 119   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 120       when not is_nil(in_reply_to) do
 121     in_reply_to_id =
 122       cond do
 123         is_bitstring(in_reply_to) ->
 124           in_reply_to
 125
 126         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 127           in_reply_to["id"]
 128
 129         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 130           Enum.at(in_reply_to, 0)
 131
 132         # Maybe I should output an error too?
 133         true ->
 134           ""
 135       end
 136
 137     case fetch_obj_helper(in_reply_to_id) do
 138       {:ok, replied_object} ->
 139         with %Activity{} = activity <-
 140                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 141           object
 142           |> Map.put("inReplyTo", replied_object.data["id"])
 143           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 144           |> Map.put("inReplyToStatusId", activity.id)
 145           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 146           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 147         else
 148           e ->
 149             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 150             object
 151         end
 152
 153       e ->
 154         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 155         object
 156     end
 157   end
 158
 159   def fix_in_reply_to(object), do: object
 160
 161   def fix_context(object) do
 162     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 163
 164     object
 165     |> Map.put("context", context)
 166     |> Map.put("conversation", context)
 167   end
 168
 169   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 170     attachments =
 171       attachment
 172       |> Enum.map(fn data ->
 173         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 174         Map.put(data, "url", url)
 175       end)
 176
 177     object
 178     |> Map.put("attachment", attachments)
 179   end
 180
 181   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 182     Map.put(object, "attachment", [attachment])
 183     |> fix_attachments()
 184   end
 185
 186   def fix_attachments(object), do: object
 187
 188   def fix_url(%{"url" => url} = object) when is_map(url) do
 189     object
 190     |> Map.put("url", url["href"])
 191   end
 192
 193   def fix_url(%{"url" => url} = object) when is_list(url) do
 194     first_element = Enum.at(url, 0)
 195
 196     url_string =
 197       cond do
 198         is_bitstring(first_element) -> first_element
 199         is_map(first_element) -> first_element["href"] || ""
 200         true -> ""
 201       end
 202
 203     object
 204     |> Map.put("url", url_string)
 205   end
 206
 207   def fix_url(object), do: object
 208
 209   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 210     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 211
 212     emoji =
 213       emoji
 214       |> Enum.reduce(%{}, fn data, mapping ->
 215         name = String.trim(data["name"], ":")
 216
 217         mapping |> Map.put(name, data["icon"]["url"])
 218       end)
 219
 220     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 221     emoji = Map.merge(object["emoji"] || %{}, emoji)
 222
 223     object
 224     |> Map.put("emoji", emoji)
 225   end
 226
 227   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 228     name = String.trim(tag["name"], ":")
 229     emoji = %{name => tag["icon"]["url"]}
 230
 231     object
 232     |> Map.put("emoji", emoji)
 233   end
 234
 235   def fix_emoji(object), do: object
 236
 237   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 238     tags =
 239       tag
 240       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 241       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 242
 243     combined = tag ++ tags
 244
 245     object
 246     |> Map.put("tag", combined)
 247   end
 248
 249   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 250     combined = [tag, String.slice(hashtag, 1..-1)]
 251
 252     object
 253     |> Map.put("tag", combined)
 254   end
 255
 256   def fix_tag(object), do: object
 257
 258   # content map usually only has one language so this will do for now.
 259   def fix_content_map(%{"contentMap" => content_map} = object) do
 260     content_groups = Map.to_list(content_map)
 261     {_, content} = Enum.at(content_groups, 0)
 262
 263     object
 264     |> Map.put("content", content)
 265   end
 266
 267   def fix_content_map(object), do: object
 268
 269   # disallow objects with bogus IDs
 270   def handle_incoming(%{"id" => nil}), do: :error
 271   def handle_incoming(%{"id" => ""}), do: :error
 272   # length of https:// = 8, should validate better, but good enough for now.
 273   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 274
 275   # TODO: validate those with a Ecto scheme
 276   # - tags
 277   # - emoji
 278   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 279       when objtype in ["Article", "Note", "Video", "Page"] do
 280     actor = get_actor(data)
 281
 282     data =
 283       Map.put(data, "actor", actor)
 284       |> fix_addressing
 285
 286     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 287          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 288       object = fix_object(data["object"])
 289
 290       params = %{
 291         to: data["to"],
 292         object: object,
 293         actor: user,
 294         context: object["conversation"],
 295         local: false,
 296         published: data["published"],
 297         additional:
 298           Map.take(data, [
 299             "cc",
 300             "id"
 301           ])
 302       }
 303
 304       ActivityPub.create(params)
 305     else
 306       %Activity{} = activity -> {:ok, activity}
 307       _e -> :error
 308     end
 309   end
 310
 311   def handle_incoming(
 312         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 313       ) do
 314     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 315          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 316          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 317       if not User.locked?(followed) do
 318         ActivityPub.accept(%{
 319           to: [follower.ap_id],
 320           actor: followed.ap_id,
 321           object: data,
 322           local: true
 323         })
 324
 325         User.follow(follower, followed)
 326       end
 327
 328       {:ok, activity}
 329     else
 330       _e -> :error
 331     end
 332   end
 333
 334   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 335     with true <- id =~ "follows",
 336          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 337          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 338       {:ok, activity}
 339     else
 340       _ -> {:error, nil}
 341     end
 342   end
 343
 344   defp mastodon_follow_hack(_), do: {:error, nil}
 345
 346   defp get_follow_activity(follow_object, followed) do
 347     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 348          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 349       {:ok, activity}
 350     else
 351       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 352       {:activity, nil} ->
 353         mastodon_follow_hack(follow_object, followed)
 354
 355       _ ->
 356         {:error, nil}
 357     end
 358   end
 359
 360   def handle_incoming(
 361         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 362       ) do
 363     with actor <- get_actor(data),
 364          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 365          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 366          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 367          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 368          {:ok, activity} <-
 369            ActivityPub.accept(%{
 370              to: follow_activity.data["to"],
 371              type: "Accept",
 372              actor: followed.ap_id,
 373              object: follow_activity.data["id"],
 374              local: false
 375            }) do
 376       if not User.following?(follower, followed) do
 377         {:ok, follower} = User.follow(follower, followed)
 378       end
 379
 380       {:ok, activity}
 381     else
 382       _e -> :error
 383     end
 384   end
 385
 386   def handle_incoming(
 387         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 388       ) do
 389     with actor <- get_actor(data),
 390          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 391          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 392          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 393          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 394          {:ok, activity} <-
 395            ActivityPub.accept(%{
 396              to: follow_activity.data["to"],
 397              type: "Accept",
 398              actor: followed.ap_id,
 399              object: follow_activity.data["id"],
 400              local: false
 401            }) do
 402       User.unfollow(follower, followed)
 403
 404       {:ok, activity}
 405     else
 406       _e -> :error
 407     end
 408   end
 409
 410   def handle_incoming(
 411         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data
 412       ) do
 413     with actor <- get_actor(data),
 414          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 415          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 416          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 417       {:ok, activity}
 418     else
 419       _e -> :error
 420     end
 421   end
 422
 423   def handle_incoming(
 424         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data
 425       ) do
 426     with actor <- get_actor(data),
 427          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 428          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 429          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 430       {:ok, activity}
 431     else
 432       _e -> :error
 433     end
 434   end
 435
 436   def handle_incoming(
 437         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 438           data
 439       )
 440       when object_type in ["Person", "Application", "Service", "Organization"] do
 441     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 442       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 443
 444       banner = new_user_data[:info]["banner"]
 445       locked = new_user_data[:info]["locked"] || false
 446
 447       update_data =
 448         new_user_data
 449         |> Map.take([:name, :bio, :avatar])
 450         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 451
 452       actor
 453       |> User.upgrade_changeset(update_data)
 454       |> User.update_and_set_cache()
 455
 456       ActivityPub.update(%{
 457         local: false,
 458         to: data["to"] || [],
 459         cc: data["cc"] || [],
 460         object: object,
 461         actor: actor_id
 462       })
 463     else
 464       e ->
 465         Logger.error(e)
 466         :error
 467     end
 468   end
 469
 470   # TODO: We presently assume that any actor on the same origin domain as the object being
 471   # deleted has the rights to delete that object.  A better way to validate whether or not
 472   # the object should be deleted is to refetch the object URI, which should return either
 473   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 474   # place.
 475   def handle_incoming(
 476         %{"type" => "Delete", "object" => object_id, "actor" => _actor, "id" => _id} = data
 477       ) do
 478     object_id = Utils.get_ap_id(object_id)
 479
 480     with actor <- get_actor(data),
 481          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 482          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 483          :ok <- contain_origin(actor.ap_id, object.data),
 484          {:ok, activity} <- ActivityPub.delete(object, false) do
 485       {:ok, activity}
 486     else
 487       _e -> :error
 488     end
 489   end
 490
 491   def handle_incoming(
 492         %{
 493           "type" => "Undo",
 494           "object" => %{"type" => "Announce", "object" => object_id},
 495           "actor" => actor,
 496           "id" => id
 497         } = data
 498       ) do
 499     with actor <- get_actor(data),
 500          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 501          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 502          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 503       {:ok, activity}
 504     else
 505       _e -> :error
 506     end
 507   end
 508
 509   def handle_incoming(
 510         %{
 511           "type" => "Undo",
 512           "object" => %{"type" => "Follow", "object" => followed},
 513           "actor" => follower,
 514           "id" => id
 515         } = _data
 516       ) do
 517     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 518          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 519          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 520       User.unfollow(follower, followed)
 521       {:ok, activity}
 522     else
 523       e -> :error
 524     end
 525   end
 526
 527   def handle_incoming(
 528         %{
 529           "type" => "Undo",
 530           "object" => %{"type" => "Block", "object" => blocked},
 531           "actor" => blocker,
 532           "id" => id
 533         } = _data
 534       ) do
 535     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 536          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 537          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 538          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 539       User.unblock(blocker, blocked)
 540       {:ok, activity}
 541     else
 542       e -> :error
 543     end
 544   end
 545
 546   def handle_incoming(
 547         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 548       ) do
 549     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 550          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 551          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 552          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 553       User.unfollow(blocker, blocked)
 554       User.block(blocker, blocked)
 555       {:ok, activity}
 556     else
 557       e -> :error
 558     end
 559   end
 560
 561   def handle_incoming(
 562         %{
 563           "type" => "Undo",
 564           "object" => %{"type" => "Like", "object" => object_id},
 565           "actor" => actor,
 566           "id" => id
 567         } = data
 568       ) do
 569     with actor <- get_actor(data),
 570          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 571          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 572          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 573       {:ok, activity}
 574     else
 575       _e -> :error
 576     end
 577   end
 578
 579   def handle_incoming(_), do: :error
 580
 581   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 582   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 583
 584   def get_obj_helper(id) do
 585     if object = Object.normalize(id), do: {:ok, object}, else: nil
 586   end
 587
 588   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 589     with false <- String.starts_with?(inReplyTo, "http"),
 590          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 591       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 592     else
 593       _e -> object
 594     end
 595   end
 596
 597   def set_reply_to_uri(obj), do: obj
 598
 599   # Prepares the object of an outgoing create activity.
 600   def prepare_object(object) do
 601     object
 602     |> set_sensitive
 603     |> add_hashtags
 604     |> add_mention_tags
 605     |> add_emoji_tags
 606     |> add_attributed_to
 607     |> prepare_attachments
 608     |> set_conversation
 609     |> set_reply_to_uri
 610     |> strip_internal_fields
 611     |> strip_internal_tags
 612   end
 613
 614   #  @doc
 615   #  """
 616   #  internal -> Mastodon
 617   #  """
 618
 619   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 620     object =
 621       object
 622       |> prepare_object
 623
 624     data =
 625       data
 626       |> Map.put("object", object)
 627       |> Map.merge(Utils.make_json_ld_header())
 628
 629     {:ok, data}
 630   end
 631
 632   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 633   # because of course it does.
 634   def prepare_outgoing(%{"type" => "Accept"} = data) do
 635     with follow_activity <- Activity.normalize(data["object"]) do
 636       object = %{
 637         "actor" => follow_activity.actor,
 638         "object" => follow_activity.data["object"],
 639         "id" => follow_activity.data["id"],
 640         "type" => "Follow"
 641       }
 642
 643       data =
 644         data
 645         |> Map.put("object", object)
 646         |> Map.merge(Utils.make_json_ld_header())
 647
 648       {:ok, data}
 649     end
 650   end
 651
 652   def prepare_outgoing(%{"type" => "Reject"} = data) do
 653     with follow_activity <- Activity.normalize(data["object"]) do
 654       object = %{
 655         "actor" => follow_activity.actor,
 656         "object" => follow_activity.data["object"],
 657         "id" => follow_activity.data["id"],
 658         "type" => "Follow"
 659       }
 660
 661       data =
 662         data
 663         |> Map.put("object", object)
 664         |> Map.merge(Utils.make_json_ld_header())
 665
 666       {:ok, data}
 667     end
 668   end
 669
 670   def prepare_outgoing(%{"type" => _type} = data) do
 671     data =
 672       data
 673       |> maybe_fix_object_url
 674       |> Map.merge(Utils.make_json_ld_header())
 675
 676     {:ok, data}
 677   end
 678
 679   def maybe_fix_object_url(data) do
 680     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 681       case fetch_obj_helper(data["object"]) do
 682         {:ok, relative_object} ->
 683           if relative_object.data["external_url"] do
 684             _data =
 685               data
 686               |> Map.put("object", relative_object.data["external_url"])
 687           else
 688             data
 689           end
 690
 691         e ->
 692           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 693           data
 694       end
 695     else
 696       data
 697     end
 698   end
 699
 700   def add_hashtags(object) do
 701     tags =
 702       (object["tag"] || [])
 703       |> Enum.map(fn tag ->
 704         %{
 705           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 706           "name" => "##{tag}",
 707           "type" => "Hashtag"
 708         }
 709       end)
 710
 711     object
 712     |> Map.put("tag", tags)
 713   end
 714
 715   def add_mention_tags(object) do
 716     mentions =
 717       object
 718       |> Utils.get_notified_from_object()
 719       |> Enum.map(fn user ->
 720         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 721       end)
 722
 723     tags = object["tag"] || []
 724
 725     object
 726     |> Map.put("tag", tags ++ mentions)
 727   end
 728
 729   # TODO: we should probably send mtime instead of unix epoch time for updated
 730   def add_emoji_tags(object) do
 731     tags = object["tag"] || []
 732     emoji = object["emoji"] || []
 733
 734     out =
 735       emoji
 736       |> Enum.map(fn {name, url} ->
 737         %{
 738           "icon" => %{"url" => url, "type" => "Image"},
 739           "name" => ":" <> name <> ":",
 740           "type" => "Emoji",
 741           "updated" => "1970-01-01T00:00:00Z",
 742           "id" => url
 743         }
 744       end)
 745
 746     object
 747     |> Map.put("tag", tags ++ out)
 748   end
 749
 750   def set_conversation(object) do
 751     Map.put(object, "conversation", object["context"])
 752   end
 753
 754   def set_sensitive(object) do
 755     tags = object["tag"] || []
 756     Map.put(object, "sensitive", "nsfw" in tags)
 757   end
 758
 759   def add_attributed_to(object) do
 760     attributedTo = object["attributedTo"] || object["actor"]
 761
 762     object
 763     |> Map.put("attributedTo", attributedTo)
 764   end
 765
 766   def prepare_attachments(object) do
 767     attachments =
 768       (object["attachment"] || [])
 769       |> Enum.map(fn data ->
 770         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 771         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 772       end)
 773
 774     object
 775     |> Map.put("attachment", attachments)
 776   end
 777
 778   defp strip_internal_fields(object) do
 779     object
 780     |> Map.drop([
 781       "likes",
 782       "like_count",
 783       "announcements",
 784       "announcement_count",
 785       "emoji",
 786       "context_id"
 787     ])
 788   end
 789
 790   defp strip_internal_tags(%{"tag" => tags} = object) do
 791     tags =
 792       tags
 793       |> Enum.filter(fn x -> is_map(x) end)
 794
 795     object
 796     |> Map.put("tag", tags)
 797   end
 798
 799   defp strip_internal_tags(object), do: object
 800
 801   defp user_upgrade_task(user) do
 802     old_follower_address = User.ap_followers(user)
 803
 804     q =
 805       from(
 806         u in User,
 807         where: ^old_follower_address in u.following,
 808         update: [
 809           set: [
 810             following:
 811               fragment(
 812                 "array_replace(?,?,?)",
 813                 u.following,
 814                 ^old_follower_address,
 815                 ^user.follower_address
 816               )
 817           ]
 818         ]
 819       )
 820
 821     Repo.update_all(q, [])
 822
 823     maybe_retire_websub(user.ap_id)
 824
 825     # Only do this for recent activties, don't go through the whole db.
 826     # Only look at the last 1000 activities.
 827     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 828
 829     q =
 830       from(
 831         a in Activity,
 832         where: ^old_follower_address in a.recipients,
 833         where: a.id > ^since,
 834         update: [
 835           set: [
 836             recipients:
 837               fragment(
 838                 "array_replace(?,?,?)",
 839                 a.recipients,
 840                 ^old_follower_address,
 841                 ^user.follower_address
 842               )
 843           ]
 844         ]
 845       )
 846
 847     Repo.update_all(q, [])
 848   end
 849
 850   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 851     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 852          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 853       data =
 854         data
 855         |> Map.put(:info, Map.merge(user.info, data[:info]))
 856
 857       already_ap = User.ap_enabled?(user)
 858
 859       {:ok, user} =
 860         User.upgrade_changeset(user, data)
 861         |> Repo.update()
 862
 863       if !already_ap do
 864         # This could potentially take a long time, do it in the background
 865         if async do
 866           Task.start(fn ->
 867             user_upgrade_task(user)
 868           end)
 869         else
 870           user_upgrade_task(user)
 871         end
 872       end
 873
 874       {:ok, user}
 875     else
 876       e -> e
 877     end
 878   end
 879
 880   def maybe_retire_websub(ap_id) do
 881     # some sanity checks
 882     if is_binary(ap_id) && String.length(ap_id) > 8 do
 883       q =
 884         from(
 885           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 886           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 887         )
 888
 889       Repo.delete_all(q)
 890     end
 891   end
 892
 893   def maybe_fix_user_url(data) do
 894     if is_map(data["url"]) do
 895       Map.put(data, "url", data["url"]["href"])
 896     else
 897       data
 898     end
 899   end
 900
 901   def maybe_fix_user_object(data) do
 902     data
 903     |> maybe_fix_user_url
 904   end
 905 end