git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  30     id
  31   end
  32
  33   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  34     get_actor(%{"actor" => actor})
  35   end
  36
  37   @doc """
  38   Checks that an imported AP object's actor matches the domain it came from.
  39   """
  40   def contain_origin(id, %{"actor" => actor} = params) do
  41     id_uri = URI.parse(id)
  42     actor_uri = URI.parse(get_actor(params))
  43
  44     if id_uri.host == actor_uri.host do
  45       :ok
  46     else
  47       :error
  48     end
  49   end
  50
  51   @doc """
  52   Modifies an incoming AP object (mastodon format) to our internal format.
  53   """
  54   def fix_object(object) do
  55     object
  56     |> fix_actor
  57     |> fix_attachments
  58     |> fix_context
  59     |> fix_in_reply_to
  60     |> fix_emoji
  61     |> fix_tag
  62     |> fix_content_map
  63     |> fix_likes
  64     |> fix_addressing
  65   end
  66
  67   def fix_addressing_list(map, field) do
  68     if is_binary(map[field]) do
  69       map
  70       |> Map.put(field, [map[field]])
  71     else
  72       map
  73     end
  74   end
  75
  76   def fix_addressing(map) do
  77     map
  78     |> fix_addressing_list("to")
  79     |> fix_addressing_list("cc")
  80     |> fix_addressing_list("bto")
  81     |> fix_addressing_list("bcc")
  82   end
  83
  84   def fix_actor(%{"attributedTo" => actor} = object) do
  85     object
  86     |> Map.put("actor", get_actor(%{"actor" => actor}))
  87   end
  88
  89   def fix_likes(%{"likes" => likes} = object)
  90       when is_bitstring(likes) do
  91     # Check for standardisation
  92     # This is what Peertube does
  93     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
  94     object
  95     |> Map.put("likes", [])
  96     |> Map.put("like_count", 0)
  97   end
  98
  99   def fix_likes(object) do
 100     object
 101   end
 102
 103   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 104       when not is_nil(in_reply_to) do
 105     in_reply_to_id =
 106       cond do
 107         is_bitstring(in_reply_to) ->
 108           in_reply_to
 109
 110         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 111           in_reply_to["id"]
 112
 113         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 114           Enum.at(in_reply_to, 0)
 115
 116         # Maybe I should output an error too?
 117         true ->
 118           ""
 119       end
 120
 121     case fetch_obj_helper(in_reply_to_id) do
 122       {:ok, replied_object} ->
 123         with %Activity{} = activity <-
 124                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 125           object
 126           |> Map.put("inReplyTo", replied_object.data["id"])
 127           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 128           |> Map.put("inReplyToStatusId", activity.id)
 129           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 130           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 131         else
 132           e ->
 133             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 134             object
 135         end
 136
 137       e ->
 138         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 139         object
 140     end
 141   end
 142
 143   def fix_in_reply_to(object), do: object
 144
 145   def fix_context(object) do
 146     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 147
 148     object
 149     |> Map.put("context", context)
 150     |> Map.put("conversation", context)
 151   end
 152
 153   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 154     attachments =
 155       attachment
 156       |> Enum.map(fn data ->
 157         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 158         Map.put(data, "url", url)
 159       end)
 160
 161     object
 162     |> Map.put("attachment", attachments)
 163   end
 164
 165   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 166     Map.put(object, "attachment", [attachment])
 167     |> fix_attachments()
 168   end
 169
 170   def fix_attachments(object), do: object
 171
 172   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 173     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 174
 175     emoji =
 176       emoji
 177       |> Enum.reduce(%{}, fn data, mapping ->
 178         name = String.trim(data["name"], ":")
 179
 180         mapping |> Map.put(name, data["icon"]["url"])
 181       end)
 182
 183     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 184     emoji = Map.merge(object["emoji"] || %{}, emoji)
 185
 186     object
 187     |> Map.put("emoji", emoji)
 188   end
 189
 190   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 191     name = String.trim(tag["name"], ":")
 192     emoji = %{name => tag["icon"]["url"]}
 193
 194     object
 195     |> Map.put("emoji", emoji)
 196   end
 197
 198   def fix_emoji(object), do: object
 199
 200   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 201     tags =
 202       tag
 203       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 204       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 205
 206     combined = tag ++ tags
 207
 208     object
 209     |> Map.put("tag", combined)
 210   end
 211
 212   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 213     combined = [tag, String.slice(hashtag, 1..-1)]
 214
 215     object
 216     |> Map.put("tag", combined)
 217   end
 218
 219   def fix_tag(object), do: object
 220
 221   # content map usually only has one language so this will do for now.
 222   def fix_content_map(%{"contentMap" => content_map} = object) do
 223     content_groups = Map.to_list(content_map)
 224     {_, content} = Enum.at(content_groups, 0)
 225
 226     object
 227     |> Map.put("content", content)
 228   end
 229
 230   def fix_content_map(object), do: object
 231
 232   # disallow objects with bogus IDs
 233   def handle_incoming(%{"id" => nil}), do: :error
 234   def handle_incoming(%{"id" => ""}), do: :error
 235   # length of https:// = 8, should validate better, but good enough for now.
 236   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 237
 238   # TODO: validate those with a Ecto scheme
 239   # - tags
 240   # - emoji
 241   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 242       when objtype in ["Article", "Note", "Video"] do
 243     actor = get_actor(data)
 244
 245     data =
 246       Map.put(data, "actor", actor)
 247       |> fix_addressing
 248
 249     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 250          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 251       object = fix_object(data["object"])
 252
 253       params = %{
 254         to: data["to"],
 255         object: object,
 256         actor: user,
 257         context: object["conversation"],
 258         local: false,
 259         published: data["published"],
 260         additional:
 261           Map.take(data, [
 262             "cc",
 263             "id"
 264           ])
 265       }
 266
 267       ActivityPub.create(params)
 268     else
 269       %Activity{} = activity -> {:ok, activity}
 270       _e -> :error
 271     end
 272   end
 273
 274   def handle_incoming(
 275         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 276       ) do
 277     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 278          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 279          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 280       if not User.locked?(followed) do
 281         ActivityPub.accept(%{
 282           to: [follower.ap_id],
 283           actor: followed.ap_id,
 284           object: data,
 285           local: true
 286         })
 287
 288         User.follow(follower, followed)
 289       end
 290
 291       {:ok, activity}
 292     else
 293       _e -> :error
 294     end
 295   end
 296
 297   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 298     with true <- id =~ "follows",
 299          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 300          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 301       {:ok, activity}
 302     else
 303       _ -> {:error, nil}
 304     end
 305   end
 306
 307   defp mastodon_follow_hack(_), do: {:error, nil}
 308
 309   defp get_follow_activity(follow_object, followed) do
 310     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 311          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 312       {:ok, activity}
 313     else
 314       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 315       {:activity, nil} ->
 316         mastodon_follow_hack(follow_object, followed)
 317
 318       _ ->
 319         {:error, nil}
 320     end
 321   end
 322
 323   def handle_incoming(
 324         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 325       ) do
 326     with actor <- get_actor(data),
 327          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 328          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 329          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 330          {:ok, activity} <-
 331            ActivityPub.accept(%{
 332              to: follow_activity.data["to"],
 333              type: "Accept",
 334              actor: followed.ap_id,
 335              object: follow_activity.data["id"],
 336              local: false
 337            }) do
 338       if not User.following?(follower, followed) do
 339         {:ok, follower} = User.follow(follower, followed)
 340       end
 341
 342       {:ok, activity}
 343     else
 344       _e -> :error
 345     end
 346   end
 347
 348   def handle_incoming(
 349         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 350       ) do
 351     with actor <- get_actor(data),
 352          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 353          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 354          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 355          {:ok, activity} <-
 356            ActivityPub.accept(%{
 357              to: follow_activity.data["to"],
 358              type: "Accept",
 359              actor: followed.ap_id,
 360              object: follow_activity.data["id"],
 361              local: false
 362            }) do
 363       User.unfollow(follower, followed)
 364
 365       {:ok, activity}
 366     else
 367       _e -> :error
 368     end
 369   end
 370
 371   def handle_incoming(
 372         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data
 373       ) do
 374     with actor <- get_actor(data),
 375          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 376          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 377          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 378       {:ok, activity}
 379     else
 380       _e -> :error
 381     end
 382   end
 383
 384   def handle_incoming(
 385         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data
 386       ) do
 387     with actor <- get_actor(data),
 388          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 389          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 390          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 391       {:ok, activity}
 392     else
 393       _e -> :error
 394     end
 395   end
 396
 397   def handle_incoming(
 398         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 399           data
 400       )
 401       when object_type in ["Person", "Application", "Service", "Organization"] do
 402     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 403       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 404
 405       banner = new_user_data[:info]["banner"]
 406       locked = new_user_data[:info]["locked"] || false
 407
 408       update_data =
 409         new_user_data
 410         |> Map.take([:name, :bio, :avatar])
 411         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 412
 413       actor
 414       |> User.upgrade_changeset(update_data)
 415       |> User.update_and_set_cache()
 416
 417       ActivityPub.update(%{
 418         local: false,
 419         to: data["to"] || [],
 420         cc: data["cc"] || [],
 421         object: object,
 422         actor: actor_id
 423       })
 424     else
 425       e ->
 426         Logger.error(e)
 427         :error
 428     end
 429   end
 430
 431   # TODO: Make secure.
 432   def handle_incoming(
 433         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = data
 434       ) do
 435     object_id = Utils.get_ap_id(object_id)
 436
 437     with actor <- get_actor(data),
 438          %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 439          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 440          {:ok, activity} <- ActivityPub.delete(object, false) do
 441       {:ok, activity}
 442     else
 443       _e -> :error
 444     end
 445   end
 446
 447   def handle_incoming(
 448         %{
 449           "type" => "Undo",
 450           "object" => %{"type" => "Announce", "object" => object_id},
 451           "actor" => actor,
 452           "id" => id
 453         } = data
 454       ) do
 455     with actor <- get_actor(data),
 456          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 457          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 458          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 459       {:ok, activity}
 460     else
 461       _e -> :error
 462     end
 463   end
 464
 465   def handle_incoming(
 466         %{
 467           "type" => "Undo",
 468           "object" => %{"type" => "Follow", "object" => followed},
 469           "actor" => follower,
 470           "id" => id
 471         } = _data
 472       ) do
 473     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 474          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 475          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 476       User.unfollow(follower, followed)
 477       {:ok, activity}
 478     else
 479       e -> :error
 480     end
 481   end
 482
 483   @ap_config Application.get_env(:pleroma, :activitypub)
 484   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 485
 486   def handle_incoming(
 487         %{
 488           "type" => "Undo",
 489           "object" => %{"type" => "Block", "object" => blocked},
 490           "actor" => blocker,
 491           "id" => id
 492         } = _data
 493       ) do
 494     with true <- @accept_blocks,
 495          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 496          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 497          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 498       User.unblock(blocker, blocked)
 499       {:ok, activity}
 500     else
 501       e -> :error
 502     end
 503   end
 504
 505   def handle_incoming(
 506         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 507       ) do
 508     with true <- @accept_blocks,
 509          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 510          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 511          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 512       User.unfollow(blocker, blocked)
 513       User.block(blocker, blocked)
 514       {:ok, activity}
 515     else
 516       e -> :error
 517     end
 518   end
 519
 520   def handle_incoming(
 521         %{
 522           "type" => "Undo",
 523           "object" => %{"type" => "Like", "object" => object_id},
 524           "actor" => actor,
 525           "id" => id
 526         } = data
 527       ) do
 528     with actor <- get_actor(data),
 529          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 530          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 531          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 532       {:ok, activity}
 533     else
 534       _e -> :error
 535     end
 536   end
 537
 538   def handle_incoming(_), do: :error
 539
 540   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 541   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 542
 543   def get_obj_helper(id) do
 544     if object = Object.normalize(id), do: {:ok, object}, else: nil
 545   end
 546
 547   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 548     with false <- String.starts_with?(inReplyTo, "http"),
 549          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 550       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 551     else
 552       _e -> object
 553     end
 554   end
 555
 556   def set_reply_to_uri(obj), do: obj
 557
 558   # Prepares the object of an outgoing create activity.
 559   def prepare_object(object) do
 560     object
 561     |> set_sensitive
 562     |> add_hashtags
 563     |> add_mention_tags
 564     |> add_emoji_tags
 565     |> add_attributed_to
 566     |> prepare_attachments
 567     |> set_conversation
 568     |> set_reply_to_uri
 569   end
 570
 571   #  @doc
 572   #  """
 573   #  internal -> Mastodon
 574   #  """
 575
 576   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 577     object =
 578       object
 579       |> prepare_object
 580
 581     data =
 582       data
 583       |> Map.put("object", object)
 584       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 585
 586     {:ok, data}
 587   end
 588
 589   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 590   # because of course it does.
 591   def prepare_outgoing(%{"type" => "Accept"} = data) do
 592     with follow_activity <- Activity.normalize(data["object"]) do
 593       object = %{
 594         "actor" => follow_activity.actor,
 595         "object" => follow_activity.data["object"],
 596         "id" => follow_activity.data["id"],
 597         "type" => "Follow"
 598       }
 599
 600       data =
 601         data
 602         |> Map.put("object", object)
 603         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 604
 605       {:ok, data}
 606     end
 607   end
 608
 609   def prepare_outgoing(%{"type" => "Reject"} = data) do
 610     with follow_activity <- Activity.normalize(data["object"]) do
 611       object = %{
 612         "actor" => follow_activity.actor,
 613         "object" => follow_activity.data["object"],
 614         "id" => follow_activity.data["id"],
 615         "type" => "Follow"
 616       }
 617
 618       data =
 619         data
 620         |> Map.put("object", object)
 621         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 622
 623       {:ok, data}
 624     end
 625   end
 626
 627   def prepare_outgoing(%{"type" => _type} = data) do
 628     data =
 629       data
 630       |> maybe_fix_object_url
 631       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 632
 633     {:ok, data}
 634   end
 635
 636   def maybe_fix_object_url(data) do
 637     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 638       case fetch_obj_helper(data["object"]) do
 639         {:ok, relative_object} ->
 640           if relative_object.data["external_url"] do
 641             _data =
 642               data
 643               |> Map.put("object", relative_object.data["external_url"])
 644           else
 645             data
 646           end
 647
 648         e ->
 649           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 650           data
 651       end
 652     else
 653       data
 654     end
 655   end
 656
 657   def add_hashtags(object) do
 658     tags =
 659       (object["tag"] || [])
 660       |> Enum.map(fn tag ->
 661         %{
 662           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 663           "name" => "##{tag}",
 664           "type" => "Hashtag"
 665         }
 666       end)
 667
 668     object
 669     |> Map.put("tag", tags)
 670   end
 671
 672   def add_mention_tags(object) do
 673     recipients = object["to"] ++ (object["cc"] || [])
 674
 675     mentions =
 676       recipients
 677       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 678       |> Enum.filter(& &1)
 679       |> Enum.map(fn user ->
 680         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 681       end)
 682
 683     tags = object["tag"] || []
 684
 685     object
 686     |> Map.put("tag", tags ++ mentions)
 687   end
 688
 689   # TODO: we should probably send mtime instead of unix epoch time for updated
 690   def add_emoji_tags(object) do
 691     tags = object["tag"] || []
 692     emoji = object["emoji"] || []
 693
 694     out =
 695       emoji
 696       |> Enum.map(fn {name, url} ->
 697         %{
 698           "icon" => %{"url" => url, "type" => "Image"},
 699           "name" => ":" <> name <> ":",
 700           "type" => "Emoji",
 701           "updated" => "1970-01-01T00:00:00Z",
 702           "id" => url
 703         }
 704       end)
 705
 706     object
 707     |> Map.put("tag", tags ++ out)
 708   end
 709
 710   def set_conversation(object) do
 711     Map.put(object, "conversation", object["context"])
 712   end
 713
 714   def set_sensitive(object) do
 715     tags = object["tag"] || []
 716     Map.put(object, "sensitive", "nsfw" in tags)
 717   end
 718
 719   def add_attributed_to(object) do
 720     attributedTo = object["attributedTo"] || object["actor"]
 721
 722     object
 723     |> Map.put("attributedTo", attributedTo)
 724   end
 725
 726   def prepare_attachments(object) do
 727     attachments =
 728       (object["attachment"] || [])
 729       |> Enum.map(fn data ->
 730         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 731         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 732       end)
 733
 734     object
 735     |> Map.put("attachment", attachments)
 736   end
 737
 738   defp user_upgrade_task(user) do
 739     old_follower_address = User.ap_followers(user)
 740
 741     q =
 742       from(
 743         u in User,
 744         where: ^old_follower_address in u.following,
 745         update: [
 746           set: [
 747             following:
 748               fragment(
 749                 "array_replace(?,?,?)",
 750                 u.following,
 751                 ^old_follower_address,
 752                 ^user.follower_address
 753               )
 754           ]
 755         ]
 756       )
 757
 758     Repo.update_all(q, [])
 759
 760     maybe_retire_websub(user.ap_id)
 761
 762     # Only do this for recent activties, don't go through the whole db.
 763     # Only look at the last 1000 activities.
 764     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 765
 766     q =
 767       from(
 768         a in Activity,
 769         where: ^old_follower_address in a.recipients,
 770         where: a.id > ^since,
 771         update: [
 772           set: [
 773             recipients:
 774               fragment(
 775                 "array_replace(?,?,?)",
 776                 a.recipients,
 777                 ^old_follower_address,
 778                 ^user.follower_address
 779               )
 780           ]
 781         ]
 782       )
 783
 784     Repo.update_all(q, [])
 785   end
 786
 787   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 788     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 789          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 790       data =
 791         data
 792         |> Map.put(:info, Map.merge(user.info, data[:info]))
 793
 794       already_ap = User.ap_enabled?(user)
 795
 796       {:ok, user} =
 797         User.upgrade_changeset(user, data)
 798         |> Repo.update()
 799
 800       if !already_ap do
 801         # This could potentially take a long time, do it in the background
 802         if async do
 803           Task.start(fn ->
 804             user_upgrade_task(user)
 805           end)
 806         else
 807           user_upgrade_task(user)
 808         end
 809       end
 810
 811       {:ok, user}
 812     else
 813       e -> e
 814     end
 815   end
 816
 817   def maybe_retire_websub(ap_id) do
 818     # some sanity checks
 819     if is_binary(ap_id) && String.length(ap_id) > 8 do
 820       q =
 821         from(
 822           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 823           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 824         )
 825
 826       Repo.delete_all(q)
 827     end
 828   end
 829
 830   def maybe_fix_user_url(data) do
 831     if is_map(data["url"]) do
 832       Map.put(data, "url", data["url"]["href"])
 833     else
 834       data
 835     end
 836   end
 837
 838   def maybe_fix_user_object(data) do
 839     data
 840     |> maybe_fix_user_url
 841   end
 842 end