git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10
  11   import Ecto.Query
  12
  13   require Logger
  14
  15   @doc """
  16   Modifies an incoming AP object (mastodon format) to our internal format.
  17   """
  18   def fix_object(object) do
  19     object
  20     |> Map.put("actor", object["attributedTo"])
  21     |> fix_attachments
  22     |> fix_context
  23     |> fix_in_reply_to
  24     |> fix_emoji
  25     |> fix_tag
  26   end
  27
  28   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  29       when not is_nil(in_reply_to_id) do
  30     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  31       {:ok, replied_object} ->
  32         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  33
  34         object
  35         |> Map.put("inReplyTo", replied_object.data["id"])
  36         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  37         |> Map.put("inReplyToStatusId", activity.id)
  38         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  39         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  40
  41       e ->
  42         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  43         object
  44     end
  45   end
  46
  47   def fix_in_reply_to(object), do: object
  48
  49   def fix_context(object) do
  50     object
  51     |> Map.put("context", object["conversation"])
  52   end
  53
  54   def fix_attachments(object) do
  55     attachments =
  56       (object["attachment"] || [])
  57       |> Enum.map(fn data ->
  58         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  59         Map.put(data, "url", url)
  60       end)
  61
  62     object
  63     |> Map.put("attachment", attachments)
  64   end
  65
  66   def fix_emoji(object) do
  67     tags = object["tag"] || []
  68     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  69
  70     emoji =
  71       emoji
  72       |> Enum.reduce(%{}, fn data, mapping ->
  73         name = data["name"]
  74
  75         name =
  76           if String.starts_with?(name, ":") do
  77             name |> String.slice(1..-2)
  78           else
  79             name
  80           end
  81
  82         mapping |> Map.put(name, data["icon"]["url"])
  83       end)
  84
  85     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  86     emoji = Map.merge(object["emoji"] || %{}, emoji)
  87
  88     object
  89     |> Map.put("emoji", emoji)
  90   end
  91
  92   def fix_tag(object) do
  93     tags =
  94       (object["tag"] || [])
  95       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  96       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  97
  98     combined = (object["tag"] || []) ++ tags
  99
 100     object
 101     |> Map.put("tag", combined)
 102   end
 103
 104   # TODO: validate those with a Ecto scheme
 105   # - tags
 106   # - emoji
 107   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 108     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 109          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 110       object = fix_object(data["object"])
 111
 112       params = %{
 113         to: data["to"],
 114         object: object,
 115         actor: user,
 116         context: object["conversation"],
 117         local: false,
 118         published: data["published"],
 119         additional:
 120           Map.take(data, [
 121             "cc",
 122             "id"
 123           ])
 124       }
 125
 126       ActivityPub.create(params)
 127     else
 128       %Activity{} = activity -> {:ok, activity}
 129       _e -> :error
 130     end
 131   end
 132
 133   def handle_incoming(
 134         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 135       ) do
 136     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 137          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 138          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 139       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 140
 141       User.follow(follower, followed)
 142       {:ok, activity}
 143     else
 144       _e -> :error
 145     end
 146   end
 147
 148   def handle_incoming(
 149         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 150       ) do
 151     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 152          {:ok, object} <-
 153            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 154          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 155       {:ok, activity}
 156     else
 157       _e -> :error
 158     end
 159   end
 160
 161   def handle_incoming(
 162         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 163       ) do
 164     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 165          {:ok, object} <-
 166            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 167          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 168       {:ok, activity}
 169     else
 170       _e -> :error
 171     end
 172   end
 173
 174   def handle_incoming(
 175         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 176           data
 177       ) do
 178     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 179       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 180
 181       banner = new_user_data[:info]["banner"]
 182
 183       update_data =
 184         new_user_data
 185         |> Map.take([:name, :bio, :avatar])
 186         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 187
 188       actor
 189       |> User.upgrade_changeset(update_data)
 190       |> User.update_and_set_cache()
 191
 192       ActivityPub.update(%{
 193         local: false,
 194         to: data["to"] || [],
 195         cc: data["cc"] || [],
 196         object: object,
 197         actor: actor_id
 198       })
 199     else
 200       e ->
 201         Logger.error(e)
 202         :error
 203     end
 204   end
 205
 206   # TODO: Make secure.
 207   def handle_incoming(
 208         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 209       ) do
 210     object_id =
 211       case object_id do
 212         %{"id" => id} -> id
 213         id -> id
 214       end
 215
 216     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 217          {:ok, object} <-
 218            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 219          {:ok, activity} <- ActivityPub.delete(object, false) do
 220       {:ok, activity}
 221     else
 222       _e -> :error
 223     end
 224   end
 225
 226   def handle_incoming(
 227         %{
 228           "type" => "Undo",
 229           "object" => %{"type" => "Announce", "object" => object_id},
 230           "actor" => actor,
 231           "id" => id
 232         } = data
 233       ) do
 234     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 235          {:ok, object} <-
 236            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 237          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 238       {:ok, activity}
 239     else
 240       e -> :error
 241     end
 242   end
 243
 244   def handle_incoming(
 245         %{
 246           "type" => "Undo",
 247           "object" => %{"type" => "Follow", "object" => followed},
 248           "actor" => follower,
 249           "id" => id
 250         } = data
 251       ) do
 252     with %User{local: true} = followed = User.get_cached_by_ap_id(followed),
 253          %User{} = follower = User.get_or_fetch_by_ap_id(follower),
 254          {:ok, activity} <- ActivityPub.unfollow(follower, followed, false) do
 255       User.unfollow(follower, followed)
 256       {:ok, activity}
 257     else
 258       e -> :error
 259     end
 260   end
 261
 262   def handle_incoming(%{"type" => "Undo", "object" => object_id} = data) do
 263     object = Object.get_by_ap_id(object_id).data
 264     data = Map.put(data, "object", object)
 265
 266     handle_incoming(data)
 267   end
 268
 269   def handle_incoming(
 270         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 271       ) do
 272     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 273          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 274          {:ok, activity} <- ActivityPub.block(blocker, blocked, false) do
 275       User.unfollow(blocker, blocked)
 276       User.block(blocker, blocked.ap_id)
 277       {:ok, activity}
 278     else
 279       e -> :error
 280     end
 281   end
 282
 283   # TODO
 284   # Accept
 285   # Undo for non-Announce
 286
 287   def handle_incoming(_), do: :error
 288
 289   def get_obj_helper(id) do
 290     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 291   end
 292
 293   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 294     with false <- String.starts_with?(inReplyTo, "http"),
 295          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 296       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 297     else
 298       _e -> object
 299     end
 300   end
 301
 302   def set_reply_to_uri(obj), do: obj
 303
 304   # Prepares the object of an outgoing create activity.
 305   def prepare_object(object) do
 306     object
 307     |> set_sensitive
 308     |> add_hashtags
 309     |> add_mention_tags
 310     |> add_emoji_tags
 311     |> add_attributed_to
 312     |> prepare_attachments
 313     |> set_conversation
 314     |> set_reply_to_uri
 315   end
 316
 317   #  @doc
 318   #  """
 319   #  internal -> Mastodon
 320   #  """
 321
 322   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 323     object =
 324       object
 325       |> prepare_object
 326
 327     data =
 328       data
 329       |> Map.put("object", object)
 330       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 331
 332     {:ok, data}
 333   end
 334
 335   def prepare_outgoing(%{"type" => _type} = data) do
 336     data =
 337       data
 338       |> maybe_fix_object_url
 339       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 340
 341     {:ok, data}
 342   end
 343
 344   def maybe_fix_object_url(data) do
 345     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 346       case ActivityPub.fetch_object_from_id(data["object"]) do
 347         {:ok, relative_object} ->
 348           if relative_object.data["external_url"] do
 349             _data =
 350               data
 351               |> Map.put("object", relative_object.data["external_url"])
 352           else
 353             data
 354           end
 355
 356         e ->
 357           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 358           data
 359       end
 360     else
 361       data
 362     end
 363   end
 364
 365   def add_hashtags(object) do
 366     tags =
 367       (object["tag"] || [])
 368       |> Enum.map(fn tag ->
 369         %{
 370           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 371           "name" => "##{tag}",
 372           "type" => "Hashtag"
 373         }
 374       end)
 375
 376     object
 377     |> Map.put("tag", tags)
 378   end
 379
 380   def add_mention_tags(object) do
 381     recipients = object["to"] ++ (object["cc"] || [])
 382
 383     mentions =
 384       recipients
 385       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 386       |> Enum.filter(& &1)
 387       |> Enum.map(fn user ->
 388         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 389       end)
 390
 391     tags = object["tag"] || []
 392
 393     object
 394     |> Map.put("tag", tags ++ mentions)
 395   end
 396
 397   # TODO: we should probably send mtime instead of unix epoch time for updated
 398   def add_emoji_tags(object) do
 399     tags = object["tag"] || []
 400     emoji = object["emoji"] || []
 401
 402     out =
 403       emoji
 404       |> Enum.map(fn {name, url} ->
 405         %{
 406           "icon" => %{"url" => url, "type" => "Image"},
 407           "name" => ":" <> name <> ":",
 408           "type" => "Emoji",
 409           "updated" => "1970-01-01T00:00:00Z",
 410           "id" => url
 411         }
 412       end)
 413
 414     object
 415     |> Map.put("tag", tags ++ out)
 416   end
 417
 418   def set_conversation(object) do
 419     Map.put(object, "conversation", object["context"])
 420   end
 421
 422   def set_sensitive(object) do
 423     tags = object["tag"] || []
 424     Map.put(object, "sensitive", "nsfw" in tags)
 425   end
 426
 427   def add_attributed_to(object) do
 428     attributedTo = object["attributedTo"] || object["actor"]
 429
 430     object
 431     |> Map.put("attributedTo", attributedTo)
 432   end
 433
 434   def prepare_attachments(object) do
 435     attachments =
 436       (object["attachment"] || [])
 437       |> Enum.map(fn data ->
 438         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 439         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 440       end)
 441
 442     object
 443     |> Map.put("attachment", attachments)
 444   end
 445
 446   defp user_upgrade_task(user) do
 447     old_follower_address = User.ap_followers(user)
 448
 449     q =
 450       from(
 451         u in User,
 452         where: ^old_follower_address in u.following,
 453         update: [
 454           set: [
 455             following:
 456               fragment(
 457                 "array_replace(?,?,?)",
 458                 u.following,
 459                 ^old_follower_address,
 460                 ^user.follower_address
 461               )
 462           ]
 463         ]
 464       )
 465
 466     Repo.update_all(q, [])
 467
 468     maybe_retire_websub(user.ap_id)
 469
 470     # Only do this for recent activties, don't go through the whole db.
 471     # Only look at the last 1000 activities.
 472     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 473
 474     q =
 475       from(
 476         a in Activity,
 477         where: ^old_follower_address in a.recipients,
 478         where: a.id > ^since,
 479         update: [
 480           set: [
 481             recipients:
 482               fragment(
 483                 "array_replace(?,?,?)",
 484                 a.recipients,
 485                 ^old_follower_address,
 486                 ^user.follower_address
 487               )
 488           ]
 489         ]
 490       )
 491
 492     Repo.update_all(q, [])
 493   end
 494
 495   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 496     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 497          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 498       data =
 499         data
 500         |> Map.put(:info, Map.merge(user.info, data[:info]))
 501
 502       already_ap = User.ap_enabled?(user)
 503
 504       {:ok, user} =
 505         User.upgrade_changeset(user, data)
 506         |> Repo.update()
 507
 508       if !already_ap do
 509         # This could potentially take a long time, do it in the background
 510         if async do
 511           Task.start(fn ->
 512             user_upgrade_task(user)
 513           end)
 514         else
 515           user_upgrade_task(user)
 516         end
 517       end
 518
 519       {:ok, user}
 520     else
 521       e -> e
 522     end
 523   end
 524
 525   def maybe_retire_websub(ap_id) do
 526     # some sanity checks
 527     if is_binary(ap_id) && String.length(ap_id) > 8 do
 528       q =
 529         from(
 530           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 531           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 532         )
 533
 534       Repo.delete_all(q)
 535     end
 536   end
 537 end