git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.Object
  12   alias Pleroma.Object.Containment
  13   alias Pleroma.Repo
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16   alias Pleroma.Web.ActivityPub.Utils
  17   alias Pleroma.Web.ActivityPub.Visibility
  18   alias Pleroma.Web.Federator
  19   alias Pleroma.Workers.TransmogrifierWorker
  20
  21   import Ecto.Query
  22
  23   require Logger
  24   require Pleroma.Constants
  25
  26   @doc """
  27   Modifies an incoming AP object (mastodon format) to our internal format.
  28   """
  29   def fix_object(object, options \\ []) do
  30     object
  31     |> strip_internal_fields
  32     |> fix_actor
  33     |> fix_url
  34     |> fix_attachments
  35     |> fix_context
  36     |> fix_in_reply_to(options)
  37     |> fix_emoji
  38     |> fix_tag
  39     |> fix_content_map
  40     |> fix_addressing
  41     |> fix_summary
  42     |> fix_type(options)
  43   end
  44
  45   def fix_summary(%{"summary" => nil} = object) do
  46     Map.put(object, "summary", "")
  47   end
  48
  49   def fix_summary(%{"summary" => _} = object) do
  50     # summary is present, nothing to do
  51     object
  52   end
  53
  54   def fix_summary(object), do: Map.put(object, "summary", "")
  55
  56   def fix_addressing_list(map, field) do
  57     cond do
  58       is_binary(map[field]) ->
  59         Map.put(map, field, [map[field]])
  60
  61       is_nil(map[field]) ->
  62         Map.put(map, field, [])
  63
  64       true ->
  65         map
  66     end
  67   end
  68
  69   def fix_explicit_addressing(
  70         %{"to" => to, "cc" => cc} = object,
  71         explicit_mentions,
  72         follower_collection
  73       ) do
  74     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  75
  76     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  77
  78     final_cc =
  79       (cc ++ explicit_cc)
  80       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  81       |> Enum.uniq()
  82
  83     object
  84     |> Map.put("to", explicit_to)
  85     |> Map.put("cc", final_cc)
  86   end
  87
  88   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  89
  90   # if directMessage flag is set to true, leave the addressing alone
  91   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  92
  93   def fix_explicit_addressing(object) do
  94     explicit_mentions = Utils.determine_explicit_mentions(object)
  95
  96     %User{follower_address: follower_collection} =
  97       object
  98       |> Containment.get_actor()
  99       |> User.get_cached_by_ap_id()
 100
 101     explicit_mentions =
 102       explicit_mentions ++
 103         [
 104           Pleroma.Constants.as_public(),
 105           follower_collection
 106         ]
 107
 108     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 109   end
 110
 111   # if as:Public is addressed, then make sure the followers collection is also addressed
 112   # so that the activities will be delivered to local users.
 113   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 114     recipients = to ++ cc
 115
 116     if followers_collection not in recipients do
 117       cond do
 118         Pleroma.Constants.as_public() in cc ->
 119           to = to ++ [followers_collection]
 120           Map.put(object, "to", to)
 121
 122         Pleroma.Constants.as_public() in to ->
 123           cc = cc ++ [followers_collection]
 124           Map.put(object, "cc", cc)
 125
 126         true ->
 127           object
 128       end
 129     else
 130       object
 131     end
 132   end
 133
 134   def fix_implicit_addressing(object, _), do: object
 135
 136   def fix_addressing(object) do
 137     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 138     followers_collection = User.ap_followers(user)
 139
 140     object
 141     |> fix_addressing_list("to")
 142     |> fix_addressing_list("cc")
 143     |> fix_addressing_list("bto")
 144     |> fix_addressing_list("bcc")
 145     |> fix_explicit_addressing()
 146     |> fix_implicit_addressing(followers_collection)
 147   end
 148
 149   def fix_actor(%{"attributedTo" => actor} = object) do
 150     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 151   end
 152
 153   def fix_in_reply_to(object, options \\ [])
 154
 155   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 156       when not is_nil(in_reply_to) do
 157     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 158     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 159
 160     if Federator.allowed_incoming_reply_depth?(options[:depth]) do
 161       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 162            %Activity{} = _ <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 163         object
 164         |> Map.put("inReplyTo", replied_object.data["id"])
 165         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 166         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 167         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 168       else
 169         e ->
 170           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 171           object
 172       end
 173     else
 174       object
 175     end
 176   end
 177
 178   def fix_in_reply_to(object, _options), do: object
 179
 180   defp prepare_in_reply_to(in_reply_to) do
 181     cond do
 182       is_bitstring(in_reply_to) ->
 183         in_reply_to
 184
 185       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 186         in_reply_to["id"]
 187
 188       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 189         Enum.at(in_reply_to, 0)
 190
 191       true ->
 192         ""
 193     end
 194   end
 195
 196   def fix_context(object) do
 197     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 198
 199     object
 200     |> Map.put("context", context)
 201     |> Map.put("conversation", context)
 202   end
 203
 204   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 205     attachments =
 206       Enum.map(attachment, fn data ->
 207         media_type = data["mediaType"] || data["mimeType"]
 208         href = data["url"] || data["href"]
 209         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 210
 211         data
 212         |> Map.put("mediaType", media_type)
 213         |> Map.put("url", url)
 214       end)
 215
 216     Map.put(object, "attachment", attachments)
 217   end
 218
 219   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 220     object
 221     |> Map.put("attachment", [attachment])
 222     |> fix_attachments()
 223   end
 224
 225   def fix_attachments(object), do: object
 226
 227   def fix_url(%{"url" => url} = object) when is_map(url) do
 228     Map.put(object, "url", url["href"])
 229   end
 230
 231   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 232     first_element = Enum.at(url, 0)
 233
 234     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 235
 236     object
 237     |> Map.put("attachment", [first_element])
 238     |> Map.put("url", link_element["href"])
 239   end
 240
 241   def fix_url(%{"type" => object_type, "url" => url} = object)
 242       when object_type != "Video" and is_list(url) do
 243     first_element = Enum.at(url, 0)
 244
 245     url_string =
 246       cond do
 247         is_bitstring(first_element) -> first_element
 248         is_map(first_element) -> first_element["href"] || ""
 249         true -> ""
 250       end
 251
 252     Map.put(object, "url", url_string)
 253   end
 254
 255   def fix_url(object), do: object
 256
 257   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 258     emoji =
 259       tags
 260       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 261       |> Enum.reduce(%{}, fn data, mapping ->
 262         name = String.trim(data["name"], ":")
 263
 264         Map.put(mapping, name, data["icon"]["url"])
 265       end)
 266
 267     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 268     emoji = Map.merge(object["emoji"] || %{}, emoji)
 269
 270     Map.put(object, "emoji", emoji)
 271   end
 272
 273   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 274     name = String.trim(tag["name"], ":")
 275     emoji = %{name => tag["icon"]["url"]}
 276
 277     Map.put(object, "emoji", emoji)
 278   end
 279
 280   def fix_emoji(object), do: object
 281
 282   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 283     tags =
 284       tag
 285       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 286       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 287
 288     Map.put(object, "tag", tag ++ tags)
 289   end
 290
 291   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 292     combined = [tag, String.slice(hashtag, 1..-1)]
 293
 294     Map.put(object, "tag", combined)
 295   end
 296
 297   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 298
 299   def fix_tag(object), do: object
 300
 301   # content map usually only has one language so this will do for now.
 302   def fix_content_map(%{"contentMap" => content_map} = object) do
 303     content_groups = Map.to_list(content_map)
 304     {_, content} = Enum.at(content_groups, 0)
 305
 306     Map.put(object, "content", content)
 307   end
 308
 309   def fix_content_map(object), do: object
 310
 311   def fix_type(object, options \\ [])
 312
 313   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 314       when is_binary(reply_id) do
 315     with true <- Federator.allowed_incoming_reply_depth?(options[:depth]),
 316          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 317       Map.put(object, "type", "Answer")
 318     else
 319       _ -> object
 320     end
 321   end
 322
 323   def fix_type(object, _), do: object
 324
 325   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 326     with true <- id =~ "follows",
 327          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 328          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 329       {:ok, activity}
 330     else
 331       _ -> {:error, nil}
 332     end
 333   end
 334
 335   defp mastodon_follow_hack(_, _), do: {:error, nil}
 336
 337   defp get_follow_activity(follow_object, followed) do
 338     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 339          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 340       {:ok, activity}
 341     else
 342       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 343       {:activity, nil} ->
 344         mastodon_follow_hack(follow_object, followed)
 345
 346       _ ->
 347         {:error, nil}
 348     end
 349   end
 350
 351   # Reduce the object list to find the reported user.
 352   defp get_reported(objects) do
 353     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 354       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 355         {:halt, user}
 356       else
 357         _ -> {:cont, nil}
 358       end
 359     end)
 360   end
 361
 362   def handle_incoming(data, options \\ [])
 363
 364   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 365   # with nil ID.
 366   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 367     with context <- data["context"] || Utils.generate_context_id(),
 368          content <- data["content"] || "",
 369          %User{} = actor <- User.get_cached_by_ap_id(actor),
 370          # Reduce the object list to find the reported user.
 371          %User{} = account <- get_reported(objects),
 372          # Remove the reported user from the object list.
 373          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 374       %{
 375         actor: actor,
 376         context: context,
 377         account: account,
 378         statuses: statuses,
 379         content: content,
 380         additional: %{"cc" => [account.ap_id]}
 381       }
 382       |> ActivityPub.flag()
 383     end
 384   end
 385
 386   # disallow objects with bogus IDs
 387   def handle_incoming(%{"id" => nil}, _options), do: :error
 388   def handle_incoming(%{"id" => ""}, _options), do: :error
 389   # length of https:// = 8, should validate better, but good enough for now.
 390   def handle_incoming(%{"id" => id}, _options) when is_binary(id) and byte_size(id) < 8,
 391     do: :error
 392
 393   # TODO: validate those with a Ecto scheme
 394   # - tags
 395   # - emoji
 396   def handle_incoming(
 397         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 398         options
 399       )
 400       when objtype in ["Article", "Event", "Note", "Video", "Page", "Question", "Answer"] do
 401     actor = Containment.get_actor(data)
 402
 403     data =
 404       Map.put(data, "actor", actor)
 405       |> fix_addressing
 406
 407     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 408          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 409       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 410       object = fix_object(data["object"], options)
 411
 412       params = %{
 413         to: data["to"],
 414         object: object,
 415         actor: user,
 416         context: object["conversation"],
 417         local: false,
 418         published: data["published"],
 419         additional:
 420           Map.take(data, [
 421             "cc",
 422             "directMessage",
 423             "id"
 424           ])
 425       }
 426
 427       ActivityPub.create(params)
 428     else
 429       %Activity{} = activity -> {:ok, activity}
 430       _e -> :error
 431     end
 432   end
 433
 434   def handle_incoming(
 435         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 436         options
 437       ) do
 438     actor = Containment.get_actor(data)
 439
 440     data =
 441       Map.put(data, "actor", actor)
 442       |> fix_addressing
 443
 444     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 445       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 446       object = fix_object(object, options)
 447
 448       params = %{
 449         to: data["to"],
 450         object: object,
 451         actor: user,
 452         context: nil,
 453         local: false,
 454         published: data["published"],
 455         additional: Map.take(data, ["cc", "id"])
 456       }
 457
 458       ActivityPub.listen(params)
 459     else
 460       _e -> :error
 461     end
 462   end
 463
 464   def handle_incoming(
 465         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 466         _options
 467       ) do
 468     with %User{local: true} = followed <-
 469            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 470          {:ok, %User{} = follower} <-
 471            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 472          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 473       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 474            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 475            {_, false} <- {:user_locked, User.locked?(followed)},
 476            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 477            {_, {:ok, _}} <-
 478              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 479            {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 480         ActivityPub.accept(%{
 481           to: [follower.ap_id],
 482           actor: followed,
 483           object: data,
 484           local: true
 485         })
 486       else
 487         {:user_blocked, true} ->
 488           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 489           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 490
 491           ActivityPub.reject(%{
 492             to: [follower.ap_id],
 493             actor: followed,
 494             object: data,
 495             local: true
 496           })
 497
 498         {:follow, {:error, _}} ->
 499           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 500           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 501
 502           ActivityPub.reject(%{
 503             to: [follower.ap_id],
 504             actor: followed,
 505             object: data,
 506             local: true
 507           })
 508
 509         {:user_locked, true} ->
 510           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "pending")
 511           :noop
 512       end
 513
 514       {:ok, activity}
 515     else
 516       _e ->
 517         :error
 518     end
 519   end
 520
 521   def handle_incoming(
 522         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 523         _options
 524       ) do
 525     with actor <- Containment.get_actor(data),
 526          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 527          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 528          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 529          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 530          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 531       ActivityPub.accept(%{
 532         to: follow_activity.data["to"],
 533         type: "Accept",
 534         actor: followed,
 535         object: follow_activity.data["id"],
 536         local: false,
 537         activity_id: id
 538       })
 539     else
 540       _e -> :error
 541     end
 542   end
 543
 544   def handle_incoming(
 545         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 546         _options
 547       ) do
 548     with actor <- Containment.get_actor(data),
 549          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 550          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 551          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 552          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 553          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "reject"),
 554          {:ok, activity} <-
 555            ActivityPub.reject(%{
 556              to: follow_activity.data["to"],
 557              type: "Reject",
 558              actor: followed,
 559              object: follow_activity.data["id"],
 560              local: false,
 561              activity_id: id
 562            }) do
 563       {:ok, activity}
 564     else
 565       _e -> :error
 566     end
 567   end
 568
 569   @misskey_reactions %{
 570     "like" => "👍",
 571     "love" => "❤️",
 572     "laugh" => "😆",
 573     "hmm" => "🤔",
 574     "surprise" => "😮",
 575     "congrats" => "🎉",
 576     "angry" => "💢",
 577     "confused" => "😥",
 578     "rip" => "😇",
 579     "pudding" => "🍮",
 580     "star" => "⭐"
 581   }
 582
 583   @doc "Rewrite misskey likes into EmojiReactions"
 584   def handle_incoming(
 585         %{
 586           "type" => "Like",
 587           "_misskey_reaction" => reaction
 588         } = data,
 589         options
 590       ) do
 591     data
 592     |> Map.put("type", "EmojiReaction")
 593     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 594     |> handle_incoming(options)
 595   end
 596
 597   def handle_incoming(
 598         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data,
 599         _options
 600       ) do
 601     with actor <- Containment.get_actor(data),
 602          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 603          {:ok, object} <- get_obj_helper(object_id),
 604          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 605       {:ok, activity}
 606     else
 607       _e -> :error
 608     end
 609   end
 610
 611   def handle_incoming(
 612         %{
 613           "type" => "EmojiReaction",
 614           "object" => object_id,
 615           "actor" => _actor,
 616           "id" => id,
 617           "content" => emoji
 618         } = data,
 619         _options
 620       ) do
 621     with actor <- Containment.get_actor(data),
 622          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 623          {:ok, object} <- get_obj_helper(object_id),
 624          {:ok, activity, _object} <-
 625            ActivityPub.react_with_emoji(actor, object, emoji, activity_id: id, local: false) do
 626       {:ok, activity}
 627     else
 628       _e -> :error
 629     end
 630   end
 631
 632   def handle_incoming(
 633         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 634         _options
 635       ) do
 636     with actor <- Containment.get_actor(data),
 637          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 638          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 639          public <- Visibility.is_public?(data),
 640          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 641       {:ok, activity}
 642     else
 643       _e -> :error
 644     end
 645   end
 646
 647   def handle_incoming(
 648         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 649           data,
 650         _options
 651       )
 652       when object_type in [
 653              "Person",
 654              "Application",
 655              "Service",
 656              "Organization"
 657            ] do
 658     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 659       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 660
 661       actor
 662       |> User.upgrade_changeset(new_user_data, true)
 663       |> User.update_and_set_cache()
 664
 665       ActivityPub.update(%{
 666         local: false,
 667         to: data["to"] || [],
 668         cc: data["cc"] || [],
 669         object: object,
 670         actor: actor_id,
 671         activity_id: data["id"]
 672       })
 673     else
 674       e ->
 675         Logger.error(e)
 676         :error
 677     end
 678   end
 679
 680   # TODO: We presently assume that any actor on the same origin domain as the object being
 681   # deleted has the rights to delete that object.  A better way to validate whether or not
 682   # the object should be deleted is to refetch the object URI, which should return either
 683   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 684   # place.
 685   def handle_incoming(
 686         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 687         _options
 688       ) do
 689     object_id = Utils.get_ap_id(object_id)
 690
 691     with actor <- Containment.get_actor(data),
 692          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 693          {:ok, object} <- get_obj_helper(object_id),
 694          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 695          {:ok, activity} <-
 696            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 697       {:ok, activity}
 698     else
 699       nil ->
 700         case User.get_cached_by_ap_id(object_id) do
 701           %User{ap_id: ^actor} = user ->
 702             User.delete(user)
 703
 704           nil ->
 705             :error
 706         end
 707
 708       _e ->
 709         :error
 710     end
 711   end
 712
 713   def handle_incoming(
 714         %{
 715           "type" => "Undo",
 716           "object" => %{"type" => "Announce", "object" => object_id},
 717           "actor" => _actor,
 718           "id" => id
 719         } = data,
 720         _options
 721       ) do
 722     with actor <- Containment.get_actor(data),
 723          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 724          {:ok, object} <- get_obj_helper(object_id),
 725          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 726       {:ok, activity}
 727     else
 728       _e -> :error
 729     end
 730   end
 731
 732   def handle_incoming(
 733         %{
 734           "type" => "Undo",
 735           "object" => %{"type" => "Follow", "object" => followed},
 736           "actor" => follower,
 737           "id" => id
 738         } = _data,
 739         _options
 740       ) do
 741     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 742          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 743          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 744       User.unfollow(follower, followed)
 745       {:ok, activity}
 746     else
 747       _e -> :error
 748     end
 749   end
 750
 751   def handle_incoming(
 752         %{
 753           "type" => "Undo",
 754           "object" => %{"type" => "EmojiReaction", "id" => reaction_activity_id},
 755           "actor" => _actor,
 756           "id" => id
 757         } = data,
 758         _options
 759       ) do
 760     with actor <- Containment.get_actor(data),
 761          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 762          {:ok, activity, _} <-
 763            ActivityPub.unreact_with_emoji(actor, reaction_activity_id,
 764              activity_id: id,
 765              local: false
 766            ) do
 767       {:ok, activity}
 768     else
 769       _e -> :error
 770     end
 771   end
 772
 773   def handle_incoming(
 774         %{
 775           "type" => "Undo",
 776           "object" => %{"type" => "Block", "object" => blocked},
 777           "actor" => blocker,
 778           "id" => id
 779         } = _data,
 780         _options
 781       ) do
 782     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 783          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 784          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 785       User.unblock(blocker, blocked)
 786       {:ok, activity}
 787     else
 788       _e -> :error
 789     end
 790   end
 791
 792   def handle_incoming(
 793         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 794         _options
 795       ) do
 796     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 797          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 798          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 799       User.unfollow(blocker, blocked)
 800       User.block(blocker, blocked)
 801       {:ok, activity}
 802     else
 803       _e -> :error
 804     end
 805   end
 806
 807   def handle_incoming(
 808         %{
 809           "type" => "Undo",
 810           "object" => %{"type" => "Like", "object" => object_id},
 811           "actor" => _actor,
 812           "id" => id
 813         } = data,
 814         _options
 815       ) do
 816     with actor <- Containment.get_actor(data),
 817          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 818          {:ok, object} <- get_obj_helper(object_id),
 819          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 820       {:ok, activity}
 821     else
 822       _e -> :error
 823     end
 824   end
 825
 826   # For Undos that don't have the complete object attached, try to find it in our database.
 827   def handle_incoming(
 828         %{
 829           "type" => "Undo",
 830           "object" => object
 831         } = activity,
 832         options
 833       )
 834       when is_binary(object) do
 835     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 836       activity
 837       |> Map.put("object", data)
 838       |> handle_incoming(options)
 839     else
 840       _e -> :error
 841     end
 842   end
 843
 844   def handle_incoming(
 845         %{
 846           "type" => "Move",
 847           "actor" => origin_actor,
 848           "object" => origin_actor,
 849           "target" => target_actor
 850         },
 851         _options
 852       ) do
 853     with %User{} = origin_user <- User.get_cached_by_ap_id(origin_actor),
 854          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_actor),
 855          true <- origin_actor in target_user.also_known_as do
 856       ActivityPub.move(origin_user, target_user, false)
 857     else
 858       _e -> :error
 859     end
 860   end
 861
 862   def handle_incoming(_, _), do: :error
 863
 864   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 865   def get_obj_helper(id, options \\ []) do
 866     case Object.normalize(id, true, options) do
 867       %Object{} = object -> {:ok, object}
 868       _ -> nil
 869     end
 870   end
 871
 872   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 873   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 874         ap_id: ap_id
 875       })
 876       when attributed_to == ap_id do
 877     with {:ok, activity} <-
 878            handle_incoming(%{
 879              "type" => "Create",
 880              "to" => data["to"],
 881              "cc" => data["cc"],
 882              "actor" => attributed_to,
 883              "object" => data
 884            }) do
 885       {:ok, Object.normalize(activity)}
 886     else
 887       _ -> get_obj_helper(object_id)
 888     end
 889   end
 890
 891   def get_embedded_obj_helper(object_id, _) do
 892     get_obj_helper(object_id)
 893   end
 894
 895   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 896     with false <- String.starts_with?(in_reply_to, "http"),
 897          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 898       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 899     else
 900       _e -> object
 901     end
 902   end
 903
 904   def set_reply_to_uri(obj), do: obj
 905
 906   # Prepares the object of an outgoing create activity.
 907   def prepare_object(object) do
 908     object
 909     |> set_sensitive
 910     |> add_hashtags
 911     |> add_mention_tags
 912     |> add_emoji_tags
 913     |> add_attributed_to
 914     |> prepare_attachments
 915     |> set_conversation
 916     |> set_reply_to_uri
 917     |> strip_internal_fields
 918     |> strip_internal_tags
 919     |> set_type
 920   end
 921
 922   #  @doc
 923   #  """
 924   #  internal -> Mastodon
 925   #  """
 926
 927   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 928       when activity_type in ["Create", "Listen"] do
 929     object =
 930       object_id
 931       |> Object.normalize()
 932       |> Map.get(:data)
 933       |> prepare_object
 934
 935     data =
 936       data
 937       |> Map.put("object", object)
 938       |> Map.merge(Utils.make_json_ld_header())
 939       |> Map.delete("bcc")
 940
 941     {:ok, data}
 942   end
 943
 944   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 945     object =
 946       object_id
 947       |> Object.normalize()
 948
 949     data =
 950       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 951         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 952       else
 953         data |> maybe_fix_object_url
 954       end
 955
 956     data =
 957       data
 958       |> strip_internal_fields
 959       |> Map.merge(Utils.make_json_ld_header())
 960       |> Map.delete("bcc")
 961
 962     {:ok, data}
 963   end
 964
 965   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 966   # because of course it does.
 967   def prepare_outgoing(%{"type" => "Accept"} = data) do
 968     with follow_activity <- Activity.normalize(data["object"]) do
 969       object = %{
 970         "actor" => follow_activity.actor,
 971         "object" => follow_activity.data["object"],
 972         "id" => follow_activity.data["id"],
 973         "type" => "Follow"
 974       }
 975
 976       data =
 977         data
 978         |> Map.put("object", object)
 979         |> Map.merge(Utils.make_json_ld_header())
 980
 981       {:ok, data}
 982     end
 983   end
 984
 985   def prepare_outgoing(%{"type" => "Reject"} = data) do
 986     with follow_activity <- Activity.normalize(data["object"]) do
 987       object = %{
 988         "actor" => follow_activity.actor,
 989         "object" => follow_activity.data["object"],
 990         "id" => follow_activity.data["id"],
 991         "type" => "Follow"
 992       }
 993
 994       data =
 995         data
 996         |> Map.put("object", object)
 997         |> Map.merge(Utils.make_json_ld_header())
 998
 999       {:ok, data}
