git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.Object
  11   alias Pleroma.Object.Containment
  12   alias Pleroma.Repo
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15   alias Pleroma.Web.ActivityPub.Utils
  16   alias Pleroma.Web.ActivityPub.Visibility
  17   alias Pleroma.Web.Federator
  18   alias Pleroma.Workers.TransmogrifierWorker
  19
  20   import Ecto.Query
  21
  22   require Logger
  23   require Pleroma.Constants
  24
  25   @doc """
  26   Modifies an incoming AP object (mastodon format) to our internal format.
  27   """
  28   def fix_object(object, options \\ []) do
  29     object
  30     |> strip_internal_fields
  31     |> fix_actor
  32     |> fix_url
  33     |> fix_attachments
  34     |> fix_context
  35     |> fix_in_reply_to(options)
  36     |> fix_emoji
  37     |> fix_tag
  38     |> fix_content_map
  39     |> fix_addressing
  40     |> fix_summary
  41     |> fix_type(options)
  42   end
  43
  44   def fix_summary(%{"summary" => nil} = object) do
  45     Map.put(object, "summary", "")
  46   end
  47
  48   def fix_summary(%{"summary" => _} = object) do
  49     # summary is present, nothing to do
  50     object
  51   end
  52
  53   def fix_summary(object), do: Map.put(object, "summary", "")
  54
  55   def fix_addressing_list(map, field) do
  56     cond do
  57       is_binary(map[field]) ->
  58         Map.put(map, field, [map[field]])
  59
  60       is_nil(map[field]) ->
  61         Map.put(map, field, [])
  62
  63       true ->
  64         map
  65     end
  66   end
  67
  68   def fix_explicit_addressing(
  69         %{"to" => to, "cc" => cc} = object,
  70         explicit_mentions,
  71         follower_collection
  72       ) do
  73     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  74
  75     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  76
  77     final_cc =
  78       (cc ++ explicit_cc)
  79       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  80       |> Enum.uniq()
  81
  82     object
  83     |> Map.put("to", explicit_to)
  84     |> Map.put("cc", final_cc)
  85   end
  86
  87   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  88
  89   # if directMessage flag is set to true, leave the addressing alone
  90   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  91
  92   def fix_explicit_addressing(object) do
  93     explicit_mentions = Utils.determine_explicit_mentions(object)
  94
  95     %User{follower_address: follower_collection} =
  96       object
  97       |> Containment.get_actor()
  98       |> User.get_cached_by_ap_id()
  99
 100     explicit_mentions =
 101       explicit_mentions ++
 102         [
 103           Pleroma.Constants.as_public(),
 104           follower_collection
 105         ]
 106
 107     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 108   end
 109
 110   # if as:Public is addressed, then make sure the followers collection is also addressed
 111   # so that the activities will be delivered to local users.
 112   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 113     recipients = to ++ cc
 114
 115     if followers_collection not in recipients do
 116       cond do
 117         Pleroma.Constants.as_public() in cc ->
 118           to = to ++ [followers_collection]
 119           Map.put(object, "to", to)
 120
 121         Pleroma.Constants.as_public() in to ->
 122           cc = cc ++ [followers_collection]
 123           Map.put(object, "cc", cc)
 124
 125         true ->
 126           object
 127       end
 128     else
 129       object
 130     end
 131   end
 132
 133   def fix_implicit_addressing(object, _), do: object
 134
 135   def fix_addressing(object) do
 136     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 137     followers_collection = User.ap_followers(user)
 138
 139     object
 140     |> fix_addressing_list("to")
 141     |> fix_addressing_list("cc")
 142     |> fix_addressing_list("bto")
 143     |> fix_addressing_list("bcc")
 144     |> fix_explicit_addressing()
 145     |> fix_implicit_addressing(followers_collection)
 146   end
 147
 148   def fix_actor(%{"attributedTo" => actor} = object) do
 149     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 150   end
 151
 152   def fix_in_reply_to(object, options \\ [])
 153
 154   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 155       when not is_nil(in_reply_to) do
 156     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 157     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 158
 159     if Federator.allowed_incoming_reply_depth?(options[:depth]) do
 160       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 161            %Activity{} = _ <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 162         object
 163         |> Map.put("inReplyTo", replied_object.data["id"])
 164         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 165         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 166         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 167       else
 168         e ->
 169           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 170           object
 171       end
 172     else
 173       object
 174     end
 175   end
 176
 177   def fix_in_reply_to(object, _options), do: object
 178
 179   defp prepare_in_reply_to(in_reply_to) do
 180     cond do
 181       is_bitstring(in_reply_to) ->
 182         in_reply_to
 183
 184       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 185         in_reply_to["id"]
 186
 187       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 188         Enum.at(in_reply_to, 0)
 189
 190       true ->
 191         ""
 192     end
 193   end
 194
 195   def fix_context(object) do
 196     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 197
 198     object
 199     |> Map.put("context", context)
 200     |> Map.put("conversation", context)
 201   end
 202
 203   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 204     attachments =
 205       Enum.map(attachment, fn data ->
 206         media_type = data["mediaType"] || data["mimeType"]
 207         href = data["url"] || data["href"]
 208         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 209
 210         data
 211         |> Map.put("mediaType", media_type)
 212         |> Map.put("url", url)
 213       end)
 214
 215     Map.put(object, "attachment", attachments)
 216   end
 217
 218   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 219     object
 220     |> Map.put("attachment", [attachment])
 221     |> fix_attachments()
 222   end
 223
 224   def fix_attachments(object), do: object
 225
 226   def fix_url(%{"url" => url} = object) when is_map(url) do
 227     Map.put(object, "url", url["href"])
 228   end
 229
 230   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 231     first_element = Enum.at(url, 0)
 232
 233     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 234
 235     object
 236     |> Map.put("attachment", [first_element])
 237     |> Map.put("url", link_element["href"])
 238   end
 239
 240   def fix_url(%{"type" => object_type, "url" => url} = object)
 241       when object_type != "Video" and is_list(url) do
 242     first_element = Enum.at(url, 0)
 243
 244     url_string =
 245       cond do
 246         is_bitstring(first_element) -> first_element
 247         is_map(first_element) -> first_element["href"] || ""
 248         true -> ""
 249       end
 250
 251     Map.put(object, "url", url_string)
 252   end
 253
 254   def fix_url(object), do: object
 255
 256   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 257     emoji =
 258       tags
 259       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 260       |> Enum.reduce(%{}, fn data, mapping ->
 261         name = String.trim(data["name"], ":")
 262
 263         Map.put(mapping, name, data["icon"]["url"])
 264       end)
 265
 266     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 267     emoji = Map.merge(object["emoji"] || %{}, emoji)
 268
 269     Map.put(object, "emoji", emoji)
 270   end
 271
 272   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 273     name = String.trim(tag["name"], ":")
 274     emoji = %{name => tag["icon"]["url"]}
 275
 276     Map.put(object, "emoji", emoji)
 277   end
 278
 279   def fix_emoji(object), do: object
 280
 281   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 282     tags =
 283       tag
 284       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 285       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 286
 287     Map.put(object, "tag", tag ++ tags)
 288   end
 289
 290   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 291     combined = [tag, String.slice(hashtag, 1..-1)]
 292
 293     Map.put(object, "tag", combined)
 294   end
 295
 296   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 297
 298   def fix_tag(object), do: object
 299
 300   # content map usually only has one language so this will do for now.
 301   def fix_content_map(%{"contentMap" => content_map} = object) do
 302     content_groups = Map.to_list(content_map)
 303     {_, content} = Enum.at(content_groups, 0)
 304
 305     Map.put(object, "content", content)
 306   end
 307
 308   def fix_content_map(object), do: object
 309
 310   def fix_type(object, options \\ [])
 311
 312   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 313       when is_binary(reply_id) do
 314     with true <- Federator.allowed_incoming_reply_depth?(options[:depth]),
 315          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 316       Map.put(object, "type", "Answer")
 317     else
 318       _ -> object
 319     end
 320   end
 321
 322   def fix_type(object, _), do: object
 323
 324   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 325     with true <- id =~ "follows",
 326          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 327          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 328       {:ok, activity}
 329     else
 330       _ -> {:error, nil}
 331     end
 332   end
 333
 334   defp mastodon_follow_hack(_, _), do: {:error, nil}
 335
 336   defp get_follow_activity(follow_object, followed) do
 337     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 338          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 339       {:ok, activity}
 340     else
 341       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 342       {:activity, nil} ->
 343         mastodon_follow_hack(follow_object, followed)
 344
 345       _ ->
 346         {:error, nil}
 347     end
 348   end
 349
 350   # Reduce the object list to find the reported user.
 351   defp get_reported(objects) do
 352     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 353       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 354         {:halt, user}
 355       else
 356         _ -> {:cont, nil}
 357       end
 358     end)
 359   end
 360
 361   def handle_incoming(data, options \\ [])
 362
 363   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 364   # with nil ID.
 365   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 366     with context <- data["context"] || Utils.generate_context_id(),
 367          content <- data["content"] || "",
 368          %User{} = actor <- User.get_cached_by_ap_id(actor),
 369          # Reduce the object list to find the reported user.
 370          %User{} = account <- get_reported(objects),
 371          # Remove the reported user from the object list.
 372          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 373       %{
 374         actor: actor,
 375         context: context,
 376         account: account,
 377         statuses: statuses,
 378         content: content,
 379         additional: %{"cc" => [account.ap_id]}
 380       }
 381       |> ActivityPub.flag()
 382     end
 383   end
 384
 385   # disallow objects with bogus IDs
 386   def handle_incoming(%{"id" => nil}, _options), do: :error
 387   def handle_incoming(%{"id" => ""}, _options), do: :error
 388   # length of https:// = 8, should validate better, but good enough for now.
 389   def handle_incoming(%{"id" => id}, _options) when not (is_binary(id) and length(id) > 8),
 390     do: :error
 391
 392   # TODO: validate those with a Ecto scheme
 393   # - tags
 394   # - emoji
 395   def handle_incoming(
 396         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 397         options
 398       )
 399       when objtype in ["Article", "Note", "Video", "Page", "Question", "Answer"] do
 400     actor = Containment.get_actor(data)
 401
 402     data =
 403       Map.put(data, "actor", actor)
 404       |> fix_addressing
 405
 406     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 407          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 408       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 409       object = fix_object(data["object"], options)
 410
 411       params = %{
 412         to: data["to"],
 413         object: object,
 414         actor: user,
 415         context: object["conversation"],
 416         local: false,
 417         published: data["published"],
 418         additional:
 419           Map.take(data, [
 420             "cc",
 421             "directMessage",
 422             "id"
 423           ])
 424       }
 425
 426       ActivityPub.create(params)
 427     else
 428       %Activity{} = activity -> {:ok, activity}
 429       _e -> :error
 430     end
 431   end
 432
 433   def handle_incoming(
 434         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 435         options
 436       ) do
 437     actor = Containment.get_actor(data)
 438
 439     data =
 440       Map.put(data, "actor", actor)
 441       |> fix_addressing
 442
 443     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 444       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 445       object = fix_object(object, options)
 446
 447       params = %{
 448         to: data["to"],
 449         object: object,
 450         actor: user,
 451         context: nil,
 452         local: false,
 453         published: data["published"],
 454         additional: Map.take(data, ["cc", "id"])
 455       }
 456
 457       ActivityPub.listen(params)
 458     else
 459       _e -> :error
 460     end
 461   end
 462
 463   def handle_incoming(
 464         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 465         _options
 466       ) do
 467     with %User{local: true} = followed <-
 468            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 469          {:ok, %User{} = follower} <-
 470            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 471          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 472       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 473            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 474            {_, false} <- {:user_locked, User.locked?(followed)},
 475            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 476            {_, {:ok, _}} <-
 477              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")} do
 478         ActivityPub.accept(%{
 479           to: [follower.ap_id],
 480           actor: followed,
 481           object: data,
 482           local: true
 483         })
 484       else
 485         {:user_blocked, true} ->
 486           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 487
 488           ActivityPub.reject(%{
 489             to: [follower.ap_id],
 490             actor: followed,
 491             object: data,
 492             local: true
 493           })
 494
 495         {:follow, {:error, _}} ->
 496           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 497
 498           ActivityPub.reject(%{
 499             to: [follower.ap_id],
 500             actor: followed,
 501             object: data,
 502             local: true
 503           })
 504
 505         {:user_locked, true} ->
 506           :noop
 507       end
 508
 509       {:ok, activity}
 510     else
 511       _e ->
 512         :error
 513     end
 514   end
 515
 516   def handle_incoming(
 517         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data,
 518         _options
 519       ) do
 520     with actor <- Containment.get_actor(data),
 521          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 522          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 523          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 524          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 525          {:ok, _follower} = User.follow(follower, followed) do
 526       ActivityPub.accept(%{
 527         to: follow_activity.data["to"],
 528         type: "Accept",
 529         actor: followed,
 530         object: follow_activity.data["id"],
 531         local: false
 532       })
 533     else
 534       _e -> :error
 535     end
 536   end
 537
 538   def handle_incoming(
 539         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data,
 540         _options
 541       ) do
 542     with actor <- Containment.get_actor(data),
 543          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 544          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 545          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 546          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 547          {:ok, activity} <-
 548            ActivityPub.reject(%{
 549              to: follow_activity.data["to"],
 550              type: "Reject",
 551              actor: followed,
 552              object: follow_activity.data["id"],
 553              local: false
 554            }) do
 555       User.unfollow(follower, followed)
 556
 557       {:ok, activity}
 558     else
 559       _e -> :error
 560     end
 561   end
 562
 563   @misskey_reactions %{
 564     "like" => "👍",
 565     "love" => "❤️",
 566     "laugh" => "😆",
 567     "hmm" => "🤔",
 568     "surprise" => "😮",
 569     "congrats" => "🎉",
 570     "angry" => "💢",
 571     "confused" => "😥",
 572     "rip" => "😇",
 573     "pudding" => "🍮"
 574   }
 575
 576   @doc "Rewrite misskey likes into EmojiReactions"
 577   def handle_incoming(
 578         %{
 579           "type" => "Like",
 580           "_misskey_reaction" => reaction
 581         } = data,
 582         options
 583       ) do
 584     data
 585     |> Map.put("type", "EmojiReaction")
 586     |> Map.put("content", @misskey_reactions[reaction])
 587     |> handle_incoming(options)
 588   end
 589
 590   def handle_incoming(
 591         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data,
 592         _options
 593       ) do
 594     with actor <- Containment.get_actor(data),
 595          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 596          {:ok, object} <- get_obj_helper(object_id),
 597          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 598       {:ok, activity}
 599     else
 600       _e -> :error
 601     end
 602   end
 603
 604   def handle_incoming(
 605         %{
 606           "type" => "EmojiReaction",
 607           "object" => object_id,
 608           "actor" => _actor,
 609           "id" => id,
 610           "content" => emoji
 611         } = data,
 612         _options
 613       ) do
 614     with actor <- Containment.get_actor(data),
 615          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 616          {:ok, object} <- get_obj_helper(object_id),
 617          {:ok, activity, _object} <-
 618            ActivityPub.react_with_emoji(actor, object, emoji, activity_id: id, local: false) do
 619       {:ok, activity}
 620     else
 621       _e -> :error
 622     end
 623   end
 624
 625   def handle_incoming(
 626         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 627         _options
 628       ) do
 629     with actor <- Containment.get_actor(data),
 630          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 631          {:ok, object} <- get_obj_helper(object_id),
 632          public <- Visibility.is_public?(data),
 633          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 634       {:ok, activity}
 635     else
 636       _e -> :error
 637     end
 638   end
 639
 640   def handle_incoming(
 641         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 642           data,
 643         _options
 644       )
 645       when object_type in ["Person", "Application", "Service", "Organization"] do
 646     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 647       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 648
 649       banner = new_user_data[:info][:banner]
 650       locked = new_user_data[:info][:locked] || false
 651       attachment = get_in(new_user_data, [:info, :source_data, "attachment"]) || []
 652
 653       fields =
 654         attachment
 655         |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 656         |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 657
 658       update_data =
 659         new_user_data
 660         |> Map.take([:name, :bio, :avatar])
 661         |> Map.put(:info, %{banner: banner, locked: locked, fields: fields})
 662
 663       actor
 664       |> User.upgrade_changeset(update_data, true)
 665       |> User.update_and_set_cache()
 666
 667       ActivityPub.update(%{
 668         local: false,
 669         to: data["to"] || [],
 670         cc: data["cc"] || [],
 671         object: object,
 672         actor: actor_id
 673       })
 674     else
 675       e ->
 676         Logger.error(e)
 677         :error
 678     end
 679   end
 680
 681   # TODO: We presently assume that any actor on the same origin domain as the object being
 682   # deleted has the rights to delete that object.  A better way to validate whether or not
 683   # the object should be deleted is to refetch the object URI, which should return either
 684   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 685   # place.
 686   def handle_incoming(
 687         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = data,
 688         _options
 689       ) do
 690     object_id = Utils.get_ap_id(object_id)
 691
 692     with actor <- Containment.get_actor(data),
 693          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 694          {:ok, object} <- get_obj_helper(object_id),
 695          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 696          {:ok, activity} <- ActivityPub.delete(object, false) do
 697       {:ok, activity}
 698     else
 699       nil ->
 700         case User.get_cached_by_ap_id(object_id) do
 701           %User{ap_id: ^actor} = user ->
 702             User.delete(user)
 703
 704           nil ->
 705             :error
 706         end
 707
 708       _e ->
 709         :error
 710     end
 711   end
 712
 713   def handle_incoming(
 714         %{
 715           "type" => "Undo",
 716           "object" => %{"type" => "Announce", "object" => object_id},
 717           "actor" => _actor,
 718           "id" => id
 719         } = data,
 720         _options
 721       ) do
 722     with actor <- Containment.get_actor(data),
 723          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 724          {:ok, object} <- get_obj_helper(object_id),
 725          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 726       {:ok, activity}
 727     else
 728       _e -> :error
 729     end
 730   end
 731
 732   def handle_incoming(
 733         %{
 734           "type" => "Undo",
 735           "object" => %{"type" => "Follow", "object" => followed},
 736           "actor" => follower,
 737           "id" => id
 738         } = _data,
 739         _options
 740       ) do
 741     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 742          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 743          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 744       User.unfollow(follower, followed)
 745       {:ok, activity}
 746     else
 747       _e -> :error
 748     end
 749   end
 750
 751   def handle_incoming(
 752         %{
 753           "type" => "Undo",
 754           "object" => %{"type" => "EmojiReaction", "id" => reaction_activity_id},
 755           "actor" => _actor,
 756           "id" => id
 757         } = data,
 758         _options
 759       ) do
 760     with actor <- Containment.get_actor(data),
 761          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 762          {:ok, activity, _} <-
 763            ActivityPub.unreact_with_emoji(actor, reaction_activity_id,
 764              activity_id: id,
 765              local: false
 766            ) do
 767       {:ok, activity}
 768     else
 769       _e -> :error
 770     end
 771   end
 772
 773   def handle_incoming(
 774         %{
 775           "type" => "Undo",
 776           "object" => %{"type" => "Block", "object" => blocked},
 777           "actor" => blocker,
 778           "id" => id
 779         } = _data,
 780         _options
 781       ) do
 782     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 783          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 784          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 785       User.unblock(blocker, blocked)
 786       {:ok, activity}
 787     else
 788       _e -> :error
 789     end
 790   end
 791
 792   def handle_incoming(
 793         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 794         _options
 795       ) do
 796     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 797          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 798          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 799       User.unfollow(blocker, blocked)
 800       User.block(blocker, blocked)
 801       {:ok, activity}
 802     else
 803       _e -> :error
 804     end
 805   end
 806
 807   def handle_incoming(
 808         %{
 809           "type" => "Undo",
 810           "object" => %{"type" => "Like", "object" => object_id},
 811           "actor" => _actor,
 812           "id" => id
 813         } = data,
 814         _options
 815       ) do
 816     with actor <- Containment.get_actor(data),
 817          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 818          {:ok, object} <- get_obj_helper(object_id),
 819          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 820       {:ok, activity}
 821     else
 822       _e -> :error
 823     end
 824   end
 825
 826   # For Undos that don't have the complete object attached, try to find it in our database.
 827   def handle_incoming(
 828         %{
 829           "type" => "Undo",
 830           "object" => object
 831         } = activity,
 832         options
 833       )
 834       when is_binary(object) do
 835     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 836       activity
 837       |> Map.put("object", data)
 838       |> handle_incoming(options)
 839     else
 840       _e -> :error
 841     end
 842   end
 843
 844   def handle_incoming(_, _), do: :error
 845
 846   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 847   def get_obj_helper(id, options \\ []) do
 848     case Object.normalize(id, true, options) do
 849       %Object{} = object -> {:ok, object}
 850       _ -> nil
 851     end
 852   end
 853
 854   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 855     with false <- String.starts_with?(in_reply_to, "http"),
 856          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 857       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 858     else
 859       _e -> object
 860     end
 861   end
 862
 863   def set_reply_to_uri(obj), do: obj
 864
 865   # Prepares the object of an outgoing create activity.
 866   def prepare_object(object) do
 867     object
 868     |> set_sensitive
 869     |> add_hashtags
 870     |> add_mention_tags
 871     |> add_emoji_tags
 872     |> add_attributed_to
 873     |> prepare_attachments
 874     |> set_conversation
 875     |> set_reply_to_uri
 876     |> strip_internal_fields
 877     |> strip_internal_tags
 878     |> set_type
 879   end
 880
 881   #  @doc
 882   #  """
 883   #  internal -> Mastodon
 884   #  """
 885
 886   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 887       when activity_type in ["Create", "Listen"] do
 888     object =
 889       object_id
 890       |> Object.normalize()
 891       |> Map.get(:data)
 892       |> prepare_object
 893
 894     data =
 895       data
 896       |> Map.put("object", object)
 897       |> Map.merge(Utils.make_json_ld_header())
 898       |> Map.delete("bcc")
 899
 900     {:ok, data}
 901   end
 902
 903   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 904     object =
 905       object_id
 906       |> Object.normalize()
 907
 908     data =
 909       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 910         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 911       else
 912         data |> maybe_fix_object_url
 913       end
 914
 915     data =
 916       data
 917       |> strip_internal_fields
 918       |> Map.merge(Utils.make_json_ld_header())
 919       |> Map.delete("bcc")
 920
 921     {:ok, data}
 922   end
 923
 924   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 925   # because of course it does.
 926   def prepare_outgoing(%{"type" => "Accept"} = data) do
 927     with follow_activity <- Activity.normalize(data["object"]) do
 928       object = %{
 929         "actor" => follow_activity.actor,
 930         "object" => follow_activity.data["object"],
 931         "id" => follow_activity.data["id"],
 932         "type" => "Follow"
 933       }
 934
 935       data =
 936         data
 937         |> Map.put("object", object)
 938         |> Map.merge(Utils.make_json_ld_header())
 939
 940       {:ok, data}
 941     end
 942   end
 943
 944   def prepare_outgoing(%{"type" => "Reject"} = data) do
 945     with follow_activity <- Activity.normalize(data["object"]) do
 946       object = %{
 947         "actor" => follow_activity.actor,
 948         "object" => follow_activity.data["object"],
 949         "id" => follow_activity.data["id"],
 950         "type" => "Follow"
 951       }
 952
 953       data =
 954         data
 955         |> Map.put("object", object)
 956         |> Map.merge(Utils.make_json_ld_header())
 957
 958       {:ok, data}
 959     end
 960   end
 961
 962   def prepare_outgoing(%{"type" => _type} = data) do
 963     data =
 964       data
 965       |> strip_internal_fields
 966       |> maybe_fix_object_url
 967       |> Map.merge(Utils.make_json_ld_header())
 968
 969     {:ok, data}
 970   end
 971
 972   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
 973     with false <- String.starts_with?(object, "http"),
 974          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
 975          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
 976            relative_object do
 977       Map.put(data, "object", external_url)
 978     else
 979       {:fetch, e} ->
 980         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
 981         data
 982
 983       _ ->
 984         data
 985     end
 986   end
 987
 988   def maybe_fix_object_url(data), do: data
 989
 990   def add_hashtags(object) do
 991     tags =
 992       (object["tag"] || [])
 993       |> Enum.map(fn
 994         # Expand internal representation tags into AS2 tags.
 995         tag when is_binary(tag) ->
 996           %{
 997             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 998             "name" => "##{tag}",
 999             "type" => "Hashtag"
1000           }
1001
1002         # Do not process tags which are already AS2 tag objects.
1003         tag when is_map(tag) ->
1004           tag
1005       end)
1006
1007     Map.put(object, "tag", tags)
1008   end
1009
1010   def add_mention_tags(object) do
1011     mentions =
1012       object
1013       |> Utils.get_notified_from_object()
1014       |> Enum.map(&build_mention_tag/1)
1015
1016     tags = object["tag"] || []
1017
1018     Map.put(object, "tag", tags ++ mentions)
1019   end
1020
1021   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1022     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1023   end
1024
1025   def take_emoji_tags(%User{info: %{emoji: emoji} = _user_info} = _user) do
1026     emoji
1027     |> Enum.flat_map(&Map.to_list/1)
1028     |> Enum.map(&build_emoji_tag/1)
1029   end
1030
1031   # TODO: we should probably send mtime instead of unix epoch time for updated
1032   def add_emoji_tags(%{"emoji" => emoji} = object) do
1033     tags = object["tag"] || []
1034
1035     out = Enum.map(emoji, &build_emoji_tag/1)
1036
1037     Map.put(object, "tag", tags ++ out)
1038   end
1039
1040   def add_emoji_tags(object), do: object
1041
1042   defp build_emoji_tag({name, url}) do
1043     %{
1044       "icon" => %{"url" => url, "type" => "Image"},
1045       "name" => ":" <> name <> ":",
1046       "type" => "Emoji",
1047       "updated" => "1970-01-01T00:00:00Z",
1048       "id" => url
1049     }
1050   end
1051
1052   def set_conversation(object) do
1053     Map.put(object, "conversation", object["context"])
1054   end
1055
1056   def set_sensitive(object) do
1057     tags = object["tag"] || []
1058     Map.put(object, "sensitive", "nsfw" in tags)
1059   end
1060
1061   def set_type(%{"type" => "Answer"} = object) do
1062     Map.put(object, "type", "Note")
1063   end
1064
1065   def set_type(object), do: object
1066
1067   def add_attributed_to(object) do
1068     attributed_to = object["attributedTo"] || object["actor"]
1069     Map.put(object, "attributedTo", attributed_to)
1070   end
1071
1072   def prepare_attachments(object) do
1073     attachments =
1074       (object["attachment"] || [])
1075       |> Enum.map(fn data ->
1076         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1077         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1078       end)
1079
1080     Map.put(object, "attachment", attachments)
1081   end
1082
1083   def strip_internal_fields(object) do
1084     object
1085     |> Map.drop(Pleroma.Constants.object_internal_fields())
1086   end
1087
1088   defp strip_internal_tags(%{"tag" => tags} = object) do
1089     tags = Enum.filter(tags, fn x -> is_map(x) end)
1090
1091     Map.put(object, "tag", tags)
1092   end
1093
1094   defp strip_internal_tags(object), do: object
1095
1096   def perform(:user_upgrade, user) do
1097     # we pass a fake user so that the followers collection is stripped away
1098     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1099
1100     q =
1101       from(
1102         u in User,
1103         where: ^old_follower_address in u.following,
1104         update: [
1105           set: [
1106             following:
1107               fragment(
1108                 "array_replace(?,?,?)",
1109                 u.following,
1110                 ^old_follower_address,
1111                 ^user.follower_address
1112               )
1113           ]
1114         ]
1115       )
1116
1117     Repo.update_all(q, [])
1118
1119     maybe_retire_websub(user.ap_id)
1120
1121     q =
1122       from(
1123         a in Activity,
1124         where: ^old_follower_address in a.recipients,
1125         update: [
1126           set: [
1127             recipients:
1128               fragment(
1129                 "array_replace(?,?,?)",
1130                 a.recipients,
1131                 ^old_follower_address,
1132                 ^user.follower_address
1133               )
1134           ]
1135         ]
1136       )
1137
1138     Repo.update_all(q, [])
1139   end
1140
1141   def upgrade_user_from_ap_id(ap_id) do
1142     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1143          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1144          already_ap <- User.ap_enabled?(user),
1145          {:ok, user} <- upgrade_user(user, data) do
1146       if not already_ap do
1147         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1148       end
1149
1150       {:ok, user}
1151     else
1152       %User{} = user -> {:ok, user}
1153       e -> e
1154     end
1155   end
1156
1157   defp upgrade_user(user, data) do
1158     user
1159     |> User.upgrade_changeset(data, true)
1160     |> User.update_and_set_cache()
1161   end
1162
1163   def maybe_retire_websub(ap_id) do
1164     # some sanity checks
1165     if is_binary(ap_id) && String.length(ap_id) > 8 do
1166       q =
1167         from(
1168           ws in Pleroma.Web.Websub.WebsubClientSubscription,
1169           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
1170         )
1171
1172       Repo.delete_all(q)
1173     end
1174   end
1175
1176   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1177     Map.put(data, "url", url["href"])
1178   end
1179
1180   def maybe_fix_user_url(data), do: data
1181
1182   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1183 end