git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type == "Person" end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => actor}) when is_map(actor) do
  30     actor["id"]
  31   end
  32
  33   @doc """
  34   Checks that an imported AP object's actor matches the domain it came from.
  35   """
  36   def contain_origin(id, %{"actor" => actor} = params) do
  37     id_uri = URI.parse(id)
  38     actor_uri = URI.parse(get_actor(params))
  39
  40     if id_uri.host == actor_uri.host do
  41       :ok
  42     else
  43       :error
  44     end
  45   end
  46
  47   @doc """
  48   Modifies an incoming AP object (mastodon format) to our internal format.
  49   """
  50   def fix_object(object) do
  51     object
  52     |> fix_actor
  53     |> fix_attachments
  54     |> fix_context
  55     |> fix_in_reply_to
  56     |> fix_emoji
  57     |> fix_tag
  58     |> fix_content_map
  59     |> fix_likes
  60     |> fix_addressing
  61   end
  62
  63   def fix_addressing_list(map, field) do
  64     if is_binary(map[field]) do
  65       map
  66       |> Map.put(field, [map[field]])
  67     else
  68       map
  69     end
  70   end
  71
  72   def fix_addressing(map) do
  73     map
  74     |> fix_addressing_list("to")
  75     |> fix_addressing_list("cc")
  76     |> fix_addressing_list("bto")
  77     |> fix_addressing_list("bcc")
  78   end
  79
  80   def fix_actor(%{"attributedTo" => actor} = object) do
  81     object
  82     |> Map.put("actor", get_actor(%{"actor" => actor}))
  83   end
  84
  85   def fix_likes(%{"likes" => likes} = object)
  86       when is_bitstring(likes) do
  87     # Check for standardisation
  88     # This is what Peertube does
  89     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
  90     object
  91     |> Map.put("likes", [])
  92     |> Map.put("like_count", 0)
  93   end
  94
  95   def fix_likes(object) do
  96     object
  97   end
  98
  99   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
 100       when not is_nil(in_reply_to_id) do
 101     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
 102       {:ok, replied_object} ->
 103         with %Activity{} = activity <-
 104                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 105           object
 106           |> Map.put("inReplyTo", replied_object.data["id"])
 107           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 108           |> Map.put("inReplyToStatusId", activity.id)
 109           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 110           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 111         else
 112           e ->
 113             Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 114             object
 115         end
 116
 117       e ->
 118         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 119         object
 120     end
 121   end
 122
 123   def fix_in_reply_to(object), do: object
 124
 125   def fix_context(object) do
 126     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 127
 128     object
 129     |> Map.put("context", context)
 130     |> Map.put("conversation", context)
 131   end
 132
 133   def fix_attachments(object) do
 134     attachments =
 135       (object["attachment"] || [])
 136       |> Enum.map(fn data ->
 137         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 138         Map.put(data, "url", url)
 139       end)
 140
 141     object
 142     |> Map.put("attachment", attachments)
 143   end
 144
 145   def fix_emoji(object) do
 146     tags = object["tag"] || []
 147     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 148
 149     emoji =
 150       emoji
 151       |> Enum.reduce(%{}, fn data, mapping ->
 152         name = data["name"]
 153
 154         name =
 155           if String.starts_with?(name, ":") do
 156             name |> String.slice(1..-2)
 157           else
 158             name
 159           end
 160
 161         mapping |> Map.put(name, data["icon"]["url"])
 162       end)
 163
 164     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 165     emoji = Map.merge(object["emoji"] || %{}, emoji)
 166
 167     object
 168     |> Map.put("emoji", emoji)
 169   end
 170
 171   def fix_tag(object) do
 172     tags =
 173       (object["tag"] || [])
 174       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 175       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 176
 177     combined = (object["tag"] || []) ++ tags
 178
 179     object
 180     |> Map.put("tag", combined)
 181   end
 182
 183   # content map usually only has one language so this will do for now.
 184   def fix_content_map(%{"contentMap" => content_map} = object) do
 185     content_groups = Map.to_list(content_map)
 186     {_, content} = Enum.at(content_groups, 0)
 187
 188     object
 189     |> Map.put("content", content)
 190   end
 191
 192   def fix_content_map(object), do: object
 193
 194   # disallow objects with bogus IDs
 195   def handle_incoming(%{"id" => nil}), do: :error
 196   def handle_incoming(%{"id" => ""}), do: :error
 197   # length of https:// = 8, should validate better, but good enough for now.
 198   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 199
 200   # TODO: validate those with a Ecto scheme
 201   # - tags
 202   # - emoji
 203   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 204       when objtype in ["Article", "Note", "Video"] do
 205     actor = get_actor(data)
 206
 207     data =
 208       Map.put(data, "actor", actor)
 209       |> fix_addressing
 210
 211     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 212          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 213       object = fix_object(data["object"])
 214
 215       params = %{
 216         to: data["to"],
 217         object: object,
 218         actor: user,
 219         context: object["conversation"],
 220         local: false,
 221         published: data["published"],
 222         additional:
 223           Map.take(data, [
 224             "cc",
 225             "id"
 226           ])
 227       }
 228
 229       ActivityPub.create(params)
 230     else
 231       %Activity{} = activity -> {:ok, activity}
 232       _e -> :error
 233     end
 234   end
 235
 236   def handle_incoming(
 237         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 238       ) do
 239     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 240          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 241          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 242       if not User.locked?(followed) do
 243         ActivityPub.accept(%{
 244           to: [follower.ap_id],
 245           actor: followed.ap_id,
 246           object: data,
 247           local: true
 248         })
 249
 250         User.follow(follower, followed)
 251       end
 252
 253       {:ok, activity}
 254     else
 255       _e -> :error
 256     end
 257   end
 258
 259   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 260     with true <- id =~ "follows",
 261          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 262          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 263       {:ok, activity}
 264     else
 265       _ -> {:error, nil}
 266     end
 267   end
 268
 269   defp mastodon_follow_hack(_), do: {:error, nil}
 270
 271   defp get_follow_activity(follow_object, followed) do
 272     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 273          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 274       {:ok, activity}
 275     else
 276       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 277       {:activity, nil} ->
 278         mastodon_follow_hack(follow_object, followed)
 279
 280       _ ->
 281         {:error, nil}
 282     end
 283   end
 284
 285   def handle_incoming(
 286         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 287       ) do
 288     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 289          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 290          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 291          {:ok, activity} <-
 292            ActivityPub.accept(%{
 293              to: follow_activity.data["to"],
 294              type: "Accept",
 295              actor: followed.ap_id,
 296              object: follow_activity.data["id"],
 297              local: false
 298            }) do
 299       if not User.following?(follower, followed) do
 300         {:ok, follower} = User.follow(follower, followed)
 301       end
 302
 303       {:ok, activity}
 304     else
 305       _e -> :error
 306     end
 307   end
 308
 309   def handle_incoming(
 310         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 311       ) do
 312     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 313          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 314          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 315          {:ok, activity} <-
 316            ActivityPub.accept(%{
 317              to: follow_activity.data["to"],
 318              type: "Accept",
 319              actor: followed.ap_id,
 320              object: follow_activity.data["id"],
 321              local: false
 322            }) do
 323       User.unfollow(follower, followed)
 324
 325       {:ok, activity}
 326     else
 327       _e -> :error
 328     end
 329   end
 330
 331   def handle_incoming(
 332         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 333       ) do
 334     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 335          {:ok, object} <-
 336            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 337          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 338       {:ok, activity}
 339     else
 340       _e -> :error
 341     end
 342   end
 343
 344   def handle_incoming(
 345         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 346       ) do
 347     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 348          {:ok, object} <-
 349            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 350          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 351       {:ok, activity}
 352     else
 353       _e -> :error
 354     end
 355   end
 356
 357   def handle_incoming(
 358         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 359           data
 360       ) do
 361     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 362       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 363
 364       banner = new_user_data[:info]["banner"]
 365       locked = new_user_data[:info]["locked"] || false
 366
 367       update_data =
 368         new_user_data
 369         |> Map.take([:name, :bio, :avatar])
 370         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 371
 372       actor
 373       |> User.upgrade_changeset(update_data)
 374       |> User.update_and_set_cache()
 375
 376       ActivityPub.update(%{
 377         local: false,
 378         to: data["to"] || [],
 379         cc: data["cc"] || [],
 380         object: object,
 381         actor: actor_id
 382       })
 383     else
 384       e ->
 385         Logger.error(e)
 386         :error
 387     end
 388   end
 389
 390   # TODO: Make secure.
 391   def handle_incoming(
 392         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 393       ) do
 394     object_id = Utils.get_ap_id(object_id)
 395
 396     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 397          {:ok, object} <-
 398            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 399          {:ok, activity} <- ActivityPub.delete(object, false) do
 400       {:ok, activity}
 401     else
 402       _e -> :error
 403     end
 404   end
 405
 406   def handle_incoming(
 407         %{
 408           "type" => "Undo",
 409           "object" => %{"type" => "Announce", "object" => object_id},
 410           "actor" => actor,
 411           "id" => id
 412         } = _data
 413       ) do
 414     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 415          {:ok, object} <-
 416            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 417          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 418       {:ok, activity}
 419     else
 420       _e -> :error
 421     end
 422   end
 423
 424   def handle_incoming(
 425         %{
 426           "type" => "Undo",
 427           "object" => %{"type" => "Follow", "object" => followed},
 428           "actor" => follower,
 429           "id" => id
 430         } = _data
 431       ) do
 432     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 433          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 434          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 435       User.unfollow(follower, followed)
 436       {:ok, activity}
 437     else
 438       e -> :error
 439     end
 440   end
 441
 442   @ap_config Application.get_env(:pleroma, :activitypub)
 443   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 444
 445   def handle_incoming(
 446         %{
 447           "type" => "Undo",
 448           "object" => %{"type" => "Block", "object" => blocked},
 449           "actor" => blocker,
 450           "id" => id
 451         } = _data
 452       ) do
 453     with true <- @accept_blocks,
 454          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 455          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 456          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 457       User.unblock(blocker, blocked)
 458       {:ok, activity}
 459     else
 460       e -> :error
 461     end
 462   end
 463
 464   def handle_incoming(
 465         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 466       ) do
 467     with true <- @accept_blocks,
 468          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 469          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 470          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 471       User.unfollow(blocker, blocked)
 472       User.block(blocker, blocked)
 473       {:ok, activity}
 474     else
 475       e -> :error
 476     end
 477   end
 478
 479   def handle_incoming(
 480         %{
 481           "type" => "Undo",
 482           "object" => %{"type" => "Like", "object" => object_id},
 483           "actor" => actor,
 484           "id" => id
 485         } = _data
 486       ) do
 487     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 488          {:ok, object} <-
 489            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 490          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 491       {:ok, activity}
 492     else
 493       _e -> :error
 494     end
 495   end
 496
 497   def handle_incoming(_), do: :error
 498
 499   def get_obj_helper(id) do
 500     if object = Object.normalize(id), do: {:ok, object}, else: nil
 501   end
 502
 503   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 504     with false <- String.starts_with?(inReplyTo, "http"),
 505          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 506       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 507     else
 508       _e -> object
 509     end
 510   end
 511
 512   def set_reply_to_uri(obj), do: obj
 513
 514   # Prepares the object of an outgoing create activity.
 515   def prepare_object(object) do
 516     object
 517     |> set_sensitive
 518     |> add_hashtags
 519     |> add_mention_tags
 520     |> add_emoji_tags
 521     |> add_attributed_to
 522     |> prepare_attachments
 523     |> set_conversation
 524     |> set_reply_to_uri
 525   end
 526
 527   #  @doc
 528   #  """
 529   #  internal -> Mastodon
 530   #  """
 531
 532   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 533     object =
 534       object
 535       |> prepare_object
 536
 537     data =
 538       data
 539       |> Map.put("object", object)
 540       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 541
 542     {:ok, data}
 543   end
 544
 545   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 546   # because of course it does.
 547   def prepare_outgoing(%{"type" => "Accept"} = data) do
 548     with follow_activity <- Activity.normalize(data["object"]) do
 549       object = %{
 550         "actor" => follow_activity.actor,
 551         "object" => follow_activity.data["object"],
 552         "id" => follow_activity.data["id"],
 553         "type" => "Follow"
 554       }
 555
 556       data =
 557         data
 558         |> Map.put("object", object)
 559         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 560
 561       {:ok, data}
 562     end
 563   end
 564
 565   def prepare_outgoing(%{"type" => "Reject"} = data) do
 566     with follow_activity <- Activity.normalize(data["object"]) do
 567       object = %{
 568         "actor" => follow_activity.actor,
 569         "object" => follow_activity.data["object"],
 570         "id" => follow_activity.data["id"],
 571         "type" => "Follow"
 572       }
 573
 574       data =
 575         data
 576         |> Map.put("object", object)
 577         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 578
 579       {:ok, data}
 580     end
 581   end
 582
 583   def prepare_outgoing(%{"type" => _type} = data) do
 584     data =
 585       data
 586       |> maybe_fix_object_url
 587       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 588
 589     {:ok, data}
 590   end
 591
 592   def maybe_fix_object_url(data) do
 593     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 594       case ActivityPub.fetch_object_from_id(data["object"]) do
 595         {:ok, relative_object} ->
 596           if relative_object.data["external_url"] do
 597             _data =
 598               data
 599               |> Map.put("object", relative_object.data["external_url"])
 600           else
 601             data
 602           end
 603
 604         e ->
 605           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 606           data
 607       end
 608     else
 609       data
 610     end
 611   end
 612
 613   def add_hashtags(object) do
 614     tags =
 615       (object["tag"] || [])
 616       |> Enum.map(fn tag ->
 617         %{
 618           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 619           "name" => "##{tag}",
 620           "type" => "Hashtag"
 621         }
 622       end)
 623
 624     object
 625     |> Map.put("tag", tags)
 626   end
 627
 628   def add_mention_tags(object) do
 629     recipients = object["to"] ++ (object["cc"] || [])
 630
 631     mentions =
 632       recipients
 633       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 634       |> Enum.filter(& &1)
 635       |> Enum.map(fn user ->
 636         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 637       end)
 638
 639     tags = object["tag"] || []
 640
 641     object
 642     |> Map.put("tag", tags ++ mentions)
 643   end
 644
 645   # TODO: we should probably send mtime instead of unix epoch time for updated
 646   def add_emoji_tags(object) do
 647     tags = object["tag"] || []
 648     emoji = object["emoji"] || []
 649
 650     out =
 651       emoji
 652       |> Enum.map(fn {name, url} ->
 653         %{
 654           "icon" => %{"url" => url, "type" => "Image"},
 655           "name" => ":" <> name <> ":",
 656           "type" => "Emoji",
 657           "updated" => "1970-01-01T00:00:00Z",
 658           "id" => url
 659         }
 660       end)
 661
 662     object
 663     |> Map.put("tag", tags ++ out)
 664   end
 665
 666   def set_conversation(object) do
 667     Map.put(object, "conversation", object["context"])
 668   end
 669
 670   def set_sensitive(object) do
 671     tags = object["tag"] || []
 672     Map.put(object, "sensitive", "nsfw" in tags)
 673   end
 674
 675   def add_attributed_to(object) do
 676     attributedTo = object["attributedTo"] || object["actor"]
 677
 678     object
 679     |> Map.put("attributedTo", attributedTo)
 680   end
 681
 682   def prepare_attachments(object) do
 683     attachments =
 684       (object["attachment"] || [])
 685       |> Enum.map(fn data ->
 686         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 687         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 688       end)
 689
 690     object
 691     |> Map.put("attachment", attachments)
 692   end
 693
 694   defp user_upgrade_task(user) do
 695     old_follower_address = User.ap_followers(user)
 696
 697     q =
 698       from(
 699         u in User,
 700         where: ^old_follower_address in u.following,
 701         update: [
 702           set: [
 703             following:
 704               fragment(
 705                 "array_replace(?,?,?)",
 706                 u.following,
 707                 ^old_follower_address,
 708                 ^user.follower_address
 709               )
 710           ]
 711         ]
 712       )
 713
 714     Repo.update_all(q, [])
 715
 716     maybe_retire_websub(user.ap_id)
 717
 718     # Only do this for recent activties, don't go through the whole db.
 719     # Only look at the last 1000 activities.
 720     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 721
 722     q =
 723       from(
 724         a in Activity,
 725         where: ^old_follower_address in a.recipients,
 726         where: a.id > ^since,
 727         update: [
 728           set: [
 729             recipients:
 730               fragment(
 731                 "array_replace(?,?,?)",
 732                 a.recipients,
 733                 ^old_follower_address,
 734                 ^user.follower_address
 735               )
 736           ]
 737         ]
 738       )
 739
 740     Repo.update_all(q, [])
 741   end
 742
 743   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 744     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 745          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 746       data =
 747         data
 748         |> Map.put(:info, Map.merge(user.info, data[:info]))
 749
 750       already_ap = User.ap_enabled?(user)
 751
 752       {:ok, user} =
 753         User.upgrade_changeset(user, data)
 754         |> Repo.update()
 755
 756       if !already_ap do
 757         # This could potentially take a long time, do it in the background
 758         if async do
 759           Task.start(fn ->
 760             user_upgrade_task(user)
 761           end)
 762         else
 763           user_upgrade_task(user)
 764         end
 765       end
 766
 767       {:ok, user}
 768     else
 769       e -> e
 770     end
 771   end
 772
 773   def maybe_retire_websub(ap_id) do
 774     # some sanity checks
 775     if is_binary(ap_id) && String.length(ap_id) > 8 do
 776       q =
 777         from(
 778           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 779           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 780         )
 781
 782       Repo.delete_all(q)
 783     end
 784   end
 785
 786   def maybe_fix_user_url(data) do
 787     if is_map(data["url"]) do
 788       Map.put(data, "url", data["url"]["href"])
 789     else
 790       data
 791     end
 792   end
 793
 794   def maybe_fix_user_object(data) do
 795     data
 796     |> maybe_fix_user_url
 797   end
 798 end