git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  30     id
  31   end
  32
  33   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  34     get_actor(%{"actor" => actor})
  35   end
  36
  37   @doc """
  38   Checks that an imported AP object's actor matches the domain it came from.
  39   """
  40   def contain_origin(id, %{"actor" => nil}), do: :error
  41
  42   def contain_origin(id, %{"actor" => actor} = params) do
  43     id_uri = URI.parse(id)
  44     actor_uri = URI.parse(get_actor(params))
  45
  46     if id_uri.host == actor_uri.host do
  47       :ok
  48     else
  49       :error
  50     end
  51   end
  52
  53   @doc """
  54   Modifies an incoming AP object (mastodon format) to our internal format.
  55   """
  56   def fix_object(object) do
  57     object
  58     |> fix_actor
  59     |> fix_attachments
  60     |> fix_url
  61     |> fix_context
  62     |> fix_in_reply_to
  63     |> fix_emoji
  64     |> fix_tag
  65     |> fix_content_map
  66     |> fix_likes
  67     |> fix_addressing
  68   end
  69
  70   def fix_addressing_list(map, field) do
  71     if is_binary(map[field]) do
  72       map
  73       |> Map.put(field, [map[field]])
  74     else
  75       map
  76     end
  77   end
  78
  79   def fix_addressing(map) do
  80     map
  81     |> fix_addressing_list("to")
  82     |> fix_addressing_list("cc")
  83     |> fix_addressing_list("bto")
  84     |> fix_addressing_list("bcc")
  85   end
  86
  87   def fix_actor(%{"attributedTo" => actor} = object) do
  88     object
  89     |> Map.put("actor", get_actor(%{"actor" => actor}))
  90   end
  91
  92   def fix_likes(%{"likes" => likes} = object)
  93       when is_bitstring(likes) do
  94     # Check for standardisation
  95     # This is what Peertube does
  96     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
  97     object
  98     |> Map.put("likes", [])
  99     |> Map.put("like_count", 0)
 100   end
 101
 102   def fix_likes(object) do
 103     object
 104   end
 105
 106   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 107       when not is_nil(in_reply_to) do
 108     in_reply_to_id =
 109       cond do
 110         is_bitstring(in_reply_to) ->
 111           in_reply_to
 112
 113         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 114           in_reply_to["id"]
 115
 116         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 117           Enum.at(in_reply_to, 0)
 118
 119         # Maybe I should output an error too?
 120         true ->
 121           ""
 122       end
 123
 124     case fetch_obj_helper(in_reply_to_id) do
 125       {:ok, replied_object} ->
 126         with %Activity{} = activity <-
 127                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 128           object
 129           |> Map.put("inReplyTo", replied_object.data["id"])
 130           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 131           |> Map.put("inReplyToStatusId", activity.id)
 132           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 133           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 134         else
 135           e ->
 136             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 137             object
 138         end
 139
 140       e ->
 141         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 142         object
 143     end
 144   end
 145
 146   def fix_in_reply_to(object), do: object
 147
 148   def fix_context(object) do
 149     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 150
 151     object
 152     |> Map.put("context", context)
 153     |> Map.put("conversation", context)
 154   end
 155
 156   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 157     attachments =
 158       attachment
 159       |> Enum.map(fn data ->
 160         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 161         Map.put(data, "url", url)
 162       end)
 163
 164     object
 165     |> Map.put("attachment", attachments)
 166   end
 167
 168   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 169     Map.put(object, "attachment", [attachment])
 170     |> fix_attachments()
 171   end
 172
 173   def fix_attachments(object), do: object
 174
 175   def fix_url(%{"url" => url} = object) when is_map(url) do
 176     object
 177     |> Map.put("url", url["href"])
 178   end
 179
 180   def fix_url(%{"url" => url} = object) when is_list(url) do
 181     first_element = Enum.at(url, 0)
 182
 183     url_string =
 184       cond do
 185         is_bitstring(first_element) -> first_element
 186         is_map(first_element) -> first_element["href"] || ""
 187         true -> ""
 188       end
 189
 190     object
 191     |> Map.put("url", url_string)
 192   end
 193
 194   def fix_url(object), do: object
 195
 196   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 197     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 198
 199     emoji =
 200       emoji
 201       |> Enum.reduce(%{}, fn data, mapping ->
 202         name = String.trim(data["name"], ":")
 203
 204         mapping |> Map.put(name, data["icon"]["url"])
 205       end)
 206
 207     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 208     emoji = Map.merge(object["emoji"] || %{}, emoji)
 209
 210     object
 211     |> Map.put("emoji", emoji)
 212   end
 213
 214   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 215     name = String.trim(tag["name"], ":")
 216     emoji = %{name => tag["icon"]["url"]}
 217
 218     object
 219     |> Map.put("emoji", emoji)
 220   end
 221
 222   def fix_emoji(object), do: object
 223
 224   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 225     tags =
 226       tag
 227       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 228       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 229
 230     combined = tag ++ tags
 231
 232     object
 233     |> Map.put("tag", combined)
 234   end
 235
 236   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 237     combined = [tag, String.slice(hashtag, 1..-1)]
 238
 239     object
 240     |> Map.put("tag", combined)
 241   end
 242
 243   def fix_tag(object), do: object
 244
 245   # content map usually only has one language so this will do for now.
 246   def fix_content_map(%{"contentMap" => content_map} = object) do
 247     content_groups = Map.to_list(content_map)
 248     {_, content} = Enum.at(content_groups, 0)
 249
 250     object
 251     |> Map.put("content", content)
 252   end
 253
 254   def fix_content_map(object), do: object
 255
 256   # disallow objects with bogus IDs
 257   def handle_incoming(%{"id" => nil}), do: :error
 258   def handle_incoming(%{"id" => ""}), do: :error
 259   # length of https:// = 8, should validate better, but good enough for now.
 260   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 261
 262   # TODO: validate those with a Ecto scheme
 263   # - tags
 264   # - emoji
 265   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 266       when objtype in ["Article", "Note", "Video"] do
 267     actor = get_actor(data)
 268
 269     data =
 270       Map.put(data, "actor", actor)
 271       |> fix_addressing
 272
 273     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 274          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 275       object = fix_object(data["object"])
 276
 277       params = %{
 278         to: data["to"],
 279         object: object,
 280         actor: user,
 281         context: object["conversation"],
 282         local: false,
 283         published: data["published"],
 284         additional:
 285           Map.take(data, [
 286             "cc",
 287             "id"
 288           ])
 289       }
 290
 291       ActivityPub.create(params)
 292     else
 293       %Activity{} = activity -> {:ok, activity}
 294       _e -> :error
 295     end
 296   end
 297
 298   def handle_incoming(
 299         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 300       ) do
 301     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 302          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 303          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 304       if not User.locked?(followed) do
 305         ActivityPub.accept(%{
 306           to: [follower.ap_id],
 307           actor: followed.ap_id,
 308           object: data,
 309           local: true
 310         })
 311
 312         User.follow(follower, followed)
 313       end
 314
 315       {:ok, activity}
 316     else
 317       _e -> :error
 318     end
 319   end
 320
 321   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 322     with true <- id =~ "follows",
 323          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 324          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 325       {:ok, activity}
 326     else
 327       _ -> {:error, nil}
 328     end
 329   end
 330
 331   defp mastodon_follow_hack(_), do: {:error, nil}
 332
 333   defp get_follow_activity(follow_object, followed) do
 334     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 335          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 336       {:ok, activity}
 337     else
 338       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 339       {:activity, nil} ->
 340         mastodon_follow_hack(follow_object, followed)
 341
 342       _ ->
 343         {:error, nil}
 344     end
 345   end
 346
 347   def handle_incoming(
 348         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 349       ) do
 350     with actor <- get_actor(data),
 351          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 352          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 353          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 354          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 355          {:ok, activity} <-
 356            ActivityPub.accept(%{
 357              to: follow_activity.data["to"],
 358              type: "Accept",
 359              actor: followed.ap_id,
 360              object: follow_activity.data["id"],
 361              local: false
 362            }) do
 363       if not User.following?(follower, followed) do
 364         {:ok, follower} = User.follow(follower, followed)
 365       end
 366
 367       {:ok, activity}
 368     else
 369       _e -> :error
 370     end
 371   end
 372
 373   def handle_incoming(
 374         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 375       ) do
 376     with actor <- get_actor(data),
 377          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 378          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 379          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 380          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 381          {:ok, activity} <-
 382            ActivityPub.accept(%{
 383              to: follow_activity.data["to"],
 384              type: "Accept",
 385              actor: followed.ap_id,
 386              object: follow_activity.data["id"],
 387              local: false
 388            }) do
 389       User.unfollow(follower, followed)
 390
 391       {:ok, activity}
 392     else
 393       _e -> :error
 394     end
 395   end
 396
 397   def handle_incoming(
 398         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data
 399       ) do
 400     with actor <- get_actor(data),
 401          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 402          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 403          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 404       {:ok, activity}
 405     else
 406       _e -> :error
 407     end
 408   end
 409
 410   def handle_incoming(
 411         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data
 412       ) do
 413     with actor <- get_actor(data),
 414          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 415          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 416          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 417       {:ok, activity}
 418     else
 419       _e -> :error
 420     end
 421   end
 422
 423   def handle_incoming(
 424         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 425           data
 426       )
 427       when object_type in ["Person", "Application", "Service", "Organization"] do
 428     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 429       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 430
 431       banner = new_user_data[:info]["banner"]
 432       locked = new_user_data[:info]["locked"] || false
 433
 434       update_data =
 435         new_user_data
 436         |> Map.take([:name, :bio, :avatar])
 437         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 438
 439       actor
 440       |> User.upgrade_changeset(update_data)
 441       |> User.update_and_set_cache()
 442
 443       ActivityPub.update(%{
 444         local: false,
 445         to: data["to"] || [],
 446         cc: data["cc"] || [],
 447         object: object,
 448         actor: actor_id
 449       })
 450     else
 451       e ->
 452         Logger.error(e)
 453         :error
 454     end
 455   end
 456
 457   # TODO: Make secure.
 458   def handle_incoming(
 459         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = data
 460       ) do
 461     object_id = Utils.get_ap_id(object_id)
 462
 463     with actor <- get_actor(data),
 464          %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 465          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 466          {:ok, activity} <- ActivityPub.delete(object, false) do
 467       {:ok, activity}
 468     else
 469       _e -> :error
 470     end
 471   end
 472
 473   def handle_incoming(
 474         %{
 475           "type" => "Undo",
 476           "object" => %{"type" => "Announce", "object" => object_id},
 477           "actor" => actor,
 478           "id" => id
 479         } = data
 480       ) do
 481     with actor <- get_actor(data),
 482          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 483          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 484          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 485       {:ok, activity}
 486     else
 487       _e -> :error
 488     end
 489   end
 490
 491   def handle_incoming(
 492         %{
 493           "type" => "Undo",
 494           "object" => %{"type" => "Follow", "object" => followed},
 495           "actor" => follower,
 496           "id" => id
 497         } = _data
 498       ) do
 499     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 500          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 501          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 502       User.unfollow(follower, followed)
 503       {:ok, activity}
 504     else
 505       e -> :error
 506     end
 507   end
 508
 509   @ap_config Application.get_env(:pleroma, :activitypub)
 510   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 511
 512   def handle_incoming(
 513         %{
 514           "type" => "Undo",
 515           "object" => %{"type" => "Block", "object" => blocked},
 516           "actor" => blocker,
 517           "id" => id
 518         } = _data
 519       ) do
 520     with true <- @accept_blocks,
 521          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 522          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 523          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 524       User.unblock(blocker, blocked)
 525       {:ok, activity}
 526     else
 527       e -> :error
 528     end
 529   end
 530
 531   def handle_incoming(
 532         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 533       ) do
 534     with true <- @accept_blocks,
 535          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 536          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 537          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 538       User.unfollow(blocker, blocked)
 539       User.block(blocker, blocked)
 540       {:ok, activity}
 541     else
 542       e -> :error
 543     end
 544   end
 545
 546   def handle_incoming(
 547         %{
 548           "type" => "Undo",
 549           "object" => %{"type" => "Like", "object" => object_id},
 550           "actor" => actor,
 551           "id" => id
 552         } = data
 553       ) do
 554     with actor <- get_actor(data),
 555          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 556          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 557          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 558       {:ok, activity}
 559     else
 560       _e -> :error
 561     end
 562   end
 563
 564   def handle_incoming(_), do: :error
 565
 566   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 567   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 568
 569   def get_obj_helper(id) do
 570     if object = Object.normalize(id), do: {:ok, object}, else: nil
 571   end
 572
 573   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 574     with false <- String.starts_with?(inReplyTo, "http"),
 575          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 576       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 577     else
 578       _e -> object
 579     end
 580   end
 581
 582   def set_reply_to_uri(obj), do: obj
 583
 584   # Prepares the object of an outgoing create activity.
 585   def prepare_object(object) do
 586     object
 587     |> set_sensitive
 588     |> add_hashtags
 589     |> add_mention_tags
 590     |> add_emoji_tags
 591     |> add_attributed_to
 592     |> prepare_attachments
 593     |> set_conversation
 594     |> set_reply_to_uri
 595   end
 596
 597   #  @doc
 598   #  """
 599   #  internal -> Mastodon
 600   #  """
 601
 602   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 603     object =
 604       object
 605       |> prepare_object
 606
 607     data =
 608       data
 609       |> Map.put("object", object)
 610       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 611
 612     {:ok, data}
 613   end
 614
 615   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 616   # because of course it does.
 617   def prepare_outgoing(%{"type" => "Accept"} = data) do
 618     with follow_activity <- Activity.normalize(data["object"]) do
 619       object = %{
 620         "actor" => follow_activity.actor,
 621         "object" => follow_activity.data["object"],
 622         "id" => follow_activity.data["id"],
 623         "type" => "Follow"
 624       }
 625
 626       data =
 627         data
 628         |> Map.put("object", object)
 629         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 630
 631       {:ok, data}
 632     end
 633   end
 634
 635   def prepare_outgoing(%{"type" => "Reject"} = data) do
 636     with follow_activity <- Activity.normalize(data["object"]) do
 637       object = %{
 638         "actor" => follow_activity.actor,
 639         "object" => follow_activity.data["object"],
 640         "id" => follow_activity.data["id"],
 641         "type" => "Follow"
 642       }
 643
 644       data =
 645         data
 646         |> Map.put("object", object)
 647         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 648
 649       {:ok, data}
 650     end
 651   end
 652
 653   def prepare_outgoing(%{"type" => _type} = data) do
 654     data =
 655       data
 656       |> maybe_fix_object_url
 657       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 658
 659     {:ok, data}
 660   end
 661
 662   def maybe_fix_object_url(data) do
 663     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 664       case fetch_obj_helper(data["object"]) do
 665         {:ok, relative_object} ->
 666           if relative_object.data["external_url"] do
 667             _data =
 668               data
 669               |> Map.put("object", relative_object.data["external_url"])
 670           else
 671             data
 672           end
 673
 674         e ->
 675           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 676           data
 677       end
 678     else
 679       data
 680     end
 681   end
 682
 683   def add_hashtags(object) do
 684     tags =
 685       (object["tag"] || [])
 686       |> Enum.map(fn tag ->
 687         %{
 688           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 689           "name" => "##{tag}",
 690           "type" => "Hashtag"
 691         }
 692       end)
 693
 694     object
 695     |> Map.put("tag", tags)
 696   end
 697
 698   def add_mention_tags(object) do
 699     recipients = object["to"] ++ (object["cc"] || [])
 700
 701     mentions =
 702       recipients
 703       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 704       |> Enum.filter(& &1)
 705       |> Enum.map(fn user ->
 706         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 707       end)
 708
 709     tags = object["tag"] || []
 710
 711     object
 712     |> Map.put("tag", tags ++ mentions)
 713   end
 714
 715   # TODO: we should probably send mtime instead of unix epoch time for updated
 716   def add_emoji_tags(object) do
 717     tags = object["tag"] || []
 718     emoji = object["emoji"] || []
 719
 720     out =
 721       emoji
 722       |> Enum.map(fn {name, url} ->
 723         %{
 724           "icon" => %{"url" => url, "type" => "Image"},
 725           "name" => ":" <> name <> ":",
 726           "type" => "Emoji",
 727           "updated" => "1970-01-01T00:00:00Z",
 728           "id" => url
 729         }
 730       end)
 731
 732     object
 733     |> Map.put("tag", tags ++ out)
 734   end
 735
 736   def set_conversation(object) do
 737     Map.put(object, "conversation", object["context"])
 738   end
 739
 740   def set_sensitive(object) do
 741     tags = object["tag"] || []
 742     Map.put(object, "sensitive", "nsfw" in tags)
 743   end
 744
 745   def add_attributed_to(object) do
 746     attributedTo = object["attributedTo"] || object["actor"]
 747
 748     object
 749     |> Map.put("attributedTo", attributedTo)
 750   end
 751
 752   def prepare_attachments(object) do
 753     attachments =
 754       (object["attachment"] || [])
 755       |> Enum.map(fn data ->
 756         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 757         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 758       end)
 759
 760     object
 761     |> Map.put("attachment", attachments)
 762   end
 763
 764   defp user_upgrade_task(user) do
 765     old_follower_address = User.ap_followers(user)
 766
 767     q =
 768       from(
 769         u in User,
 770         where: ^old_follower_address in u.following,
 771         update: [
 772           set: [
 773             following:
 774               fragment(
 775                 "array_replace(?,?,?)",
 776                 u.following,
 777                 ^old_follower_address,
 778                 ^user.follower_address
 779               )
 780           ]
 781         ]
 782       )
 783
 784     Repo.update_all(q, [])
 785
 786     maybe_retire_websub(user.ap_id)
 787
 788     # Only do this for recent activties, don't go through the whole db.
 789     # Only look at the last 1000 activities.
 790     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 791
 792     q =
 793       from(
 794         a in Activity,
 795         where: ^old_follower_address in a.recipients,
 796         where: a.id > ^since,
 797         update: [
 798           set: [
 799             recipients:
 800               fragment(
 801                 "array_replace(?,?,?)",
 802                 a.recipients,
 803                 ^old_follower_address,
 804                 ^user.follower_address
 805               )
 806           ]
 807         ]
 808       )
 809
 810     Repo.update_all(q, [])
 811   end
 812
 813   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 814     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 815          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 816       data =
 817         data
 818         |> Map.put(:info, Map.merge(user.info, data[:info]))
 819
 820       already_ap = User.ap_enabled?(user)
 821
 822       {:ok, user} =
 823         User.upgrade_changeset(user, data)
 824         |> Repo.update()
 825
 826       if !already_ap do
 827         # This could potentially take a long time, do it in the background
 828         if async do
 829           Task.start(fn ->
 830             user_upgrade_task(user)
 831           end)
 832         else
 833           user_upgrade_task(user)
 834         end
 835       end
 836
 837       {:ok, user}
 838     else
 839       e -> e
 840     end
 841   end
 842
 843   def maybe_retire_websub(ap_id) do
 844     # some sanity checks
 845     if is_binary(ap_id) && String.length(ap_id) > 8 do
 846       q =
 847         from(
 848           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 849           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 850         )
 851
 852       Repo.delete_all(q)
 853     end
 854   end
 855
 856   def maybe_fix_user_url(data) do
 857     if is_map(data["url"]) do
 858       Map.put(data, "url", data["url"]["href"])
 859     else
 860       data
 861     end
 862   end
 863
 864   def maybe_fix_user_object(data) do
 865     data
 866     |> maybe_fix_user_url
 867   end
 868 end