git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.Object
  12   alias Pleroma.Object.Containment
  13   alias Pleroma.Repo
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16   alias Pleroma.Web.ActivityPub.ObjectValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  18   alias Pleroma.Web.ActivityPub.Pipeline
  19   alias Pleroma.Web.ActivityPub.Utils
  20   alias Pleroma.Web.ActivityPub.Visibility
  21   alias Pleroma.Web.Federator
  22   alias Pleroma.Workers.TransmogrifierWorker
  23
  24   import Ecto.Query
  25
  26   require Logger
  27   require Pleroma.Constants
  28
  29   @doc """
  30   Modifies an incoming AP object (mastodon format) to our internal format.
  31   """
  32   def fix_object(object, options \\ []) do
  33     object
  34     |> strip_internal_fields
  35     |> fix_actor
  36     |> fix_url
  37     |> fix_attachments
  38     |> fix_context
  39     |> fix_in_reply_to(options)
  40     |> fix_emoji
  41     |> fix_tag
  42     |> fix_content_map
  43     |> fix_addressing
  44     |> fix_summary
  45     |> fix_type(options)
  46   end
  47
  48   def fix_summary(%{"summary" => nil} = object) do
  49     Map.put(object, "summary", "")
  50   end
  51
  52   def fix_summary(%{"summary" => _} = object) do
  53     # summary is present, nothing to do
  54     object
  55   end
  56
  57   def fix_summary(object), do: Map.put(object, "summary", "")
  58
  59   def fix_addressing_list(map, field) do
  60     cond do
  61       is_binary(map[field]) ->
  62         Map.put(map, field, [map[field]])
  63
  64       is_nil(map[field]) ->
  65         Map.put(map, field, [])
  66
  67       true ->
  68         map
  69     end
  70   end
  71
  72   def fix_explicit_addressing(
  73         %{"to" => to, "cc" => cc} = object,
  74         explicit_mentions,
  75         follower_collection
  76       ) do
  77     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  78
  79     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  80
  81     final_cc =
  82       (cc ++ explicit_cc)
  83       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  84       |> Enum.uniq()
  85
  86     object
  87     |> Map.put("to", explicit_to)
  88     |> Map.put("cc", final_cc)
  89   end
  90
  91   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  92
  93   # if directMessage flag is set to true, leave the addressing alone
  94   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  95
  96   def fix_explicit_addressing(object) do
  97     explicit_mentions = Utils.determine_explicit_mentions(object)
  98
  99     %User{follower_address: follower_collection} =
 100       object
 101       |> Containment.get_actor()
 102       |> User.get_cached_by_ap_id()
 103
 104     explicit_mentions =
 105       explicit_mentions ++
 106         [
 107           Pleroma.Constants.as_public(),
 108           follower_collection
 109         ]
 110
 111     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 112   end
 113
 114   # if as:Public is addressed, then make sure the followers collection is also addressed
 115   # so that the activities will be delivered to local users.
 116   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 117     recipients = to ++ cc
 118
 119     if followers_collection not in recipients do
 120       cond do
 121         Pleroma.Constants.as_public() in cc ->
 122           to = to ++ [followers_collection]
 123           Map.put(object, "to", to)
 124
 125         Pleroma.Constants.as_public() in to ->
 126           cc = cc ++ [followers_collection]
 127           Map.put(object, "cc", cc)
 128
 129         true ->
 130           object
 131       end
 132     else
 133       object
 134     end
 135   end
 136
 137   def fix_implicit_addressing(object, _), do: object
 138
 139   def fix_addressing(object) do
 140     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 141     followers_collection = User.ap_followers(user)
 142
 143     object
 144     |> fix_addressing_list("to")
 145     |> fix_addressing_list("cc")
 146     |> fix_addressing_list("bto")
 147     |> fix_addressing_list("bcc")
 148     |> fix_explicit_addressing()
 149     |> fix_implicit_addressing(followers_collection)
 150   end
 151
 152   def fix_actor(%{"attributedTo" => actor} = object) do
 153     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 154   end
 155
 156   def fix_in_reply_to(object, options \\ [])
 157
 158   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 159       when not is_nil(in_reply_to) do
 160     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 161     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 162     depth = (options[:depth] || 0) + 1
 163
 164     if Federator.allowed_thread_distance?(depth) do
 165       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 166            %Activity{} <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 167         object
 168         |> Map.put("inReplyTo", replied_object.data["id"])
 169         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 170         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 171         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 172       else
 173         e ->
 174           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 175           object
 176       end
 177     else
 178       object
 179     end
 180   end
 181
 182   def fix_in_reply_to(object, _options), do: object
 183
 184   defp prepare_in_reply_to(in_reply_to) do
 185     cond do
 186       is_bitstring(in_reply_to) ->
 187         in_reply_to
 188
 189       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 190         in_reply_to["id"]
 191
 192       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 193         Enum.at(in_reply_to, 0)
 194
 195       true ->
 196         ""
 197     end
 198   end
 199
 200   def fix_context(object) do
 201     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 202
 203     object
 204     |> Map.put("context", context)
 205     |> Map.put("conversation", context)
 206   end
 207
 208   defp add_if_present(map, _key, nil), do: map
 209
 210   defp add_if_present(map, key, value) do
 211     Map.put(map, key, value)
 212   end
 213
 214   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 215     attachments =
 216       Enum.map(attachment, fn data ->
 217         url =
 218           cond do
 219             is_list(data["url"]) -> List.first(data["url"])
 220             is_map(data["url"]) -> data["url"]
 221             true -> nil
 222           end
 223
 224         media_type =
 225           cond do
 226             is_map(url) && is_binary(url["mediaType"]) -> url["mediaType"]
 227             is_binary(data["mediaType"]) -> data["mediaType"]
 228             is_binary(data["mimeType"]) -> data["mimeType"]
 229             true -> nil
 230           end
 231
 232         href =
 233           cond do
 234             is_map(url) && is_binary(url["href"]) -> url["href"]
 235             is_binary(data["url"]) -> data["url"]
 236             is_binary(data["href"]) -> data["href"]
 237           end
 238
 239         attachment_url =
 240           %{"href" => href}
 241           |> add_if_present("mediaType", media_type)
 242           |> add_if_present("type", Map.get(url || %{}, "type"))
 243
 244         %{"url" => [attachment_url]}
 245         |> add_if_present("mediaType", media_type)
 246         |> add_if_present("type", data["type"])
 247         |> add_if_present("name", data["name"])
 248       end)
 249
 250     Map.put(object, "attachment", attachments)
 251   end
 252
 253   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 254     object
 255     |> Map.put("attachment", [attachment])
 256     |> fix_attachments()
 257   end
 258
 259   def fix_attachments(object), do: object
 260
 261   def fix_url(%{"url" => url} = object) when is_map(url) do
 262     Map.put(object, "url", url["href"])
 263   end
 264
 265   def fix_url(%{"type" => object_type, "url" => url} = object)
 266       when object_type in ["Video", "Audio"] and is_list(url) do
 267     first_element = Enum.at(url, 0)
 268
 269     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 270
 271     object
 272     |> Map.put("attachment", [first_element])
 273     |> Map.put("url", link_element["href"])
 274   end
 275
 276   def fix_url(%{"type" => object_type, "url" => url} = object)
 277       when object_type != "Video" and is_list(url) do
 278     first_element = Enum.at(url, 0)
 279
 280     url_string =
 281       cond do
 282         is_bitstring(first_element) -> first_element
 283         is_map(first_element) -> first_element["href"] || ""
 284         true -> ""
 285       end
 286
 287     Map.put(object, "url", url_string)
 288   end
 289
 290   def fix_url(object), do: object
 291
 292   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 293     emoji =
 294       tags
 295       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 296       |> Enum.reduce(%{}, fn data, mapping ->
 297         name = String.trim(data["name"], ":")
 298
 299         Map.put(mapping, name, data["icon"]["url"])
 300       end)
 301
 302     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 303     emoji = Map.merge(object["emoji"] || %{}, emoji)
 304
 305     Map.put(object, "emoji", emoji)
 306   end
 307
 308   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 309     name = String.trim(tag["name"], ":")
 310     emoji = %{name => tag["icon"]["url"]}
 311
 312     Map.put(object, "emoji", emoji)
 313   end
 314
 315   def fix_emoji(object), do: object
 316
 317   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 318     tags =
 319       tag
 320       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 321       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 322
 323     Map.put(object, "tag", tag ++ tags)
 324   end
 325
 326   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 327     combined = [tag, String.slice(hashtag, 1..-1)]
 328
 329     Map.put(object, "tag", combined)
 330   end
 331
 332   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 333
 334   def fix_tag(object), do: object
 335
 336   # content map usually only has one language so this will do for now.
 337   def fix_content_map(%{"contentMap" => content_map} = object) do
 338     content_groups = Map.to_list(content_map)
 339     {_, content} = Enum.at(content_groups, 0)
 340
 341     Map.put(object, "content", content)
 342   end
 343
 344   def fix_content_map(object), do: object
 345
 346   def fix_type(object, options \\ [])
 347
 348   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 349       when is_binary(reply_id) do
 350     with true <- Federator.allowed_thread_distance?(options[:depth]),
 351          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 352       Map.put(object, "type", "Answer")
 353     else
 354       _ -> object
 355     end
 356   end
 357
 358   def fix_type(object, _), do: object
 359
 360   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 361     with true <- id =~ "follows",
 362          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 363          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 364       {:ok, activity}
 365     else
 366       _ -> {:error, nil}
 367     end
 368   end
 369
 370   defp mastodon_follow_hack(_, _), do: {:error, nil}
 371
 372   defp get_follow_activity(follow_object, followed) do
 373     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 374          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 375       {:ok, activity}
 376     else
 377       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 378       {:activity, nil} ->
 379         mastodon_follow_hack(follow_object, followed)
 380
 381       _ ->
 382         {:error, nil}
 383     end
 384   end
 385
 386   # Reduce the object list to find the reported user.
 387   defp get_reported(objects) do
 388     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 389       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 390         {:halt, user}
 391       else
 392         _ -> {:cont, nil}
 393       end
 394     end)
 395   end
 396
 397   def handle_incoming(data, options \\ [])
 398
 399   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 400   # with nil ID.
 401   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 402     with context <- data["context"] || Utils.generate_context_id(),
 403          content <- data["content"] || "",
 404          %User{} = actor <- User.get_cached_by_ap_id(actor),
 405          # Reduce the object list to find the reported user.
 406          %User{} = account <- get_reported(objects),
 407          # Remove the reported user from the object list.
 408          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 409       %{
 410         actor: actor,
 411         context: context,
 412         account: account,
 413         statuses: statuses,
 414         content: content,
 415         additional: %{"cc" => [account.ap_id]}
 416       }
 417       |> ActivityPub.flag()
 418     end
 419   end
 420
 421   # disallow objects with bogus IDs
 422   def handle_incoming(%{"id" => nil}, _options), do: :error
 423   def handle_incoming(%{"id" => ""}, _options), do: :error
 424   # length of https:// = 8, should validate better, but good enough for now.
 425   def handle_incoming(%{"id" => id}, _options) when is_binary(id) and byte_size(id) < 8,
 426     do: :error
 427
 428   # TODO: validate those with a Ecto scheme
 429   # - tags
 430   # - emoji
 431   def handle_incoming(
 432         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 433         options
 434       )
 435       when objtype in ["Article", "Event", "Note", "Video", "Page", "Question", "Answer", "Audio"] do
 436     actor = Containment.get_actor(data)
 437
 438     data =
 439       Map.put(data, "actor", actor)
 440       |> fix_addressing
 441
 442     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 443          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 444       object = fix_object(object, options)
 445
 446       params = %{
 447         to: data["to"],
 448         object: object,
 449         actor: user,
 450         context: object["conversation"],
 451         local: false,
 452         published: data["published"],
 453         additional:
 454           Map.take(data, [
 455             "cc",
 456             "directMessage",
 457             "id"
 458           ])
 459       }
 460
 461       with {:ok, created_activity} <- ActivityPub.create(params) do
 462         reply_depth = (options[:depth] || 0) + 1
 463
 464         if Federator.allowed_thread_distance?(reply_depth) do
 465           for reply_id <- replies(object) do
 466             Pleroma.Workers.RemoteFetcherWorker.enqueue("fetch_remote", %{
 467               "id" => reply_id,
 468               "depth" => reply_depth
 469             })
 470           end
 471         end
 472
 473         {:ok, created_activity}
 474       end
 475     else
 476       %Activity{} = activity -> {:ok, activity}
 477       _e -> :error
 478     end
 479   end
 480
 481   def handle_incoming(
 482         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 483         options
 484       ) do
 485     actor = Containment.get_actor(data)
 486
 487     data =
 488       Map.put(data, "actor", actor)
 489       |> fix_addressing
 490
 491     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 492       reply_depth = (options[:depth] || 0) + 1
 493       options = Keyword.put(options, :depth, reply_depth)
 494       object = fix_object(object, options)
 495
 496       params = %{
 497         to: data["to"],
 498         object: object,
 499         actor: user,
 500         context: nil,
 501         local: false,
 502         published: data["published"],
 503         additional: Map.take(data, ["cc", "id"])
 504       }
 505
 506       ActivityPub.listen(params)
 507     else
 508       _e -> :error
 509     end
 510   end
 511
 512   def handle_incoming(
 513         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 514         _options
 515       ) do
 516     with %User{local: true} = followed <-
 517            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 518          {:ok, %User{} = follower} <-
 519            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 520          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 521       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 522            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 523            {_, false} <- {:user_locked, User.locked?(followed)},
 524            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 525            {_, {:ok, _}} <-
 526              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 527            {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 528         ActivityPub.accept(%{
 529           to: [follower.ap_id],
 530           actor: followed,
 531           object: data,
 532           local: true
 533         })
 534       else
 535         {:user_blocked, true} ->
 536           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 537           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 538
 539           ActivityPub.reject(%{
 540             to: [follower.ap_id],
 541             actor: followed,
 542             object: data,
 543             local: true
 544           })
 545
 546         {:follow, {:error, _}} ->
 547           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 548           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 549
 550           ActivityPub.reject(%{
 551             to: [follower.ap_id],
 552             actor: followed,
 553             object: data,
 554             local: true
 555           })
 556
 557         {:user_locked, true} ->
 558           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "pending")
 559           :noop
 560       end
 561
 562       {:ok, activity}
 563     else
 564       _e ->
 565         :error
 566     end
 567   end
 568
 569   def handle_incoming(
 570         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 571         _options
 572       ) do
 573     with actor <- Containment.get_actor(data),
 574          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 575          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 576          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 577          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 578          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 579       ActivityPub.accept(%{
 580         to: follow_activity.data["to"],
 581         type: "Accept",
 582         actor: followed,
 583         object: follow_activity.data["id"],
 584         local: false,
 585         activity_id: id
 586       })
 587     else
 588       _e -> :error
 589     end
 590   end
 591
 592   def handle_incoming(
 593         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 594         _options
 595       ) do
 596     with actor <- Containment.get_actor(data),
 597          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 598          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 599          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 600          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 601          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "reject"),
 602          {:ok, activity} <-
 603            ActivityPub.reject(%{
 604              to: follow_activity.data["to"],
 605              type: "Reject",
 606              actor: followed,
 607              object: follow_activity.data["id"],
 608              local: false,
 609              activity_id: id
 610            }) do
 611       {:ok, activity}
 612     else
 613       _e -> :error
 614     end
 615   end
 616
 617   @misskey_reactions %{
 618     "like" => "👍",
 619     "love" => "❤️",
 620     "laugh" => "😆",
 621     "hmm" => "🤔",
 622     "surprise" => "😮",
 623     "congrats" => "🎉",
 624     "angry" => "💢",
 625     "confused" => "😥",
 626     "rip" => "😇",
 627     "pudding" => "🍮",
 628     "star" => "⭐"
 629   }
 630
 631   @doc "Rewrite misskey likes into EmojiReacts"
 632   def handle_incoming(
 633         %{
 634           "type" => "Like",
 635           "_misskey_reaction" => reaction
 636         } = data,
 637         options
 638       ) do
 639     data
 640     |> Map.put("type", "EmojiReact")
 641     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 642     |> handle_incoming(options)
 643   end
 644
 645   def handle_incoming(%{"type" => "Like"} = data, _options) do
 646     with {_, {:ok, cast_data_sym}} <-
 647            {:casting_data,
 648             data |> LikeValidator.cast_data() |> Ecto.Changeset.apply_action(:insert)},
 649          cast_data = ObjectValidator.stringify_keys(Map.from_struct(cast_data_sym)),
 650          :ok <- ObjectValidator.fetch_actor_and_object(cast_data),
 651          {_, {:ok, cast_data}} <- {:ensure_context_presence, ensure_context_presence(cast_data)},
 652          {_, {:ok, cast_data}} <-
 653            {:ensure_recipients_presence, ensure_recipients_presence(cast_data)},
 654          {_, {:ok, activity, _meta}} <-
 655            {:common_pipeline, Pipeline.common_pipeline(cast_data, local: false)} do
 656       {:ok, activity}
 657     else
 658       e -> {:error, e}
 659     end
 660   end
 661
 662   def handle_incoming(
 663         %{
 664           "type" => "EmojiReact",
 665           "object" => object_id,
 666           "actor" => _actor,
 667           "id" => id,
 668           "content" => emoji
 669         } = data,
 670         _options
 671       ) do
 672     with actor <- Containment.get_actor(data),
 673          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 674          {:ok, object} <- get_obj_helper(object_id),
 675          {:ok, activity, _object} <-
 676            ActivityPub.react_with_emoji(actor, object, emoji, activity_id: id, local: false) do
 677       {:ok, activity}
 678     else
 679       _e -> :error
 680     end
 681   end
 682
 683   def handle_incoming(
 684         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 685         _options
 686       ) do
 687     with actor <- Containment.get_actor(data),
 688          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 689          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 690          public <- Visibility.is_public?(data),
 691          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 692       {:ok, activity}
 693     else
 694       _e -> :error
 695     end
 696   end
 697
 698   def handle_incoming(
 699         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 700           data,
 701         _options
 702       )
 703       when object_type in [
 704              "Person",
 705              "Application",
 706              "Service",
 707              "Organization"
 708            ] do
 709     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 710       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 711
 712       actor
 713       |> User.upgrade_changeset(new_user_data, true)
 714       |> User.update_and_set_cache()
 715
 716       ActivityPub.update(%{
 717         local: false,
 718         to: data["to"] || [],
 719         cc: data["cc"] || [],
 720         object: object,
 721         actor: actor_id,
 722         activity_id: data["id"]
 723       })
 724     else
 725       e ->
 726         Logger.error(e)
 727         :error
 728     end
 729   end
 730
 731   # TODO: We presently assume that any actor on the same origin domain as the object being
 732   # deleted has the rights to delete that object.  A better way to validate whether or not
 733   # the object should be deleted is to refetch the object URI, which should return either
 734   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 735   # place.
 736   def handle_incoming(
 737         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 738         _options
 739       ) do
 740     object_id = Utils.get_ap_id(object_id)
 741
 742     with actor <- Containment.get_actor(data),
 743          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 744          {:ok, object} <- get_obj_helper(object_id),
 745          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 746          {:ok, activity} <-
 747            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 748       {:ok, activity}
 749     else
 750       nil ->
 751         case User.get_cached_by_ap_id(object_id) do
 752           %User{ap_id: ^actor} = user ->
 753             User.delete(user)
 754
 755           nil ->
 756             :error
 757         end
 758
 759       _e ->
 760         :error
 761     end
 762   end
 763
 764   def handle_incoming(
 765         %{
 766           "type" => "Undo",
 767           "object" => %{"type" => "Announce", "object" => object_id},
 768           "actor" => _actor,
 769           "id" => id
 770         } = data,
 771         _options
 772       ) do
 773     with actor <- Containment.get_actor(data),
 774          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 775          {:ok, object} <- get_obj_helper(object_id),
 776          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 777       {:ok, activity}
 778     else
 779       _e -> :error
 780     end
 781   end
 782
 783   def handle_incoming(
 784         %{
 785           "type" => "Undo",
 786           "object" => %{"type" => "Follow", "object" => followed},
 787           "actor" => follower,
 788           "id" => id
 789         } = _data,
 790         _options
 791       ) do
 792     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 793          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 794          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 795       User.unfollow(follower, followed)
 796       {:ok, activity}
 797     else
 798       _e -> :error
 799     end
 800   end
 801
 802   def handle_incoming(
 803         %{
 804           "type" => "Undo",
 805           "object" => %{"type" => "EmojiReact", "id" => reaction_activity_id},
 806           "actor" => _actor,
 807           "id" => id
 808         } = data,
 809         _options
 810       ) do
 811     with actor <- Containment.get_actor(data),
 812          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 813          {:ok, activity, _} <-
 814            ActivityPub.unreact_with_emoji(actor, reaction_activity_id,
 815              activity_id: id,
 816              local: false
 817            ) do
 818       {:ok, activity}
 819     else
 820       _e -> :error
 821     end
 822   end
 823
 824   def handle_incoming(
 825         %{
 826           "type" => "Undo",
 827           "object" => %{"type" => "Block", "object" => blocked},
 828           "actor" => blocker,
 829           "id" => id
 830         } = _data,
 831         _options
 832       ) do
 833     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 834          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 835          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 836       User.unblock(blocker, blocked)
 837       {:ok, activity}
 838     else
 839       _e -> :error
 840     end
 841   end
 842
 843   def handle_incoming(
 844         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 845         _options
 846       ) do
 847     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 848          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 849          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 850       User.unfollow(blocker, blocked)
 851       User.block(blocker, blocked)
 852       {:ok, activity}
 853     else
 854       _e -> :error
 855     end
 856   end
 857
 858   def handle_incoming(
 859         %{
 860           "type" => "Undo",
 861           "object" => %{"type" => "Like", "object" => object_id},
 862           "actor" => _actor,
 863           "id" => id
 864         } = data,
 865         _options
 866       ) do
 867     with actor <- Containment.get_actor(data),
 868          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 869          {:ok, object} <- get_obj_helper(object_id),
 870          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 871       {:ok, activity}
 872     else
 873       _e -> :error
 874     end
 875   end
 876
 877   # For Undos that don't have the complete object attached, try to find it in our database.
 878   def handle_incoming(
 879         %{
 880           "type" => "Undo",
 881           "object" => object
 882         } = activity,
 883         options
 884       )
 885       when is_binary(object) do
 886     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 887       activity
 888       |> Map.put("object", data)
 889       |> handle_incoming(options)
 890     else
 891       _e -> :error
 892     end
 893   end
 894
 895   def handle_incoming(
 896         %{
 897           "type" => "Move",
 898           "actor" => origin_actor,
 899           "object" => origin_actor,
 900           "target" => target_actor
 901         },
 902         _options
 903       ) do
 904     with %User{} = origin_user <- User.get_cached_by_ap_id(origin_actor),
 905          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_actor),
 906          true <- origin_actor in target_user.also_known_as do
 907       ActivityPub.move(origin_user, target_user, false)
 908     else
 909       _e -> :error
 910     end
 911   end
 912
 913   def handle_incoming(_, _), do: :error
 914
 915   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 916   def get_obj_helper(id, options \\ []) do
 917     case Object.normalize(id, true, options) do
 918       %Object{} = object -> {:ok, object}
 919       _ -> nil
 920     end
 921   end
 922
 923   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 924   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 925         ap_id: ap_id
 926       })
 927       when attributed_to == ap_id do
 928     with {:ok, activity} <-
 929            handle_incoming(%{
 930              "type" => "Create",
 931              "to" => data["to"],
 932              "cc" => data["cc"],
 933              "actor" => attributed_to,
 934              "object" => data
 935            }) do
 936       {:ok, Object.normalize(activity)}
 937     else
 938       _ -> get_obj_helper(object_id)
 939     end
 940   end
 941
 942   def get_embedded_obj_helper(object_id, _) do
 943     get_obj_helper(object_id)
 944   end
 945
 946   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 947     with false <- String.starts_with?(in_reply_to, "http"),
 948          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 949       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 950     else
 951       _e -> object
 952     end
 953   end
 954
 955   def set_reply_to_uri(obj), do: obj
 956
 957   @doc """
 958   Serialized Mastodon-compatible `replies` collection containing _self-replies_.
 959   Based on Mastodon's ActivityPub::NoteSerializer#replies.
 960   """
 961   def set_replies(obj_data) do
 962     replies_uris =
 963       with limit when limit > 0 <-
 964              Pleroma.Config.get([:activitypub, :note_replies_output_limit], 0),
 965            %Object{} = object <- Object.get_cached_by_ap_id(obj_data["id"]) do
 966         object
 967         |> Object.self_replies()
 968         |> select([o], fragment("?->>'id'", o.data))
 969         |> limit(^limit)
 970         |> Repo.all()
 971       else
 972         _ -> []
 973       end
 974
 975     set_replies(obj_data, replies_uris)
 976   end
 977
 978   defp set_replies(obj, []) do
 979     obj
 980   end
 981
 982   defp set_replies(obj, replies_uris) do
 983     replies_collection = %{
 984       "type" => "Collection",
 985       "items" => replies_uris
 986     }
 987
 988     Map.merge(obj, %{"replies" => replies_collection})
 989   end
 990
 991   def replies(%{"replies" => %{"first" => %{"items" => items}}}) when not is_nil(items) do
 992     items
 993   end
 994
 995   def replies(%{"replies" => %{"items" => items}}) when not is_nil(items) do
 996     items
 997   end
 998
 999   def replies(_), do: []
