git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.User
  11   alias Pleroma.Object
  12   alias Pleroma.Repo
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.ActivityPub.Utils
  15
  16   import Ecto.Query
  17
  18   require Logger
  19
  20   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  21     actor
  22   end
  23
  24   def get_actor(%{"actor" => actor}) when is_list(actor) do
  25     if is_binary(Enum.at(actor, 0)) do
  26       Enum.at(actor, 0)
  27     else
  28       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  29       |> Map.get("id")
  30     end
  31   end
  32
  33   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  34     id
  35   end
  36
  37   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  38     get_actor(%{"actor" => actor})
  39   end
  40
  41   @doc """
  42   Checks that an imported AP object's actor matches the domain it came from.
  43   """
  44   def contain_origin(_id, %{"actor" => nil}), do: :error
  45
  46   def contain_origin(id, %{"actor" => _actor} = params) do
  47     id_uri = URI.parse(id)
  48     actor_uri = URI.parse(get_actor(params))
  49
  50     if id_uri.host == actor_uri.host do
  51       :ok
  52     else
  53       :error
  54     end
  55   end
  56
  57   def contain_origin_from_id(_id, %{"id" => nil}), do: :error
  58
  59   def contain_origin_from_id(id, %{"id" => other_id} = _params) do
  60     id_uri = URI.parse(id)
  61     other_uri = URI.parse(other_id)
  62
  63     if id_uri.host == other_uri.host do
  64       :ok
  65     else
  66       :error
  67     end
  68   end
  69
  70   @doc """
  71   Modifies an incoming AP object (mastodon format) to our internal format.
  72   """
  73   def fix_object(object) do
  74     object
  75     |> fix_actor
  76     |> fix_url
  77     |> fix_attachments
  78     |> fix_context
  79     |> fix_in_reply_to
  80     |> fix_emoji
  81     |> fix_tag
  82     |> fix_content_map
  83     |> fix_likes
  84     |> fix_addressing
  85   end
  86
  87   def fix_addressing_list(map, field) do
  88     if is_binary(map[field]) do
  89       map
  90       |> Map.put(field, [map[field]])
  91     else
  92       map
  93     end
  94   end
  95
  96   def fix_explicit_addressing(%{"to" => to, "cc" => cc} = object, explicit_mentions) do
  97     explicit_to =
  98       to
  99       |> Enum.filter(fn x -> x in explicit_mentions end)
 100
 101     explicit_cc =
 102       to
 103       |> Enum.filter(fn x -> x not in explicit_mentions end)
 104
 105     final_cc =
 106       (cc ++ explicit_cc)
 107       |> Enum.uniq()
 108
 109     object
 110     |> Map.put("to", explicit_to)
 111     |> Map.put("cc", final_cc)
 112   end
 113
 114   def fix_explicit_addressing(object, _explicit_mentions), do: object
 115
 116   # if directMessage flag is set to true, leave the addressing alone
 117   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
 118
 119   def fix_explicit_addressing(object) do
 120     explicit_mentions =
 121       object
 122       |> Utils.determine_explicit_mentions()
 123
 124     explicit_mentions = explicit_mentions ++ ["https://www.w3.org/ns/activitystreams#Public"]
 125
 126     object
 127     |> fix_explicit_addressing(explicit_mentions)
 128   end
 129
 130   def fix_addressing(object) do
 131     object
 132     |> fix_addressing_list("to")
 133     |> fix_addressing_list("cc")
 134     |> fix_addressing_list("bto")
 135     |> fix_addressing_list("bcc")
 136     |> fix_explicit_addressing
 137   end
 138
 139   def fix_actor(%{"attributedTo" => actor} = object) do
 140     object
 141     |> Map.put("actor", get_actor(%{"actor" => actor}))
 142   end
 143
 144   # Check for standardisation
 145   # This is what Peertube does
 146   # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
 147   # Prismo returns only an integer (count) as "likes"
 148   def fix_likes(%{"likes" => likes} = object) when not is_map(likes) do
 149     object
 150     |> Map.put("likes", [])
 151     |> Map.put("like_count", 0)
 152   end
 153
 154   def fix_likes(object) do
 155     object
 156   end
 157
 158   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 159       when not is_nil(in_reply_to) do
 160     in_reply_to_id =
 161       cond do
 162         is_bitstring(in_reply_to) ->
 163           in_reply_to
 164
 165         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 166           in_reply_to["id"]
 167
 168         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 169           Enum.at(in_reply_to, 0)
 170
 171         # Maybe I should output an error too?
 172         true ->
 173           ""
 174       end
 175
 176     case fetch_obj_helper(in_reply_to_id) do
 177       {:ok, replied_object} ->
 178         with %Activity{} = activity <-
 179                Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 180           object
 181           |> Map.put("inReplyTo", replied_object.data["id"])
 182           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 183           |> Map.put("inReplyToStatusId", activity.id)
 184           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 185           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 186         else
 187           e ->
 188             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 189             object
 190         end
 191
 192       e ->
 193         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 194         object
 195     end
 196   end
 197
 198   def fix_in_reply_to(object), do: object
 199
 200   def fix_context(object) do
 201     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 202
 203     object
 204     |> Map.put("context", context)
 205     |> Map.put("conversation", context)
 206   end
 207
 208   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 209     attachments =
 210       attachment
 211       |> Enum.map(fn data ->
 212         media_type = data["mediaType"] || data["mimeType"]
 213         href = data["url"] || data["href"]
 214
 215         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 216
 217         data
 218         |> Map.put("mediaType", media_type)
 219         |> Map.put("url", url)
 220       end)
 221
 222     object
 223     |> Map.put("attachment", attachments)
 224   end
 225
 226   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 227     Map.put(object, "attachment", [attachment])
 228     |> fix_attachments()
 229   end
 230
 231   def fix_attachments(object), do: object
 232
 233   def fix_url(%{"url" => url} = object) when is_map(url) do
 234     object
 235     |> Map.put("url", url["href"])
 236   end
 237
 238   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 239     first_element = Enum.at(url, 0)
 240
 241     link_element =
 242       url
 243       |> Enum.filter(fn x -> is_map(x) end)
 244       |> Enum.filter(fn x -> x["mimeType"] == "text/html" end)
 245       |> Enum.at(0)
 246
 247     object
 248     |> Map.put("attachment", [first_element])
 249     |> Map.put("url", link_element["href"])
 250   end
 251
 252   def fix_url(%{"type" => object_type, "url" => url} = object)
 253       when object_type != "Video" and is_list(url) do
 254     first_element = Enum.at(url, 0)
 255
 256     url_string =
 257       cond do
 258         is_bitstring(first_element) -> first_element
 259         is_map(first_element) -> first_element["href"] || ""
 260         true -> ""
 261       end
 262
 263     object
 264     |> Map.put("url", url_string)
 265   end
 266
 267   def fix_url(object), do: object
 268
 269   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 270     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 271
 272     emoji =
 273       emoji
 274       |> Enum.reduce(%{}, fn data, mapping ->
 275         name = String.trim(data["name"], ":")
 276
 277         mapping |> Map.put(name, data["icon"]["url"])
 278       end)
 279
 280     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 281     emoji = Map.merge(object["emoji"] || %{}, emoji)
 282
 283     object
 284     |> Map.put("emoji", emoji)
 285   end
 286
 287   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 288     name = String.trim(tag["name"], ":")
 289     emoji = %{name => tag["icon"]["url"]}
 290
 291     object
 292     |> Map.put("emoji", emoji)
 293   end
 294
 295   def fix_emoji(object), do: object
 296
 297   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 298     tags =
 299       tag
 300       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 301       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 302
 303     combined = tag ++ tags
 304
 305     object
 306     |> Map.put("tag", combined)
 307   end
 308
 309   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 310     combined = [tag, String.slice(hashtag, 1..-1)]
 311
 312     object
 313     |> Map.put("tag", combined)
 314   end
 315
 316   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 317
 318   def fix_tag(object), do: object
 319
 320   # content map usually only has one language so this will do for now.
 321   def fix_content_map(%{"contentMap" => content_map} = object) do
 322     content_groups = Map.to_list(content_map)
 323     {_, content} = Enum.at(content_groups, 0)
 324
 325     object
 326     |> Map.put("content", content)
 327   end
 328
 329   def fix_content_map(object), do: object
 330
 331   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 332     with true <- id =~ "follows",
 333          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 334          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 335       {:ok, activity}
 336     else
 337       _ -> {:error, nil}
 338     end
 339   end
 340
 341   defp mastodon_follow_hack(_, _), do: {:error, nil}
 342
 343   defp get_follow_activity(follow_object, followed) do
 344     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 345          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 346       {:ok, activity}
 347     else
 348       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 349       {:activity, nil} ->
 350         mastodon_follow_hack(follow_object, followed)
 351
 352       _ ->
 353         {:error, nil}
 354     end
 355   end
 356
 357   # disallow objects with bogus IDs
 358   def handle_incoming(%{"id" => nil}), do: :error
 359   def handle_incoming(%{"id" => ""}), do: :error
 360   # length of https:// = 8, should validate better, but good enough for now.
 361   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 362
 363   # TODO: validate those with a Ecto scheme
 364   # - tags
 365   # - emoji
 366   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 367       when objtype in ["Article", "Note", "Video", "Page"] do
 368     actor = get_actor(data)
 369
 370     data =
 371       Map.put(data, "actor", actor)
 372       |> fix_addressing
 373
 374     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 375          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 376       object = fix_object(data["object"])
 377
 378       params = %{
 379         to: data["to"],
 380         object: object,
 381         actor: user,
 382         context: object["conversation"],
 383         local: false,
 384         published: data["published"],
 385         additional:
 386           Map.take(data, [
 387             "cc",
 388             "directMessage",
 389             "id"
 390           ])
 391       }
 392
 393       ActivityPub.create(params)
 394     else
 395       %Activity{} = activity -> {:ok, activity}
 396       _e -> :error
 397     end
 398   end
 399
 400   def handle_incoming(
 401         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 402       ) do
 403     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 404          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 405          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 406       if not User.locked?(followed) do
 407         ActivityPub.accept(%{
 408           to: [follower.ap_id],
 409           actor: followed,
 410           object: data,
 411           local: true
 412         })
 413
 414         User.follow(follower, followed)
 415       end
 416
 417       {:ok, activity}
 418     else
 419       _e -> :error
 420     end
 421   end
 422
 423   def handle_incoming(
 424         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 425       ) do
 426     with actor <- get_actor(data),
 427          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 428          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 429          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 430          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 431          {:ok, activity} <-
 432            ActivityPub.accept(%{
 433              to: follow_activity.data["to"],
 434              type: "Accept",
 435              actor: followed,
 436              object: follow_activity.data["id"],
 437              local: false
 438            }) do
 439       if not User.following?(follower, followed) do
 440         {:ok, _follower} = User.follow(follower, followed)
 441       end
 442
 443       {:ok, activity}
 444     else
 445       _e -> :error
 446     end
 447   end
 448
 449   def handle_incoming(
 450         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 451       ) do
 452     with actor <- get_actor(data),
 453          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 454          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 455          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 456          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 457          {:ok, activity} <-
 458            ActivityPub.reject(%{
 459              to: follow_activity.data["to"],
 460              type: "Reject",
 461              actor: followed,
 462              object: follow_activity.data["id"],
 463              local: false
 464            }) do
 465       User.unfollow(follower, followed)
 466
 467       {:ok, activity}
 468     else
 469       _e -> :error
 470     end
 471   end
 472
 473   def handle_incoming(
 474         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data
 475       ) do
 476     with actor <- get_actor(data),
 477          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 478          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 479          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 480       {:ok, activity}
 481     else
 482       _e -> :error
 483     end
 484   end
 485
 486   def handle_incoming(
 487         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data
 488       ) do
 489     with actor <- get_actor(data),
 490          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 491          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 492          public <- ActivityPub.is_public?(data),
 493          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 494       {:ok, activity}
 495     else
 496       _e -> :error
 497     end
 498   end
 499
 500   def handle_incoming(
 501         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 502           data
 503       )
 504       when object_type in ["Person", "Application", "Service", "Organization"] do
 505     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 506       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 507
 508       banner = new_user_data[:info]["banner"]
 509       locked = new_user_data[:info]["locked"] || false
 510
 511       update_data =
 512         new_user_data
 513         |> Map.take([:name, :bio, :avatar])
 514         |> Map.put(:info, %{"banner" => banner, "locked" => locked})
 515
 516       actor
 517       |> User.upgrade_changeset(update_data)
 518       |> User.update_and_set_cache()
 519
 520       ActivityPub.update(%{
 521         local: false,
 522         to: data["to"] || [],
 523         cc: data["cc"] || [],
 524         object: object,
 525         actor: actor_id
 526       })
 527     else
 528       e ->
 529         Logger.error(e)
 530         :error
 531     end
 532   end
 533
 534   # TODO: We presently assume that any actor on the same origin domain as the object being
 535   # deleted has the rights to delete that object.  A better way to validate whether or not
 536   # the object should be deleted is to refetch the object URI, which should return either
 537   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 538   # place.
 539   def handle_incoming(
 540         %{"type" => "Delete", "object" => object_id, "actor" => _actor, "id" => _id} = data
 541       ) do
 542     object_id = Utils.get_ap_id(object_id)
 543
 544     with actor <- get_actor(data),
 545          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 546          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 547          :ok <- contain_origin(actor.ap_id, object.data),
 548          {:ok, activity} <- ActivityPub.delete(object, false) do
 549       {:ok, activity}
 550     else
 551       _e -> :error
 552     end
 553   end
 554
 555   def handle_incoming(
 556         %{
 557           "type" => "Undo",
 558           "object" => %{"type" => "Announce", "object" => object_id},
 559           "actor" => _actor,
 560           "id" => id
 561         } = data
 562       ) do
 563     with actor <- get_actor(data),
 564          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 565          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 566          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 567       {:ok, activity}
 568     else
 569       _e -> :error
 570     end
 571   end
 572
 573   def handle_incoming(
 574         %{
 575           "type" => "Undo",
 576           "object" => %{"type" => "Follow", "object" => followed},
 577           "actor" => follower,
 578           "id" => id
 579         } = _data
 580       ) do
 581     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 582          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 583          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 584       User.unfollow(follower, followed)
 585       {:ok, activity}
 586     else
 587       _e -> :error
 588     end
 589   end
 590
 591   def handle_incoming(
 592         %{
 593           "type" => "Undo",
 594           "object" => %{"type" => "Block", "object" => blocked},
 595           "actor" => blocker,
 596           "id" => id
 597         } = _data
 598       ) do
 599     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 600          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 601          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 602          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 603       User.unblock(blocker, blocked)
 604       {:ok, activity}
 605     else
 606       _e -> :error
 607     end
 608   end
 609
 610   def handle_incoming(
 611         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data
 612       ) do
 613     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 614          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 615          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 616          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 617       User.unfollow(blocker, blocked)
 618       User.block(blocker, blocked)
 619       {:ok, activity}
 620     else
 621       _e -> :error
 622     end
 623   end
 624
 625   def handle_incoming(
 626         %{
 627           "type" => "Undo",
 628           "object" => %{"type" => "Like", "object" => object_id},
 629           "actor" => _actor,
 630           "id" => id
 631         } = data
 632       ) do
 633     with actor <- get_actor(data),
 634          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 635          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 636          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 637       {:ok, activity}
 638     else
 639       _e -> :error
 640     end
 641   end
 642
 643   def handle_incoming(_), do: :error
 644
 645   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 646   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 647
 648   def get_obj_helper(id) do
 649     if object = Object.normalize(id), do: {:ok, object}, else: nil
 650   end
 651
 652   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) when is_binary(inReplyTo) do
 653     with false <- String.starts_with?(inReplyTo, "http"),
 654          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 655       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 656     else
 657       _e -> object
 658     end
 659   end
 660
 661   def set_reply_to_uri(obj), do: obj
 662
 663   # Prepares the object of an outgoing create activity.
 664   def prepare_object(object) do
 665     object
 666     |> set_sensitive
 667     |> add_hashtags
 668     |> add_mention_tags
 669     |> add_emoji_tags
 670     |> add_attributed_to
 671     |> add_likes
 672     |> prepare_attachments
 673     |> set_conversation
 674     |> set_reply_to_uri
 675     |> strip_internal_fields
 676     |> strip_internal_tags
 677   end
 678
 679   #  @doc
 680   #  """
 681   #  internal -> Mastodon
 682   #  """
 683
 684   def prepare_outgoing(%{"type" => "Create", "object" => object} = data) do
 685     object =
 686       object
 687       |> prepare_object
 688
 689     data =
 690       data
 691       |> Map.put("object", object)
 692       |> Map.merge(Utils.make_json_ld_header())
 693
 694     {:ok, data}
 695   end
 696
 697   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 698   # because of course it does.
 699   def prepare_outgoing(%{"type" => "Accept"} = data) do
 700     with follow_activity <- Activity.normalize(data["object"]) do
 701       object = %{
 702         "actor" => follow_activity.actor,
 703         "object" => follow_activity.data["object"],
 704         "id" => follow_activity.data["id"],
 705         "type" => "Follow"
 706       }
 707
 708       data =
 709         data
 710         |> Map.put("object", object)
 711         |> Map.merge(Utils.make_json_ld_header())
 712
 713       {:ok, data}
 714     end
 715   end
 716
 717   def prepare_outgoing(%{"type" => "Reject"} = data) do
 718     with follow_activity <- Activity.normalize(data["object"]) do
 719       object = %{
 720         "actor" => follow_activity.actor,
 721         "object" => follow_activity.data["object"],
 722         "id" => follow_activity.data["id"],
 723         "type" => "Follow"
 724       }
 725
 726       data =
 727         data
 728         |> Map.put("object", object)
 729         |> Map.merge(Utils.make_json_ld_header())
 730
 731       {:ok, data}
 732     end
 733   end
 734
 735   def prepare_outgoing(%{"type" => _type} = data) do
 736     data =
 737       data
 738       |> maybe_fix_object_url
 739       |> Map.merge(Utils.make_json_ld_header())
 740
 741     {:ok, data}
 742   end
 743
 744   def maybe_fix_object_url(data) do
 745     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 746       case fetch_obj_helper(data["object"]) do
 747         {:ok, relative_object} ->
 748           if relative_object.data["external_url"] do
 749             _data =
 750               data
 751               |> Map.put("object", relative_object.data["external_url"])
 752           else
 753             data
 754           end
 755
 756         e ->
 757           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 758           data
 759       end
 760     else
 761       data
 762     end
 763   end
 764
 765   def add_hashtags(object) do
 766     tags =
 767       (object["tag"] || [])
 768       |> Enum.map(fn
 769         # Expand internal representation tags into AS2 tags.
 770         tag when is_binary(tag) ->
 771           %{
 772             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 773             "name" => "##{tag}",
 774             "type" => "Hashtag"
 775           }
 776
 777         # Do not process tags which are already AS2 tag objects.
 778         tag when is_map(tag) ->
 779           tag
 780       end)
 781
 782     object
 783     |> Map.put("tag", tags)
 784   end
 785
 786   def add_mention_tags(object) do
 787     mentions =
 788       object
 789       |> Utils.get_notified_from_object()
 790       |> Enum.map(fn user ->
 791         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 792       end)
 793
 794     tags = object["tag"] || []
 795
 796     object
 797     |> Map.put("tag", tags ++ mentions)
 798   end
 799
 800   # TODO: we should probably send mtime instead of unix epoch time for updated
 801   def add_emoji_tags(object) do
 802     tags = object["tag"] || []
 803     emoji = object["emoji"] || []
 804
 805     out =
 806       emoji
 807       |> Enum.map(fn {name, url} ->
 808         %{
 809           "icon" => %{"url" => url, "type" => "Image"},
 810           "name" => ":" <> name <> ":",
 811           "type" => "Emoji",
 812           "updated" => "1970-01-01T00:00:00Z",
 813           "id" => url
 814         }
 815       end)
 816
 817     object
 818     |> Map.put("tag", tags ++ out)
 819   end
 820
 821   def set_conversation(object) do
 822     Map.put(object, "conversation", object["context"])
 823   end
 824
 825   def set_sensitive(object) do
 826     tags = object["tag"] || []
 827     Map.put(object, "sensitive", "nsfw" in tags)
 828   end
 829
 830   def add_attributed_to(object) do
 831     attributedTo = object["attributedTo"] || object["actor"]
 832
 833     object
 834     |> Map.put("attributedTo", attributedTo)
 835   end
 836
 837   def add_likes(%{"id" => id, "like_count" => likes} = object) do
 838     likes = %{
 839       "id" => "#{id}/likes",
 840       "first" => "#{id}/likes?page=1",
 841       "type" => "OrderedCollection",
 842       "totalItems" => likes
 843     }
 844
 845     object
 846     |> Map.put("likes", likes)
 847   end
 848
 849   def add_likes(object) do
 850     object
 851   end
 852
 853   def prepare_attachments(object) do
 854     attachments =
 855       (object["attachment"] || [])
 856       |> Enum.map(fn data ->
 857         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 858         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 859       end)
 860
 861     object
 862     |> Map.put("attachment", attachments)
 863   end
 864
 865   defp strip_internal_fields(object) do
 866     object
 867     |> Map.drop([
 868       "like_count",
 869       "announcements",
 870       "announcement_count",
 871       "emoji",
 872       "context_id"
 873     ])
 874   end
 875
 876   defp strip_internal_tags(%{"tag" => tags} = object) do
 877     tags =
 878       tags
 879       |> Enum.filter(fn x -> is_map(x) end)
 880
 881     object
 882     |> Map.put("tag", tags)
 883   end
 884
 885   defp strip_internal_tags(object), do: object
 886
 887   defp user_upgrade_task(user) do
 888     old_follower_address = User.ap_followers(user)
 889
 890     q =
 891       from(
 892         u in User,
 893         where: ^old_follower_address in u.following,
 894         update: [
 895           set: [
 896             following:
 897               fragment(
 898                 "array_replace(?,?,?)",
 899                 u.following,
 900                 ^old_follower_address,
 901                 ^user.follower_address
 902               )
 903           ]
 904         ]
 905       )
 906
 907     Repo.update_all(q, [])
 908
 909     maybe_retire_websub(user.ap_id)
 910
 911     q =
 912       from(
 913         a in Activity,
 914         where: ^old_follower_address in a.recipients,
 915         update: [
 916           set: [
 917             recipients:
 918               fragment(
 919                 "array_replace(?,?,?)",
 920                 a.recipients,
 921                 ^old_follower_address,
 922                 ^user.follower_address
 923               )
 924           ]
 925         ]
 926       )
 927
 928     Repo.update_all(q, [])
 929   end
 930
 931   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 932     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 933          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 934       already_ap = User.ap_enabled?(user)
 935
 936       {:ok, user} =
 937         User.upgrade_changeset(user, data)
 938         |> Repo.update()
 939
 940       if !already_ap do
 941         # This could potentially take a long time, do it in the background
 942         if async do
 943           Task.start(fn ->
 944             user_upgrade_task(user)
 945           end)
 946         else
 947           user_upgrade_task(user)
 948         end
 949       end
 950
 951       {:ok, user}
 952     else
 953       e -> e
 954     end
 955   end
 956
 957   def maybe_retire_websub(ap_id) do
 958     # some sanity checks
 959     if is_binary(ap_id) && String.length(ap_id) > 8 do
 960       q =
 961         from(
 962           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 963           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 964         )
 965
 966       Repo.delete_all(q)
 967     end
 968   end
 969
 970   def maybe_fix_user_url(data) do
 971     if is_map(data["url"]) do
 972       Map.put(data, "url", data["url"]["href"])
 973     else
 974       data
 975     end
 976   end
 977
 978   def maybe_fix_user_object(data) do
 979     data
 980     |> maybe_fix_user_url
 981   end
 982 end