git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.Object
  12   alias Pleroma.Object.Containment
  13   alias Pleroma.Repo
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16   alias Pleroma.Web.ActivityPub.Utils
  17   alias Pleroma.Web.ActivityPub.Visibility
  18   alias Pleroma.Web.Federator
  19   alias Pleroma.Workers.TransmogrifierWorker
  20
  21   import Ecto.Query
  22
  23   require Logger
  24   require Pleroma.Constants
  25
  26   @doc """
  27   Modifies an incoming AP object (mastodon format) to our internal format.
  28   """
  29   def fix_object(object, options \\ []) do
  30     object
  31     |> strip_internal_fields
  32     |> fix_actor
  33     |> fix_url
  34     |> fix_attachments
  35     |> fix_context
  36     |> fix_in_reply_to(options)
  37     |> fix_emoji
  38     |> fix_tag
  39     |> fix_content_map
  40     |> fix_addressing
  41     |> fix_summary
  42     |> fix_type(options)
  43   end
  44
  45   def fix_summary(%{"summary" => nil} = object) do
  46     Map.put(object, "summary", "")
  47   end
  48
  49   def fix_summary(%{"summary" => _} = object) do
  50     # summary is present, nothing to do
  51     object
  52   end
  53
  54   def fix_summary(object), do: Map.put(object, "summary", "")
  55
  56   def fix_addressing_list(map, field) do
  57     cond do
  58       is_binary(map[field]) ->
  59         Map.put(map, field, [map[field]])
  60
  61       is_nil(map[field]) ->
  62         Map.put(map, field, [])
  63
  64       true ->
  65         map
  66     end
  67   end
  68
  69   def fix_explicit_addressing(
  70         %{"to" => to, "cc" => cc} = object,
  71         explicit_mentions,
  72         follower_collection
  73       ) do
  74     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  75
  76     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  77
  78     final_cc =
  79       (cc ++ explicit_cc)
  80       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  81       |> Enum.uniq()
  82
  83     object
  84     |> Map.put("to", explicit_to)
  85     |> Map.put("cc", final_cc)
  86   end
  87
  88   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  89
  90   # if directMessage flag is set to true, leave the addressing alone
  91   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  92
  93   def fix_explicit_addressing(object) do
  94     explicit_mentions = Utils.determine_explicit_mentions(object)
  95
  96     %User{follower_address: follower_collection} =
  97       object
  98       |> Containment.get_actor()
  99       |> User.get_cached_by_ap_id()
 100
 101     explicit_mentions =
 102       explicit_mentions ++
 103         [
 104           Pleroma.Constants.as_public(),
 105           follower_collection
 106         ]
 107
 108     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 109   end
 110
 111   # if as:Public is addressed, then make sure the followers collection is also addressed
 112   # so that the activities will be delivered to local users.
 113   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 114     recipients = to ++ cc
 115
 116     if followers_collection not in recipients do
 117       cond do
 118         Pleroma.Constants.as_public() in cc ->
 119           to = to ++ [followers_collection]
 120           Map.put(object, "to", to)
 121
 122         Pleroma.Constants.as_public() in to ->
 123           cc = cc ++ [followers_collection]
 124           Map.put(object, "cc", cc)
 125
 126         true ->
 127           object
 128       end
 129     else
 130       object
 131     end
 132   end
 133
 134   def fix_implicit_addressing(object, _), do: object
 135
 136   def fix_addressing(object) do
 137     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 138     followers_collection = User.ap_followers(user)
 139
 140     object
 141     |> fix_addressing_list("to")
 142     |> fix_addressing_list("cc")
 143     |> fix_addressing_list("bto")
 144     |> fix_addressing_list("bcc")
 145     |> fix_explicit_addressing()
 146     |> fix_implicit_addressing(followers_collection)
 147   end
 148
 149   def fix_actor(%{"attributedTo" => actor} = object) do
 150     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 151   end
 152
 153   def fix_in_reply_to(object, options \\ [])
 154
 155   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 156       when not is_nil(in_reply_to) do
 157     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 158     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 159
 160     if Federator.allowed_incoming_reply_depth?(options[:depth]) do
 161       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 162            %Activity{} = _ <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 163         object
 164         |> Map.put("inReplyTo", replied_object.data["id"])
 165         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 166         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 167         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 168       else
 169         e ->
 170           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 171           object
 172       end
 173     else
 174       object
 175     end
 176   end
 177
 178   def fix_in_reply_to(object, _options), do: object
 179
 180   defp prepare_in_reply_to(in_reply_to) do
 181     cond do
 182       is_bitstring(in_reply_to) ->
 183         in_reply_to
 184
 185       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 186         in_reply_to["id"]
 187
 188       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 189         Enum.at(in_reply_to, 0)
 190
 191       true ->
 192         ""
 193     end
 194   end
 195
 196   def fix_context(object) do
 197     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 198
 199     object
 200     |> Map.put("context", context)
 201     |> Map.put("conversation", context)
 202   end
 203
 204   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 205     attachments =
 206       Enum.map(attachment, fn data ->
 207         media_type = data["mediaType"] || data["mimeType"]
 208         href = data["url"] || data["href"]
 209         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 210
 211         data
 212         |> Map.put("mediaType", media_type)
 213         |> Map.put("url", url)
 214       end)
 215
 216     Map.put(object, "attachment", attachments)
 217   end
 218
 219   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 220     object
 221     |> Map.put("attachment", [attachment])
 222     |> fix_attachments()
 223   end
 224
 225   def fix_attachments(object), do: object
 226
 227   def fix_url(%{"url" => url} = object) when is_map(url) do
 228     Map.put(object, "url", url["href"])
 229   end
 230
 231   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 232     first_element = Enum.at(url, 0)
 233
 234     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 235
 236     object
 237     |> Map.put("attachment", [first_element])
 238     |> Map.put("url", link_element["href"])
 239   end
 240
 241   def fix_url(%{"type" => object_type, "url" => url} = object)
 242       when object_type != "Video" and is_list(url) do
 243     first_element = Enum.at(url, 0)
 244
 245     url_string =
 246       cond do
 247         is_bitstring(first_element) -> first_element
 248         is_map(first_element) -> first_element["href"] || ""
 249         true -> ""
 250       end
 251
 252     Map.put(object, "url", url_string)
 253   end
 254
 255   def fix_url(object), do: object
 256
 257   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 258     emoji =
 259       tags
 260       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 261       |> Enum.reduce(%{}, fn data, mapping ->
 262         name = String.trim(data["name"], ":")
 263
 264         Map.put(mapping, name, data["icon"]["url"])
 265       end)
 266
 267     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 268     emoji = Map.merge(object["emoji"] || %{}, emoji)
 269
 270     Map.put(object, "emoji", emoji)
 271   end
 272
 273   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 274     name = String.trim(tag["name"], ":")
 275     emoji = %{name => tag["icon"]["url"]}
 276
 277     Map.put(object, "emoji", emoji)
 278   end
 279
 280   def fix_emoji(object), do: object
 281
 282   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 283     tags =
 284       tag
 285       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 286       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 287
 288     Map.put(object, "tag", tag ++ tags)
 289   end
 290
 291   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 292     combined = [tag, String.slice(hashtag, 1..-1)]
 293
 294     Map.put(object, "tag", combined)
 295   end
 296
 297   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 298
 299   def fix_tag(object), do: object
 300
 301   # content map usually only has one language so this will do for now.
 302   def fix_content_map(%{"contentMap" => content_map} = object) do
 303     content_groups = Map.to_list(content_map)
 304     {_, content} = Enum.at(content_groups, 0)
 305
 306     Map.put(object, "content", content)
 307   end
 308
 309   def fix_content_map(object), do: object
 310
 311   def fix_type(object, options \\ [])
 312
 313   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 314       when is_binary(reply_id) do
 315     with true <- Federator.allowed_incoming_reply_depth?(options[:depth]),
 316          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 317       Map.put(object, "type", "Answer")
 318     else
 319       _ -> object
 320     end
 321   end
 322
 323   def fix_type(object, _), do: object
 324
 325   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 326     with true <- id =~ "follows",
 327          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 328          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 329       {:ok, activity}
 330     else
 331       _ -> {:error, nil}
 332     end
 333   end
 334
 335   defp mastodon_follow_hack(_, _), do: {:error, nil}
 336
 337   defp get_follow_activity(follow_object, followed) do
 338     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 339          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 340       {:ok, activity}
 341     else
 342       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 343       {:activity, nil} ->
 344         mastodon_follow_hack(follow_object, followed)
 345
 346       _ ->
 347         {:error, nil}
 348     end
 349   end
 350
 351   # Reduce the object list to find the reported user.
 352   defp get_reported(objects) do
 353     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 354       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 355         {:halt, user}
 356       else
 357         _ -> {:cont, nil}
 358       end
 359     end)
 360   end
 361
 362   def handle_incoming(data, options \\ [])
 363
 364   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 365   # with nil ID.
 366   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 367     with context <- data["context"] || Utils.generate_context_id(),
 368          content <- data["content"] || "",
 369          %User{} = actor <- User.get_cached_by_ap_id(actor),
 370          # Reduce the object list to find the reported user.
 371          %User{} = account <- get_reported(objects),
 372          # Remove the reported user from the object list.
 373          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 374       %{
 375         actor: actor,
 376         context: context,
 377         account: account,
 378         statuses: statuses,
 379         content: content,
 380         additional: %{"cc" => [account.ap_id]}
 381       }
 382       |> ActivityPub.flag()
 383     end
 384   end
 385
 386   # disallow objects with bogus IDs
 387   def handle_incoming(%{"id" => nil}, _options), do: :error
 388   def handle_incoming(%{"id" => ""}, _options), do: :error
 389   # length of https:// = 8, should validate better, but good enough for now.
 390   def handle_incoming(%{"id" => id}, _options) when not (is_binary(id) and length(id) > 8),
 391     do: :error
 392
 393   # TODO: validate those with a Ecto scheme
 394   # - tags
 395   # - emoji
 396   def handle_incoming(
 397         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 398         options
 399       )
 400       when objtype in ["Article", "Note", "Video", "Page", "Question", "Answer"] do
 401     actor = Containment.get_actor(data)
 402
 403     data =
 404       Map.put(data, "actor", actor)
 405       |> fix_addressing
 406
 407     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 408          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 409       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 410       object = fix_object(data["object"], options)
 411
 412       params = %{
 413         to: data["to"],
 414         object: object,
 415         actor: user,
 416         context: object["conversation"],
 417         local: false,
 418         published: data["published"],
 419         additional:
 420           Map.take(data, [
 421             "cc",
 422             "directMessage",
 423             "id"
 424           ])
 425       }
 426
 427       ActivityPub.create(params)
 428     else
 429       %Activity{} = activity -> {:ok, activity}
 430       _e -> :error
 431     end
 432   end
 433
 434   def handle_incoming(
 435         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 436         options
 437       ) do
 438     actor = Containment.get_actor(data)
 439
 440     data =
 441       Map.put(data, "actor", actor)
 442       |> fix_addressing
 443
 444     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 445       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 446       object = fix_object(object, options)
 447
 448       params = %{
 449         to: data["to"],
 450         object: object,
 451         actor: user,
 452         context: nil,
 453         local: false,
 454         published: data["published"],
 455         additional: Map.take(data, ["cc", "id"])
 456       }
 457
 458       ActivityPub.listen(params)
 459     else
 460       _e -> :error
 461     end
 462   end
 463
 464   def handle_incoming(
 465         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 466         _options
 467       ) do
 468     with %User{local: true} = followed <-
 469            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 470          {:ok, %User{} = follower} <-
 471            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 472          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 473       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 474            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 475            {_, false} <- {:user_locked, User.locked?(followed)},
 476            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 477            {_, {:ok, _}} <-
 478              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 479            {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 480         ActivityPub.accept(%{
 481           to: [follower.ap_id],
 482           actor: followed,
 483           object: data,
 484           local: true
 485         })
 486       else
 487         {:user_blocked, true} ->
 488           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 489           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 490
 491           ActivityPub.reject(%{
 492             to: [follower.ap_id],
 493             actor: followed,
 494             object: data,
 495             local: true
 496           })
 497
 498         {:follow, {:error, _}} ->
 499           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 500           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 501
 502           ActivityPub.reject(%{
 503             to: [follower.ap_id],
 504             actor: followed,
 505             object: data,
 506             local: true
 507           })
 508
 509         {:user_locked, true} ->
 510           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "pending")
 511           :noop
 512       end
 513
 514       {:ok, activity}
 515     else
 516       _e ->
 517         :error
 518     end
 519   end
 520
 521   def handle_incoming(
 522         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 523         _options
 524       ) do
 525     with actor <- Containment.get_actor(data),
 526          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 527          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 528          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 529          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 530          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 531       ActivityPub.accept(%{
 532         to: follow_activity.data["to"],
 533         type: "Accept",
 534         actor: followed,
 535         object: follow_activity.data["id"],
 536         local: false,
 537         activity_id: id
 538       })
 539     else
 540       _e -> :error
 541     end
 542   end
 543
 544   def handle_incoming(
 545         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 546         _options
 547       ) do
 548     with actor <- Containment.get_actor(data),
 549          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 550          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 551          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 552          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 553          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "reject"),
 554          {:ok, activity} <-
 555            ActivityPub.reject(%{
 556              to: follow_activity.data["to"],
 557              type: "Reject",
 558              actor: followed,
 559              object: follow_activity.data["id"],
 560              local: false,
 561              activity_id: id
 562            }) do
 563       {:ok, activity}
 564     else
 565       _e -> :error
 566     end
 567   end
 568
 569   def handle_incoming(
 570         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data,
 571         _options
 572       ) do
 573     with actor <- Containment.get_actor(data),
 574          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 575          {:ok, object} <- get_obj_helper(object_id),
 576          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 577       {:ok, activity}
 578     else
 579       _e -> :error
 580     end
 581   end
 582
 583   def handle_incoming(
 584         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 585         _options
 586       ) do
 587     with actor <- Containment.get_actor(data),
 588          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 589          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 590          public <- Visibility.is_public?(data),
 591          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 592       {:ok, activity}
 593     else
 594       _e -> :error
 595     end
 596   end
 597
 598   def handle_incoming(
 599         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 600           data,
 601         _options
 602       )
 603       when object_type in [
 604              "Person",
 605              "Application",
 606              "Service",
 607              "Organization"
 608            ] do
 609     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 610       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 611
 612       locked = new_user_data[:locked] || false
 613       attachment = get_in(new_user_data, [:source_data, "attachment"]) || []
 614       invisible = new_user_data[:invisible] || false
 615
 616       fields =
 617         attachment
 618         |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 619         |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 620
 621       update_data =
 622         new_user_data
 623         |> Map.take([:avatar, :banner, :bio, :name])
 624         |> Map.put(:fields, fields)
 625         |> Map.put(:locked, locked)
 626         |> Map.put(:invisible, invisible)
 627
 628       actor
 629       |> User.upgrade_changeset(update_data, true)
 630       |> User.update_and_set_cache()
 631
 632       ActivityPub.update(%{
 633         local: false,
 634         to: data["to"] || [],
 635         cc: data["cc"] || [],
 636         object: object,
 637         actor: actor_id,
 638         activity_id: data["id"]
 639       })
 640     else
 641       e ->
 642         Logger.error(e)
 643         :error
 644     end
 645   end
 646
 647   # TODO: We presently assume that any actor on the same origin domain as the object being
 648   # deleted has the rights to delete that object.  A better way to validate whether or not
 649   # the object should be deleted is to refetch the object URI, which should return either
 650   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 651   # place.
 652   def handle_incoming(
 653         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 654         _options
 655       ) do
 656     object_id = Utils.get_ap_id(object_id)
 657
 658     with actor <- Containment.get_actor(data),
 659          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 660          {:ok, object} <- get_obj_helper(object_id),
 661          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 662          {:ok, activity} <-
 663            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 664       {:ok, activity}
 665     else
 666       nil ->
 667         case User.get_cached_by_ap_id(object_id) do
 668           %User{ap_id: ^actor} = user ->
 669             User.delete(user)
 670
 671           nil ->
 672             :error
 673         end
 674
 675       _e ->
 676         :error
 677     end
 678   end
 679
 680   def handle_incoming(
 681         %{
 682           "type" => "Undo",
 683           "object" => %{"type" => "Announce", "object" => object_id},
 684           "actor" => _actor,
 685           "id" => id
 686         } = data,
 687         _options
 688       ) do
 689     with actor <- Containment.get_actor(data),
 690          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 691          {:ok, object} <- get_obj_helper(object_id),
 692          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 693       {:ok, activity}
 694     else
 695       _e -> :error
 696     end
 697   end
 698
 699   def handle_incoming(
 700         %{
 701           "type" => "Undo",
 702           "object" => %{"type" => "Follow", "object" => followed},
 703           "actor" => follower,
 704           "id" => id
 705         } = _data,
 706         _options
 707       ) do
 708     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 709          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 710          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 711       User.unfollow(follower, followed)
 712       {:ok, activity}
 713     else
 714       _e -> :error
 715     end
 716   end
 717
 718   def handle_incoming(
 719         %{
 720           "type" => "Undo",
 721           "object" => %{"type" => "Block", "object" => blocked},
 722           "actor" => blocker,
 723           "id" => id
 724         } = _data,
 725         _options
 726       ) do
 727     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 728          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 729          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 730       User.unblock(blocker, blocked)
 731       {:ok, activity}
 732     else
 733       _e -> :error
 734     end
 735   end
 736
 737   def handle_incoming(
 738         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 739         _options
 740       ) do
 741     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 742          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 743          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 744       User.unfollow(blocker, blocked)
 745       User.block(blocker, blocked)
 746       {:ok, activity}
 747     else
 748       _e -> :error
 749     end
 750   end
 751
 752   def handle_incoming(
 753         %{
 754           "type" => "Undo",
 755           "object" => %{"type" => "Like", "object" => object_id},
 756           "actor" => _actor,
 757           "id" => id
 758         } = data,
 759         _options
 760       ) do
 761     with actor <- Containment.get_actor(data),
 762          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 763          {:ok, object} <- get_obj_helper(object_id),
 764          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 765       {:ok, activity}
 766     else
 767       _e -> :error
 768     end
 769   end
 770
 771   # For Undos that don't have the complete object attached, try to find it in our database.
 772   def handle_incoming(
 773         %{
 774           "type" => "Undo",
 775           "object" => object
 776         } = activity,
 777         options
 778       )
 779       when is_binary(object) do
 780     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 781       activity
 782       |> Map.put("object", data)
 783       |> handle_incoming(options)
 784     else
 785       _e -> :error
 786     end
 787   end
 788
 789   def handle_incoming(_, _), do: :error
 790
 791   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 792   def get_obj_helper(id, options \\ []) do
 793     case Object.normalize(id, true, options) do
 794       %Object{} = object -> {:ok, object}
 795       _ -> nil
 796     end
 797   end
 798
 799   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 800   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 801         ap_id: ap_id
 802       })
 803       when attributed_to == ap_id do
 804     with {:ok, activity} <-
 805            handle_incoming(%{
 806              "type" => "Create",
 807              "to" => data["to"],
 808              "cc" => data["cc"],
 809              "actor" => attributed_to,
 810              "object" => data
 811            }) do
 812       {:ok, Object.normalize(activity)}
 813     else
 814       _ -> get_obj_helper(object_id)
 815     end
 816   end
 817
 818   def get_embedded_obj_helper(object_id, _) do
 819     get_obj_helper(object_id)
 820   end
 821
 822   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 823     with false <- String.starts_with?(in_reply_to, "http"),
 824          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 825       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 826     else
 827       _e -> object
 828     end
 829   end
 830
 831   def set_reply_to_uri(obj), do: obj
 832
 833   # Prepares the object of an outgoing create activity.
 834   def prepare_object(object) do
 835     object
 836     |> set_sensitive
 837     |> add_hashtags
 838     |> add_mention_tags
 839     |> add_emoji_tags
 840     |> add_attributed_to
 841     |> prepare_attachments
 842     |> set_conversation
 843     |> set_reply_to_uri
 844     |> strip_internal_fields
 845     |> strip_internal_tags
 846     |> set_type
 847   end
 848
 849   #  @doc
 850   #  """
 851   #  internal -> Mastodon
 852   #  """
 853
 854   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 855       when activity_type in ["Create", "Listen"] do
 856     object =
 857       object_id
 858       |> Object.normalize()
 859       |> Map.get(:data)
 860       |> prepare_object
 861
 862     data =
 863       data
 864       |> Map.put("object", object)
 865       |> Map.merge(Utils.make_json_ld_header())
 866       |> Map.delete("bcc")
 867
 868     {:ok, data}
 869   end
 870
 871   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 872     object =
 873       object_id
 874       |> Object.normalize()
 875
 876     data =
 877       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 878         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 879       else
 880         data |> maybe_fix_object_url
 881       end
 882
 883     data =
 884       data
 885       |> strip_internal_fields
 886       |> Map.merge(Utils.make_json_ld_header())
 887       |> Map.delete("bcc")
 888
 889     {:ok, data}
 890   end
 891
 892   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 893   # because of course it does.
 894   def prepare_outgoing(%{"type" => "Accept"} = data) do
 895     with follow_activity <- Activity.normalize(data["object"]) do
 896       object = %{
 897         "actor" => follow_activity.actor,
 898         "object" => follow_activity.data["object"],
 899         "id" => follow_activity.data["id"],
 900         "type" => "Follow"
 901       }
 902
 903       data =
 904         data
 905         |> Map.put("object", object)
 906         |> Map.merge(Utils.make_json_ld_header())
 907
 908       {:ok, data}
 909     end
 910   end
 911
 912   def prepare_outgoing(%{"type" => "Reject"} = data) do
 913     with follow_activity <- Activity.normalize(data["object"]) do
 914       object = %{
 915         "actor" => follow_activity.actor,
 916         "object" => follow_activity.data["object"],
 917         "id" => follow_activity.data["id"],
 918         "type" => "Follow"
 919       }
 920
 921       data =
 922         data
 923         |> Map.put("object", object)
 924         |> Map.merge(Utils.make_json_ld_header())
 925
 926       {:ok, data}
 927     end
 928   end
 929
 930   def prepare_outgoing(%{"type" => _type} = data) do
 931     data =
 932       data
 933       |> strip_internal_fields
 934       |> maybe_fix_object_url
 935       |> Map.merge(Utils.make_json_ld_header())
 936
 937     {:ok, data}
 938   end
 939
 940   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
 941     with false <- String.starts_with?(object, "http"),
 942          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
 943          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
 944            relative_object do
 945       Map.put(data, "object", external_url)
 946     else
 947       {:fetch, e} ->
 948         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
 949         data
 950
 951       _ ->
 952         data
 953     end
 954   end
 955
 956   def maybe_fix_object_url(data), do: data
 957
 958   def add_hashtags(object) do
 959     tags =
 960       (object["tag"] || [])
 961       |> Enum.map(fn
 962         # Expand internal representation tags into AS2 tags.
 963         tag when is_binary(tag) ->
 964           %{
 965             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 966             "name" => "##{tag}",
 967             "type" => "Hashtag"
 968           }
 969
 970         # Do not process tags which are already AS2 tag objects.
 971         tag when is_map(tag) ->
 972           tag
 973       end)
 974
 975     Map.put(object, "tag", tags)
 976   end
 977
 978   def add_mention_tags(object) do
 979     mentions =
 980       object
 981       |> Utils.get_notified_from_object()
 982       |> Enum.map(&build_mention_tag/1)
 983
 984     tags = object["tag"] || []
 985
 986     Map.put(object, "tag", tags ++ mentions)
 987   end
 988
 989   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
 990     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
 991   end
 992
 993   def take_emoji_tags(%User{emoji: emoji}) do
 994     emoji
 995     |> Enum.flat_map(&Map.to_list/1)
 996     |> Enum.map(&build_emoji_tag/1)
 997   end
 998
 999   # TODO: we should probably send mtime instead of unix epoch time for updated
