git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type == "Person" end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => actor}) when is_map(actor) do
  30     actor["id"]
  31   end
  32
  33   @doc """
  34   Checks that an imported AP object's actor matches the domain it came from.
  35   """
  36   def contain_origin(id, %{"actor" => actor} = params) do
  37     id_uri = URI.parse(id)
  38     actor_uri = URI.parse(get_actor(params))
  39
  40     if id_uri.host == actor_uri.host do
  41       :ok
  42     else
  43       :error
  44     end
  45   end
  46
  47   @doc """
  48   Modifies an incoming AP object (mastodon format) to our internal format.
  49   """
  50   def fix_object(object) do
  51     object
  52     |> fix_actor
  53     |> fix_attachments
  54     |> fix_context
  55     |> fix_in_reply_to
  56     |> fix_emoji
  57     |> fix_tag
  58     |> fix_content_map
  59     |> fix_likes
  60     |> fix_addressing
  61   end
  62
  63   def fix_addressing_list(map, field) do
  64     if is_binary(map[field]) do
  65       map
  66       |> Map.put(field, [map[field]])
  67     else
  68       map
  69     end
  70   end
  71
  72   def fix_addressing(map) do
  73     map
  74     |> fix_addressing_list("to")
  75     |> fix_addressing_list("cc")
  76     |> fix_addressing_list("bto")
  77     |> fix_addressing_list("bcc")
  78   end
  79
  80   def fix_actor(%{"attributedTo" => actor} = object) do
  81     object
  82     |> Map.put("actor", get_actor(%{"actor" => actor}))
  83   end
  84
  85   def fix_likes(%{"likes" => likes} = object)
  86       when is_bitstring(likes) do
  87     # Check for standardisation
  88     # This is what Peertube does
  89     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
  90     object
  91     |> Map.put("likes", [])
  92     |> Map.put("like_count", 0)
  93   end
  94
  95   def fix_likes(object) do
  96     object
  97   end
  98
  99   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 100       when not is_nil(in_reply_to) do
 101     in_reply_to_id =
 102       if is_bitstring(in_reply_to) do
 103         in_reply_to
 104       else
 105         if is_map(in_reply_to) && in_reply_to["id"] do
 106           in_reply_to["id"]
 107         end
 108       end
 109
 110     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
 111       {:ok, replied_object} ->
 112         with %Activity{} = activity <-
 113                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 114           object
 115           |> Map.put("inReplyTo", replied_object.data["id"])
 116           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 117           |> Map.put("inReplyToStatusId", activity.id)
 118           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 119           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 120         else
 121           e ->
 122             Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 123             object
 124         end
 125
 126       e ->
 127         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 128         object
 129     end
 130   end
 131
 132   def fix_in_reply_to(object), do: object
 133
 134   def fix_context(object) do
 135     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 136
 137     object
 138     |> Map.put("context", context)
 139     |> Map.put("conversation", context)
 140   end
 141
 142   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 143     attachments =
 144       attachment
 145       |> Enum.map(fn data ->
 146         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 147         Map.put(data, "url", url)
 148       end)
 149
 150     object
 151     |> Map.put("attachment", attachments)
 152   end
 153
 154   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 155     attachment =
 156       Map.put(attachment, "url", [
 157         %{"type" => "Link", "mediaType" => attachment["mediaType"], "href" => attachment["url"]}
 158       ])
 159
 160     Map.put(object, "attachment", attachment)
 161   end
 162
 163   def fix_attachments(object) do
 164     object
 165   end
 166
 167   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 168     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 169
 170     emoji =
 171       emoji
 172       |> Enum.reduce(%{}, fn data, mapping ->
 173         name = String.trim(data["name"], ":")
 174
 175         mapping |> Map.put(name, data["icon"]["url"])
 176       end)
 177
 178     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 179     emoji = Map.merge(object["emoji"] || %{}, emoji)
 180
 181     object
 182     |> Map.put("emoji", emoji)
 183   end
 184
 185   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 186     name = String.trim(tag["name"], ":")
 187     emoji = %{name => tag["icon"]["url"]}
 188
 189     object
 190     |> Map.put("emoji", emoji)
 191   end
 192
 193   def fix_emoji(object) do
 194     object
 195   end
 196
 197   def fix_tag(object) do
 198     tags =
 199       (object["tag"] || [])
 200       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 201       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 202
 203     combined = (object["tag"] || []) ++ tags
 204
 205     object
 206     |> Map.put("tag", combined)
 207   end
 208
 209   # content map usually only has one language so this will do for now.
 210   def fix_content_map(%{"contentMap" => content_map} = object) do
 211     content_groups = Map.to_list(content_map)
 212     {_, content} = Enum.at(content_groups, 0)
 213
 214     object
 215     |> Map.put("content", content)
 216   end
 217
 218   def fix_content_map(object), do: object
 219
 220   # disallow objects with bogus IDs
 221   def handle_incoming(%{"id" => nil}), do: :error
 222   def handle_incoming(%{"id" => ""}), do: :error
 223   # length of https:// = 8, should validate better, but good enough for now.
 224   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 225
 226   # TODO: validate those with a Ecto scheme
 227   # - tags
 228   # - emoji
 229   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 230       when objtype in ["Article", "Note", "Video"] do
 231     actor = get_actor(data)
 232
 233     data =
 234       Map.put(data, "actor", actor)
 235       |> fix_addressing
 236
 237     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 238          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 239       object = fix_object(data["object"])
 240
 241       params = %{
 242         to: data["to"],
 243         object: object,
 244         actor: user,
 245         context: object["conversation"],
 246         local: false,
 247         published: data["published"],
 248         additional:
 249           Map.take(data, [
 250             "cc",
 251             "id"
 252           ])
 253       }
 254
 255       ActivityPub.create(params)
 256     else
 257       %Activity{} = activity -> {:ok, activity}
 258       _e -> :error
 259     end
 260   end
 261
 262   def handle_incoming(
 263         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 264       ) do
 265     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 266          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 267          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 268       if not User.locked?(followed) do
 269         ActivityPub.accept(%{
 270           to: [follower.ap_id],
 271           actor: followed.ap_id,
 272           object: data,
 273           local: true
 274         })
 275
 276         User.follow(follower, followed)
 277       end
 278
 279       {:ok, activity}
 280     else
 281       _e -> :error
 282     end
 283   end
 284
 285   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 286     with true <- id =~ "follows",
 287          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 288          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 289       {:ok, activity}
 290     else
 291       _ -> {:error, nil}
 292     end
 293   end
 294
 295   defp mastodon_follow_hack(_), do: {:error, nil}
 296
 297   defp get_follow_activity(follow_object, followed) do
 298     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 299          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 300       {:ok, activity}
 301     else
 302       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 303       {:activity, nil} ->
 304         mastodon_follow_hack(follow_object, followed)
 305
 306       _ ->
 307         {:error, nil}
 308     end
 309   end
 310
 311   def handle_incoming(
 312         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 313       ) do
 314     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 315          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 316          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 317          {:ok, activity} <-
 318            ActivityPub.accept(%{
 319              to: follow_activity.data["to"],
 320              type: "Accept",
 321              actor: followed.ap_id,
 322              object: follow_activity.data["id"],
 323              local: false
 324            }) do
 325       if not User.following?(follower, followed) do
 326         {:ok, follower} = User.follow(follower, followed)
 327       end
 328
 329       {:ok, activity}
 330     else
 331       _e -> :error
 332     end
 333   end
 334
 335   def handle_incoming(
 336         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 337       ) do
 338     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 339          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 340          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 341          {:ok, activity} <-
 342            ActivityPub.accept(%{
 343              to: follow_activity.data["to"],
 344              type: "Accept",
 345              actor: followed.ap_id,
 346              object: follow_activity.data["id"],
 347              local: false
 348            }) do
 349       User.unfollow(follower, followed)
 350
 351       {:ok, activity}
 352     else
 353       _e -> :error
 354     end
 355   end
 356
 357   def handle_incoming(
 358         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 359       ) do
 360     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 361          {:ok, object} <-
 362            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 363          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 364       {:ok, activity}
 365     else
 366       _e -> :error
 367     end
 368   end
 369
 370   def handle_incoming(
 371         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 372       ) do
 373     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 374          {:ok, object} <-
 375            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 376          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 377       {:ok, activity}
 378     else
 379       _e -> :error
 380     end
 381   end
 382
 383   def handle_incoming(
 384         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 385           data
 386       )
 387       when object_type in ["Person", "Application", "Service", "Organization"] do
 388     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 389       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 390
 391       banner = new_user_data[:info]["banner"]
 392       locked = new_user_data[:info]["locked"] || false
 393
 394       update_data =
 395         new_user_data
 396         |> Map.take([:name, :bio, :avatar])
 397         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 398
 399       actor
 400       |> User.upgrade_changeset(update_data)
 401       |> User.update_and_set_cache()
 402
 403       ActivityPub.update(%{
 404         local: false,
 405         to: data["to"] || [],
 406         cc: data["cc"] || [],
 407         object: object,
 408         actor: actor_id
 409       })
 410     else
 411       e ->
 412         Logger.error(e)
 413         :error
 414     end
 415   end
 416
 417   # TODO: Make secure.
 418   def handle_incoming(
 419         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 420       ) do
 421     object_id = Utils.get_ap_id(object_id)
 422
 423     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 424          {:ok, object} <-
 425            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 426          {:ok, activity} <- ActivityPub.delete(object, false) do
 427       {:ok, activity}
 428     else
 429       _e -> :error
 430     end
 431   end
 432
 433   def handle_incoming(
 434         %{
 435           "type" => "Undo",
 436           "object" => %{"type" => "Announce", "object" => object_id},
 437           "actor" => actor,
 438           "id" => id
 439         } = _data
 440       ) do
 441     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 442          {:ok, object} <-
 443            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 444          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 445       {:ok, activity}
 446     else
 447       _e -> :error
 448     end
 449   end
 450
 451   def handle_incoming(
 452         %{
 453           "type" => "Undo",
 454           "object" => %{"type" => "Follow", "object" => followed},
 455           "actor" => follower,
 456           "id" => id
 457         } = _data
 458       ) do
 459     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 460          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 461          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 462       User.unfollow(follower, followed)
 463       {:ok, activity}
 464     else
 465       e -> :error
 466     end
 467   end
 468
 469   @ap_config Application.get_env(:pleroma, :activitypub)
 470   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 471
 472   def handle_incoming(
 473         %{
 474           "type" => "Undo",
 475           "object" => %{"type" => "Block", "object" => blocked},
 476           "actor" => blocker,
 477           "id" => id
 478         } = _data
 479       ) do
 480     with true <- @accept_blocks,
 481          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 482          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 483          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 484       User.unblock(blocker, blocked)
 485       {:ok, activity}
 486     else
 487       e -> :error
 488     end
 489   end
 490
 491   def handle_incoming(
 492         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 493       ) do
 494     with true <- @accept_blocks,
 495          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 496          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 497          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 498       User.unfollow(blocker, blocked)
 499       User.block(blocker, blocked)
 500       {:ok, activity}
 501     else
 502       e -> :error
 503     end
 504   end
 505
 506   def handle_incoming(
 507         %{
 508           "type" => "Undo",
 509           "object" => %{"type" => "Like", "object" => object_id},
 510           "actor" => actor,
 511           "id" => id
 512         } = _data
 513       ) do
 514     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 515          {:ok, object} <-
 516            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 517          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 518       {:ok, activity}
 519     else
 520       _e -> :error
 521     end
 522   end
 523
 524   def handle_incoming(_), do: :error
 525
 526   def get_obj_helper(id) do
 527     if object = Object.normalize(id), do: {:ok, object}, else: nil
 528   end
 529
 530   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 531     with false <- String.starts_with?(inReplyTo, "http"),
 532          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 533       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 534     else
 535       _e -> object
 536     end
 537   end
 538
 539   def set_reply_to_uri(obj), do: obj
 540
 541   # Prepares the object of an outgoing create activity.
 542   def prepare_object(object) do
 543     object
 544     |> set_sensitive
 545     |> add_hashtags
 546     |> add_mention_tags
 547     |> add_emoji_tags
 548     |> add_attributed_to
 549     |> prepare_attachments
 550     |> set_conversation
 551     |> set_reply_to_uri
 552   end
 553
 554   #  @doc
 555   #  """
 556   #  internal -> Mastodon
 557   #  """
 558
 559   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 560     object =
 561       object
 562       |> prepare_object
 563
 564     data =
 565       data
 566       |> Map.put("object", object)
 567       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 568
 569     {:ok, data}
 570   end
 571
 572   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 573   # because of course it does.
 574   def prepare_outgoing(%{"type" => "Accept"} = data) do
 575     with follow_activity <- Activity.normalize(data["object"]) do
 576       object = %{
 577         "actor" => follow_activity.actor,
 578         "object" => follow_activity.data["object"],
 579         "id" => follow_activity.data["id"],
 580         "type" => "Follow"
 581       }
 582
 583       data =
 584         data
 585         |> Map.put("object", object)
 586         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 587
 588       {:ok, data}
 589     end
 590   end
 591
 592   def prepare_outgoing(%{"type" => "Reject"} = data) do
 593     with follow_activity <- Activity.normalize(data["object"]) do
 594       object = %{
 595         "actor" => follow_activity.actor,
 596         "object" => follow_activity.data["object"],
 597         "id" => follow_activity.data["id"],
 598         "type" => "Follow"
 599       }
 600
 601       data =
 602         data
 603         |> Map.put("object", object)
 604         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 605
 606       {:ok, data}
 607     end
 608   end
 609
 610   def prepare_outgoing(%{"type" => _type} = data) do
 611     data =
 612       data
 613       |> maybe_fix_object_url
 614       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 615
 616     {:ok, data}
 617   end
 618
 619   def maybe_fix_object_url(data) do
 620     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 621       case ActivityPub.fetch_object_from_id(data["object"]) do
 622         {:ok, relative_object} ->
 623           if relative_object.data["external_url"] do
 624             _data =
 625               data
 626               |> Map.put("object", relative_object.data["external_url"])
 627           else
 628             data
 629           end
 630
 631         e ->
 632           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 633           data
 634       end
 635     else
 636       data
 637     end
 638   end
 639
 640   def add_hashtags(object) do
 641     tags =
 642       (object["tag"] || [])
 643       |> Enum.map(fn tag ->
 644         %{
 645           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 646           "name" => "##{tag}",
 647           "type" => "Hashtag"
 648         }
 649       end)
 650
 651     object
 652     |> Map.put("tag", tags)
 653   end
 654
 655   def add_mention_tags(object) do
 656     recipients = object["to"] ++ (object["cc"] || [])
 657
 658     mentions =
 659       recipients
 660       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 661       |> Enum.filter(& &1)
 662       |> Enum.map(fn user ->
 663         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 664       end)
 665
 666     tags = object["tag"] || []
 667
 668     object
 669     |> Map.put("tag", tags ++ mentions)
 670   end
 671
 672   # TODO: we should probably send mtime instead of unix epoch time for updated
 673   def add_emoji_tags(object) do
 674     tags = object["tag"] || []
 675     emoji = object["emoji"] || []
 676
 677     out =
 678       emoji
 679       |> Enum.map(fn {name, url} ->
 680         %{
 681           "icon" => %{"url" => url, "type" => "Image"},
 682           "name" => ":" <> name <> ":",
 683           "type" => "Emoji",
 684           "updated" => "1970-01-01T00:00:00Z",
 685           "id" => url
 686         }
 687       end)
 688
 689     object
 690     |> Map.put("tag", tags ++ out)
 691   end
 692
 693   def set_conversation(object) do
 694     Map.put(object, "conversation", object["context"])
 695   end
 696
 697   def set_sensitive(object) do
 698     tags = object["tag"] || []
 699     Map.put(object, "sensitive", "nsfw" in tags)
 700   end
 701
 702   def add_attributed_to(object) do
 703     attributedTo = object["attributedTo"] || object["actor"]
 704
 705     object
 706     |> Map.put("attributedTo", attributedTo)
 707   end
 708
 709   def prepare_attachments(object) do
 710     attachments =
 711       (object["attachment"] || [])
 712       |> Enum.map(fn data ->
 713         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 714         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 715       end)
 716
 717     object
 718     |> Map.put("attachment", attachments)
 719   end
 720
 721   defp user_upgrade_task(user) do
 722     old_follower_address = User.ap_followers(user)
 723
 724     q =
 725       from(
 726         u in User,
 727         where: ^old_follower_address in u.following,
 728         update: [
 729           set: [
 730             following:
 731               fragment(
 732                 "array_replace(?,?,?)",
 733                 u.following,
 734                 ^old_follower_address,
 735                 ^user.follower_address
 736               )
 737           ]
 738         ]
 739       )
 740
 741     Repo.update_all(q, [])
 742
 743     maybe_retire_websub(user.ap_id)
 744
 745     # Only do this for recent activties, don't go through the whole db.
 746     # Only look at the last 1000 activities.
 747     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 748
 749     q =
 750       from(
 751         a in Activity,
 752         where: ^old_follower_address in a.recipients,
 753         where: a.id > ^since,
 754         update: [
 755           set: [
 756             recipients:
 757               fragment(
 758                 "array_replace(?,?,?)",
 759                 a.recipients,
 760                 ^old_follower_address,
 761                 ^user.follower_address
 762               )
 763           ]
 764         ]
 765       )
 766
 767     Repo.update_all(q, [])
 768   end
 769
 770   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 771     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 772          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 773       data =
 774         data
 775         |> Map.put(:info, Map.merge(user.info, data[:info]))
 776
 777       already_ap = User.ap_enabled?(user)
 778
 779       {:ok, user} =
 780         User.upgrade_changeset(user, data)
 781         |> Repo.update()
 782
 783       if !already_ap do
 784         # This could potentially take a long time, do it in the background
 785         if async do
 786           Task.start(fn ->
 787             user_upgrade_task(user)
 788           end)
 789         else
 790           user_upgrade_task(user)
 791         end
 792       end
 793
 794       {:ok, user}
 795     else
 796       e -> e
 797     end
 798   end
 799
 800   def maybe_retire_websub(ap_id) do
 801     # some sanity checks
 802     if is_binary(ap_id) && String.length(ap_id) > 8 do
 803       q =
 804         from(
 805           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 806           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 807         )
 808
 809       Repo.delete_all(q)
 810     end
 811   end
 812
 813   def maybe_fix_user_url(data) do
 814     if is_map(data["url"]) do
 815       Map.put(data, "url", data["url"]["href"])
 816     else
 817       data
 818     end
 819   end
 820
 821   def maybe_fix_user_object(data) do
 822     data
 823     |> maybe_fix_user_url
 824   end
 825 end