1000
1001   # Prepares the object of an outgoing create activity.
1002   def prepare_object(object) do
1003     object
1004     |> set_sensitive
1005     |> add_hashtags
1006     |> add_mention_tags
1007     |> add_emoji_tags
1008     |> add_attributed_to
1009     |> prepare_attachments
1010     |> set_conversation
1011     |> set_reply_to_uri
1012     |> set_replies
1013     |> strip_internal_fields
1014     |> strip_internal_tags
1015     |> set_type
1016   end
1017
1018   #  @doc
1019   #  """
1020   #  internal -> Mastodon
1021   #  """
1022
1023   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
1024       when activity_type in ["Create", "Listen"] do
1025     object =
1026       object_id
1027       |> Object.normalize()
1028       |> Map.get(:data)
1029       |> prepare_object
1030
1031     data =
1032       data
1033       |> Map.put("object", object)
1034       |> Map.merge(Utils.make_json_ld_header())
1035       |> Map.delete("bcc")
1036
1037     {:ok, data}
1038   end
1039
1040   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
1041     object =
1042       object_id
1043       |> Object.normalize()
1044
1045     data =
1046       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
1047         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
1048       else
1049         data |> maybe_fix_object_url
1050       end
1051
1052     data =
1053       data
1054       |> strip_internal_fields
1055       |> Map.merge(Utils.make_json_ld_header())
1056       |> Map.delete("bcc")
1057
1058     {:ok, data}
1059   end
1060
1061   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
1062   # because of course it does.
1063   def prepare_outgoing(%{"type" => "Accept"} = data) do
1064     with follow_activity <- Activity.normalize(data["object"]) do
1065       object = %{
1066         "actor" => follow_activity.actor,
1067         "object" => follow_activity.data["object"],
1068         "id" => follow_activity.data["id"],
1069         "type" => "Follow"
1070       }
1071
1072       data =
1073         data
1074         |> Map.put("object", object)
1075         |> Map.merge(Utils.make_json_ld_header())
1076
1077       {:ok, data}
1078     end
1079   end
1080
1081   def prepare_outgoing(%{"type" => "Reject"} = data) do
1082     with follow_activity <- Activity.normalize(data["object"]) do
1083       object = %{
1084         "actor" => follow_activity.actor,
1085         "object" => follow_activity.data["object"],
1086         "id" => follow_activity.data["id"],
1087         "type" => "Follow"
1088       }
1089
1090       data =
1091         data
1092         |> Map.put("object", object)
1093         |> Map.merge(Utils.make_json_ld_header())
1094
1095       {:ok, data}
1096     end
1097   end
1098
1099   def prepare_outgoing(%{"type" => _type} = data) do
1100     data =
1101       data
1102       |> strip_internal_fields
1103       |> maybe_fix_object_url
1104       |> Map.merge(Utils.make_json_ld_header())
1105
1106     {:ok, data}
1107   end
1108
1109   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
1110     with false <- String.starts_with?(object, "http"),
1111          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
1112          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
1113            relative_object do
1114       Map.put(data, "object", external_url)
1115     else
1116       {:fetch, e} ->
1117         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
1118         data
1119
1120       _ ->
1121         data
1122     end
1123   end
1124
1125   def maybe_fix_object_url(data), do: data
1126
1127   def add_hashtags(object) do
1128     tags =
1129       (object["tag"] || [])
1130       |> Enum.map(fn
1131         # Expand internal representation tags into AS2 tags.
1132         tag when is_binary(tag) ->
1133           %{
1134             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
1135             "name" => "##{tag}",
1136             "type" => "Hashtag"
1137           }
1138
1139         # Do not process tags which are already AS2 tag objects.
1140         tag when is_map(tag) ->
1141           tag
1142       end)
1143
1144     Map.put(object, "tag", tags)
1145   end
1146
1147   def add_mention_tags(object) do
1148     {enabled_receivers, disabled_receivers} = Utils.get_notified_from_object(object)
1149     potential_receivers = enabled_receivers ++ disabled_receivers
1150     mentions = Enum.map(potential_receivers, &build_mention_tag/1)
1151
1152     tags = object["tag"] || []
1153     Map.put(object, "tag", tags ++ mentions)
1154   end
1155
1156   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1157     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1158   end
1159
1160   def take_emoji_tags(%User{emoji: emoji}) do
1161     emoji
1162     |> Enum.flat_map(&Map.to_list/1)
1163     |> Enum.map(&build_emoji_tag/1)
1164   end
1165
1166   # TODO: we should probably send mtime instead of unix epoch time for updated
1167   def add_emoji_tags(%{"emoji" => emoji} = object) do
1168     tags = object["tag"] || []
1169
1170     out = Enum.map(emoji, &build_emoji_tag/1)
1171
1172     Map.put(object, "tag", tags ++ out)
1173   end
1174
1175   def add_emoji_tags(object), do: object
1176
1177   defp build_emoji_tag({name, url}) do
1178     %{
1179       "icon" => %{"url" => url, "type" => "Image"},
1180       "name" => ":" <> name <> ":",
1181       "type" => "Emoji",
1182       "updated" => "1970-01-01T00:00:00Z",
1183       "id" => url
1184     }
1185   end
1186
1187   def set_conversation(object) do
1188     Map.put(object, "conversation", object["context"])
1189   end
1190
1191   def set_sensitive(object) do
1192     tags = object["tag"] || []
1193     Map.put(object, "sensitive", "nsfw" in tags)
1194   end
1195
1196   def set_type(%{"type" => "Answer"} = object) do
1197     Map.put(object, "type", "Note")
1198   end
1199
1200   def set_type(object), do: object
1201
1202   def add_attributed_to(object) do
1203     attributed_to = object["attributedTo"] || object["actor"]
1204     Map.put(object, "attributedTo", attributed_to)
1205   end
1206
1207   def prepare_attachments(object) do
1208     attachments =
1209       (object["attachment"] || [])
1210       |> Enum.map(fn data ->
1211         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1212         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1213       end)
1214
1215     Map.put(object, "attachment", attachments)
1216   end
1217
1218   def strip_internal_fields(object) do
1219     object
1220     |> Map.drop(Pleroma.Constants.object_internal_fields())
1221   end
1222
1223   defp strip_internal_tags(%{"tag" => tags} = object) do
1224     tags = Enum.filter(tags, fn x -> is_map(x) end)
1225
1226     Map.put(object, "tag", tags)
1227   end
1228
1229   defp strip_internal_tags(object), do: object
1230
1231   def perform(:user_upgrade, user) do
1232     # we pass a fake user so that the followers collection is stripped away
1233     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1234
1235     from(
1236       a in Activity,
1237       where: ^old_follower_address in a.recipients,
1238       update: [
1239         set: [
1240           recipients:
1241             fragment(
1242               "array_replace(?,?,?)",
1243               a.recipients,
1244               ^old_follower_address,
1245               ^user.follower_address
1246             )
1247         ]
1248       ]
1249     )
1250     |> Repo.update_all([])
1251   end
1252
1253   def upgrade_user_from_ap_id(ap_id) do
1254     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1255          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1256          already_ap <- User.ap_enabled?(user),
1257          {:ok, user} <- upgrade_user(user, data) do
1258       if not already_ap do
1259         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1260       end
1261
1262       {:ok, user}
1263     else
1264       %User{} = user -> {:ok, user}
1265       e -> e
1266     end
1267   end
1268
1269   defp upgrade_user(user, data) do
1270     user
1271     |> User.upgrade_changeset(data, true)
1272     |> User.update_and_set_cache()
1273   end
1274
1275   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1276     Map.put(data, "url", url["href"])
1277   end
1278
1279   def maybe_fix_user_url(data), do: data
1280
1281   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1282
1283   defp ensure_context_presence(%{"context" => context} = data) when is_binary(context),
1284     do: {:ok, data}
1285
1286   defp ensure_context_presence(%{"object" => object} = data) when is_binary(object) do
1287     with %{data: %{"context" => context}} when is_binary(context) <- Object.normalize(object) do
1288       {:ok, Map.put(data, "context", context)}
1289     else
1290       _ ->
1291         {:error, :no_context}
1292     end
1293   end
1294
1295   defp ensure_context_presence(_) do
1296     {:error, :no_context}
1297   end
1298
1299   defp ensure_recipients_presence(%{"to" => [_ | _], "cc" => [_ | _]} = data),
1300     do: {:ok, data}
1301
1302   defp ensure_recipients_presence(%{"object" => object} = data) do
1303     case Object.normalize(object) do
1304       %{data: %{"actor" => actor}} ->
1305         data =
1306           data
1307           |> Map.put("to", [actor])
1308           |> Map.put("cc", data["cc"] || [])
1309
1310         {:ok, data}
1311
1312       nil ->
1313         {:error, :no_object}
1314
1315       _ ->
1316         {:error, :no_actor}
1317     end
1318   end
1319
1320   defp ensure_recipients_presence(_) do
1321     {:error, :no_object}
1322   end
1323 end