git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10
  11   import Ecto.Query
  12
  13   require Logger
  14
  15   @doc """
  16   Modifies an incoming AP object (mastodon format) to our internal format.
  17   """
  18   def fix_object(object) do
  19     object
  20     |> Map.put("actor", object["attributedTo"])
  21     |> fix_attachments
  22     |> fix_context
  23     |> fix_in_reply_to
  24     |> fix_emoji
  25     |> fix_tag
  26   end
  27
  28   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  29       when not is_nil(in_reply_to_id) do
  30     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  31       {:ok, replied_object} ->
  32         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  33
  34         object
  35         |> Map.put("inReplyTo", replied_object.data["id"])
  36         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  37         |> Map.put("inReplyToStatusId", activity.id)
  38         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  39         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  40
  41       e ->
  42         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  43         object
  44     end
  45   end
  46
  47   def fix_in_reply_to(object), do: object
  48
  49   def fix_context(object) do
  50     object
  51     |> Map.put("context", object["conversation"])
  52   end
  53
  54   def fix_attachments(object) do
  55     attachments =
  56       (object["attachment"] || [])
  57       |> Enum.map(fn data ->
  58         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  59         Map.put(data, "url", url)
  60       end)
  61
  62     object
  63     |> Map.put("attachment", attachments)
  64   end
  65
  66   def fix_emoji(object) do
  67     tags = object["tag"] || []
  68     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  69
  70     emoji =
  71       emoji
  72       |> Enum.reduce(%{}, fn data, mapping ->
  73         name = data["name"]
  74
  75         name =
  76           if String.starts_with?(name, ":") do
  77             name |> String.slice(1..-2)
  78           else
  79             name
  80           end
  81
  82         mapping |> Map.put(name, data["icon"]["url"])
  83       end)
  84
  85     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  86     emoji = Map.merge(object["emoji"] || %{}, emoji)
  87
  88     object
  89     |> Map.put("emoji", emoji)
  90   end
  91
  92   def fix_tag(object) do
  93     tags =
  94       (object["tag"] || [])
  95       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  96       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  97
  98     combined = (object["tag"] || []) ++ tags
  99
 100     object
 101     |> Map.put("tag", combined)
 102   end
 103
 104   # TODO: validate those with a Ecto scheme
 105   # - tags
 106   # - emoji
 107   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 108     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 109          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 110       object = fix_object(data["object"])
 111
 112       params = %{
 113         to: data["to"],
 114         object: object,
 115         actor: user,
 116         context: object["conversation"],
 117         local: false,
 118         published: data["published"],
 119         additional:
 120           Map.take(data, [
 121             "cc",
 122             "id"
 123           ])
 124       }
 125
 126       ActivityPub.create(params)
 127     else
 128       %Activity{} = activity -> {:ok, activity}
 129       _e -> :error
 130     end
 131   end
 132
 133   def handle_incoming(
 134         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 135       ) do
 136     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 137          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 138          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 139       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 140
 141       User.follow(follower, followed)
 142       {:ok, activity}
 143     else
 144       _e -> :error
 145     end
 146   end
 147
 148   def handle_incoming(
 149         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 150       ) do
 151     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 152          {:ok, object} <-
 153            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 154          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 155       {:ok, activity}
 156     else
 157       _e -> :error
 158     end
 159   end
 160
 161   def handle_incoming(
 162         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 163       ) do
 164     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 165          {:ok, object} <-
 166            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 167          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 168       {:ok, activity}
 169     else
 170       _e -> :error
 171     end
 172   end
 173
 174   def handle_incoming(
 175         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 176           data
 177       ) do
 178     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 179       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 180
 181       banner = new_user_data[:info]["banner"]
 182
 183       update_data =
 184         new_user_data
 185         |> Map.take([:name, :bio, :avatar])
 186         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 187
 188       actor
 189       |> User.upgrade_changeset(update_data)
 190       |> User.update_and_set_cache()
 191
 192       ActivityPub.update(%{
 193         local: false,
 194         to: data["to"] || [],
 195         cc: data["cc"] || [],
 196         object: object,
 197         actor: actor_id
 198       })
 199     else
 200       e ->
 201         Logger.error(e)
 202         :error
 203     end
 204   end
 205
 206   # TODO: Make secure.
 207   def handle_incoming(
 208         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 209       ) do
 210     object_id =
 211       case object_id do
 212         %{"id" => id} -> id
 213         id -> id
 214       end
 215
 216     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 217          {:ok, object} <-
 218            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 219          {:ok, activity} <- ActivityPub.delete(object, false) do
 220       {:ok, activity}
 221     else
 222       _e -> :error
 223     end
 224   end
 225
 226   def handle_incoming(
 227         %{
 228           "type" => "Undo",
 229           "object" => %{"type" => "Announce", "object" => object_id},
 230           "actor" => actor,
 231           "id" => id
 232         } = data
 233       ) do
 234     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 235          {:ok, object} <-
 236            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 237          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 238       {:ok, activity}
 239     else
 240       e -> :error
 241     end
 242   end
 243
 244   def handle_incoming(
 245         %{
 246           "type" => "Undo",
 247           "object" => %{"type" => "Follow", "object" => followed},
 248           "actor" => follower,
 249           "id" => id
 250         } = data
 251       ) do
 252     with %User{local: true} = followed = User.get_cached_by_ap_id(followed),
 253          %User{} = follower = User.get_or_fetch_by_ap_id(follower),
 254          {:ok, activity} <- ActivityPub.unfollow(follower, followed, false) do
 255       User.unfollow(follower, followed)
 256       {:ok, activity}
 257     else
 258       e -> :error
 259     end
 260   end
 261
 262   def handle_incoming(
 263         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 264       ) do
 265     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 266          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 267          {:ok, activity} <- ActivityPub.block(blocker, blocked, false) do
 268       User.unfollow(blocker, blocked)
 269       User.block(blocker, blocked.ap_id)
 270       {:ok, activity}
 271     else
 272       e -> :error
 273     end
 274   end
 275
 276   # TODO
 277   # Accept
 278   # Undo for non-Announce
 279
 280   def handle_incoming(_), do: :error
 281
 282   def get_obj_helper(id) do
 283     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 284   end
 285
 286   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 287     with false <- String.starts_with?(inReplyTo, "http"),
 288          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 289       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 290     else
 291       _e -> object
 292     end
 293   end
 294
 295   def set_reply_to_uri(obj), do: obj
 296
 297   # Prepares the object of an outgoing create activity.
 298   def prepare_object(object) do
 299     object
 300     |> set_sensitive
 301     |> add_hashtags
 302     |> add_mention_tags
 303     |> add_emoji_tags
 304     |> add_attributed_to
 305     |> prepare_attachments
 306     |> set_conversation
 307     |> set_reply_to_uri
 308   end
 309
 310   #  @doc
 311   #  """
 312   #  internal -> Mastodon
 313   #  """
 314
 315   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 316     object =
 317       object
 318       |> prepare_object
 319
 320     data =
 321       data
 322       |> Map.put("object", object)
 323       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 324
 325     {:ok, data}
 326   end
 327
 328   def prepare_outgoing(%{"type" => _type} = data) do
 329     data =
 330       data
 331       |> maybe_fix_object_url
 332       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 333
 334     {:ok, data}
 335   end
 336
 337   def maybe_fix_object_url(data) do
 338     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 339       case ActivityPub.fetch_object_from_id(data["object"]) do
 340         {:ok, relative_object} ->
 341           if relative_object.data["external_url"] do
 342             _data =
 343               data
 344               |> Map.put("object", relative_object.data["external_url"])
 345           else
 346             data
 347           end
 348
 349         e ->
 350           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 351           data
 352       end
 353     else
 354       data
 355     end
 356   end
 357
 358   def add_hashtags(object) do
 359     tags =
 360       (object["tag"] || [])
 361       |> Enum.map(fn tag ->
 362         %{
 363           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 364           "name" => "##{tag}",
 365           "type" => "Hashtag"
 366         }
 367       end)
 368
 369     object
 370     |> Map.put("tag", tags)
 371   end
 372
 373   def add_mention_tags(object) do
 374     recipients = object["to"] ++ (object["cc"] || [])
 375
 376     mentions =
 377       recipients
 378       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 379       |> Enum.filter(& &1)
 380       |> Enum.map(fn user ->
 381         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 382       end)
 383
 384     tags = object["tag"] || []
 385
 386     object
 387     |> Map.put("tag", tags ++ mentions)
 388   end
 389
 390   # TODO: we should probably send mtime instead of unix epoch time for updated
 391   def add_emoji_tags(object) do
 392     tags = object["tag"] || []
 393     emoji = object["emoji"] || []
 394
 395     out =
 396       emoji
 397       |> Enum.map(fn {name, url} ->
 398         %{
 399           "icon" => %{"url" => url, "type" => "Image"},
 400           "name" => ":" <> name <> ":",
 401           "type" => "Emoji",
 402           "updated" => "1970-01-01T00:00:00Z",
 403           "id" => url
 404         }
 405       end)
 406
 407     object
 408     |> Map.put("tag", tags ++ out)
 409   end
 410
 411   def set_conversation(object) do
 412     Map.put(object, "conversation", object["context"])
 413   end
 414
 415   def set_sensitive(object) do
 416     tags = object["tag"] || []
 417     Map.put(object, "sensitive", "nsfw" in tags)
 418   end
 419
 420   def add_attributed_to(object) do
 421     attributedTo = object["attributedTo"] || object["actor"]
 422
 423     object
 424     |> Map.put("attributedTo", attributedTo)
 425   end
 426
 427   def prepare_attachments(object) do
 428     attachments =
 429       (object["attachment"] || [])
 430       |> Enum.map(fn data ->
 431         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 432         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 433       end)
 434
 435     object
 436     |> Map.put("attachment", attachments)
 437   end
 438
 439   defp user_upgrade_task(user) do
 440     old_follower_address = User.ap_followers(user)
 441
 442     q =
 443       from(
 444         u in User,
 445         where: ^old_follower_address in u.following,
 446         update: [
 447           set: [
 448             following:
 449               fragment(
 450                 "array_replace(?,?,?)",
 451                 u.following,
 452                 ^old_follower_address,
 453                 ^user.follower_address
 454               )
 455           ]
 456         ]
 457       )
 458
 459     Repo.update_all(q, [])
 460
 461     maybe_retire_websub(user.ap_id)
 462
 463     # Only do this for recent activties, don't go through the whole db.
 464     # Only look at the last 1000 activities.
 465     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 466
 467     q =
 468       from(
 469         a in Activity,
 470         where: ^old_follower_address in a.recipients,
 471         where: a.id > ^since,
 472         update: [
 473           set: [
 474             recipients:
 475               fragment(
 476                 "array_replace(?,?,?)",
 477                 a.recipients,
 478                 ^old_follower_address,
 479                 ^user.follower_address
 480               )
 481           ]
 482         ]
 483       )
 484
 485     Repo.update_all(q, [])
 486   end
 487
 488   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 489     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 490          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 491       data =
 492         data
 493         |> Map.put(:info, Map.merge(user.info, data[:info]))
 494
 495       already_ap = User.ap_enabled?(user)
 496
 497       {:ok, user} =
 498         User.upgrade_changeset(user, data)
 499         |> Repo.update()
 500
 501       if !already_ap do
 502         # This could potentially take a long time, do it in the background
 503         if async do
 504           Task.start(fn ->
 505             user_upgrade_task(user)
 506           end)
 507         else
 508           user_upgrade_task(user)
 509         end
 510       end
 511
 512       {:ok, user}
 513     else
 514       e -> e
 515     end
 516   end
 517
 518   def maybe_retire_websub(ap_id) do
 519     # some sanity checks
 520     if is_binary(ap_id) && String.length(ap_id) > 8 do
 521       q =
 522         from(
 523           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 524           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 525         )
 526
 527       Repo.delete_all(q)
 528     end
 529   end
 530 end