git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.Object
  11   alias Pleroma.Object.Containment
  12   alias Pleroma.Repo
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15   alias Pleroma.Web.ActivityPub.Utils
  16   alias Pleroma.Web.ActivityPub.Visibility
  17   alias Pleroma.Web.Federator
  18   alias Pleroma.Workers.TransmogrifierWorker
  19
  20   import Ecto.Query
  21
  22   require Logger
  23   require Pleroma.Constants
  24
  25   @doc """
  26   Modifies an incoming AP object (mastodon format) to our internal format.
  27   """
  28   def fix_object(object, options \\ []) do
  29     object
  30     |> strip_internal_fields
  31     |> fix_actor
  32     |> fix_url
  33     |> fix_attachments
  34     |> fix_context
  35     |> fix_in_reply_to(options)
  36     |> fix_emoji
  37     |> fix_tag
  38     |> fix_content_map
  39     |> fix_addressing
  40     |> fix_summary
  41     |> fix_type(options)
  42   end
  43
  44   def fix_summary(%{"summary" => nil} = object) do
  45     Map.put(object, "summary", "")
  46   end
  47
  48   def fix_summary(%{"summary" => _} = object) do
  49     # summary is present, nothing to do
  50     object
  51   end
  52
  53   def fix_summary(object), do: Map.put(object, "summary", "")
  54
  55   def fix_addressing_list(map, field) do
  56     cond do
  57       is_binary(map[field]) ->
  58         Map.put(map, field, [map[field]])
  59
  60       is_nil(map[field]) ->
  61         Map.put(map, field, [])
  62
  63       true ->
  64         map
  65     end
  66   end
  67
  68   def fix_explicit_addressing(
  69         %{"to" => to, "cc" => cc} = object,
  70         explicit_mentions,
  71         follower_collection
  72       ) do
  73     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  74
  75     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  76
  77     final_cc =
  78       (cc ++ explicit_cc)
  79       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  80       |> Enum.uniq()
  81
  82     object
  83     |> Map.put("to", explicit_to)
  84     |> Map.put("cc", final_cc)
  85   end
  86
  87   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  88
  89   # if directMessage flag is set to true, leave the addressing alone
  90   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  91
  92   def fix_explicit_addressing(object) do
  93     explicit_mentions = Utils.determine_explicit_mentions(object)
  94
  95     %User{follower_address: follower_collection} =
  96       object
  97       |> Containment.get_actor()
  98       |> User.get_cached_by_ap_id()
  99
 100     explicit_mentions =
 101       explicit_mentions ++
 102         [
 103           Pleroma.Constants.as_public(),
 104           follower_collection
 105         ]
 106
 107     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 108   end
 109
 110   # if as:Public is addressed, then make sure the followers collection is also addressed
 111   # so that the activities will be delivered to local users.
 112   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 113     recipients = to ++ cc
 114
 115     if followers_collection not in recipients do
 116       cond do
 117         Pleroma.Constants.as_public() in cc ->
 118           to = to ++ [followers_collection]
 119           Map.put(object, "to", to)
 120
 121         Pleroma.Constants.as_public() in to ->
 122           cc = cc ++ [followers_collection]
 123           Map.put(object, "cc", cc)
 124
 125         true ->
 126           object
 127       end
 128     else
 129       object
 130     end
 131   end
 132
 133   def fix_implicit_addressing(object, _), do: object
 134
 135   def fix_addressing(object) do
 136     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 137     followers_collection = User.ap_followers(user)
 138
 139     object
 140     |> fix_addressing_list("to")
 141     |> fix_addressing_list("cc")
 142     |> fix_addressing_list("bto")
 143     |> fix_addressing_list("bcc")
 144     |> fix_explicit_addressing()
 145     |> fix_implicit_addressing(followers_collection)
 146   end
 147
 148   def fix_actor(%{"attributedTo" => actor} = object) do
 149     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 150   end
 151
 152   def fix_in_reply_to(object, options \\ [])
 153
 154   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 155       when not is_nil(in_reply_to) do
 156     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 157     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 158
 159     if Federator.allowed_incoming_reply_depth?(options[:depth]) do
 160       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 161            %Activity{} = _ <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 162         object
 163         |> Map.put("inReplyTo", replied_object.data["id"])
 164         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 165         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 166         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 167       else
 168         e ->
 169           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 170           object
 171       end
 172     else
 173       object
 174     end
 175   end
 176
 177   def fix_in_reply_to(object, _options), do: object
 178
 179   defp prepare_in_reply_to(in_reply_to) do
 180     cond do
 181       is_bitstring(in_reply_to) ->
 182         in_reply_to
 183
 184       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 185         in_reply_to["id"]
 186
 187       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 188         Enum.at(in_reply_to, 0)
 189
 190       true ->
 191         ""
 192     end
 193   end
 194
 195   def fix_context(object) do
 196     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 197
 198     object
 199     |> Map.put("context", context)
 200     |> Map.put("conversation", context)
 201   end
 202
 203   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 204     attachments =
 205       Enum.map(attachment, fn data ->
 206         media_type = data["mediaType"] || data["mimeType"]
 207         href = data["url"] || data["href"]
 208         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 209
 210         data
 211         |> Map.put("mediaType", media_type)
 212         |> Map.put("url", url)
 213       end)
 214
 215     Map.put(object, "attachment", attachments)
 216   end
 217
 218   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 219     object
 220     |> Map.put("attachment", [attachment])
 221     |> fix_attachments()
 222   end
 223
 224   def fix_attachments(object), do: object
 225
 226   def fix_url(%{"url" => url} = object) when is_map(url) do
 227     Map.put(object, "url", url["href"])
 228   end
 229
 230   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 231     first_element = Enum.at(url, 0)
 232
 233     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 234
 235     object
 236     |> Map.put("attachment", [first_element])
 237     |> Map.put("url", link_element["href"])
 238   end
 239
 240   def fix_url(%{"type" => object_type, "url" => url} = object)
 241       when object_type != "Video" and is_list(url) do
 242     first_element = Enum.at(url, 0)
 243
 244     url_string =
 245       cond do
 246         is_bitstring(first_element) -> first_element
 247         is_map(first_element) -> first_element["href"] || ""
 248         true -> ""
 249       end
 250
 251     Map.put(object, "url", url_string)
 252   end
 253
 254   def fix_url(object), do: object
 255
 256   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 257     emoji =
 258       tags
 259       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 260       |> Enum.reduce(%{}, fn data, mapping ->
 261         name = String.trim(data["name"], ":")
 262
 263         Map.put(mapping, name, data["icon"]["url"])
 264       end)
 265
 266     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 267     emoji = Map.merge(object["emoji"] || %{}, emoji)
 268
 269     Map.put(object, "emoji", emoji)
 270   end
 271
 272   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 273     name = String.trim(tag["name"], ":")
 274     emoji = %{name => tag["icon"]["url"]}
 275
 276     Map.put(object, "emoji", emoji)
 277   end
 278
 279   def fix_emoji(object), do: object
 280
 281   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 282     tags =
 283       tag
 284       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 285       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 286
 287     Map.put(object, "tag", tag ++ tags)
 288   end
 289
 290   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 291     combined = [tag, String.slice(hashtag, 1..-1)]
 292
 293     Map.put(object, "tag", combined)
 294   end
 295
 296   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 297
 298   def fix_tag(object), do: object
 299
 300   # content map usually only has one language so this will do for now.
 301   def fix_content_map(%{"contentMap" => content_map} = object) do
 302     content_groups = Map.to_list(content_map)
 303     {_, content} = Enum.at(content_groups, 0)
 304
 305     Map.put(object, "content", content)
 306   end
 307
 308   def fix_content_map(object), do: object
 309
 310   def fix_type(object, options \\ [])
 311
 312   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 313       when is_binary(reply_id) do
 314     with true <- Federator.allowed_incoming_reply_depth?(options[:depth]),
 315          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 316       Map.put(object, "type", "Answer")
 317     else
 318       _ -> object
 319     end
 320   end
 321
 322   def fix_type(object, _), do: object
 323
 324   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 325     with true <- id =~ "follows",
 326          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 327          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 328       {:ok, activity}
 329     else
 330       _ -> {:error, nil}
 331     end
 332   end
 333
 334   defp mastodon_follow_hack(_, _), do: {:error, nil}
 335
 336   defp get_follow_activity(follow_object, followed) do
 337     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 338          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 339       {:ok, activity}
 340     else
 341       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 342       {:activity, nil} ->
 343         mastodon_follow_hack(follow_object, followed)
 344
 345       _ ->
 346         {:error, nil}
 347     end
 348   end
 349
 350   # Reduce the object list to find the reported user.
 351   defp get_reported(objects) do
 352     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 353       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 354         {:halt, user}
 355       else
 356         _ -> {:cont, nil}
 357       end
 358     end)
 359   end
 360
 361   def handle_incoming(data, options \\ [])
 362
 363   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 364   # with nil ID.
 365   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 366     with context <- data["context"] || Utils.generate_context_id(),
 367          content <- data["content"] || "",
 368          %User{} = actor <- User.get_cached_by_ap_id(actor),
 369          # Reduce the object list to find the reported user.
 370          %User{} = account <- get_reported(objects),
 371          # Remove the reported user from the object list.
 372          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 373       %{
 374         actor: actor,
 375         context: context,
 376         account: account,
 377         statuses: statuses,
 378         content: content,
 379         additional: %{"cc" => [account.ap_id]}
 380       }
 381       |> ActivityPub.flag()
 382     end
 383   end
 384
 385   # disallow objects with bogus IDs
 386   def handle_incoming(%{"id" => nil}, _options), do: :error
 387   def handle_incoming(%{"id" => ""}, _options), do: :error
 388   # length of https:// = 8, should validate better, but good enough for now.
 389   def handle_incoming(%{"id" => id}, _options) when not (is_binary(id) and length(id) > 8),
 390     do: :error
 391
 392   # TODO: validate those with a Ecto scheme
 393   # - tags
 394   # - emoji
 395   def handle_incoming(
 396         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 397         options
 398       )
 399       when objtype in ["Article", "Note", "Video", "Page", "Question", "Answer"] do
 400     actor = Containment.get_actor(data)
 401
 402     data =
 403       Map.put(data, "actor", actor)
 404       |> fix_addressing
 405
 406     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 407          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 408       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 409       object = fix_object(data["object"], options)
 410
 411       params = %{
 412         to: data["to"],
 413         object: object,
 414         actor: user,
 415         context: object["conversation"],
 416         local: false,
 417         published: data["published"],
 418         additional:
 419           Map.take(data, [
 420             "cc",
 421             "directMessage",
 422             "id"
 423           ])
 424       }
 425
 426       ActivityPub.create(params)
 427     else
 428       %Activity{} = activity -> {:ok, activity}
 429       _e -> :error
 430     end
 431   end
 432
 433   def handle_incoming(
 434         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 435         options
 436       ) do
 437     actor = Containment.get_actor(data)
 438
 439     data =
 440       Map.put(data, "actor", actor)
 441       |> fix_addressing
 442
 443     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 444       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 445       object = fix_object(object, options)
 446
 447       params = %{
 448         to: data["to"],
 449         object: object,
 450         actor: user,
 451         context: nil,
 452         local: false,
 453         published: data["published"],
 454         additional: Map.take(data, ["cc", "id"])
 455       }
 456
 457       ActivityPub.listen(params)
 458     else
 459       _e -> :error
 460     end
 461   end
 462
 463   def handle_incoming(
 464         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 465         _options
 466       ) do
 467     with %User{local: true} = followed <-
 468            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 469          {:ok, %User{} = follower} <-
 470            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 471          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 472       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 473            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 474            {_, false} <- {:user_locked, User.locked?(followed)},
 475            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 476            {_, {:ok, _}} <-
 477              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")} do
 478         ActivityPub.accept(%{
 479           to: [follower.ap_id],
 480           actor: followed,
 481           object: data,
 482           local: true
 483         })
 484       else
 485         {:user_blocked, true} ->
 486           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 487
 488           ActivityPub.reject(%{
 489             to: [follower.ap_id],
 490             actor: followed,
 491             object: data,
 492             local: true
 493           })
 494
 495         {:follow, {:error, _}} ->
 496           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 497
 498           ActivityPub.reject(%{
 499             to: [follower.ap_id],
 500             actor: followed,
 501             object: data,
 502             local: true
 503           })
 504
 505         {:user_locked, true} ->
 506           :noop
 507       end
 508
 509       {:ok, activity}
 510     else
 511       _e ->
 512         :error
 513     end
 514   end
 515
 516   def handle_incoming(
 517         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data,
 518         _options
 519       ) do
 520     with actor <- Containment.get_actor(data),
 521          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 522          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 523          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 524          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 525          {:ok, _follower} = User.follow(follower, followed) do
 526       ActivityPub.accept(%{
 527         to: follow_activity.data["to"],
 528         type: "Accept",
 529         actor: followed,
 530         object: follow_activity.data["id"],
 531         local: false
 532       })
 533     else
 534       _e -> :error
 535     end
 536   end
 537
 538   def handle_incoming(
 539         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data,
 540         _options
 541       ) do
 542     with actor <- Containment.get_actor(data),
 543          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 544          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 545          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 546          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 547          {:ok, activity} <-
 548            ActivityPub.reject(%{
 549              to: follow_activity.data["to"],
 550              type: "Reject",
 551              actor: followed,
 552              object: follow_activity.data["id"],
 553              local: false
 554            }) do
 555       User.unfollow(follower, followed)
 556
 557       {:ok, activity}
 558     else
 559       _e -> :error
 560     end
 561   end
 562
 563   def handle_incoming(
 564         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data,
 565         _options
 566       ) do
 567     with actor <- Containment.get_actor(data),
 568          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 569          {:ok, object} <- get_obj_helper(object_id),
 570          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 571       {:ok, activity}
 572     else
 573       _e -> :error
 574     end
 575   end
 576
 577   def handle_incoming(
 578         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 579         _options
 580       ) do
 581     with actor <- Containment.get_actor(data),
 582          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 583          {:ok, object} <- get_obj_helper(object_id),
 584          public <- Visibility.is_public?(data),
 585          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 586       {:ok, activity}
 587     else
 588       _e -> :error
 589     end
 590   end
 591
 592   def handle_incoming(
 593         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 594           data,
 595         _options
 596       )
 597       when object_type in ["Person", "Application", "Service", "Organization"] do
 598     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 599       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 600
 601       banner = new_user_data[:info][:banner]
 602       locked = new_user_data[:info][:locked] || false
 603       attachment = get_in(new_user_data, [:info, :source_data, "attachment"]) || []
 604
 605       fields =
 606         attachment
 607         |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 608         |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 609
 610       update_data =
 611         new_user_data
 612         |> Map.take([:name, :bio, :avatar])
 613         |> Map.put(:info, %{banner: banner, locked: locked, fields: fields})
 614
 615       actor
 616       |> User.upgrade_changeset(update_data, true)
 617       |> User.update_and_set_cache()
 618
 619       ActivityPub.update(%{
 620         local: false,
 621         to: data["to"] || [],
 622         cc: data["cc"] || [],
 623         object: object,
 624         actor: actor_id
 625       })
 626     else
 627       e ->
 628         Logger.error(e)
 629         :error
 630     end
 631   end
 632
 633   # TODO: We presently assume that any actor on the same origin domain as the object being
 634   # deleted has the rights to delete that object.  A better way to validate whether or not
 635   # the object should be deleted is to refetch the object URI, which should return either
 636   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 637   # place.
 638   def handle_incoming(
 639         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = data,
 640         _options
 641       ) do
 642     object_id = Utils.get_ap_id(object_id)
 643
 644     with actor <- Containment.get_actor(data),
 645          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 646          {:ok, object} <- get_obj_helper(object_id),
 647          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 648          {:ok, activity} <- ActivityPub.delete(object, false) do
 649       {:ok, activity}
 650     else
 651       nil ->
 652         case User.get_cached_by_ap_id(object_id) do
 653           %User{ap_id: ^actor} = user ->
 654             User.delete(user)
 655
 656           nil ->
 657             :error
 658         end
 659
 660       _e ->
 661         :error
 662     end
 663   end
 664
 665   def handle_incoming(
 666         %{
 667           "type" => "Undo",
 668           "object" => %{"type" => "Announce", "object" => object_id},
 669           "actor" => _actor,
 670           "id" => id
 671         } = data,
 672         _options
 673       ) do
 674     with actor <- Containment.get_actor(data),
 675          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 676          {:ok, object} <- get_obj_helper(object_id),
 677          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 678       {:ok, activity}
 679     else
 680       _e -> :error
 681     end
 682   end
 683
 684   def handle_incoming(
 685         %{
 686           "type" => "Undo",
 687           "object" => %{"type" => "Follow", "object" => followed},
 688           "actor" => follower,
 689           "id" => id
 690         } = _data,
 691         _options
 692       ) do
 693     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 694          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 695          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 696       User.unfollow(follower, followed)
 697       {:ok, activity}
 698     else
 699       _e -> :error
 700     end
 701   end
 702
 703   def handle_incoming(
 704         %{
 705           "type" => "Undo",
 706           "object" => %{"type" => "Block", "object" => blocked},
 707           "actor" => blocker,
 708           "id" => id
 709         } = _data,
 710         _options
 711       ) do
 712     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 713          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 714          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 715       User.unblock(blocker, blocked)
 716       {:ok, activity}
 717     else
 718       _e -> :error
 719     end
 720   end
 721
 722   def handle_incoming(
 723         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 724         _options
 725       ) do
 726     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 727          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 728          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 729       User.unfollow(blocker, blocked)
 730       User.block(blocker, blocked)
 731       {:ok, activity}
 732     else
 733       _e -> :error
 734     end
 735   end
 736
 737   def handle_incoming(
 738         %{
 739           "type" => "Undo",
 740           "object" => %{"type" => "Like", "object" => object_id},
 741           "actor" => _actor,
 742           "id" => id
 743         } = data,
 744         _options
 745       ) do
 746     with actor <- Containment.get_actor(data),
 747          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 748          {:ok, object} <- get_obj_helper(object_id),
 749          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 750       {:ok, activity}
 751     else
 752       _e -> :error
 753     end
 754   end
 755
 756   def handle_incoming(_, _), do: :error
 757
 758   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 759   def get_obj_helper(id, options \\ []) do
 760     case Object.normalize(id, true, options) do
 761       %Object{} = object -> {:ok, object}
 762       _ -> nil
 763     end
 764   end
 765
 766   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 767     with false <- String.starts_with?(in_reply_to, "http"),
 768          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 769       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 770     else
 771       _e -> object
 772     end
 773   end
 774
 775   def set_reply_to_uri(obj), do: obj
 776
 777   # Prepares the object of an outgoing create activity.
 778   def prepare_object(object) do
 779     object
 780     |> set_sensitive
 781     |> add_hashtags
 782     |> add_mention_tags
 783     |> add_emoji_tags
 784     |> add_attributed_to
 785     |> prepare_attachments
 786     |> set_conversation
 787     |> set_reply_to_uri
 788     |> strip_internal_fields
 789     |> strip_internal_tags
 790     |> set_type
 791   end
 792
 793   #  @doc
 794   #  """
 795   #  internal -> Mastodon
 796   #  """
 797
 798   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 799       when activity_type in ["Create", "Listen"] do
 800     object =
 801       object_id
 802       |> Object.normalize()
 803       |> Map.get(:data)
 804       |> prepare_object
 805
 806     data =
 807       data
 808       |> Map.put("object", object)
 809       |> Map.merge(Utils.make_json_ld_header())
 810       |> Map.delete("bcc")
 811
 812     {:ok, data}
 813   end
 814
 815   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 816   # because of course it does.
 817   def prepare_outgoing(%{"type" => "Accept"} = data) do
 818     with follow_activity <- Activity.normalize(data["object"]) do
 819       object = %{
 820         "actor" => follow_activity.actor,
 821         "object" => follow_activity.data["object"],
 822         "id" => follow_activity.data["id"],
 823         "type" => "Follow"
 824       }
 825
 826       data =
 827         data
 828         |> Map.put("object", object)
 829         |> Map.merge(Utils.make_json_ld_header())
 830
 831       {:ok, data}
 832     end
 833   end
 834
 835   def prepare_outgoing(%{"type" => "Reject"} = data) do
 836     with follow_activity <- Activity.normalize(data["object"]) do
 837       object = %{
 838         "actor" => follow_activity.actor,
 839         "object" => follow_activity.data["object"],
 840         "id" => follow_activity.data["id"],
 841         "type" => "Follow"
 842       }
 843
 844       data =
 845         data
 846         |> Map.put("object", object)
 847         |> Map.merge(Utils.make_json_ld_header())
 848
 849       {:ok, data}
 850     end
 851   end
 852
 853   def prepare_outgoing(%{"type" => _type} = data) do
 854     data =
 855       data
 856       |> strip_internal_fields
 857       |> maybe_fix_object_url
 858       |> Map.merge(Utils.make_json_ld_header())
 859
 860     {:ok, data}
 861   end
 862
 863   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
 864     with false <- String.starts_with?(object, "http"),
 865          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
 866          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
 867            relative_object do
 868       Map.put(data, "object", external_url)
 869     else
 870       {:fetch, e} ->
 871         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
 872         data
 873
 874       _ ->
 875         data
 876     end
 877   end
 878
 879   def maybe_fix_object_url(data), do: data
 880
 881   def add_hashtags(object) do
 882     tags =
 883       (object["tag"] || [])
 884       |> Enum.map(fn
 885         # Expand internal representation tags into AS2 tags.
 886         tag when is_binary(tag) ->
 887           %{
 888             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 889             "name" => "##{tag}",
 890             "type" => "Hashtag"
 891           }
 892
 893         # Do not process tags which are already AS2 tag objects.
 894         tag when is_map(tag) ->
 895           tag
 896       end)
 897
 898     Map.put(object, "tag", tags)
 899   end
 900
 901   def add_mention_tags(object) do
 902     mentions =
 903       object
 904       |> Utils.get_notified_from_object()
 905       |> Enum.map(&build_mention_tag/1)
 906
 907     tags = object["tag"] || []
 908
 909     Map.put(object, "tag", tags ++ mentions)
 910   end
 911
 912   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
 913     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
 914   end
 915
 916   def take_emoji_tags(%User{info: %{emoji: emoji} = _user_info} = _user) do
 917     emoji
 918     |> Enum.flat_map(&Map.to_list/1)
 919     |> Enum.map(&build_emoji_tag/1)
 920   end
 921
 922   # TODO: we should probably send mtime instead of unix epoch time for updated
 923   def add_emoji_tags(%{"emoji" => emoji} = object) do
 924     tags = object["tag"] || []
 925
 926     out = Enum.map(emoji, &build_emoji_tag/1)
 927
 928     Map.put(object, "tag", tags ++ out)
 929   end
 930
 931   def add_emoji_tags(object), do: object
 932
 933   defp build_emoji_tag({name, url}) do
 934     %{
 935       "icon" => %{"url" => url, "type" => "Image"},
 936       "name" => ":" <> name <> ":",
 937       "type" => "Emoji",
 938       "updated" => "1970-01-01T00:00:00Z",
 939       "id" => url
 940     }
 941   end
 942
 943   def set_conversation(object) do
 944     Map.put(object, "conversation", object["context"])
 945   end
 946
 947   def set_sensitive(object) do
 948     tags = object["tag"] || []
 949     Map.put(object, "sensitive", "nsfw" in tags)
 950   end
 951
 952   def set_type(%{"type" => "Answer"} = object) do
 953     Map.put(object, "type", "Note")
 954   end
 955
 956   def set_type(object), do: object
 957
 958   def add_attributed_to(object) do
 959     attributed_to = object["attributedTo"] || object["actor"]
 960     Map.put(object, "attributedTo", attributed_to)
 961   end
 962
 963   def prepare_attachments(object) do
 964     attachments =
 965       (object["attachment"] || [])
 966       |> Enum.map(fn data ->
 967         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 968         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 969       end)
 970
 971     Map.put(object, "attachment", attachments)
 972   end
 973
 974   defp strip_internal_fields(object) do
 975     object
 976     |> Map.drop(Pleroma.Constants.object_internal_fields())
 977   end
 978
 979   defp strip_internal_tags(%{"tag" => tags} = object) do
 980     tags = Enum.filter(tags, fn x -> is_map(x) end)
 981
 982     Map.put(object, "tag", tags)
 983   end
 984
 985   defp strip_internal_tags(object), do: object
 986
 987   def perform(:user_upgrade, user) do
 988     # we pass a fake user so that the followers collection is stripped away
 989     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
 990
 991     q =
 992       from(
 993         u in User,
 994         where: ^old_follower_address in u.following,
 995         update: [
 996           set: [
 997             following:
 998               fragment(
 999                 "array_replace(?,?,?)",
1000                 u.following,
1001                 ^old_follower_address,
1002                 ^user.follower_address
1003               )
1004           ]
1005         ]
1006       )
1007
1008     Repo.update_all(q, [])
1009
1010     maybe_retire_websub(user.ap_id)
1011
1012     q =
1013       from(
1014         a in Activity,
1015         where: ^old_follower_address in a.recipients,
1016         update: [
1017           set: [
1018             recipients:
1019               fragment(
1020                 "array_replace(?,?,?)",
1021                 a.recipients,
1022                 ^old_follower_address,
1023                 ^user.follower_address
1024               )
1025           ]
1026         ]
1027       )
1028
1029     Repo.update_all(q, [])
1030   end
1031
1032   def upgrade_user_from_ap_id(ap_id) do
1033     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1034          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1035          already_ap <- User.ap_enabled?(user),
1036          {:ok, user} <- upgrade_user(user, data) do
1037       if not already_ap do
1038         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1039       end
1040
1041       {:ok, user}
1042     else
1043       %User{} = user -> {:ok, user}
1044       e -> e
1045     end
1046   end
1047
1048   defp upgrade_user(user, data) do
1049     user
1050     |> User.upgrade_changeset(data, true)
1051     |> User.update_and_set_cache()
1052   end
1053
1054   def maybe_retire_websub(ap_id) do
1055     # some sanity checks
1056     if is_binary(ap_id) && String.length(ap_id) > 8 do
1057       q =
1058         from(
1059           ws in Pleroma.Web.Websub.WebsubClientSubscription,
1060           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
1061         )
1062
1063       Repo.delete_all(q)
1064     end
1065   end
1066
1067   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1068     Map.put(data, "url", url["href"])
1069   end
1070
1071   def maybe_fix_user_url(data), do: data
1072
1073   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1074 end