git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.{Activity, User, Object, Repo}
  10   alias Pleroma.Web.ActivityPub.{ActivityPub, Utils}
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  30     id
  31   end
  32
  33   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  34     get_actor(%{"actor" => actor})
  35   end
  36
  37   @doc """
  38   Checks that an imported AP object's actor matches the domain it came from.
  39   """
  40   def contain_origin(_id, %{"actor" => nil}), do: :error
  41
  42   def contain_origin(id, %{"actor" => _actor} = params) do
  43     id_uri = URI.parse(id)
  44     actor_uri = URI.parse(get_actor(params))
  45
  46     if id_uri.host == actor_uri.host do
  47       :ok
  48     else
  49       :error
  50     end
  51   end
  52
  53   def contain_origin_from_id(_id, %{"id" => nil}), do: :error
  54
  55   def contain_origin_from_id(id, %{"id" => other_id} = _params) do
  56     id_uri = URI.parse(id)
  57     other_uri = URI.parse(other_id)
  58
  59     if id_uri.host == other_uri.host do
  60       :ok
  61     else
  62       :error
  63     end
  64   end
  65
  66   @doc """
  67   Modifies an incoming AP object (mastodon format) to our internal format.
  68   """
  69   def fix_object(object) do
  70     object
  71     |> fix_actor
  72     |> fix_url
  73     |> fix_attachments
  74     |> fix_context
  75     |> fix_in_reply_to
  76     |> fix_emoji
  77     |> fix_tag
  78     |> fix_content_map
  79     |> fix_likes
  80     |> fix_addressing
  81   end
  82
  83   def fix_addressing_list(map, field) do
  84     if is_binary(map[field]) do
  85       map
  86       |> Map.put(field, [map[field]])
  87     else
  88       map
  89     end
  90   end
  91
  92   def fix_explicit_addressing(%{"to" => to, "cc" => cc} = object, explicit_mentions) do
  93     explicit_to =
  94       to
  95       |> Enum.filter(fn x -> x in explicit_mentions end)
  96
  97     explicit_cc =
  98       to
  99       |> Enum.filter(fn x -> x not in explicit_mentions end)
 100
 101     final_cc =
 102       (cc ++ explicit_cc)
 103       |> Enum.uniq()
 104
 105     object
 106     |> Map.put("to", explicit_to)
 107     |> Map.put("cc", final_cc)
 108   end
 109
 110   def fix_explicit_addressing(object, _explicit_mentions), do: object
 111
 112   # if directMessage flag is set to true, leave the addressing alone
 113   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
 114
 115   def fix_explicit_addressing(object) do
 116     explicit_mentions =
 117       object
 118       |> Utils.determine_explicit_mentions()
 119
 120     explicit_mentions = explicit_mentions ++ ["https://www.w3.org/ns/activitystreams#Public"]
 121
 122     object
 123     |> fix_explicit_addressing(explicit_mentions)
 124   end
 125
 126   def fix_addressing(object) do
 127     object
 128     |> fix_addressing_list("to")
 129     |> fix_addressing_list("cc")
 130     |> fix_addressing_list("bto")
 131     |> fix_addressing_list("bcc")
 132     |> fix_explicit_addressing
 133   end
 134
 135   def fix_actor(%{"attributedTo" => actor} = object) do
 136     object
 137     |> Map.put("actor", get_actor(%{"actor" => actor}))
 138   end
 139
 140   # Check for standardisation
 141   # This is what Peertube does
 142   # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
 143   # Prismo returns only an integer (count) as "likes"
 144   def fix_likes(%{"likes" => likes} = object) when not is_map(likes) do
 145     object
 146     |> Map.put("likes", [])
 147     |> Map.put("like_count", 0)
 148   end
 149
 150   def fix_likes(object) do
 151     object
 152   end
 153
 154   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 155       when not is_nil(in_reply_to) do
 156     in_reply_to_id =
 157       cond do
 158         is_bitstring(in_reply_to) ->
 159           in_reply_to
 160
 161         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 162           in_reply_to["id"]
 163
 164         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 165           Enum.at(in_reply_to, 0)
 166
 167         # Maybe I should output an error too?
 168         true ->
 169           ""
 170       end
 171
 172     case fetch_obj_helper(in_reply_to_id) do
 173       {:ok, replied_object} ->
 174         with %Activity{} = activity <-
 175                Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 176           object
 177           |> Map.put("inReplyTo", replied_object.data["id"])
 178           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 179           |> Map.put("inReplyToStatusId", activity.id)
 180           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 181           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 182         else
 183           e ->
 184             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 185             object
 186         end
 187
 188       e ->
 189         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 190         object
 191     end
 192   end
 193
 194   def fix_in_reply_to(object), do: object
 195
 196   def fix_context(object) do
 197     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 198
 199     object
 200     |> Map.put("context", context)
 201     |> Map.put("conversation", context)
 202   end
 203
 204   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 205     attachments =
 206       attachment
 207       |> Enum.map(fn data ->
 208         media_type = data["mediaType"] || data["mimeType"]
 209         href = data["url"] || data["href"]
 210
 211         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 212
 213         data
 214         |> Map.put("mediaType", media_type)
 215         |> Map.put("url", url)
 216       end)
 217
 218     object
 219     |> Map.put("attachment", attachments)
 220   end
 221
 222   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 223     Map.put(object, "attachment", [attachment])
 224     |> fix_attachments()
 225   end
 226
 227   def fix_attachments(object), do: object
 228
 229   def fix_url(%{"url" => url} = object) when is_map(url) do
 230     object
 231     |> Map.put("url", url["href"])
 232   end
 233
 234   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 235     first_element = Enum.at(url, 0)
 236
 237     link_element =
 238       url
 239       |> Enum.filter(fn x -> is_map(x) end)
 240       |> Enum.filter(fn x -> x["mimeType"] == "text/html" end)
 241       |> Enum.at(0)
 242
 243     object
 244     |> Map.put("attachment", [first_element])
 245     |> Map.put("url", link_element["href"])
 246   end
 247
 248   def fix_url(%{"type" => object_type, "url" => url} = object)
 249       when object_type != "Video" and is_list(url) do
 250     first_element = Enum.at(url, 0)
 251
 252     url_string =
 253       cond do
 254         is_bitstring(first_element) -> first_element
 255         is_map(first_element) -> first_element["href"] || ""
 256         true -> ""
 257       end
 258
 259     object
 260     |> Map.put("url", url_string)
 261   end
 262
 263   def fix_url(object), do: object
 264
 265   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 266     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 267
 268     emoji =
 269       emoji
 270       |> Enum.reduce(%{}, fn data, mapping ->
 271         name = String.trim(data["name"], ":")
 272
 273         mapping |> Map.put(name, data["icon"]["url"])
 274       end)
 275
 276     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 277     emoji = Map.merge(object["emoji"] || %{}, emoji)
 278
 279     object
 280     |> Map.put("emoji", emoji)
 281   end
 282
 283   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 284     name = String.trim(tag["name"], ":")
 285     emoji = %{name => tag["icon"]["url"]}
 286
 287     object
 288     |> Map.put("emoji", emoji)
 289   end
 290
 291   def fix_emoji(object), do: object
 292
 293   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 294     tags =
 295       tag
 296       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 297       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 298
 299     combined = tag ++ tags
 300
 301     object
 302     |> Map.put("tag", combined)
 303   end
 304
 305   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 306     combined = [tag, String.slice(hashtag, 1..-1)]
 307
 308     object
 309     |> Map.put("tag", combined)
 310   end
 311
 312   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 313
 314   def fix_tag(object), do: object
 315
 316   # content map usually only has one language so this will do for now.
 317   def fix_content_map(%{"contentMap" => content_map} = object) do
 318     content_groups = Map.to_list(content_map)
 319     {_, content} = Enum.at(content_groups, 0)
 320
 321     object
 322     |> Map.put("content", content)
 323   end
 324
 325   def fix_content_map(object), do: object
 326
 327   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 328     with true <- id =~ "follows",
 329          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 330          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 331       {:ok, activity}
 332     else
 333       _ -> {:error, nil}
 334     end
 335   end
 336
 337   defp mastodon_follow_hack(_, _), do: {:error, nil}
 338
 339   defp get_follow_activity(follow_object, followed) do
 340     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 341          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 342       {:ok, activity}
 343     else
 344       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 345       {:activity, nil} ->
 346         mastodon_follow_hack(follow_object, followed)
 347
 348       _ ->
 349         {:error, nil}
 350     end
 351   end
 352
 353   # disallow objects with bogus IDs
 354   def handle_incoming(%{"id" => nil}), do: :error
 355   def handle_incoming(%{"id" => ""}), do: :error
 356   # length of https:// = 8, should validate better, but good enough for now.
 357   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 358
 359   # TODO: validate those with a Ecto scheme
 360   # - tags
 361   # - emoji
 362   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 363       when objtype in ["Article", "Note", "Video", "Page"] do
 364     actor = get_actor(data)
 365
 366     data =
 367       Map.put(data, "actor", actor)
 368       |> fix_addressing
 369
 370     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 371          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 372       object = fix_object(data["object"])
 373
 374       params = %{
 375         to: data["to"],
 376         object: object,
 377         actor: user,
 378         context: object["conversation"],
 379         local: false,
 380         published: data["published"],
 381         additional:
 382           Map.take(data, [
 383             "cc",
 384             "directMessage",
 385             "id"
 386           ])
 387       }
 388
 389       ActivityPub.create(params)
 390     else
 391       %Activity{} = activity -> {:ok, activity}
 392       _e -> :error
 393     end
 394   end
 395
 396   def handle_incoming(
 397         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 398       ) do
 399     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 400          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 401          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 402       if not User.locked?(followed) do
 403         ActivityPub.accept(%{
 404           to: [follower.ap_id],
 405           actor: followed.ap_id,
 406           object: data,
 407           local: true
 408         })
 409
 410         User.follow(follower, followed)
 411       end
 412
 413       {:ok, activity}
 414     else
 415       _e -> :error
 416     end
 417   end
 418
 419   def handle_incoming(
 420         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 421       ) do
 422     with actor <- get_actor(data),
 423          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 424          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 425          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 426          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 427          {:ok, activity} <-
 428            ActivityPub.accept(%{
 429              to: follow_activity.data["to"],
 430              type: "Accept",
 431              actor: followed.ap_id,
 432              object: follow_activity.data["id"],
 433              local: false
 434            }) do
 435       if not User.following?(follower, followed) do
 436         {:ok, _follower} = User.follow(follower, followed)
 437       end
 438
 439       {:ok, activity}
 440     else
 441       _e -> :error
 442     end
 443   end
 444
 445   def handle_incoming(
 446         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 447       ) do
 448     with actor <- get_actor(data),
 449          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 450          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 451          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 452          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 453          {:ok, activity} <-
 454            ActivityPub.reject(%{
 455              to: follow_activity.data["to"],
 456              type: "Reject",
 457              actor: followed.ap_id,
 458              object: follow_activity.data["id"],
 459              local: false
 460            }) do
 461       User.unfollow(follower, followed)
 462
 463       {:ok, activity}
 464     else
 465       _e -> :error
 466     end
 467   end
 468
 469   def handle_incoming(
 470         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data
 471       ) do
 472     with actor <- get_actor(data),
 473          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 474          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 475          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 476       {:ok, activity}
 477     else
 478       _e -> :error
 479     end
 480   end
 481
 482   def handle_incoming(
 483         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data
 484       ) do
 485     with actor <- get_actor(data),
 486          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 487          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 488          public <- ActivityPub.is_public?(data),
 489          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 490       {:ok, activity}
 491     else
 492       _e -> :error
 493     end
 494   end
 495
 496   def handle_incoming(
 497         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 498           data
 499       )
 500       when object_type in ["Person", "Application", "Service", "Organization"] do
 501     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 502       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 503
 504       banner = new_user_data[:info]["banner"]
 505       locked = new_user_data[:info]["locked"] || false
 506
 507       update_data =
 508         new_user_data
 509         |> Map.take([:name, :bio, :avatar])
 510         |> Map.put(:info, %{"banner" => banner, "locked" => locked})
 511
 512       actor
 513       |> User.upgrade_changeset(update_data)
 514       |> User.update_and_set_cache()
 515
 516       ActivityPub.update(%{
 517         local: false,
 518         to: data["to"] || [],
 519         cc: data["cc"] || [],
 520         object: object,
 521         actor: actor_id
 522       })
 523     else
 524       e ->
 525         Logger.error(e)
 526         :error
 527     end
 528   end
 529
 530   # TODO: We presently assume that any actor on the same origin domain as the object being
 531   # deleted has the rights to delete that object.  A better way to validate whether or not
 532   # the object should be deleted is to refetch the object URI, which should return either
 533   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 534   # place.
 535   def handle_incoming(
 536         %{"type" => "Delete", "object" => object_id, "actor" => _actor, "id" => _id} = data
 537       ) do
 538     object_id = Utils.get_ap_id(object_id)
 539
 540     with actor <- get_actor(data),
 541          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 542          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 543          :ok <- contain_origin(actor.ap_id, object.data),
 544          {:ok, activity} <- ActivityPub.delete(object, false) do
 545       {:ok, activity}
 546     else
 547       _e -> :error
 548     end
 549   end
 550
 551   def handle_incoming(
 552         %{
 553           "type" => "Undo",
 554           "object" => %{"type" => "Announce", "object" => object_id},
 555           "actor" => _actor,
 556           "id" => id
 557         } = data
 558       ) do
 559     with actor <- get_actor(data),
 560          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 561          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 562          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 563       {:ok, activity}
 564     else
 565       _e -> :error
 566     end
 567   end
 568
 569   def handle_incoming(
 570         %{
 571           "type" => "Undo",
 572           "object" => %{"type" => "Follow", "object" => followed},
 573           "actor" => follower,
 574           "id" => id
 575         } = _data
 576       ) do
 577     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 578          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 579          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 580       User.unfollow(follower, followed)
 581       {:ok, activity}
 582     else
 583       _e -> :error
 584     end
 585   end
 586
 587   def handle_incoming(
 588         %{
 589           "type" => "Undo",
 590           "object" => %{"type" => "Block", "object" => blocked},
 591           "actor" => blocker,
 592           "id" => id
 593         } = _data
 594       ) do
 595     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 596          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 597          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 598          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 599       User.unblock(blocker, blocked)
 600       {:ok, activity}
 601     else
 602       _e -> :error
 603     end
 604   end
 605
 606   def handle_incoming(
 607         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data
 608       ) do
 609     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 610          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 611          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 612          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 613       User.unfollow(blocker, blocked)
 614       User.block(blocker, blocked)
 615       {:ok, activity}
 616     else
 617       _e -> :error
 618     end
 619   end
 620
 621   def handle_incoming(
 622         %{
 623           "type" => "Undo",
 624           "object" => %{"type" => "Like", "object" => object_id},
 625           "actor" => _actor,
 626           "id" => id
 627         } = data
 628       ) do
 629     with actor <- get_actor(data),
 630          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 631          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 632          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 633       {:ok, activity}
 634     else
 635       _e -> :error
 636     end
 637   end
 638
 639   def handle_incoming(_), do: :error
 640
 641   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 642   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 643
 644   def get_obj_helper(id) do
 645     if object = Object.normalize(id), do: {:ok, object}, else: nil
 646   end
 647
 648   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 649     with false <- String.starts_with?(inReplyTo, "http"),
 650          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 651       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 652     else
 653       _e -> object
 654     end
 655   end
 656
 657   def set_reply_to_uri(obj), do: obj
 658
 659   # Prepares the object of an outgoing create activity.
 660   def prepare_object(object) do
 661     object
 662     |> set_sensitive
 663     |> add_hashtags
 664     |> add_mention_tags
 665     |> add_emoji_tags
 666     |> add_attributed_to
 667     |> add_likes
 668     |> prepare_attachments
 669     |> set_conversation
 670     |> set_reply_to_uri
 671     |> strip_internal_fields
 672     |> strip_internal_tags
 673   end
 674
 675   #  @doc
 676   #  """
 677   #  internal -> Mastodon
 678   #  """
 679
 680   def prepare_outgoing(%{"type" => "Create", "object" => object} = data) do
 681     object =
 682       object
 683       |> prepare_object
 684
 685     data =
 686       data
 687       |> Map.put("object", object)
 688       |> Map.merge(Utils.make_json_ld_header())
 689
 690     {:ok, data}
 691   end
 692
 693   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 694   # because of course it does.
 695   def prepare_outgoing(%{"type" => "Accept"} = data) do
 696     with follow_activity <- Activity.normalize(data["object"]) do
 697       object = %{
 698         "actor" => follow_activity.actor,
 699         "object" => follow_activity.data["object"],
 700         "id" => follow_activity.data["id"],
 701         "type" => "Follow"
 702       }
 703
 704       data =
 705         data
 706         |> Map.put("object", object)
 707         |> Map.merge(Utils.make_json_ld_header())
 708
 709       {:ok, data}
 710     end
 711   end
 712
 713   def prepare_outgoing(%{"type" => "Reject"} = data) do
 714     with follow_activity <- Activity.normalize(data["object"]) do
 715       object = %{
 716         "actor" => follow_activity.actor,
 717         "object" => follow_activity.data["object"],
 718         "id" => follow_activity.data["id"],
 719         "type" => "Follow"
 720       }
 721
 722       data =
 723         data
 724         |> Map.put("object", object)
 725         |> Map.merge(Utils.make_json_ld_header())
 726
 727       {:ok, data}
 728     end
 729   end
 730
 731   def prepare_outgoing(%{"type" => _type} = data) do
 732     data =
 733       data
 734       |> maybe_fix_object_url
 735       |> Map.merge(Utils.make_json_ld_header())
 736
 737     {:ok, data}
 738   end
 739
 740   def maybe_fix_object_url(data) do
 741     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 742       case fetch_obj_helper(data["object"]) do
 743         {:ok, relative_object} ->
 744           if relative_object.data["external_url"] do
 745             _data =
 746               data
 747               |> Map.put("object", relative_object.data["external_url"])
 748           else
 749             data
 750           end
 751
 752         e ->
 753           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 754           data
 755       end
 756     else
 757       data
 758     end
 759   end
 760
 761   def add_hashtags(object) do
 762     tags =
 763       (object["tag"] || [])
 764       |> Enum.map(fn tag ->
 765         %{
 766           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 767           "name" => "##{tag}",
 768           "type" => "Hashtag"
 769         }
 770       end)
 771
 772     object
 773     |> Map.put("tag", tags)
 774   end
 775
 776   def add_mention_tags(object) do
 777     mentions =
 778       object
 779       |> Utils.get_notified_from_object()
 780       |> Enum.map(fn user ->
 781         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 782       end)
 783
 784     tags = object["tag"] || []
 785
 786     object
 787     |> Map.put("tag", tags ++ mentions)
 788   end
 789
 790   # TODO: we should probably send mtime instead of unix epoch time for updated
 791   def add_emoji_tags(object) do
 792     tags = object["tag"] || []
 793     emoji = object["emoji"] || []
 794
 795     out =
 796       emoji
 797       |> Enum.map(fn {name, url} ->
 798         %{
 799           "icon" => %{"url" => url, "type" => "Image"},
 800           "name" => ":" <> name <> ":",
 801           "type" => "Emoji",
 802           "updated" => "1970-01-01T00:00:00Z",
 803           "id" => url
 804         }
 805       end)
 806
 807     object
 808     |> Map.put("tag", tags ++ out)
 809   end
 810
 811   def set_conversation(object) do
 812     Map.put(object, "conversation", object["context"])
 813   end
 814
 815   def set_sensitive(object) do
 816     tags = object["tag"] || []
 817     Map.put(object, "sensitive", "nsfw" in tags)
 818   end
 819
 820   def add_attributed_to(object) do
 821     attributedTo = object["attributedTo"] || object["actor"]
 822
 823     object
 824     |> Map.put("attributedTo", attributedTo)
 825   end
 826
 827   def add_likes(%{"id" => id, "like_count" => likes} = object) do
 828     likes = %{
 829       "id" => "#{id}/likes",
 830       "first" => "#{id}/likes?page=1",
 831       "type" => "OrderedCollection",
 832       "totalItems" => likes
 833     }
 834
 835     object
 836     |> Map.put("likes", likes)
 837   end
 838
 839   def add_likes(object) do
 840     object
 841   end
 842
 843   def prepare_attachments(object) do
 844     attachments =
 845       (object["attachment"] || [])
 846       |> Enum.map(fn data ->
 847         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 848         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 849       end)
 850
 851     object
 852     |> Map.put("attachment", attachments)
 853   end
 854
 855   defp strip_internal_fields(object) do
 856     object
 857     |> Map.drop([
 858       "like_count",
 859       "announcements",
 860       "announcement_count",
 861       "emoji",
 862       "context_id"
 863     ])
 864   end
 865
 866   defp strip_internal_tags(%{"tag" => tags} = object) do
 867     tags =
 868       tags
 869       |> Enum.filter(fn x -> is_map(x) end)
 870
 871     object
 872     |> Map.put("tag", tags)
 873   end
 874
 875   defp strip_internal_tags(object), do: object
 876
 877   defp user_upgrade_task(user) do
 878     old_follower_address = User.ap_followers(user)
 879
 880     q =
 881       from(
 882         u in User,
 883         where: ^old_follower_address in u.following,
 884         update: [
 885           set: [
 886             following:
 887               fragment(
 888                 "array_replace(?,?,?)",
 889                 u.following,
 890                 ^old_follower_address,
 891                 ^user.follower_address
 892               )
 893           ]
 894         ]
 895       )
 896
 897     Repo.update_all(q, [])
 898
 899     maybe_retire_websub(user.ap_id)
 900
 901     q =
 902       from(
 903         a in Activity,
 904         where: ^old_follower_address in a.recipients,
 905         update: [
 906           set: [
 907             recipients:
 908               fragment(
 909                 "array_replace(?,?,?)",
 910                 a.recipients,
 911                 ^old_follower_address,
 912                 ^user.follower_address
 913               )
 914           ]
 915         ]
 916       )
 917
 918     Repo.update_all(q, [])
 919   end
 920
 921   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 922     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 923          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 924       already_ap = User.ap_enabled?(user)
 925
 926       {:ok, user} =
 927         User.upgrade_changeset(user, data)
 928         |> Repo.update()
 929
 930       if !already_ap do
 931         # This could potentially take a long time, do it in the background
 932         if async do
 933           Task.start(fn ->
 934             user_upgrade_task(user)
 935           end)
 936         else
 937           user_upgrade_task(user)
 938         end
 939       end
 940
 941       {:ok, user}
 942     else
 943       e -> e
 944     end
 945   end
 946
 947   def maybe_retire_websub(ap_id) do
 948     # some sanity checks
 949     if is_binary(ap_id) && String.length(ap_id) > 8 do
 950       q =
 951         from(
 952           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 953           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 954         )
 955
 956       Repo.delete_all(q)
 957     end
 958   end
 959
 960   def maybe_fix_user_url(data) do
 961     if is_map(data["url"]) do
 962       Map.put(data, "url", data["url"]["href"])
 963     else
 964       data
 965     end
 966   end
 967
 968   def maybe_fix_user_object(data) do
 969     data
 970     |> maybe_fix_user_url
 971   end
 972 end