git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  30     id
  31   end
  32
  33   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  34     get_actor(%{"actor" => actor})
  35   end
  36
  37   @doc """
  38   Checks that an imported AP object's actor matches the domain it came from.
  39   """
  40   def contain_origin(_id, %{"actor" => nil}), do: :error
  41
  42   def contain_origin(id, %{"actor" => _actor} = params) do
  43     id_uri = URI.parse(id)
  44     actor_uri = URI.parse(get_actor(params))
  45
  46     if id_uri.host == actor_uri.host do
  47       :ok
  48     else
  49       :error
  50     end
  51   end
  52
  53   def contain_origin_from_id(_id, %{"id" => nil}), do: :error
  54
  55   def contain_origin_from_id(id, %{"id" => other_id} = _params) do
  56     id_uri = URI.parse(id)
  57     other_uri = URI.parse(other_id)
  58
  59     if id_uri.host == other_uri.host do
  60       :ok
  61     else
  62       :error
  63     end
  64   end
  65
  66   @doc """
  67   Modifies an incoming AP object (mastodon format) to our internal format.
  68   """
  69   def fix_object(object) do
  70     object
  71     |> fix_actor
  72     |> fix_attachments
  73     |> fix_url
  74     |> fix_context
  75     |> fix_in_reply_to
  76     |> fix_emoji
  77     |> fix_tag
  78     |> fix_content_map
  79     |> fix_likes
  80     |> fix_addressing
  81   end
  82
  83   def fix_addressing_list(map, field) do
  84     if is_binary(map[field]) do
  85       map
  86       |> Map.put(field, [map[field]])
  87     else
  88       map
  89     end
  90   end
  91
  92   def fix_addressing(map) do
  93     map
  94     |> fix_addressing_list("to")
  95     |> fix_addressing_list("cc")
  96     |> fix_addressing_list("bto")
  97     |> fix_addressing_list("bcc")
  98   end
  99
 100   def fix_actor(%{"attributedTo" => actor} = object) do
 101     object
 102     |> Map.put("actor", get_actor(%{"actor" => actor}))
 103   end
 104
 105   def fix_likes(%{"likes" => likes} = object)
 106       when is_bitstring(likes) do
 107     # Check for standardisation
 108     # This is what Peertube does
 109     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
 110     object
 111     |> Map.put("likes", [])
 112     |> Map.put("like_count", 0)
 113   end
 114
 115   def fix_likes(object) do
 116     object
 117   end
 118
 119   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 120       when not is_nil(in_reply_to) do
 121     in_reply_to_id =
 122       cond do
 123         is_bitstring(in_reply_to) ->
 124           in_reply_to
 125
 126         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 127           in_reply_to["id"]
 128
 129         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 130           Enum.at(in_reply_to, 0)
 131
 132         # Maybe I should output an error too?
 133         true ->
 134           ""
 135       end
 136
 137     case fetch_obj_helper(in_reply_to_id) do
 138       {:ok, replied_object} ->
 139         with %Activity{} = activity <-
 140                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 141           object
 142           |> Map.put("inReplyTo", replied_object.data["id"])
 143           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 144           |> Map.put("inReplyToStatusId", activity.id)
 145           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 146           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 147         else
 148           e ->
 149             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 150             object
 151         end
 152
 153       e ->
 154         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 155         object
 156     end
 157   end
 158
 159   def fix_in_reply_to(object), do: object
 160
 161   def fix_context(object) do
 162     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 163
 164     object
 165     |> Map.put("context", context)
 166     |> Map.put("conversation", context)
 167   end
 168
 169   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 170     attachments =
 171       attachment
 172       |> Enum.map(fn data ->
 173         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 174         Map.put(data, "url", url)
 175       end)
 176
 177     object
 178     |> Map.put("attachment", attachments)
 179   end
 180
 181   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 182     Map.put(object, "attachment", [attachment])
 183     |> fix_attachments()
 184   end
 185
 186   def fix_attachments(object), do: object
 187
 188   def fix_url(%{"url" => url} = object) when is_map(url) do
 189     object
 190     |> Map.put("url", url["href"])
 191   end
 192
 193   def fix_url(%{"url" => url} = object) when is_list(url) do
 194     first_element = Enum.at(url, 0)
 195
 196     url_string =
 197       cond do
 198         is_bitstring(first_element) -> first_element
 199         is_map(first_element) -> first_element["href"] || ""
 200         true -> ""
 201       end
 202
 203     object
 204     |> Map.put("url", url_string)
 205   end
 206
 207   def fix_url(object), do: object
 208
 209   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 210     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 211
 212     emoji =
 213       emoji
 214       |> Enum.reduce(%{}, fn data, mapping ->
 215         name = String.trim(data["name"], ":")
 216
 217         mapping |> Map.put(name, data["icon"]["url"])
 218       end)
 219
 220     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 221     emoji = Map.merge(object["emoji"] || %{}, emoji)
 222
 223     object
 224     |> Map.put("emoji", emoji)
 225   end
 226
 227   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 228     name = String.trim(tag["name"], ":")
 229     emoji = %{name => tag["icon"]["url"]}
 230
 231     object
 232     |> Map.put("emoji", emoji)
 233   end
 234
 235   def fix_emoji(object), do: object
 236
 237   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 238     tags =
 239       tag
 240       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 241       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 242
 243     combined = tag ++ tags
 244
 245     object
 246     |> Map.put("tag", combined)
 247   end
 248
 249   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 250     combined = [tag, String.slice(hashtag, 1..-1)]
 251
 252     object
 253     |> Map.put("tag", combined)
 254   end
 255
 256   def fix_tag(object), do: object
 257
 258   # content map usually only has one language so this will do for now.
 259   def fix_content_map(%{"contentMap" => content_map} = object) do
 260     content_groups = Map.to_list(content_map)
 261     {_, content} = Enum.at(content_groups, 0)
 262
 263     object
 264     |> Map.put("content", content)
 265   end
 266
 267   def fix_content_map(object), do: object
 268
 269   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 270     with true <- id =~ "follows",
 271          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 272          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 273       {:ok, activity}
 274     else
 275       _ -> {:error, nil}
 276     end
 277   end
 278
 279   defp mastodon_follow_hack(_, _), do: {:error, nil}
 280
 281   defp get_follow_activity(follow_object, followed) do
 282     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 283          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 284       {:ok, activity}
 285     else
 286       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 287       {:activity, nil} ->
 288         mastodon_follow_hack(follow_object, followed)
 289
 290       _ ->
 291         {:error, nil}
 292     end
 293   end
 294
 295   # disallow objects with bogus IDs
 296   def handle_incoming(%{"id" => nil}), do: :error
 297   def handle_incoming(%{"id" => ""}), do: :error
 298   # length of https:// = 8, should validate better, but good enough for now.
 299   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 300
 301   # TODO: validate those with a Ecto scheme
 302   # - tags
 303   # - emoji
 304   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 305       when objtype in ["Article", "Note", "Video", "Page"] do
 306     actor = get_actor(data)
 307
 308     data =
 309       Map.put(data, "actor", actor)
 310       |> fix_addressing
 311
 312     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 313          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 314       object = fix_object(data["object"])
 315
 316       params = %{
 317         to: data["to"],
 318         object: object,
 319         actor: user,
 320         context: object["conversation"],
 321         local: false,
 322         published: data["published"],
 323         additional:
 324           Map.take(data, [
 325             "cc",
 326             "id"
 327           ])
 328       }
 329
 330       ActivityPub.create(params)
 331     else
 332       %Activity{} = activity -> {:ok, activity}
 333       _e -> :error
 334     end
 335   end
 336
 337   def handle_incoming(
 338         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 339       ) do
 340     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 341          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 342          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 343       if not User.locked?(followed) do
 344         ActivityPub.accept(%{
 345           to: [follower.ap_id],
 346           actor: followed.ap_id,
 347           object: data,
 348           local: true
 349         })
 350
 351         User.follow(follower, followed)
 352       end
 353
 354       {:ok, activity}
 355     else
 356       _e -> :error
 357     end
 358   end
 359
 360   def handle_incoming(
 361         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 362       ) do
 363     with actor <- get_actor(data),
 364          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 365          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 366          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 367          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 368          {:ok, activity} <-
 369            ActivityPub.accept(%{
 370              to: follow_activity.data["to"],
 371              type: "Accept",
 372              actor: followed.ap_id,
 373              object: follow_activity.data["id"],
 374              local: false
 375            }) do
 376       if not User.following?(follower, followed) do
 377         {:ok, _follower} = User.follow(follower, followed)
 378       end
 379
 380       {:ok, activity}
 381     else
 382       _e -> :error
 383     end
 384   end
 385
 386   def handle_incoming(
 387         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 388       ) do
 389     with actor <- get_actor(data),
 390          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 391          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 392          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 393          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 394          {:ok, activity} <-
 395            ActivityPub.accept(%{
 396              to: follow_activity.data["to"],
 397              type: "Accept",
 398              actor: followed.ap_id,
 399              object: follow_activity.data["id"],
 400              local: false
 401            }) do
 402       User.unfollow(follower, followed)
 403
 404       {:ok, activity}
 405     else
 406       _e -> :error
 407     end
 408   end
 409
 410   def handle_incoming(
 411         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data
 412       ) do
 413     with actor <- get_actor(data),
 414          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 415          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 416          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 417       {:ok, activity}
 418     else
 419       _e -> :error
 420     end
 421   end
 422
 423   def handle_incoming(
 424         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data
 425       ) do
 426     with actor <- get_actor(data),
 427          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 428          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 429          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 430       {:ok, activity}
 431     else
 432       _e -> :error
 433     end
 434   end
 435
 436   def handle_incoming(
 437         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 438           data
 439       )
 440       when object_type in ["Person", "Application", "Service", "Organization"] do
 441     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 442       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 443
 444       banner = new_user_data[:info]["banner"]
 445       locked = new_user_data[:info]["locked"] || false
 446
 447       update_data =
 448         new_user_data
 449         |> Map.take([:name, :bio, :avatar])
 450         |> Map.put(:info, %{"banner" => banner, "locked" => locked})
 451
 452       actor
 453       |> User.upgrade_changeset(update_data)
 454       |> User.update_and_set_cache()
 455
 456       ActivityPub.update(%{
 457         local: false,
 458         to: data["to"] || [],
 459         cc: data["cc"] || [],
 460         object: object,
 461         actor: actor_id
 462       })
 463     else
 464       e ->
 465         Logger.error(e)
 466         :error
 467     end
 468   end
 469
 470   # TODO: We presently assume that any actor on the same origin domain as the object being
 471   # deleted has the rights to delete that object.  A better way to validate whether or not
 472   # the object should be deleted is to refetch the object URI, which should return either
 473   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 474   # place.
 475   def handle_incoming(
 476         %{"type" => "Delete", "object" => object_id, "actor" => _actor, "id" => _id} = data
 477       ) do
 478     object_id = Utils.get_ap_id(object_id)
 479
 480     with actor <- get_actor(data),
 481          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 482          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 483          :ok <- contain_origin(actor.ap_id, object.data),
 484          {:ok, activity} <- ActivityPub.delete(object, false) do
 485       {:ok, activity}
 486     else
 487       _e -> :error
 488     end
 489   end
 490
 491   def handle_incoming(
 492         %{
 493           "type" => "Undo",
 494           "object" => %{"type" => "Announce", "object" => object_id},
 495           "actor" => _actor,
 496           "id" => id
 497         } = data
 498       ) do
 499     with actor <- get_actor(data),
 500          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 501          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 502          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 503       {:ok, activity}
 504     else
 505       _e -> :error
 506     end
 507   end
 508
 509   def handle_incoming(
 510         %{
 511           "type" => "Undo",
 512           "object" => %{"type" => "Follow", "object" => followed},
 513           "actor" => follower,
 514           "id" => id
 515         } = _data
 516       ) do
 517     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 518          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 519          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 520       User.unfollow(follower, followed)
 521       {:ok, activity}
 522     else
 523       _e -> :error
 524     end
 525   end
 526
 527   def handle_incoming(
 528         %{
 529           "type" => "Undo",
 530           "object" => %{"type" => "Block", "object" => blocked},
 531           "actor" => blocker,
 532           "id" => id
 533         } = _data
 534       ) do
 535     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 536          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 537          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 538          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 539       User.unblock(blocker, blocked)
 540       {:ok, activity}
 541     else
 542       _e -> :error
 543     end
 544   end
 545
 546   def handle_incoming(
 547         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data
 548       ) do
 549     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 550          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 551          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 552          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 553       User.unfollow(blocker, blocked)
 554       User.block(blocker, blocked)
 555       {:ok, activity}
 556     else
 557       _e -> :error
 558     end
 559   end
 560
 561   def handle_incoming(
 562         %{
 563           "type" => "Undo",
 564           "object" => %{"type" => "Like", "object" => object_id},
 565           "actor" => _actor,
 566           "id" => id
 567         } = data
 568       ) do
 569     with actor <- get_actor(data),
 570          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 571          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 572          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 573       {:ok, activity}
 574     else
 575       _e -> :error
 576     end
 577   end
 578
 579   def handle_incoming(_), do: :error
 580
 581   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 582   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 583
 584   def get_obj_helper(id) do
 585     if object = Object.normalize(id), do: {:ok, object}, else: nil
 586   end
 587
 588   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 589     with false <- is_nil(inReplyTo),
 590          false <- String.starts_with?(inReplyTo, "http"),
 591          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 592       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 593     else
 594       _e -> object
 595     end
 596   end
 597
 598   def set_reply_to_uri(obj), do: obj
 599
 600   # Prepares the object of an outgoing create activity.
 601   def prepare_object(object) do
 602     object
 603     |> set_sensitive
 604     |> add_hashtags
 605     |> add_mention_tags
 606     |> add_emoji_tags
 607     |> add_attributed_to
 608     |> prepare_attachments
 609     |> set_conversation
 610     |> set_reply_to_uri
 611     |> strip_internal_fields
 612     |> strip_internal_tags
 613   end
 614
 615   #  @doc
 616   #  """
 617   #  internal -> Mastodon
 618   #  """
 619
 620   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 621     object =
 622       object
 623       |> prepare_object
 624
 625     data =
 626       data
 627       |> Map.put("object", object)
 628       |> Map.merge(Utils.make_json_ld_header())
 629
 630     {:ok, data}
 631   end
 632
 633   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 634   # because of course it does.
 635   def prepare_outgoing(%{"type" => "Accept"} = data) do
 636     with follow_activity <- Activity.normalize(data["object"]) do
 637       object = %{
 638         "actor" => follow_activity.actor,
 639         "object" => follow_activity.data["object"],
 640         "id" => follow_activity.data["id"],
 641         "type" => "Follow"
 642       }
 643
 644       data =
 645         data
 646         |> Map.put("object", object)
 647         |> Map.merge(Utils.make_json_ld_header())
 648
 649       {:ok, data}
 650     end
 651   end
 652
 653   def prepare_outgoing(%{"type" => "Reject"} = data) do
 654     with follow_activity <- Activity.normalize(data["object"]) do
 655       object = %{
 656         "actor" => follow_activity.actor,
 657         "object" => follow_activity.data["object"],
 658         "id" => follow_activity.data["id"],
 659         "type" => "Follow"
 660       }
 661
 662       data =
 663         data
 664         |> Map.put("object", object)
 665         |> Map.merge(Utils.make_json_ld_header())
 666
 667       {:ok, data}
 668     end
 669   end
 670
 671   def prepare_outgoing(%{"type" => _type} = data) do
 672     data =
 673       data
 674       |> maybe_fix_object_url
 675       |> Map.merge(Utils.make_json_ld_header())
 676
 677     {:ok, data}
 678   end
 679
 680   def maybe_fix_object_url(data) do
 681     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 682       case fetch_obj_helper(data["object"]) do
 683         {:ok, relative_object} ->
 684           if relative_object.data["external_url"] do
 685             _data =
 686               data
 687               |> Map.put("object", relative_object.data["external_url"])
 688           else
 689             data
 690           end
 691
 692         e ->
 693           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 694           data
 695       end
 696     else
 697       data
 698     end
 699   end
 700
 701   def add_hashtags(object) do
 702     tags =
 703       (object["tag"] || [])
 704       |> Enum.map(fn tag ->
 705         %{
 706           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 707           "name" => "##{tag}",
 708           "type" => "Hashtag"
 709         }
 710       end)
 711
 712     object
 713     |> Map.put("tag", tags)
 714   end
 715
 716   def add_mention_tags(object) do
 717     mentions =
 718       object
 719       |> Utils.get_notified_from_object()
 720       |> Enum.map(fn user ->
 721         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 722       end)
 723
 724     tags = object["tag"] || []
 725
 726     object
 727     |> Map.put("tag", tags ++ mentions)
 728   end
 729
 730   # TODO: we should probably send mtime instead of unix epoch time for updated
 731   def add_emoji_tags(object) do
 732     tags = object["tag"] || []
 733     emoji = object["emoji"] || []
 734
 735     out =
 736       emoji
 737       |> Enum.map(fn {name, url} ->
 738         %{
 739           "icon" => %{"url" => url, "type" => "Image"},
 740           "name" => ":" <> name <> ":",
 741           "type" => "Emoji",
 742           "updated" => "1970-01-01T00:00:00Z",
 743           "id" => url
 744         }
 745       end)
 746
 747     object
 748     |> Map.put("tag", tags ++ out)
 749   end
 750
 751   def set_conversation(object) do
 752     Map.put(object, "conversation", object["context"])
 753   end
 754
 755   def set_sensitive(object) do
 756     tags = object["tag"] || []
 757     Map.put(object, "sensitive", "nsfw" in tags)
 758   end
 759
 760   def add_attributed_to(object) do
 761     attributedTo = object["attributedTo"] || object["actor"]
 762
 763     object
 764     |> Map.put("attributedTo", attributedTo)
 765   end
 766
 767   def prepare_attachments(object) do
 768     attachments =
 769       (object["attachment"] || [])
 770       |> Enum.map(fn data ->
 771         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 772         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 773       end)
 774
 775     object
 776     |> Map.put("attachment", attachments)
 777   end
 778
 779   defp strip_internal_fields(object) do
 780     object
 781     |> Map.drop([
 782       "likes",
 783       "like_count",
 784       "announcements",
 785       "announcement_count",
 786       "emoji",
 787       "context_id"
 788     ])
 789   end
 790
 791   defp strip_internal_tags(%{"tag" => tags} = object) do
 792     tags =
 793       tags
 794       |> Enum.filter(fn x -> is_map(x) end)
 795
 796     object
 797     |> Map.put("tag", tags)
 798   end
 799
 800   defp strip_internal_tags(object), do: object
 801
 802   defp user_upgrade_task(user) do
 803     old_follower_address = User.ap_followers(user)
 804
 805     q =
 806       from(
 807         u in User,
 808         where: ^old_follower_address in u.following,
 809         update: [
 810           set: [
 811             following:
 812               fragment(
 813                 "array_replace(?,?,?)",
 814                 u.following,
 815                 ^old_follower_address,
 816                 ^user.follower_address
 817               )
 818           ]
 819         ]
 820       )
 821
 822     Repo.update_all(q, [])
 823
 824     maybe_retire_websub(user.ap_id)
 825
 826     # Only do this for recent activties, don't go through the whole db.
 827     # Only look at the last 1000 activities.
 828     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 829
 830     q =
 831       from(
 832         a in Activity,
 833         where: ^old_follower_address in a.recipients,
 834         where: a.id > ^since,
 835         update: [
 836           set: [
 837             recipients:
 838               fragment(
 839                 "array_replace(?,?,?)",
 840                 a.recipients,
 841                 ^old_follower_address,
 842                 ^user.follower_address
 843               )
 844           ]
 845         ]
 846       )
 847
 848     Repo.update_all(q, [])
 849   end
 850
 851   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 852     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 853          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 854       already_ap = User.ap_enabled?(user)
 855
 856       {:ok, user} =
 857         User.upgrade_changeset(user, data)
 858         |> Repo.update()
 859
 860       if !already_ap do
 861         # This could potentially take a long time, do it in the background
 862         if async do
 863           Task.start(fn ->
 864             user_upgrade_task(user)
 865           end)
 866         else
 867           user_upgrade_task(user)
 868         end
 869       end
 870
 871       {:ok, user}
 872     else
 873       e -> e
 874     end
 875   end
 876
 877   def maybe_retire_websub(ap_id) do
 878     # some sanity checks
 879     if is_binary(ap_id) && String.length(ap_id) > 8 do
 880       q =
 881         from(
 882           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 883           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 884         )
 885
 886       Repo.delete_all(q)
 887     end
 888   end
 889
 890   def maybe_fix_user_url(data) do
 891     if is_map(data["url"]) do
 892       Map.put(data, "url", data["url"]["href"])
 893     else
 894       data
 895     end
 896   end
 897
 898   def maybe_fix_user_object(data) do
 899     data
 900     |> maybe_fix_user_url
 901   end
 902 end