git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9
  10   @doc """
  11   Modifies an incoming AP object (mastodon format) to our internal format.
  12   """
  13   def fix_object(object) do
  14     object
  15     |> Map.put("actor", object["attributedTo"])
  16     |> fix_attachments
  17   end
  18
  19   def fix_attachments(object) do
  20     attachments = (object["attachment"] || [])
  21     |> Enum.map(fn (data) ->
  22       url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  23       Map.put(data, "url", url)
  24     end)
  25
  26     object
  27     |> Map.put("attachment", attachments)
  28   end
  29
  30   # TODO: validate those with a Ecto scheme
  31   # - tags
  32   # - emoji
  33   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
  34     with %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
  35       object = fix_object(data["object"])
  36       params = %{
  37         to: data["to"],
  38         object: object,
  39         actor: user,
  40         context: data["object"]["conversation"],
  41         local: false,
  42         published: data["published"],
  43         additional: Map.take(data, [
  44               "cc",
  45               "id"
  46             ])
  47       }
  48
  49       ActivityPub.create(params)
  50     else
  51       _e -> :error
  52     end
  53   end
  54
  55   def handle_incoming(%{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data) do
  56     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
  57          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
  58          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
  59       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
  60       User.follow(follower, followed)
  61       {:ok, activity}
  62     else
  63       _e -> :error
  64     end
  65   end
  66
  67   def handle_incoming(%{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data) do
  68     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
  69          %Object{} = object <- Object.get_by_ap_id(object_id),
  70          {:ok, activity, object} <- ActivityPub.like(actor, object, id, false) do
  71       {:ok, activity}
  72     else
  73       _e -> :error
  74     end
  75   end
  76
  77   def handle_incoming(%{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data) do
  78     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
  79          {:ok, object} <- get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
  80          {:ok, activity, object} <- ActivityPub.announce(actor, object, id, false) do
  81       {:ok, activity}
  82     else
  83       _e -> :error
  84     end
  85   end
  86
  87   # TODO
  88   # Accept
  89   # Undo
  90
  91   def handle_incoming(_), do: :error
  92
  93   def get_obj_helper(id) do
  94     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
  95   end
  96
  97   @doc
  98   """
  99   internal -> Mastodon
 100   """
 101   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 102     object = object
 103     |> add_hashtags
 104     |> add_mention_tags
 105     |> add_attributed_to
 106     |> prepare_attachments
 107     |> set_conversation
 108
 109     data = data
 110     |> Map.put("object", object)
 111     |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 112
 113     {:ok, data}
 114   end
 115
 116   def prepare_outgoing(%{"type" => type} = data) when type in ["Follow", "Accept", "Like", "Announce"] do
 117     data = data
 118     |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 119
 120     {:ok, data}
 121   end
 122
 123   def add_hashtags(object) do
 124     tags = (object["tag"] || [])
 125     |> Enum.map fn (tag) -> %{"href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}", "name" => "##{tag}", "type" => "Hashtag"} end
 126
 127     object
 128     |> Map.put("tag", tags)
 129   end
 130
 131   def add_mention_tags(object) do
 132     mentions = object["to"]
 133     |> Enum.map(fn (ap_id) -> User.get_cached_by_ap_id(ap_id) end)
 134     |> Enum.filter(&(&1))
 135     |> Enum.map(fn(user) -> %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"} end)
 136
 137     tags = object["tag"] || []
 138
 139     object
 140     |> Map.put("tag", tags ++ mentions)
 141   end
 142
 143   def set_conversation(object) do
 144     Map.put(object, "conversation", object["context"])
 145   end
 146
 147   def add_attributed_to(object) do
 148     attributedTo = object["attributedTo"] || object["actor"]
 149
 150     object
 151     |> Map.put("attributedTo", attributedTo)
 152   end
 153
 154   def prepare_attachments(object) do
 155     attachments = (object["attachment"] || [])
 156     |> Enum.map(fn (data) ->
 157       [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 158       %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 159     end)
 160
 161     object
 162     |> Map.put("attachment", attachments)
 163   end
 164 end