1000   def add_emoji_tags(%{"emoji" => emoji} = object) do
1001     tags = object["tag"] || []
1002
1003     out = Enum.map(emoji, &build_emoji_tag/1)
1004
1005     Map.put(object, "tag", tags ++ out)
1006   end
1007
1008   def add_emoji_tags(object), do: object
1009
1010   defp build_emoji_tag({name, url}) do
1011     %{
1012       "icon" => %{"url" => url, "type" => "Image"},
1013       "name" => ":" <> name <> ":",
1014       "type" => "Emoji",
1015       "updated" => "1970-01-01T00:00:00Z",
1016       "id" => url
1017     }
1018   end
1019
1020   def set_conversation(object) do
1021     Map.put(object, "conversation", object["context"])
1022   end
1023
1024   def set_sensitive(object) do
1025     tags = object["tag"] || []
1026     Map.put(object, "sensitive", "nsfw" in tags)
1027   end
1028
1029   def set_type(%{"type" => "Answer"} = object) do
1030     Map.put(object, "type", "Note")
1031   end
1032
1033   def set_type(object), do: object
1034
1035   def add_attributed_to(object) do
1036     attributed_to = object["attributedTo"] || object["actor"]
1037     Map.put(object, "attributedTo", attributed_to)
1038   end
1039
1040   def prepare_attachments(object) do
1041     attachments =
1042       (object["attachment"] || [])
1043       |> Enum.map(fn data ->
1044         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1045         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1046       end)
1047
1048     Map.put(object, "attachment", attachments)
1049   end
1050
1051   defp strip_internal_fields(object) do
1052     object
1053     |> Map.drop(Pleroma.Constants.object_internal_fields())
1054   end
1055
1056   defp strip_internal_tags(%{"tag" => tags} = object) do
1057     tags = Enum.filter(tags, fn x -> is_map(x) end)
1058
1059     Map.put(object, "tag", tags)
1060   end
1061
1062   defp strip_internal_tags(object), do: object
1063
1064   def perform(:user_upgrade, user) do
1065     # we pass a fake user so that the followers collection is stripped away
1066     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1067
1068     from(
1069       a in Activity,
1070       where: ^old_follower_address in a.recipients,
1071       update: [
1072         set: [
1073           recipients:
1074             fragment(
1075               "array_replace(?,?,?)",
1076               a.recipients,
1077               ^old_follower_address,
1078               ^user.follower_address
1079             )
1080         ]
1081       ]
1082     )
1083     |> Repo.update_all([])
1084   end
1085
1086   def upgrade_user_from_ap_id(ap_id) do
1087     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1088          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1089          already_ap <- User.ap_enabled?(user),
1090          {:ok, user} <- upgrade_user(user, data) do
1091       if not already_ap do
1092         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1093       end
1094
1095       {:ok, user}
1096     else
1097       %User{} = user -> {:ok, user}
1098       e -> e
1099     end
1100   end
1101
1102   defp upgrade_user(user, data) do
1103     user
1104     |> User.upgrade_changeset(data, true)
1105     |> User.update_and_set_cache()
1106   end
1107
1108   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1109     Map.put(data, "url", url["href"])
1110   end
1111
1112   def maybe_fix_user_url(data), do: data
1113
1114   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1115 end