git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.Object
  12   alias Pleroma.Object.Containment
  13   alias Pleroma.Repo
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16   alias Pleroma.Web.ActivityPub.ObjectValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  18   alias Pleroma.Web.ActivityPub.Pipeline
  19   alias Pleroma.Web.ActivityPub.Utils
  20   alias Pleroma.Web.ActivityPub.Visibility
  21   alias Pleroma.Web.Federator
  22   alias Pleroma.Workers.TransmogrifierWorker
  23
  24   import Ecto.Query
  25
  26   require Logger
  27   require Pleroma.Constants
  28
  29   @doc """
  30   Modifies an incoming AP object (mastodon format) to our internal format.
  31   """
  32   def fix_object(object, options \\ []) do
  33     object
  34     |> strip_internal_fields
  35     |> fix_actor
  36     |> fix_url
  37     |> fix_attachments
  38     |> fix_context
  39     |> fix_in_reply_to(options)
  40     |> fix_emoji
  41     |> fix_tag
  42     |> fix_content_map
  43     |> fix_addressing
  44     |> fix_summary
  45     |> fix_type(options)
  46   end
  47
  48   def fix_summary(%{"summary" => nil} = object) do
  49     Map.put(object, "summary", "")
  50   end
  51
  52   def fix_summary(%{"summary" => _} = object) do
  53     # summary is present, nothing to do
  54     object
  55   end
  56
  57   def fix_summary(object), do: Map.put(object, "summary", "")
  58
  59   def fix_addressing_list(map, field) do
  60     cond do
  61       is_binary(map[field]) ->
  62         Map.put(map, field, [map[field]])
  63
  64       is_nil(map[field]) ->
  65         Map.put(map, field, [])
  66
  67       true ->
  68         map
  69     end
  70   end
  71
  72   def fix_explicit_addressing(
  73         %{"to" => to, "cc" => cc} = object,
  74         explicit_mentions,
  75         follower_collection
  76       ) do
  77     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  78
  79     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  80
  81     final_cc =
  82       (cc ++ explicit_cc)
  83       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  84       |> Enum.uniq()
  85
  86     object
  87     |> Map.put("to", explicit_to)
  88     |> Map.put("cc", final_cc)
  89   end
  90
  91   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  92
  93   # if directMessage flag is set to true, leave the addressing alone
  94   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  95
  96   def fix_explicit_addressing(object) do
  97     explicit_mentions = Utils.determine_explicit_mentions(object)
  98
  99     %User{follower_address: follower_collection} =
 100       object
 101       |> Containment.get_actor()
 102       |> User.get_cached_by_ap_id()
 103
 104     explicit_mentions =
 105       explicit_mentions ++
 106         [
 107           Pleroma.Constants.as_public(),
 108           follower_collection
 109         ]
 110
 111     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 112   end
 113
 114   # if as:Public is addressed, then make sure the followers collection is also addressed
 115   # so that the activities will be delivered to local users.
 116   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 117     recipients = to ++ cc
 118
 119     if followers_collection not in recipients do
 120       cond do
 121         Pleroma.Constants.as_public() in cc ->
 122           to = to ++ [followers_collection]
 123           Map.put(object, "to", to)
 124
 125         Pleroma.Constants.as_public() in to ->
 126           cc = cc ++ [followers_collection]
 127           Map.put(object, "cc", cc)
 128
 129         true ->
 130           object
 131       end
 132     else
 133       object
 134     end
 135   end
 136
 137   def fix_implicit_addressing(object, _), do: object
 138
 139   def fix_addressing(object) do
 140     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 141     followers_collection = User.ap_followers(user)
 142
 143     object
 144     |> fix_addressing_list("to")
 145     |> fix_addressing_list("cc")
 146     |> fix_addressing_list("bto")
 147     |> fix_addressing_list("bcc")
 148     |> fix_explicit_addressing()
 149     |> fix_implicit_addressing(followers_collection)
 150   end
 151
 152   def fix_actor(%{"attributedTo" => actor} = object) do
 153     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 154   end
 155
 156   def fix_in_reply_to(object, options \\ [])
 157
 158   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 159       when not is_nil(in_reply_to) do
 160     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 161     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 162     depth = (options[:depth] || 0) + 1
 163
 164     if Federator.allowed_thread_distance?(depth) do
 165       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 166            %Activity{} <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 167         object
 168         |> Map.put("inReplyTo", replied_object.data["id"])
 169         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 170         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 171         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 172       else
 173         e ->
 174           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 175           object
 176       end
 177     else
 178       object
 179     end
 180   end
 181
 182   def fix_in_reply_to(object, _options), do: object
 183
 184   defp prepare_in_reply_to(in_reply_to) do
 185     cond do
 186       is_bitstring(in_reply_to) ->
 187         in_reply_to
 188
 189       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 190         in_reply_to["id"]
 191
 192       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 193         Enum.at(in_reply_to, 0)
 194
 195       true ->
 196         ""
 197     end
 198   end
 199
 200   def fix_context(object) do
 201     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 202
 203     object
 204     |> Map.put("context", context)
 205     |> Map.put("conversation", context)
 206   end
 207
 208   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 209     attachments =
 210       Enum.map(attachment, fn data ->
 211         media_type = data["mediaType"] || data["mimeType"]
 212         href = data["url"] || data["href"]
 213         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 214
 215         data
 216         |> Map.put("mediaType", media_type)
 217         |> Map.put("url", url)
 218       end)
 219
 220     Map.put(object, "attachment", attachments)
 221   end
 222
 223   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 224     object
 225     |> Map.put("attachment", [attachment])
 226     |> fix_attachments()
 227   end
 228
 229   def fix_attachments(object), do: object
 230
 231   def fix_url(%{"url" => url} = object) when is_map(url) do
 232     Map.put(object, "url", url["href"])
 233   end
 234
 235   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 236     first_element = Enum.at(url, 0)
 237
 238     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 239
 240     object
 241     |> Map.put("attachment", [first_element])
 242     |> Map.put("url", link_element["href"])
 243   end
 244
 245   def fix_url(%{"type" => object_type, "url" => url} = object)
 246       when object_type != "Video" and is_list(url) do
 247     first_element = Enum.at(url, 0)
 248
 249     url_string =
 250       cond do
 251         is_bitstring(first_element) -> first_element
 252         is_map(first_element) -> first_element["href"] || ""
 253         true -> ""
 254       end
 255
 256     Map.put(object, "url", url_string)
 257   end
 258
 259   def fix_url(object), do: object
 260
 261   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 262     emoji =
 263       tags
 264       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 265       |> Enum.reduce(%{}, fn data, mapping ->
 266         name = String.trim(data["name"], ":")
 267
 268         Map.put(mapping, name, data["icon"]["url"])
 269       end)
 270
 271     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 272     emoji = Map.merge(object["emoji"] || %{}, emoji)
 273
 274     Map.put(object, "emoji", emoji)
 275   end
 276
 277   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 278     name = String.trim(tag["name"], ":")
 279     emoji = %{name => tag["icon"]["url"]}
 280
 281     Map.put(object, "emoji", emoji)
 282   end
 283
 284   def fix_emoji(object), do: object
 285
 286   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 287     tags =
 288       tag
 289       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 290       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 291
 292     Map.put(object, "tag", tag ++ tags)
 293   end
 294
 295   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 296     combined = [tag, String.slice(hashtag, 1..-1)]
 297
 298     Map.put(object, "tag", combined)
 299   end
 300
 301   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 302
 303   def fix_tag(object), do: object
 304
 305   # content map usually only has one language so this will do for now.
 306   def fix_content_map(%{"contentMap" => content_map} = object) do
 307     content_groups = Map.to_list(content_map)
 308     {_, content} = Enum.at(content_groups, 0)
 309
 310     Map.put(object, "content", content)
 311   end
 312
 313   def fix_content_map(object), do: object
 314
 315   def fix_type(object, options \\ [])
 316
 317   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 318       when is_binary(reply_id) do
 319     with true <- Federator.allowed_thread_distance?(options[:depth]),
 320          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 321       Map.put(object, "type", "Answer")
 322     else
 323       _ -> object
 324     end
 325   end
 326
 327   def fix_type(object, _), do: object
 328
 329   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 330     with true <- id =~ "follows",
 331          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 332          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 333       {:ok, activity}
 334     else
 335       _ -> {:error, nil}
 336     end
 337   end
 338
 339   defp mastodon_follow_hack(_, _), do: {:error, nil}
 340
 341   defp get_follow_activity(follow_object, followed) do
 342     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 343          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 344       {:ok, activity}
 345     else
 346       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 347       {:activity, nil} ->
 348         mastodon_follow_hack(follow_object, followed)
 349
 350       _ ->
 351         {:error, nil}
 352     end
 353   end
 354
 355   # Reduce the object list to find the reported user.
 356   defp get_reported(objects) do
 357     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 358       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 359         {:halt, user}
 360       else
 361         _ -> {:cont, nil}
 362       end
 363     end)
 364   end
 365
 366   def handle_incoming(data, options \\ [])
 367
 368   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 369   # with nil ID.
 370   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 371     with context <- data["context"] || Utils.generate_context_id(),
 372          content <- data["content"] || "",
 373          %User{} = actor <- User.get_cached_by_ap_id(actor),
 374          # Reduce the object list to find the reported user.
 375          %User{} = account <- get_reported(objects),
 376          # Remove the reported user from the object list.
 377          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 378       %{
 379         actor: actor,
 380         context: context,
 381         account: account,
 382         statuses: statuses,
 383         content: content,
 384         additional: %{"cc" => [account.ap_id]}
 385       }
 386       |> ActivityPub.flag()
 387     end
 388   end
 389
 390   # disallow objects with bogus IDs
 391   def handle_incoming(%{"id" => nil}, _options), do: :error
 392   def handle_incoming(%{"id" => ""}, _options), do: :error
 393   # length of https:// = 8, should validate better, but good enough for now.
 394   def handle_incoming(%{"id" => id}, _options) when is_binary(id) and byte_size(id) < 8,
 395     do: :error
 396
 397   # TODO: validate those with a Ecto scheme
 398   # - tags
 399   # - emoji
 400   def handle_incoming(
 401         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 402         options
 403       )
 404       when objtype in ["Article", "Event", "Note", "Video", "Page", "Question", "Answer"] do
 405     actor = Containment.get_actor(data)
 406
 407     data =
 408       Map.put(data, "actor", actor)
 409       |> fix_addressing
 410
 411     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 412          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 413       object = fix_object(object, options)
 414
 415       params = %{
 416         to: data["to"],
 417         object: object,
 418         actor: user,
 419         context: object["conversation"],
 420         local: false,
 421         published: data["published"],
 422         additional:
 423           Map.take(data, [
 424             "cc",
 425             "directMessage",
 426             "id"
 427           ])
 428       }
 429
 430       with {:ok, created_activity} <- ActivityPub.create(params) do
 431         reply_depth = (options[:depth] || 0) + 1
 432
 433         if Federator.allowed_thread_distance?(reply_depth) do
 434           for reply_id <- replies(object) do
 435             Pleroma.Workers.RemoteFetcherWorker.enqueue("fetch_remote", %{
 436               "id" => reply_id,
 437               "depth" => reply_depth
 438             })
 439           end
 440         end
 441
 442         {:ok, created_activity}
 443       end
 444     else
 445       %Activity{} = activity -> {:ok, activity}
 446       _e -> :error
 447     end
 448   end
 449
 450   def handle_incoming(
 451         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 452         options
 453       ) do
 454     actor = Containment.get_actor(data)
 455
 456     data =
 457       Map.put(data, "actor", actor)
 458       |> fix_addressing
 459
 460     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 461       reply_depth = (options[:depth] || 0) + 1
 462       options = Keyword.put(options, :depth, reply_depth)
 463       object = fix_object(object, options)
 464
 465       params = %{
 466         to: data["to"],
 467         object: object,
 468         actor: user,
 469         context: nil,
 470         local: false,
 471         published: data["published"],
 472         additional: Map.take(data, ["cc", "id"])
 473       }
 474
 475       ActivityPub.listen(params)
 476     else
 477       _e -> :error
 478     end
 479   end
 480
 481   def handle_incoming(
 482         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 483         _options
 484       ) do
 485     with %User{local: true} = followed <-
 486            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 487          {:ok, %User{} = follower} <-
 488            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 489          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 490       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 491            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 492            {_, false} <- {:user_locked, User.locked?(followed)},
 493            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 494            {_, {:ok, _}} <-
 495              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 496            {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 497         ActivityPub.accept(%{
 498           to: [follower.ap_id],
 499           actor: followed,
 500           object: data,
 501           local: true
 502         })
 503       else
 504         {:user_blocked, true} ->
 505           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 506           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 507
 508           ActivityPub.reject(%{
 509             to: [follower.ap_id],
 510             actor: followed,
 511             object: data,
 512             local: true
 513           })
 514
 515         {:follow, {:error, _}} ->
 516           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 517           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 518
 519           ActivityPub.reject(%{
 520             to: [follower.ap_id],
 521             actor: followed,
 522             object: data,
 523             local: true
 524           })
 525
 526         {:user_locked, true} ->
 527           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "pending")
 528           :noop
 529       end
 530
 531       {:ok, activity}
 532     else
 533       _e ->
 534         :error
 535     end
 536   end
 537
 538   def handle_incoming(
 539         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 540         _options
 541       ) do
 542     with actor <- Containment.get_actor(data),
 543          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 544          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 545          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 546          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 547          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 548       ActivityPub.accept(%{
 549         to: follow_activity.data["to"],
 550         type: "Accept",
 551         actor: followed,
 552         object: follow_activity.data["id"],
 553         local: false,
 554         activity_id: id
 555       })
 556     else
 557       _e -> :error
 558     end
 559   end
 560
 561   def handle_incoming(
 562         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 563         _options
 564       ) do
 565     with actor <- Containment.get_actor(data),
 566          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 567          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 568          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 569          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 570          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "reject"),
 571          {:ok, activity} <-
 572            ActivityPub.reject(%{
 573              to: follow_activity.data["to"],
 574              type: "Reject",
 575              actor: followed,
 576              object: follow_activity.data["id"],
 577              local: false,
 578              activity_id: id
 579            }) do
 580       {:ok, activity}
 581     else
 582       _e -> :error
 583     end
 584   end
 585
 586   @misskey_reactions %{
 587     "like" => "👍",
 588     "love" => "❤️",
 589     "laugh" => "😆",
 590     "hmm" => "🤔",
 591     "surprise" => "😮",
 592     "congrats" => "🎉",
 593     "angry" => "💢",
 594     "confused" => "😥",
 595     "rip" => "😇",
 596     "pudding" => "🍮",
 597     "star" => "⭐"
 598   }
 599
 600   @doc "Rewrite misskey likes into EmojiReacts"
 601   def handle_incoming(
 602         %{
 603           "type" => "Like",
 604           "_misskey_reaction" => reaction
 605         } = data,
 606         options
 607       ) do
 608     data
 609     |> Map.put("type", "EmojiReact")
 610     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 611     |> handle_incoming(options)
 612   end
 613
 614   def handle_incoming(%{"type" => "Like"} = data, _options) do
 615     with {_, {:ok, cast_data_sym}} <-
 616            {:casting_data,
 617             data |> LikeValidator.cast_data() |> Ecto.Changeset.apply_action(:insert)},
 618          {_, cast_data} <-
 619            {:stringify_keys, ObjectValidator.stringify_keys(cast_data_sym |> Map.from_struct())},
 620          :ok <- ObjectValidator.fetch_actor_and_object(cast_data),
 621          {_, {:ok, cast_data}} <- {:maybe_add_context, maybe_add_context_from_object(cast_data)},
 622          {_, {:ok, cast_data}} <-
 623            {:maybe_add_recipients, maybe_add_recipients_from_object(cast_data)},
 624          {_, {:ok, activity, _meta}} <-
 625            {:common_pipeline, Pipeline.common_pipeline(cast_data, local: false)} do
 626       {:ok, activity}
 627     else
 628       e -> {:error, e}
 629     end
 630   end
 631
 632   def handle_incoming(
 633         %{
 634           "type" => "EmojiReact",
 635           "object" => object_id,
 636           "actor" => _actor,
 637           "id" => id,
 638           "content" => emoji
 639         } = data,
 640         _options
 641       ) do
 642     with actor <- Containment.get_actor(data),
 643          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 644          {:ok, object} <- get_obj_helper(object_id),
 645          {:ok, activity, _object} <-
 646            ActivityPub.react_with_emoji(actor, object, emoji, activity_id: id, local: false) do
 647       {:ok, activity}
 648     else
 649       _e -> :error
 650     end
 651   end
 652
 653   def handle_incoming(
 654         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 655         _options
 656       ) do
 657     with actor <- Containment.get_actor(data),
 658          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 659          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 660          public <- Visibility.is_public?(data),
 661          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 662       {:ok, activity}
 663     else
 664       _e -> :error
 665     end
 666   end
 667
 668   def handle_incoming(
 669         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 670           data,
 671         _options
 672       )
 673       when object_type in [
 674              "Person",
 675              "Application",
 676              "Service",
 677              "Organization"
 678            ] do
 679     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 680       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 681
 682       actor
 683       |> User.upgrade_changeset(new_user_data, true)
 684       |> User.update_and_set_cache()
 685
 686       ActivityPub.update(%{
 687         local: false,
 688         to: data["to"] || [],
 689         cc: data["cc"] || [],
 690         object: object,
 691         actor: actor_id,
 692         activity_id: data["id"]
 693       })
 694     else
 695       e ->
 696         Logger.error(e)
 697         :error
 698     end
 699   end
 700
 701   # TODO: We presently assume that any actor on the same origin domain as the object being
 702   # deleted has the rights to delete that object.  A better way to validate whether or not
 703   # the object should be deleted is to refetch the object URI, which should return either
 704   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 705   # place.
 706   def handle_incoming(
 707         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 708         _options
 709       ) do
 710     object_id = Utils.get_ap_id(object_id)
 711
 712     with actor <- Containment.get_actor(data),
 713          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 714          {:ok, object} <- get_obj_helper(object_id),
 715          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 716          {:ok, activity} <-
 717            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 718       {:ok, activity}
 719     else
 720       nil ->
 721         case User.get_cached_by_ap_id(object_id) do
 722           %User{ap_id: ^actor} = user ->
 723             User.delete(user)
 724
 725           nil ->
 726             :error
 727         end
 728
 729       _e ->
 730         :error
 731     end
 732   end
 733
 734   def handle_incoming(
 735         %{
 736           "type" => "Undo",
 737           "object" => %{"type" => "Announce", "object" => object_id},
 738           "actor" => _actor,
 739           "id" => id
 740         } = data,
 741         _options
 742       ) do
 743     with actor <- Containment.get_actor(data),
 744          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 745          {:ok, object} <- get_obj_helper(object_id),
 746          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 747       {:ok, activity}
 748     else
 749       _e -> :error
 750     end
 751   end
 752
 753   def handle_incoming(
 754         %{
 755           "type" => "Undo",
 756           "object" => %{"type" => "Follow", "object" => followed},
 757           "actor" => follower,
 758           "id" => id
 759         } = _data,
 760         _options
 761       ) do
 762     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 763          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 764          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 765       User.unfollow(follower, followed)
 766       {:ok, activity}
 767     else
 768       _e -> :error
 769     end
 770   end
 771
 772   def handle_incoming(
 773         %{
 774           "type" => "Undo",
 775           "object" => %{"type" => "EmojiReact", "id" => reaction_activity_id},
 776           "actor" => _actor,
 777           "id" => id
 778         } = data,
 779         _options
 780       ) do
 781     with actor <- Containment.get_actor(data),
 782          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 783          {:ok, activity, _} <-
 784            ActivityPub.unreact_with_emoji(actor, reaction_activity_id,
 785              activity_id: id,
 786              local: false
 787            ) do
 788       {:ok, activity}
 789     else
 790       _e -> :error
 791     end
 792   end
 793
 794   def handle_incoming(
 795         %{
 796           "type" => "Undo",
 797           "object" => %{"type" => "Block", "object" => blocked},
 798           "actor" => blocker,
 799           "id" => id
 800         } = _data,
 801         _options
 802       ) do
 803     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 804          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 805          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 806       User.unblock(blocker, blocked)
 807       {:ok, activity}
 808     else
 809       _e -> :error
 810     end
 811   end
 812
 813   def handle_incoming(
 814         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 815         _options
 816       ) do
 817     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 818          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 819          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 820       User.unfollow(blocker, blocked)
 821       User.block(blocker, blocked)
 822       {:ok, activity}
 823     else
 824       _e -> :error
 825     end
 826   end
 827
 828   def handle_incoming(
 829         %{
 830           "type" => "Undo",
 831           "object" => %{"type" => "Like", "object" => object_id},
 832           "actor" => _actor,
 833           "id" => id
 834         } = data,
 835         _options
 836       ) do
 837     with actor <- Containment.get_actor(data),
 838          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 839          {:ok, object} <- get_obj_helper(object_id),
 840          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 841       {:ok, activity}
 842     else
 843       _e -> :error
 844     end
 845   end
 846
 847   # For Undos that don't have the complete object attached, try to find it in our database.
 848   def handle_incoming(
 849         %{
 850           "type" => "Undo",
 851           "object" => object
 852         } = activity,
 853         options
 854       )
 855       when is_binary(object) do
 856     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 857       activity
 858       |> Map.put("object", data)
 859       |> handle_incoming(options)
 860     else
 861       _e -> :error
 862     end
 863   end
 864
 865   def handle_incoming(
 866         %{
 867           "type" => "Move",
 868           "actor" => origin_actor,
 869           "object" => origin_actor,
 870           "target" => target_actor
 871         },
 872         _options
 873       ) do
 874     with %User{} = origin_user <- User.get_cached_by_ap_id(origin_actor),
 875          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_actor),
 876          true <- origin_actor in target_user.also_known_as do
 877       ActivityPub.move(origin_user, target_user, false)
 878     else
 879       _e -> :error
 880     end
 881   end
 882
 883   def handle_incoming(_, _), do: :error
 884
 885   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 886   def get_obj_helper(id, options \\ []) do
 887     case Object.normalize(id, true, options) do
 888       %Object{} = object -> {:ok, object}
 889       _ -> nil
 890     end
 891   end
 892
 893   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 894   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 895         ap_id: ap_id
 896       })
 897       when attributed_to == ap_id do
 898     with {:ok, activity} <-
 899            handle_incoming(%{
 900              "type" => "Create",
 901              "to" => data["to"],
 902              "cc" => data["cc"],
 903              "actor" => attributed_to,
 904              "object" => data
 905            }) do
 906       {:ok, Object.normalize(activity)}
 907     else
 908       _ -> get_obj_helper(object_id)
 909     end
 910   end
 911
 912   def get_embedded_obj_helper(object_id, _) do
 913     get_obj_helper(object_id)
 914   end
 915
 916   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 917     with false <- String.starts_with?(in_reply_to, "http"),
 918          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 919       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 920     else
 921       _e -> object
 922     end
 923   end
 924
 925   def set_reply_to_uri(obj), do: obj
 926
 927   @doc """
 928   Serialized Mastodon-compatible `replies` collection containing _self-replies_.
 929   Based on Mastodon's ActivityPub::NoteSerializer#replies.
 930   """
 931   def set_replies(obj_data) do
 932     replies_uris =
 933       with limit when limit > 0 <-
 934              Pleroma.Config.get([:activitypub, :note_replies_output_limit], 0),
 935            %Object{} = object <- Object.get_cached_by_ap_id(obj_data["id"]) do
 936         object
 937         |> Object.self_replies()
 938         |> select([o], fragment("?->>'id'", o.data))
 939         |> limit(^limit)
 940         |> Repo.all()
 941       else
 942         _ -> []
 943       end
 944
 945     set_replies(obj_data, replies_uris)
 946   end
 947
 948   defp set_replies(obj, []) do
 949     obj
 950   end
 951
 952   defp set_replies(obj, replies_uris) do
 953     replies_collection = %{
 954       "type" => "Collection",
 955       "items" => replies_uris
 956     }
 957
 958     Map.merge(obj, %{"replies" => replies_collection})
 959   end
 960
 961   def replies(%{"replies" => %{"first" => %{"items" => items}}}) when not is_nil(items) do
 962     items
 963   end
 964
 965   def replies(%{"replies" => %{"items" => items}}) when not is_nil(items) do
 966     items
 967   end
 968
 969   def replies(_), do: []
 970
 971   # Prepares the object of an outgoing create activity.
 972   def prepare_object(object) do
 973     object
 974     |> set_sensitive
 975     |> add_hashtags
 976     |> add_mention_tags
 977     |> add_emoji_tags
 978     |> add_attributed_to
 979     |> prepare_attachments
 980     |> set_conversation
 981     |> set_reply_to_uri
 982     |> set_replies
 983     |> strip_internal_fields
 984     |> strip_internal_tags
 985     |> set_type
 986   end
 987
 988   #  @doc
 989   #  """
 990   #  internal -> Mastodon
 991   #  """
 992
 993   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 994       when activity_type in ["Create", "Listen"] do
 995     object =
 996       object_id
 997       |> Object.normalize()
 998       |> Map.get(:data)
 999       |> prepare_object
