git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.EarmarkRenderer
  11   alias Pleroma.FollowingRelationship
  12   alias Pleroma.Object
  13   alias Pleroma.Object.Containment
  14   alias Pleroma.Repo
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ActivityPub
  17   alias Pleroma.Web.ActivityPub.ObjectValidator
  18   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  19   alias Pleroma.Web.ActivityPub.Pipeline
  20   alias Pleroma.Web.ActivityPub.Utils
  21   alias Pleroma.Web.ActivityPub.Visibility
  22   alias Pleroma.Web.Federator
  23   alias Pleroma.Workers.TransmogrifierWorker
  24
  25   import Ecto.Query
  26
  27   require Logger
  28   require Pleroma.Constants
  29
  30   @doc """
  31   Modifies an incoming AP object (mastodon format) to our internal format.
  32   """
  33   def fix_object(object, options \\ []) do
  34     object
  35     |> strip_internal_fields
  36     |> fix_actor
  37     |> fix_url
  38     |> fix_attachments
  39     |> fix_context
  40     |> fix_in_reply_to(options)
  41     |> fix_emoji
  42     |> fix_tag
  43     |> fix_content_map
  44     |> fix_addressing
  45     |> fix_summary
  46     |> fix_type(options)
  47     |> fix_content
  48   end
  49
  50   def fix_summary(%{"summary" => nil} = object) do
  51     Map.put(object, "summary", "")
  52   end
  53
  54   def fix_summary(%{"summary" => _} = object) do
  55     # summary is present, nothing to do
  56     object
  57   end
  58
  59   def fix_summary(object), do: Map.put(object, "summary", "")
  60
  61   def fix_addressing_list(map, field) do
  62     cond do
  63       is_binary(map[field]) ->
  64         Map.put(map, field, [map[field]])
  65
  66       is_nil(map[field]) ->
  67         Map.put(map, field, [])
  68
  69       true ->
  70         map
  71     end
  72   end
  73
  74   def fix_explicit_addressing(
  75         %{"to" => to, "cc" => cc} = object,
  76         explicit_mentions,
  77         follower_collection
  78       ) do
  79     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  80
  81     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  82
  83     final_cc =
  84       (cc ++ explicit_cc)
  85       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  86       |> Enum.uniq()
  87
  88     object
  89     |> Map.put("to", explicit_to)
  90     |> Map.put("cc", final_cc)
  91   end
  92
  93   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  94
  95   # if directMessage flag is set to true, leave the addressing alone
  96   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  97
  98   def fix_explicit_addressing(object) do
  99     explicit_mentions = Utils.determine_explicit_mentions(object)
 100
 101     %User{follower_address: follower_collection} =
 102       object
 103       |> Containment.get_actor()
 104       |> User.get_cached_by_ap_id()
 105
 106     explicit_mentions =
 107       explicit_mentions ++
 108         [
 109           Pleroma.Constants.as_public(),
 110           follower_collection
 111         ]
 112
 113     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 114   end
 115
 116   # if as:Public is addressed, then make sure the followers collection is also addressed
 117   # so that the activities will be delivered to local users.
 118   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 119     recipients = to ++ cc
 120
 121     if followers_collection not in recipients do
 122       cond do
 123         Pleroma.Constants.as_public() in cc ->
 124           to = to ++ [followers_collection]
 125           Map.put(object, "to", to)
 126
 127         Pleroma.Constants.as_public() in to ->
 128           cc = cc ++ [followers_collection]
 129           Map.put(object, "cc", cc)
 130
 131         true ->
 132           object
 133       end
 134     else
 135       object
 136     end
 137   end
 138
 139   def fix_implicit_addressing(object, _), do: object
 140
 141   def fix_addressing(object) do
 142     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 143     followers_collection = User.ap_followers(user)
 144
 145     object
 146     |> fix_addressing_list("to")
 147     |> fix_addressing_list("cc")
 148     |> fix_addressing_list("bto")
 149     |> fix_addressing_list("bcc")
 150     |> fix_explicit_addressing()
 151     |> fix_implicit_addressing(followers_collection)
 152   end
 153
 154   def fix_actor(%{"attributedTo" => actor} = object) do
 155     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 156   end
 157
 158   def fix_in_reply_to(object, options \\ [])
 159
 160   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 161       when not is_nil(in_reply_to) do
 162     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 163     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 164     depth = (options[:depth] || 0) + 1
 165
 166     if Federator.allowed_thread_distance?(depth) do
 167       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 168            %Activity{} <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 169         object
 170         |> Map.put("inReplyTo", replied_object.data["id"])
 171         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 172         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 173         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 174       else
 175         e ->
 176           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 177           object
 178       end
 179     else
 180       object
 181     end
 182   end
 183
 184   def fix_in_reply_to(object, _options), do: object
 185
 186   defp prepare_in_reply_to(in_reply_to) do
 187     cond do
 188       is_bitstring(in_reply_to) ->
 189         in_reply_to
 190
 191       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 192         in_reply_to["id"]
 193
 194       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 195         Enum.at(in_reply_to, 0)
 196
 197       true ->
 198         ""
 199     end
 200   end
 201
 202   def fix_context(object) do
 203     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 204
 205     object
 206     |> Map.put("context", context)
 207     |> Map.put("conversation", context)
 208   end
 209
 210   defp add_if_present(map, _key, nil), do: map
 211
 212   defp add_if_present(map, key, value) do
 213     Map.put(map, key, value)
 214   end
 215
 216   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 217     attachments =
 218       Enum.map(attachment, fn data ->
 219         url =
 220           cond do
 221             is_list(data["url"]) -> List.first(data["url"])
 222             is_map(data["url"]) -> data["url"]
 223             true -> nil
 224           end
 225
 226         media_type =
 227           cond do
 228             is_map(url) && is_binary(url["mediaType"]) -> url["mediaType"]
 229             is_binary(data["mediaType"]) -> data["mediaType"]
 230             is_binary(data["mimeType"]) -> data["mimeType"]
 231             true -> nil
 232           end
 233
 234         href =
 235           cond do
 236             is_map(url) && is_binary(url["href"]) -> url["href"]
 237             is_binary(data["url"]) -> data["url"]
 238             is_binary(data["href"]) -> data["href"]
 239           end
 240
 241         attachment_url =
 242           %{"href" => href}
 243           |> add_if_present("mediaType", media_type)
 244           |> add_if_present("type", Map.get(url || %{}, "type"))
 245
 246         %{"url" => [attachment_url]}
 247         |> add_if_present("mediaType", media_type)
 248         |> add_if_present("type", data["type"])
 249         |> add_if_present("name", data["name"])
 250       end)
 251
 252     Map.put(object, "attachment", attachments)
 253   end
 254
 255   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 256     object
 257     |> Map.put("attachment", [attachment])
 258     |> fix_attachments()
 259   end
 260
 261   def fix_attachments(object), do: object
 262
 263   def fix_url(%{"url" => url} = object) when is_map(url) do
 264     Map.put(object, "url", url["href"])
 265   end
 266
 267   def fix_url(%{"type" => object_type, "url" => url} = object)
 268       when object_type in ["Video", "Audio"] and is_list(url) do
 269     first_element = Enum.at(url, 0)
 270
 271     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 272
 273     object
 274     |> Map.put("attachment", [first_element])
 275     |> Map.put("url", link_element["href"])
 276   end
 277
 278   def fix_url(%{"type" => object_type, "url" => url} = object)
 279       when object_type != "Video" and is_list(url) do
 280     first_element = Enum.at(url, 0)
 281
 282     url_string =
 283       cond do
 284         is_bitstring(first_element) -> first_element
 285         is_map(first_element) -> first_element["href"] || ""
 286         true -> ""
 287       end
 288
 289     Map.put(object, "url", url_string)
 290   end
 291
 292   def fix_url(object), do: object
 293
 294   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 295     emoji =
 296       tags
 297       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 298       |> Enum.reduce(%{}, fn data, mapping ->
 299         name = String.trim(data["name"], ":")
 300
 301         Map.put(mapping, name, data["icon"]["url"])
 302       end)
 303
 304     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 305     emoji = Map.merge(object["emoji"] || %{}, emoji)
 306
 307     Map.put(object, "emoji", emoji)
 308   end
 309
 310   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 311     name = String.trim(tag["name"], ":")
 312     emoji = %{name => tag["icon"]["url"]}
 313
 314     Map.put(object, "emoji", emoji)
 315   end
 316
 317   def fix_emoji(object), do: object
 318
 319   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 320     tags =
 321       tag
 322       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 323       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 324
 325     Map.put(object, "tag", tag ++ tags)
 326   end
 327
 328   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 329     combined = [tag, String.slice(hashtag, 1..-1)]
 330
 331     Map.put(object, "tag", combined)
 332   end
 333
 334   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 335
 336   def fix_tag(object), do: object
 337
 338   # content map usually only has one language so this will do for now.
 339   def fix_content_map(%{"contentMap" => content_map} = object) do
 340     content_groups = Map.to_list(content_map)
 341     {_, content} = Enum.at(content_groups, 0)
 342
 343     Map.put(object, "content", content)
 344   end
 345
 346   def fix_content_map(object), do: object
 347
 348   def fix_type(object, options \\ [])
 349
 350   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 351       when is_binary(reply_id) do
 352     with true <- Federator.allowed_thread_distance?(options[:depth]),
 353          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 354       Map.put(object, "type", "Answer")
 355     else
 356       _ -> object
 357     end
 358   end
 359
 360   def fix_type(object, _), do: object
 361
 362   defp fix_content(%{"mediaType" => "text/markdown", "content" => content} = object)
 363        when is_binary(content) do
 364     html_content =
 365       content
 366       |> Earmark.as_html!(%Earmark.Options{renderer: EarmarkRenderer})
 367       |> Pleroma.HTML.filter_tags()
 368
 369     Map.merge(object, %{"content" => html_content, "mediaType" => "text/html"})
 370   end
 371
 372   defp fix_content(object), do: object
 373
 374   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 375     with true <- id =~ "follows",
 376          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 377          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 378       {:ok, activity}
 379     else
 380       _ -> {:error, nil}
 381     end
 382   end
 383
 384   defp mastodon_follow_hack(_, _), do: {:error, nil}
 385
 386   defp get_follow_activity(follow_object, followed) do
 387     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 388          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 389       {:ok, activity}
 390     else
 391       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 392       {:activity, nil} ->
 393         mastodon_follow_hack(follow_object, followed)
 394
 395       _ ->
 396         {:error, nil}
 397     end
 398   end
 399
 400   # Reduce the object list to find the reported user.
 401   defp get_reported(objects) do
 402     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 403       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 404         {:halt, user}
 405       else
 406         _ -> {:cont, nil}
 407       end
 408     end)
 409   end
 410
 411   def handle_incoming(data, options \\ [])
 412
 413   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 414   # with nil ID.
 415   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 416     with context <- data["context"] || Utils.generate_context_id(),
 417          content <- data["content"] || "",
 418          %User{} = actor <- User.get_cached_by_ap_id(actor),
 419          # Reduce the object list to find the reported user.
 420          %User{} = account <- get_reported(objects),
 421          # Remove the reported user from the object list.
 422          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 423       %{
 424         actor: actor,
 425         context: context,
 426         account: account,
 427         statuses: statuses,
 428         content: content,
 429         additional: %{"cc" => [account.ap_id]}
 430       }
 431       |> ActivityPub.flag()
 432     end
 433   end
 434
 435   # disallow objects with bogus IDs
 436   def handle_incoming(%{"id" => nil}, _options), do: :error
 437   def handle_incoming(%{"id" => ""}, _options), do: :error
 438   # length of https:// = 8, should validate better, but good enough for now.
 439   def handle_incoming(%{"id" => id}, _options) when is_binary(id) and byte_size(id) < 8,
 440     do: :error
 441
 442   # TODO: validate those with a Ecto scheme
 443   # - tags
 444   # - emoji
 445   def handle_incoming(
 446         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 447         options
 448       )
 449       when objtype in ["Article", "Event", "Note", "Video", "Page", "Question", "Answer", "Audio"] do
 450     actor = Containment.get_actor(data)
 451
 452     data =
 453       Map.put(data, "actor", actor)
 454       |> fix_addressing
 455
 456     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 457          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 458       object = fix_object(object, options)
 459
 460       params = %{
 461         to: data["to"],
 462         object: object,
 463         actor: user,
 464         context: object["conversation"],
 465         local: false,
 466         published: data["published"],
 467         additional:
 468           Map.take(data, [
 469             "cc",
 470             "directMessage",
 471             "id"
 472           ])
 473       }
 474
 475       with {:ok, created_activity} <- ActivityPub.create(params) do
 476         reply_depth = (options[:depth] || 0) + 1
 477
 478         if Federator.allowed_thread_distance?(reply_depth) do
 479           for reply_id <- replies(object) do
 480             Pleroma.Workers.RemoteFetcherWorker.enqueue("fetch_remote", %{
 481               "id" => reply_id,
 482               "depth" => reply_depth
 483             })
 484           end
 485         end
 486
 487         {:ok, created_activity}
 488       end
 489     else
 490       %Activity{} = activity -> {:ok, activity}
 491       _e -> :error
 492     end
 493   end
 494
 495   def handle_incoming(
 496         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 497         options
 498       ) do
 499     actor = Containment.get_actor(data)
 500
 501     data =
 502       Map.put(data, "actor", actor)
 503       |> fix_addressing
 504
 505     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 506       reply_depth = (options[:depth] || 0) + 1
 507       options = Keyword.put(options, :depth, reply_depth)
 508       object = fix_object(object, options)
 509
 510       params = %{
 511         to: data["to"],
 512         object: object,
 513         actor: user,
 514         context: nil,
 515         local: false,
 516         published: data["published"],
 517         additional: Map.take(data, ["cc", "id"])
 518       }
 519
 520       ActivityPub.listen(params)
 521     else
 522       _e -> :error
 523     end
 524   end
 525
 526   def handle_incoming(
 527         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 528         _options
 529       ) do
 530     with %User{local: true} = followed <-
 531            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 532          {:ok, %User{} = follower} <-
 533            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 534          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 535       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 536            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 537            {_, false} <- {:user_locked, User.locked?(followed)},
 538            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 539            {_, {:ok, _}} <-
 540              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 541            {:ok, _relationship} <-
 542              FollowingRelationship.update(follower, followed, :follow_accept) do
 543         ActivityPub.accept(%{
 544           to: [follower.ap_id],
 545           actor: followed,
 546           object: data,
 547           local: true
 548         })
 549       else
 550         {:user_blocked, true} ->
 551           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 552           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 553
 554           ActivityPub.reject(%{
 555             to: [follower.ap_id],
 556             actor: followed,
 557             object: data,
 558             local: true
 559           })
 560
 561         {:follow, {:error, _}} ->
 562           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 563           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 564
 565           ActivityPub.reject(%{
 566             to: [follower.ap_id],
 567             actor: followed,
 568             object: data,
 569             local: true
 570           })
 571
 572         {:user_locked, true} ->
 573           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_pending)
 574           :noop
 575       end
 576
 577       {:ok, activity}
 578     else
 579       _e ->
 580         :error
 581     end
 582   end
 583
 584   def handle_incoming(
 585         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 586         _options
 587       ) do
 588     with actor <- Containment.get_actor(data),
 589          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 590          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 591          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 592          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 593          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_accept) do
 594       ActivityPub.accept(%{
 595         to: follow_activity.data["to"],
 596         type: "Accept",
 597         actor: followed,
 598         object: follow_activity.data["id"],
 599         local: false,
 600         activity_id: id
 601       })
 602     else
 603       _e -> :error
 604     end
 605   end
 606
 607   def handle_incoming(
 608         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 609         _options
 610       ) do
 611     with actor <- Containment.get_actor(data),
 612          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 613          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 614          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 615          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 616          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_reject),
 617          {:ok, activity} <-
 618            ActivityPub.reject(%{
 619              to: follow_activity.data["to"],
 620              type: "Reject",
 621              actor: followed,
 622              object: follow_activity.data["id"],
 623              local: false,
 624              activity_id: id
 625            }) do
 626       {:ok, activity}
 627     else
 628       _e -> :error
 629     end
 630   end
 631
 632   @misskey_reactions %{
 633     "like" => "👍",
 634     "love" => "❤️",
 635     "laugh" => "😆",
 636     "hmm" => "🤔",
 637     "surprise" => "😮",
 638     "congrats" => "🎉",
 639     "angry" => "💢",
 640     "confused" => "😥",
 641     "rip" => "😇",
 642     "pudding" => "🍮",
 643     "star" => "⭐"
 644   }
 645
 646   @doc "Rewrite misskey likes into EmojiReacts"
 647   def handle_incoming(
 648         %{
 649           "type" => "Like",
 650           "_misskey_reaction" => reaction
 651         } = data,
 652         options
 653       ) do
 654     data
 655     |> Map.put("type", "EmojiReact")
 656     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 657     |> handle_incoming(options)
 658   end
 659
 660   def handle_incoming(%{"type" => "Like"} = data, _options) do
 661     with {_, {:ok, cast_data_sym}} <-
 662            {:casting_data,
 663             data |> LikeValidator.cast_data() |> Ecto.Changeset.apply_action(:insert)},
 664          cast_data = ObjectValidator.stringify_keys(Map.from_struct(cast_data_sym)),
 665          :ok <- ObjectValidator.fetch_actor_and_object(cast_data),
 666          {_, {:ok, cast_data}} <- {:ensure_context_presence, ensure_context_presence(cast_data)},
 667          {_, {:ok, cast_data}} <-
 668            {:ensure_recipients_presence, ensure_recipients_presence(cast_data)},
 669          {_, {:ok, activity, _meta}} <-
 670            {:common_pipeline, Pipeline.common_pipeline(cast_data, local: false)} do
 671       {:ok, activity}
 672     else
 673       e -> {:error, e}
 674     end
 675   end
 676
 677   def handle_incoming(
 678         %{
 679           "type" => "EmojiReact",
 680           "object" => object_id,
 681           "actor" => _actor,
 682           "id" => id,
 683           "content" => emoji
 684         } = data,
 685         _options
 686       ) do
 687     with actor <- Containment.get_actor(data),
 688          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 689          {:ok, object} <- get_obj_helper(object_id),
 690          {:ok, activity, _object} <-
 691            ActivityPub.react_with_emoji(actor, object, emoji, activity_id: id, local: false) do
 692       {:ok, activity}
 693     else
 694       _e -> :error
 695     end
 696   end
 697
 698   def handle_incoming(
 699         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 700         _options
 701       ) do
 702     with actor <- Containment.get_actor(data),
 703          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 704          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 705          public <- Visibility.is_public?(data),
 706          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 707       {:ok, activity}
 708     else
 709       _e -> :error
 710     end
 711   end
 712
 713   def handle_incoming(
 714         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 715           data,
 716         _options
 717       )
 718       when object_type in [
 719              "Person",
 720              "Application",
 721              "Service",
 722              "Organization"
 723            ] do
 724     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 725       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 726
 727       actor
 728       |> User.remote_user_changeset(new_user_data)
 729       |> User.update_and_set_cache()
 730
 731       ActivityPub.update(%{
 732         local: false,
 733         to: data["to"] || [],
 734         cc: data["cc"] || [],
 735         object: object,
 736         actor: actor_id,
 737         activity_id: data["id"]
 738       })
 739     else
 740       e ->
 741         Logger.error(e)
 742         :error
 743     end
 744   end
 745
 746   # TODO: We presently assume that any actor on the same origin domain as the object being
 747   # deleted has the rights to delete that object.  A better way to validate whether or not
 748   # the object should be deleted is to refetch the object URI, which should return either
 749   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 750   # place.
 751   def handle_incoming(
 752         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 753         _options
 754       ) do
 755     object_id = Utils.get_ap_id(object_id)
 756
 757     with actor <- Containment.get_actor(data),
 758          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 759          {:ok, object} <- get_obj_helper(object_id),
 760          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 761          {:ok, activity} <-
 762            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 763       {:ok, activity}
 764     else
 765       nil ->
 766         case User.get_cached_by_ap_id(object_id) do
 767           %User{ap_id: ^actor} = user ->
 768             User.delete(user)
 769
 770           nil ->
 771             :error
 772         end
 773
 774       _e ->
 775         :error
 776     end
 777   end
 778
 779   def handle_incoming(
 780         %{
 781           "type" => "Undo",
 782           "object" => %{"type" => "Announce", "object" => object_id},
 783           "actor" => _actor,
 784           "id" => id
 785         } = data,
 786         _options
 787       ) do
 788     with actor <- Containment.get_actor(data),
 789          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 790          {:ok, object} <- get_obj_helper(object_id),
 791          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 792       {:ok, activity}
 793     else
 794       _e -> :error
 795     end
 796   end
 797
 798   def handle_incoming(
 799         %{
 800           "type" => "Undo",
 801           "object" => %{"type" => "Follow", "object" => followed},
 802           "actor" => follower,
 803           "id" => id
 804         } = _data,
 805         _options
 806       ) do
 807     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 808          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 809          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 810       User.unfollow(follower, followed)
 811       {:ok, activity}
 812     else
 813       _e -> :error
 814     end
 815   end
 816
 817   def handle_incoming(
 818         %{
 819           "type" => "Undo",
 820           "object" => %{"type" => "EmojiReact", "id" => reaction_activity_id},
 821           "actor" => _actor,
 822           "id" => id
 823         } = data,
 824         _options
 825       ) do
 826     with actor <- Containment.get_actor(data),
 827          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 828          {:ok, activity, _} <-
 829            ActivityPub.unreact_with_emoji(actor, reaction_activity_id,
 830              activity_id: id,
 831              local: false
 832            ) do
 833       {:ok, activity}
 834     else
 835       _e -> :error
 836     end
 837   end
 838
 839   def handle_incoming(
 840         %{
 841           "type" => "Undo",
 842           "object" => %{"type" => "Block", "object" => blocked},
 843           "actor" => blocker,
 844           "id" => id
 845         } = _data,
 846         _options
 847       ) do
 848     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 849          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 850          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 851       User.unblock(blocker, blocked)
 852       {:ok, activity}
 853     else
 854       _e -> :error
 855     end
 856   end
 857
 858   def handle_incoming(
 859         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 860         _options
 861       ) do
 862     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 863          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 864          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 865       User.unfollow(blocker, blocked)
 866       User.block(blocker, blocked)
 867       {:ok, activity}
 868     else
 869       _e -> :error
 870     end
 871   end
 872
 873   def handle_incoming(
 874         %{
 875           "type" => "Undo",
 876           "object" => %{"type" => "Like", "object" => object_id},
 877           "actor" => _actor,
 878           "id" => id
 879         } = data,
 880         _options
 881       ) do
 882     with actor <- Containment.get_actor(data),
 883          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 884          {:ok, object} <- get_obj_helper(object_id),
 885          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 886       {:ok, activity}
 887     else
 888       _e -> :error
 889     end
 890   end
 891
 892   # For Undos that don't have the complete object attached, try to find it in our database.
 893   def handle_incoming(
 894         %{
 895           "type" => "Undo",
 896           "object" => object
 897         } = activity,
 898         options
 899       )
 900       when is_binary(object) do
 901     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 902       activity
 903       |> Map.put("object", data)
 904       |> handle_incoming(options)
 905     else
 906       _e -> :error
 907     end
 908   end
 909
 910   def handle_incoming(
 911         %{
 912           "type" => "Move",
 913           "actor" => origin_actor,
 914           "object" => origin_actor,
 915           "target" => target_actor
 916         },
 917         _options
 918       ) do
 919     with %User{} = origin_user <- User.get_cached_by_ap_id(origin_actor),
 920          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_actor),
 921          true <- origin_actor in target_user.also_known_as do
 922       ActivityPub.move(origin_user, target_user, false)
 923     else
 924       _e -> :error
 925     end
 926   end
 927
 928   def handle_incoming(_, _), do: :error
 929
 930   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 931   def get_obj_helper(id, options \\ []) do
 932     case Object.normalize(id, true, options) do
 933       %Object{} = object -> {:ok, object}
 934       _ -> nil
 935     end
 936   end
 937
 938   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 939   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 940         ap_id: ap_id
 941       })
 942       when attributed_to == ap_id do
 943     with {:ok, activity} <-
 944            handle_incoming(%{
 945              "type" => "Create",
 946              "to" => data["to"],
 947              "cc" => data["cc"],
 948              "actor" => attributed_to,
 949              "object" => data
 950            }) do
 951       {:ok, Object.normalize(activity)}
 952     else
 953       _ -> get_obj_helper(object_id)
 954     end
 955   end
 956
 957   def get_embedded_obj_helper(object_id, _) do
 958     get_obj_helper(object_id)
 959   end
 960
 961   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 962     with false <- String.starts_with?(in_reply_to, "http"),
 963          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 964       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 965     else
 966       _e -> object
 967     end
 968   end
 969
 970   def set_reply_to_uri(obj), do: obj
 971
 972   @doc """
 973   Serialized Mastodon-compatible `replies` collection containing _self-replies_.
 974   Based on Mastodon's ActivityPub::NoteSerializer#replies.
 975   """
 976   def set_replies(obj_data) do
 977     replies_uris =
 978       with limit when limit > 0 <-
 979              Pleroma.Config.get([:activitypub, :note_replies_output_limit], 0),
 980            %Object{} = object <- Object.get_cached_by_ap_id(obj_data["id"]) do
 981         object
 982         |> Object.self_replies()
 983         |> select([o], fragment("?->>'id'", o.data))
 984         |> limit(^limit)
 985         |> Repo.all()
 986       else
 987         _ -> []
 988       end
 989
 990     set_replies(obj_data, replies_uris)
 991   end
 992
 993   defp set_replies(obj, []) do
 994     obj
 995   end
 996
 997   defp set_replies(obj, replies_uris) do
 998     replies_collection = %{
 999       "type" => "Collection",
1000       "items" => replies_uris
1001     }
1002
1003     Map.merge(obj, %{"replies" => replies_collection})
1004   end
1005
1006   def replies(%{"replies" => %{"first" => %{"items" => items}}}) when not is_nil(items) do
1007     items
1008   end
1009
1010   def replies(%{"replies" => %{"items" => items}}) when not is_nil(items) do
1011     items
1012   end
1013
1014   def replies(_), do: []
1015
1016   # Prepares the object of an outgoing create activity.
1017   def prepare_object(object) do
1018     object
1019     |> set_sensitive
1020     |> add_hashtags
1021     |> add_mention_tags
1022     |> add_emoji_tags
1023     |> add_attributed_to
1024     |> prepare_attachments
1025     |> set_conversation
1026     |> set_reply_to_uri
1027     |> set_replies
1028     |> strip_internal_fields
1029     |> strip_internal_tags
1030     |> set_type
1031   end
1032
1033   #  @doc
1034   #  """
1035   #  internal -> Mastodon
1036   #  """
1037
1038   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
1039       when activity_type in ["Create", "Listen"] do
1040     object =
1041       object_id
1042       |> Object.normalize()
1043       |> Map.get(:data)
1044       |> prepare_object
1045
1046     data =
1047       data
1048       |> Map.put("object", object)
1049       |> Map.merge(Utils.make_json_ld_header())
1050       |> Map.delete("bcc")
1051
1052     {:ok, data}
1053   end
1054
1055   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
1056     object =
1057       object_id
1058       |> Object.normalize()
1059
1060     data =
1061       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
1062         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
1063       else
1064         data |> maybe_fix_object_url
1065       end
1066
1067     data =
1068       data
1069       |> strip_internal_fields
1070       |> Map.merge(Utils.make_json_ld_header())
1071       |> Map.delete("bcc")
1072
1073     {:ok, data}
1074   end
1075
1076   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
1077   # because of course it does.
1078   def prepare_outgoing(%{"type" => "Accept"} = data) do
1079     with follow_activity <- Activity.normalize(data["object"]) do
1080       object = %{
1081         "actor" => follow_activity.actor,
1082         "object" => follow_activity.data["object"],
1083         "id" => follow_activity.data["id"],
1084         "type" => "Follow"
1085       }
1086
1087       data =
1088         data
1089         |> Map.put("object", object)
1090         |> Map.merge(Utils.make_json_ld_header())
1091
1092       {:ok, data}
1093     end
1094   end
1095
1096   def prepare_outgoing(%{"type" => "Reject"} = data) do
1097     with follow_activity <- Activity.normalize(data["object"]) do
1098       object = %{
1099         "actor" => follow_activity.actor,
1100         "object" => follow_activity.data["object"],
1101         "id" => follow_activity.data["id"],
1102         "type" => "Follow"
1103       }
1104
1105       data =
1106         data
1107         |> Map.put("object", object)
1108         |> Map.merge(Utils.make_json_ld_header())
1109
1110       {:ok, data}
1111     end
1112   end
1113
1114   def prepare_outgoing(%{"type" => _type} = data) do
1115     data =
1116       data
1117       |> strip_internal_fields
1118       |> maybe_fix_object_url
1119       |> Map.merge(Utils.make_json_ld_header())
1120
1121     {:ok, data}
1122   end
1123
1124   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
1125     with false <- String.starts_with?(object, "http"),
1126          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
1127          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
1128            relative_object do
1129       Map.put(data, "object", external_url)
1130     else
1131       {:fetch, e} ->
1132         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
1133         data
1134
1135       _ ->
1136         data
1137     end
1138   end
1139
1140   def maybe_fix_object_url(data), do: data
1141
1142   def add_hashtags(object) do
1143     tags =
1144       (object["tag"] || [])
1145       |> Enum.map(fn
1146         # Expand internal representation tags into AS2 tags.
1147         tag when is_binary(tag) ->
1148           %{
1149             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
1150             "name" => "##{tag}",
1151             "type" => "Hashtag"
1152           }
1153
1154         # Do not process tags which are already AS2 tag objects.
1155         tag when is_map(tag) ->
1156           tag
1157       end)
1158
1159     Map.put(object, "tag", tags)
1160   end
1161
1162   def add_mention_tags(object) do
1163     {enabled_receivers, disabled_receivers} = Utils.get_notified_from_object(object)
1164     potential_receivers = enabled_receivers ++ disabled_receivers
1165     mentions = Enum.map(potential_receivers, &build_mention_tag/1)
1166
1167     tags = object["tag"] || []
1168     Map.put(object, "tag", tags ++ mentions)
1169   end
1170
1171   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1172     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1173   end
1174
1175   def take_emoji_tags(%User{emoji: emoji}) do
1176     emoji
1177     |> Map.to_list()
1178     |> Enum.map(&build_emoji_tag/1)
1179   end
1180
1181   # TODO: we should probably send mtime instead of unix epoch time for updated
1182   def add_emoji_tags(%{"emoji" => emoji} = object) do
1183     tags = object["tag"] || []
1184
1185     out = Enum.map(emoji, &build_emoji_tag/1)
1186
1187     Map.put(object, "tag", tags ++ out)
1188   end
1189
1190   def add_emoji_tags(object), do: object
1191
1192   defp build_emoji_tag({name, url}) do
1193     %{
1194       "icon" => %{"url" => url, "type" => "Image"},
1195       "name" => ":" <> name <> ":",
1196       "type" => "Emoji",
1197       "updated" => "1970-01-01T00:00:00Z",
1198       "id" => url
1199     }
1200   end
1201
1202   def set_conversation(object) do
1203     Map.put(object, "conversation", object["context"])
1204   end
1205
1206   def set_sensitive(object) do
1207     tags = object["tag"] || []
1208     Map.put(object, "sensitive", "nsfw" in tags)
1209   end
1210
1211   def set_type(%{"type" => "Answer"} = object) do
1212     Map.put(object, "type", "Note")
1213   end
1214
1215   def set_type(object), do: object
1216
1217   def add_attributed_to(object) do
1218     attributed_to = object["attributedTo"] || object["actor"]
1219     Map.put(object, "attributedTo", attributed_to)
1220   end
1221
1222   def prepare_attachments(object) do
1223     attachments =
1224       object
1225       |> Map.get("attachment", [])
1226       |> Enum.map(fn data ->
1227         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1228
1229         %{
1230           "url" => href,
1231           "mediaType" => media_type,
1232           "name" => data["name"],
1233           "type" => "Document"
1234         }
1235       end)
1236
1237     Map.put(object, "attachment", attachments)
1238   end
1239
1240   def strip_internal_fields(object) do
1241     Map.drop(object, Pleroma.Constants.object_internal_fields())
1242   end
1243
1244   defp strip_internal_tags(%{"tag" => tags} = object) do
1245     tags = Enum.filter(tags, fn x -> is_map(x) end)
1246
1247     Map.put(object, "tag", tags)
1248   end
1249
1250   defp strip_internal_tags(object), do: object
1251
1252   def perform(:user_upgrade, user) do
1253     # we pass a fake user so that the followers collection is stripped away
1254     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1255
1256     from(
1257       a in Activity,
1258       where: ^old_follower_address in a.recipients,
1259       update: [
1260         set: [
1261           recipients:
1262             fragment(
1263               "array_replace(?,?,?)",
1264               a.recipients,
1265               ^old_follower_address,
1266               ^user.follower_address
1267             )
1268         ]
1269       ]
1270     )
1271     |> Repo.update_all([])
1272   end
1273
1274   def upgrade_user_from_ap_id(ap_id) do
1275     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1276          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1277          {:ok, user} <- update_user(user, data) do
1278       TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1279       {:ok, user}
1280     else
1281       %User{} = user -> {:ok, user}
1282       e -> e
1283     end
1284   end
1285
1286   defp update_user(user, data) do
1287     user
1288     |> User.remote_user_changeset(data)
1289     |> User.update_and_set_cache()
1290   end
1291
1292   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1293     Map.put(data, "url", url["href"])
1294   end
1295
1296   def maybe_fix_user_url(data), do: data
1297
1298   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1299
1300   defp ensure_context_presence(%{"context" => context} = data) when is_binary(context),
1301     do: {:ok, data}
1302
1303   defp ensure_context_presence(%{"object" => object} = data) when is_binary(object) do
1304     with %{data: %{"context" => context}} when is_binary(context) <- Object.normalize(object) do
1305       {:ok, Map.put(data, "context", context)}
1306     else
1307       _ ->
1308         {:error, :no_context}
1309     end
1310   end
1311
1312   defp ensure_context_presence(_) do
1313     {:error, :no_context}
1314   end
1315
1316   defp ensure_recipients_presence(%{"to" => [_ | _], "cc" => [_ | _]} = data),
1317     do: {:ok, data}
1318
1319   defp ensure_recipients_presence(%{"object" => object} = data) do
1320     case Object.normalize(object) do
1321       %{data: %{"actor" => actor}} ->
1322         data =
1323           data
1324           |> Map.put("to", [actor])
1325           |> Map.put("cc", data["cc"] || [])
1326
1327         {:ok, data}
1328
1329       nil ->
1330         {:error, :no_object}
1331
1332       _ ->
1333         {:error, :no_actor}
1334     end
1335   end
1336
1337   defp ensure_recipients_presence(_) do
1338     {:error, :no_object}
1339   end
1340 end