1000     end
1001   end
1002
1003   def prepare_outgoing(%{"type" => _type} = data) do
1004     data =
1005       data
1006       |> strip_internal_fields
1007       |> maybe_fix_object_url
1008       |> Map.merge(Utils.make_json_ld_header())
1009
1010     {:ok, data}
1011   end
1012
1013   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
1014     with false <- String.starts_with?(object, "http"),
1015          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
1016          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
1017            relative_object do
1018       Map.put(data, "object", external_url)
1019     else
1020       {:fetch, e} ->
1021         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
1022         data
1023
1024       _ ->
1025         data
1026     end
1027   end
1028
1029   def maybe_fix_object_url(data), do: data
1030
1031   def add_hashtags(object) do
1032     tags =
1033       (object["tag"] || [])
1034       |> Enum.map(fn
1035         # Expand internal representation tags into AS2 tags.
1036         tag when is_binary(tag) ->
1037           %{
1038             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
1039             "name" => "##{tag}",
1040             "type" => "Hashtag"
1041           }
1042
1043         # Do not process tags which are already AS2 tag objects.
1044         tag when is_map(tag) ->
1045           tag
1046       end)
1047
1048     Map.put(object, "tag", tags)
1049   end
1050
1051   def add_mention_tags(object) do
1052     mentions =
1053       object
1054       |> Utils.get_notified_from_object()
1055       |> Enum.map(&build_mention_tag/1)
1056
1057     tags = object["tag"] || []
1058
1059     Map.put(object, "tag", tags ++ mentions)
1060   end
1061
1062   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1063     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1064   end
1065
1066   def take_emoji_tags(%User{emoji: emoji}) do
1067     emoji
1068     |> Enum.flat_map(&Map.to_list/1)
1069     |> Enum.map(&build_emoji_tag/1)
1070   end
1071
1072   # TODO: we should probably send mtime instead of unix epoch time for updated
1073   def add_emoji_tags(%{"emoji" => emoji} = object) do
1074     tags = object["tag"] || []
1075
1076     out = Enum.map(emoji, &build_emoji_tag/1)
1077
1078     Map.put(object, "tag", tags ++ out)
1079   end
1080
1081   def add_emoji_tags(object), do: object
1082
1083   defp build_emoji_tag({name, url}) do
1084     %{
1085       "icon" => %{"url" => url, "type" => "Image"},
1086       "name" => ":" <> name <> ":",
1087       "type" => "Emoji",
1088       "updated" => "1970-01-01T00:00:00Z",
1089       "id" => url
1090     }
1091   end
1092
1093   def set_conversation(object) do
1094     Map.put(object, "conversation", object["context"])
1095   end
1096
1097   def set_sensitive(object) do
1098     tags = object["tag"] || []
1099     Map.put(object, "sensitive", "nsfw" in tags)
1100   end
1101
1102   def set_type(%{"type" => "Answer"} = object) do
1103     Map.put(object, "type", "Note")
1104   end
1105
1106   def set_type(object), do: object
1107
1108   def add_attributed_to(object) do
1109     attributed_to = object["attributedTo"] || object["actor"]
1110     Map.put(object, "attributedTo", attributed_to)
1111   end
1112
1113   def prepare_attachments(object) do
1114     attachments =
1115       (object["attachment"] || [])
1116       |> Enum.map(fn data ->
1117         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1118         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1119       end)
1120
1121     Map.put(object, "attachment", attachments)
1122   end
1123
1124   def strip_internal_fields(object) do
1125     object
1126     |> Map.drop(Pleroma.Constants.object_internal_fields())
1127   end
1128
1129   defp strip_internal_tags(%{"tag" => tags} = object) do
1130     tags = Enum.filter(tags, fn x -> is_map(x) end)
1131
1132     Map.put(object, "tag", tags)
1133   end
1134
1135   defp strip_internal_tags(object), do: object
1136
1137   def perform(:user_upgrade, user) do
1138     # we pass a fake user so that the followers collection is stripped away
1139     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1140
1141     from(
1142       a in Activity,
1143       where: ^old_follower_address in a.recipients,
1144       update: [
1145         set: [
1146           recipients:
1147             fragment(
1148               "array_replace(?,?,?)",
1149               a.recipients,
1150               ^old_follower_address,
1151               ^user.follower_address
1152             )
1153         ]
1154       ]
1155     )
1156     |> Repo.update_all([])
1157   end
1158
1159   def upgrade_user_from_ap_id(ap_id) do
1160     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1161          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1162          already_ap <- User.ap_enabled?(user),
1163          {:ok, user} <- upgrade_user(user, data) do
1164       if not already_ap do
1165         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1166       end
1167
1168       {:ok, user}
1169     else
1170       %User{} = user -> {:ok, user}
1171       e -> e
1172     end
1173   end
1174
1175   defp upgrade_user(user, data) do
1176     user
1177     |> User.upgrade_changeset(data, true)
1178     |> User.update_and_set_cache()
1179   end
1180
1181   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1182     Map.put(data, "url", url["href"])
1183   end
1184
1185   def maybe_fix_user_url(data), do: data
1186
1187   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1188 end