1000
1001     data =
1002       data
1003       |> Map.put("object", object)
1004       |> Map.merge(Utils.make_json_ld_header())
1005       |> Map.delete("bcc")
1006
1007     {:ok, data}
1008   end
1009
1010   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
1011     object =
1012       object_id
1013       |> Object.normalize()
1014
1015     data =
1016       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
1017         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
1018       else
1019         data |> maybe_fix_object_url
1020       end
1021
1022     data =
1023       data
1024       |> strip_internal_fields
1025       |> Map.merge(Utils.make_json_ld_header())
1026       |> Map.delete("bcc")
1027
1028     {:ok, data}
1029   end
1030
1031   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
1032   # because of course it does.
1033   def prepare_outgoing(%{"type" => "Accept"} = data) do
1034     with follow_activity <- Activity.normalize(data["object"]) do
1035       object = %{
1036         "actor" => follow_activity.actor,
1037         "object" => follow_activity.data["object"],
1038         "id" => follow_activity.data["id"],
1039         "type" => "Follow"
1040       }
1041
1042       data =
1043         data
1044         |> Map.put("object", object)
1045         |> Map.merge(Utils.make_json_ld_header())
1046
1047       {:ok, data}
1048     end
1049   end
1050
1051   def prepare_outgoing(%{"type" => "Reject"} = data) do
1052     with follow_activity <- Activity.normalize(data["object"]) do
1053       object = %{
1054         "actor" => follow_activity.actor,
1055         "object" => follow_activity.data["object"],
1056         "id" => follow_activity.data["id"],
1057         "type" => "Follow"
1058       }
1059
1060       data =
1061         data
1062         |> Map.put("object", object)
1063         |> Map.merge(Utils.make_json_ld_header())
1064
1065       {:ok, data}
1066     end
1067   end
1068
1069   def prepare_outgoing(%{"type" => _type} = data) do
1070     data =
1071       data
1072       |> strip_internal_fields
1073       |> maybe_fix_object_url
1074       |> Map.merge(Utils.make_json_ld_header())
1075
1076     {:ok, data}
1077   end
1078
1079   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
1080     with false <- String.starts_with?(object, "http"),
1081          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
1082          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
1083            relative_object do
1084       Map.put(data, "object", external_url)
1085     else
1086       {:fetch, e} ->
1087         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
1088         data
1089
1090       _ ->
1091         data
1092     end
1093   end
1094
1095   def maybe_fix_object_url(data), do: data
1096
1097   def add_hashtags(object) do
1098     tags =
1099       (object["tag"] || [])
1100       |> Enum.map(fn
1101         # Expand internal representation tags into AS2 tags.
1102         tag when is_binary(tag) ->
1103           %{
1104             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
1105             "name" => "##{tag}",
1106             "type" => "Hashtag"
1107           }
1108
1109         # Do not process tags which are already AS2 tag objects.
1110         tag when is_map(tag) ->
1111           tag
1112       end)
1113
1114     Map.put(object, "tag", tags)
1115   end
1116
1117   def add_mention_tags(object) do
1118     mentions =
1119       object
1120       |> Utils.get_notified_from_object()
1121       |> Enum.map(&build_mention_tag/1)
1122
1123     tags = object["tag"] || []
1124
1125     Map.put(object, "tag", tags ++ mentions)
1126   end
1127
1128   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1129     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1130   end
1131
1132   def take_emoji_tags(%User{emoji: emoji}) do
1133     emoji
1134     |> Enum.flat_map(&Map.to_list/1)
1135     |> Enum.map(&build_emoji_tag/1)
1136   end
1137
1138   # TODO: we should probably send mtime instead of unix epoch time for updated
1139   def add_emoji_tags(%{"emoji" => emoji} = object) do
1140     tags = object["tag"] || []
1141
1142     out = Enum.map(emoji, &build_emoji_tag/1)
1143
1144     Map.put(object, "tag", tags ++ out)
1145   end
1146
1147   def add_emoji_tags(object), do: object
1148
1149   defp build_emoji_tag({name, url}) do
1150     %{
1151       "icon" => %{"url" => url, "type" => "Image"},
1152       "name" => ":" <> name <> ":",
1153       "type" => "Emoji",
1154       "updated" => "1970-01-01T00:00:00Z",
1155       "id" => url
1156     }
1157   end
1158
1159   def set_conversation(object) do
1160     Map.put(object, "conversation", object["context"])
1161   end
1162
1163   def set_sensitive(object) do
1164     tags = object["tag"] || []
1165     Map.put(object, "sensitive", "nsfw" in tags)
1166   end
1167
1168   def set_type(%{"type" => "Answer"} = object) do
1169     Map.put(object, "type", "Note")
1170   end
1171
1172   def set_type(object), do: object
1173
1174   def add_attributed_to(object) do
1175     attributed_to = object["attributedTo"] || object["actor"]
1176     Map.put(object, "attributedTo", attributed_to)
1177   end
1178
1179   def prepare_attachments(object) do
1180     attachments =
1181       (object["attachment"] || [])
1182       |> Enum.map(fn data ->
1183         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1184         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1185       end)
1186
1187     Map.put(object, "attachment", attachments)
1188   end
1189
1190   def strip_internal_fields(object) do
1191     object
1192     |> Map.drop(Pleroma.Constants.object_internal_fields())
1193   end
1194
1195   defp strip_internal_tags(%{"tag" => tags} = object) do
1196     tags = Enum.filter(tags, fn x -> is_map(x) end)
1197
1198     Map.put(object, "tag", tags)
1199   end
1200
1201   defp strip_internal_tags(object), do: object
1202
1203   def perform(:user_upgrade, user) do
1204     # we pass a fake user so that the followers collection is stripped away
1205     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1206
1207     from(
1208       a in Activity,
1209       where: ^old_follower_address in a.recipients,
1210       update: [
1211         set: [
1212           recipients:
1213             fragment(
1214               "array_replace(?,?,?)",
1215               a.recipients,
1216               ^old_follower_address,
1217               ^user.follower_address
1218             )
1219         ]
1220       ]
1221     )
1222     |> Repo.update_all([])
1223   end
1224
1225   def upgrade_user_from_ap_id(ap_id) do
1226     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1227          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1228          already_ap <- User.ap_enabled?(user),
1229          {:ok, user} <- upgrade_user(user, data) do
1230       if not already_ap do
1231         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1232       end
1233
1234       {:ok, user}
1235     else
1236       %User{} = user -> {:ok, user}
1237       e -> e
1238     end
1239   end
1240
1241   defp upgrade_user(user, data) do
1242     user
1243     |> User.upgrade_changeset(data, true)
1244     |> User.update_and_set_cache()
1245   end
1246
1247   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1248     Map.put(data, "url", url["href"])
1249   end
1250
1251   def maybe_fix_user_url(data), do: data
1252
1253   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1254
1255   defp maybe_add_context_from_object(%{"context" => context} = data) when is_binary(context),
1256     do: {:ok, data}
1257
1258   defp maybe_add_context_from_object(%{"object" => object} = data) when is_binary(object) do
1259     if object = Object.normalize(object) do
1260       data =
1261         data
1262         |> Map.put("context", object.data["context"])
1263
1264       {:ok, data}
1265     else
1266       {:error, "No context on referenced object"}
1267     end
1268   end
1269
1270   defp maybe_add_context_from_object(_) do
1271     {:error, "No referenced object"}
1272   end
1273
1274   defp maybe_add_recipients_from_object(%{"object" => object} = data) do
1275     to = data["to"] || []
1276     cc = data["cc"] || []
1277
1278     if to == [] && cc == [] do
1279       if object = Object.normalize(object) do
1280         data =
1281           data
1282           |> Map.put("to", [object.data["actor"]])
1283           |> Map.put("cc", cc)
1284
1285         {:ok, data}
1286       else
1287         {:error, "No actor on referenced object"}
1288       end
1289     else
1290       {:ok, data}
1291     end
1292   end
1293
1294   defp maybe_add_recipients_from_object(_) do
1295     {:error, "No referenced object"}
1296   end
1297 end