git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10
  11   import Ecto.Query
  12
  13   require Logger
  14
  15   @doc """
  16   Modifies an incoming AP object (mastodon format) to our internal format.
  17   """
  18   def fix_object(object) do
  19     object
  20     |> Map.put("actor", object["attributedTo"])
  21     |> fix_attachments
  22     |> fix_context
  23     |> fix_in_reply_to
  24     |> fix_emoji
  25     |> fix_tag
  26   end
  27
  28   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  29       when not is_nil(in_reply_to_id) do
  30     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  31       {:ok, replied_object} ->
  32         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  33
  34         object
  35         |> Map.put("inReplyTo", replied_object.data["id"])
  36         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  37         |> Map.put("inReplyToStatusId", activity.id)
  38         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  39         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  40
  41       e ->
  42         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  43         object
  44     end
  45   end
  46
  47   def fix_in_reply_to(object), do: object
  48
  49   def fix_context(object) do
  50     object
  51     |> Map.put("context", object["conversation"])
  52   end
  53
  54   def fix_attachments(object) do
  55     attachments =
  56       (object["attachment"] || [])
  57       |> Enum.map(fn data ->
  58         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  59         Map.put(data, "url", url)
  60       end)
  61
  62     object
  63     |> Map.put("attachment", attachments)
  64   end
  65
  66   def fix_emoji(object) do
  67     tags = object["tag"] || []
  68     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  69
  70     emoji =
  71       emoji
  72       |> Enum.reduce(%{}, fn data, mapping ->
  73         name = data["name"]
  74
  75         name =
  76           if String.starts_with?(name, ":") do
  77             name |> String.slice(1..-2)
  78           else
  79             name
  80           end
  81
  82         mapping |> Map.put(name, data["icon"]["url"])
  83       end)
  84
  85     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  86     emoji = Map.merge(object["emoji"] || %{}, emoji)
  87
  88     object
  89     |> Map.put("emoji", emoji)
  90   end
  91
  92   def fix_tag(object) do
  93     tags =
  94       (object["tag"] || [])
  95       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  96       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  97
  98     combined = (object["tag"] || []) ++ tags
  99
 100     object
 101     |> Map.put("tag", combined)
 102   end
 103
 104   # TODO: validate those with a Ecto scheme
 105   # - tags
 106   # - emoji
 107   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 108     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 109          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 110       object = fix_object(data["object"])
 111
 112       params = %{
 113         to: data["to"],
 114         object: object,
 115         actor: user,
 116         context: object["conversation"],
 117         local: false,
 118         published: data["published"],
 119         additional:
 120           Map.take(data, [
 121             "cc",
 122             "id"
 123           ])
 124       }
 125
 126       ActivityPub.create(params)
 127     else
 128       %Activity{} = activity -> {:ok, activity}
 129       _e -> :error
 130     end
 131   end
 132
 133   def handle_incoming(
 134         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 135       ) do
 136     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 137          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 138          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 139       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 140
 141       User.follow(follower, followed)
 142       {:ok, activity}
 143     else
 144       _e -> :error
 145     end
 146   end
 147
 148   def handle_incoming(
 149         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 150       ) do
 151     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 152          {:ok, object} <-
 153            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 154          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 155       {:ok, activity}
 156     else
 157       _e -> :error
 158     end
 159   end
 160
 161   def handle_incoming(
 162         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 163       ) do
 164     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 165          {:ok, object} <-
 166            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 167          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 168       {:ok, activity}
 169     else
 170       _e -> :error
 171     end
 172   end
 173
 174   def handle_incoming(
 175         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 176           data
 177       ) do
 178     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 179       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 180
 181       banner = new_user_data[:info]["banner"]
 182
 183       update_data =
 184         new_user_data
 185         |> Map.take([:name, :bio, :avatar])
 186         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 187
 188       actor
 189       |> User.upgrade_changeset(update_data)
 190       |> User.update_and_set_cache()
 191
 192       ActivityPub.update(%{
 193         local: false,
 194         to: data["to"] || [],
 195         cc: data["cc"] || [],
 196         object: object,
 197         actor: actor_id
 198       })
 199     else
 200       e ->
 201         Logger.error(e)
 202         :error
 203     end
 204   end
 205
 206   # TODO: Make secure.
 207   def handle_incoming(
 208         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 209       ) do
 210     object_id =
 211       case object_id do
 212         %{"id" => id} -> id
 213         id -> id
 214       end
 215
 216     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 217          {:ok, object} <-
 218            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 219          {:ok, activity} <- ActivityPub.delete(object, false) do
 220       {:ok, activity}
 221     else
 222       _e -> :error
 223     end
 224   end
 225
 226   def handle_incoming(
 227         %{
 228           "type" => "Undo",
 229           "object" => %{"type" => "Announce", "object" => object_id},
 230           "actor" => actor,
 231           "id" => id
 232         } = data
 233       ) do
 234     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 235          {:ok, object} <-
 236            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 237          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 238       {:ok, activity}
 239     else
 240       e -> :error
 241     end
 242   end
 243
 244   def handle_incoming(
 245         %{
 246           "type" => "Undo",
 247           "object" => %{"type" => "Follow", "object" => followed},
 248           "actor" => follower,
 249           "id" => id
 250         } = data
 251       ) do
 252     with %User{local: true} = followed = User.get_cached_by_ap_id(followed),
 253          %User{} = follower = User.get_or_fetch_by_ap_id(follower),
 254          {:ok, activity} <- ActivityPub.unfollow(follower, followed, false) do
 255       User.unfollow(follower, followed)
 256       {:ok, activity}
 257     else
 258       e -> :error
 259     end
 260   end
 261
 262   def handle_incoming(%{"type" => "Undo", "object" => object_id} = data) do
 263     object = Object.get_by_ap_id(object_id).data
 264     data = Map.put(data, "object", object)
 265
 266     handle_incoming(data)
 267   end
 268
 269   def handle_incoming(%{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data) do
 270     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 271          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 272          {:ok, activity} <- ActivityPub.block(blocker, blocked, false) do
 273       User.unfollow(follower, followed)
 274       User.block(blocker, blocked.ap_id)
 275       {:ok, activity}
 276     else
 277       e -> :error
 278     end
 279   end
 280   # TODO
 281   # Accept
 282   # Undo for non-Announce
 283
 284   def handle_incoming(_), do: :error
 285
 286   def get_obj_helper(id) do
 287     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 288   end
 289
 290   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 291     with false <- String.starts_with?(inReplyTo, "http"),
 292          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 293       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 294     else
 295       _e -> object
 296     end
 297   end
 298
 299   def set_reply_to_uri(obj), do: obj
 300
 301   # Prepares the object of an outgoing create activity.
 302   def prepare_object(object) do
 303     object
 304     |> set_sensitive
 305     |> add_hashtags
 306     |> add_mention_tags
 307     |> add_emoji_tags
 308     |> add_attributed_to
 309     |> prepare_attachments
 310     |> set_conversation
 311     |> set_reply_to_uri
 312   end
 313
 314   #  @doc
 315   #  """
 316   #  internal -> Mastodon
 317   #  """
 318
 319   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 320     object =
 321       object
 322       |> prepare_object
 323
 324     data =
 325       data
 326       |> Map.put("object", object)
 327       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 328
 329     {:ok, data}
 330   end
 331
 332   def prepare_outgoing(%{"type" => _type} = data) do
 333     data =
 334       data
 335       |> maybe_fix_object_url
 336       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 337
 338     {:ok, data}
 339   end
 340
 341   def maybe_fix_object_url(data) do
 342     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 343       case ActivityPub.fetch_object_from_id(data["object"]) do
 344         {:ok, relative_object} ->
 345           if relative_object.data["external_url"] do
 346             _data =
 347               data
 348               |> Map.put("object", relative_object.data["external_url"])
 349           else
 350             data
 351           end
 352
 353         e ->
 354           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 355           data
 356       end
 357     else
 358       data
 359     end
 360   end
 361
 362   def add_hashtags(object) do
 363     tags =
 364       (object["tag"] || [])
 365       |> Enum.map(fn tag ->
 366         %{
 367           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 368           "name" => "##{tag}",
 369           "type" => "Hashtag"
 370         }
 371       end)
 372
 373     object
 374     |> Map.put("tag", tags)
 375   end
 376
 377   def add_mention_tags(object) do
 378     recipients = object["to"] ++ (object["cc"] || [])
 379
 380     mentions =
 381       recipients
 382       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 383       |> Enum.filter(& &1)
 384       |> Enum.map(fn user ->
 385         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 386       end)
 387
 388     tags = object["tag"] || []
 389
 390     object
 391     |> Map.put("tag", tags ++ mentions)
 392   end
 393
 394   # TODO: we should probably send mtime instead of unix epoch time for updated
 395   def add_emoji_tags(object) do
 396     tags = object["tag"] || []
 397     emoji = object["emoji"] || []
 398
 399     out =
 400       emoji
 401       |> Enum.map(fn {name, url} ->
 402         %{
 403           "icon" => %{"url" => url, "type" => "Image"},
 404           "name" => ":" <> name <> ":",
 405           "type" => "Emoji",
 406           "updated" => "1970-01-01T00:00:00Z",
 407           "id" => url
 408         }
 409       end)
 410
 411     object
 412     |> Map.put("tag", tags ++ out)
 413   end
 414
 415   def set_conversation(object) do
 416     Map.put(object, "conversation", object["context"])
 417   end
 418
 419   def set_sensitive(object) do
 420     tags = object["tag"] || []
 421     Map.put(object, "sensitive", "nsfw" in tags)
 422   end
 423
 424   def add_attributed_to(object) do
 425     attributedTo = object["attributedTo"] || object["actor"]
 426
 427     object
 428     |> Map.put("attributedTo", attributedTo)
 429   end
 430
 431   def prepare_attachments(object) do
 432     attachments =
 433       (object["attachment"] || [])
 434       |> Enum.map(fn data ->
 435         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 436         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 437       end)
 438
 439     object
 440     |> Map.put("attachment", attachments)
 441   end
 442
 443   defp user_upgrade_task(user) do
 444     old_follower_address = User.ap_followers(user)
 445
 446     q =
 447       from(
 448         u in User,
 449         where: ^old_follower_address in u.following,
 450         update: [
 451           set: [
 452             following:
 453               fragment(
 454                 "array_replace(?,?,?)",
 455                 u.following,
 456                 ^old_follower_address,
 457                 ^user.follower_address
 458               )
 459           ]
 460         ]
 461       )
 462
 463     Repo.update_all(q, [])
 464
 465     maybe_retire_websub(user.ap_id)
 466
 467     # Only do this for recent activties, don't go through the whole db.
 468     # Only look at the last 1000 activities.
 469     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 470
 471     q =
 472       from(
 473         a in Activity,
 474         where: ^old_follower_address in a.recipients,
 475         where: a.id > ^since,
 476         update: [
 477           set: [
 478             recipients:
 479               fragment(
 480                 "array_replace(?,?,?)",
 481                 a.recipients,
 482                 ^old_follower_address,
 483                 ^user.follower_address
 484               )
 485           ]
 486         ]
 487       )
 488
 489     Repo.update_all(q, [])
 490   end
 491
 492   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 493     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 494          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 495       data =
 496         data
 497         |> Map.put(:info, Map.merge(user.info, data[:info]))
 498
 499       already_ap = User.ap_enabled?(user)
 500
 501       {:ok, user} =
 502         User.upgrade_changeset(user, data)
 503         |> Repo.update()
 504
 505       if !already_ap do
 506         # This could potentially take a long time, do it in the background
 507         if async do
 508           Task.start(fn ->
 509             user_upgrade_task(user)
 510           end)
 511         else
 512           user_upgrade_task(user)
 513         end
 514       end
 515
 516       {:ok, user}
 517     else
 518       e -> e
 519     end
 520   end
 521
 522   def maybe_retire_websub(ap_id) do
 523     # some sanity checks
 524     if is_binary(ap_id) && String.length(ap_id) > 8 do
 525       q =
 526         from(
 527           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 528           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 529         )
 530
 531       Repo.delete_all(q)
 532     end
 533   end
 534 end