git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.Object
  12   alias Pleroma.Object.Containment
  13   alias Pleroma.Repo
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16   alias Pleroma.Web.ActivityPub.ObjectValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  18   alias Pleroma.Web.ActivityPub.Pipeline
  19   alias Pleroma.Web.ActivityPub.Utils
  20   alias Pleroma.Web.ActivityPub.Visibility
  21   alias Pleroma.Web.Federator
  22   alias Pleroma.Workers.TransmogrifierWorker
  23
  24   import Ecto.Query
  25
  26   require Logger
  27   require Pleroma.Constants
  28
  29   @doc """
  30   Modifies an incoming AP object (mastodon format) to our internal format.
  31   """
  32   def fix_object(object, options \\ []) do
  33     object
  34     |> strip_internal_fields
  35     |> fix_actor
  36     |> fix_url
  37     |> fix_attachments
  38     |> fix_context
  39     |> fix_in_reply_to(options)
  40     |> fix_emoji
  41     |> fix_tag
  42     |> fix_content_map
  43     |> fix_addressing
  44     |> fix_summary
  45     |> fix_type(options)
  46   end
  47
  48   def fix_summary(%{"summary" => nil} = object) do
  49     Map.put(object, "summary", "")
  50   end
  51
  52   def fix_summary(%{"summary" => _} = object) do
  53     # summary is present, nothing to do
  54     object
  55   end
  56
  57   def fix_summary(object), do: Map.put(object, "summary", "")
  58
  59   def fix_addressing_list(map, field) do
  60     cond do
  61       is_binary(map[field]) ->
  62         Map.put(map, field, [map[field]])
  63
  64       is_nil(map[field]) ->
  65         Map.put(map, field, [])
  66
  67       true ->
  68         map
  69     end
  70   end
  71
  72   def fix_explicit_addressing(
  73         %{"to" => to, "cc" => cc} = object,
  74         explicit_mentions,
  75         follower_collection
  76       ) do
  77     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  78
  79     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  80
  81     final_cc =
  82       (cc ++ explicit_cc)
  83       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  84       |> Enum.uniq()
  85
  86     object
  87     |> Map.put("to", explicit_to)
  88     |> Map.put("cc", final_cc)
  89   end
  90
  91   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  92
  93   # if directMessage flag is set to true, leave the addressing alone
  94   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  95
  96   def fix_explicit_addressing(object) do
  97     explicit_mentions = Utils.determine_explicit_mentions(object)
  98
  99     %User{follower_address: follower_collection} =
 100       object
 101       |> Containment.get_actor()
 102       |> User.get_cached_by_ap_id()
 103
 104     explicit_mentions =
 105       explicit_mentions ++
 106         [
 107           Pleroma.Constants.as_public(),
 108           follower_collection
 109         ]
 110
 111     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 112   end
 113
 114   # if as:Public is addressed, then make sure the followers collection is also addressed
 115   # so that the activities will be delivered to local users.
 116   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 117     recipients = to ++ cc
 118
 119     if followers_collection not in recipients do
 120       cond do
 121         Pleroma.Constants.as_public() in cc ->
 122           to = to ++ [followers_collection]
 123           Map.put(object, "to", to)
 124
 125         Pleroma.Constants.as_public() in to ->
 126           cc = cc ++ [followers_collection]
 127           Map.put(object, "cc", cc)
 128
 129         true ->
 130           object
 131       end
 132     else
 133       object
 134     end
 135   end
 136
 137   def fix_implicit_addressing(object, _), do: object
 138
 139   def fix_addressing(object) do
 140     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 141     followers_collection = User.ap_followers(user)
 142
 143     object
 144     |> fix_addressing_list("to")
 145     |> fix_addressing_list("cc")
 146     |> fix_addressing_list("bto")
 147     |> fix_addressing_list("bcc")
 148     |> fix_explicit_addressing()
 149     |> fix_implicit_addressing(followers_collection)
 150   end
 151
 152   def fix_actor(%{"attributedTo" => actor} = object) do
 153     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 154   end
 155
 156   def fix_in_reply_to(object, options \\ [])
 157
 158   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 159       when not is_nil(in_reply_to) do
 160     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 161     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 162
 163     if Federator.allowed_incoming_reply_depth?(options[:depth]) do
 164       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 165            %Activity{} = _ <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 166         object
 167         |> Map.put("inReplyTo", replied_object.data["id"])
 168         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 169         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 170         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 171       else
 172         e ->
 173           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 174           object
 175       end
 176     else
 177       object
 178     end
 179   end
 180
 181   def fix_in_reply_to(object, _options), do: object
 182
 183   defp prepare_in_reply_to(in_reply_to) do
 184     cond do
 185       is_bitstring(in_reply_to) ->
 186         in_reply_to
 187
 188       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 189         in_reply_to["id"]
 190
 191       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 192         Enum.at(in_reply_to, 0)
 193
 194       true ->
 195         ""
 196     end
 197   end
 198
 199   def fix_context(object) do
 200     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 201
 202     object
 203     |> Map.put("context", context)
 204     |> Map.put("conversation", context)
 205   end
 206
 207   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 208     attachments =
 209       Enum.map(attachment, fn data ->
 210         media_type = data["mediaType"] || data["mimeType"]
 211         href = data["url"] || data["href"]
 212         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 213
 214         data
 215         |> Map.put("mediaType", media_type)
 216         |> Map.put("url", url)
 217       end)
 218
 219     Map.put(object, "attachment", attachments)
 220   end
 221
 222   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 223     object
 224     |> Map.put("attachment", [attachment])
 225     |> fix_attachments()
 226   end
 227
 228   def fix_attachments(object), do: object
 229
 230   def fix_url(%{"url" => url} = object) when is_map(url) do
 231     Map.put(object, "url", url["href"])
 232   end
 233
 234   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 235     first_element = Enum.at(url, 0)
 236
 237     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 238
 239     object
 240     |> Map.put("attachment", [first_element])
 241     |> Map.put("url", link_element["href"])
 242   end
 243
 244   def fix_url(%{"type" => object_type, "url" => url} = object)
 245       when object_type != "Video" and is_list(url) do
 246     first_element = Enum.at(url, 0)
 247
 248     url_string =
 249       cond do
 250         is_bitstring(first_element) -> first_element
 251         is_map(first_element) -> first_element["href"] || ""
 252         true -> ""
 253       end
 254
 255     Map.put(object, "url", url_string)
 256   end
 257
 258   def fix_url(object), do: object
 259
 260   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 261     emoji =
 262       tags
 263       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 264       |> Enum.reduce(%{}, fn data, mapping ->
 265         name = String.trim(data["name"], ":")
 266
 267         Map.put(mapping, name, data["icon"]["url"])
 268       end)
 269
 270     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 271     emoji = Map.merge(object["emoji"] || %{}, emoji)
 272
 273     Map.put(object, "emoji", emoji)
 274   end
 275
 276   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 277     name = String.trim(tag["name"], ":")
 278     emoji = %{name => tag["icon"]["url"]}
 279
 280     Map.put(object, "emoji", emoji)
 281   end
 282
 283   def fix_emoji(object), do: object
 284
 285   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 286     tags =
 287       tag
 288       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 289       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 290
 291     Map.put(object, "tag", tag ++ tags)
 292   end
 293
 294   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 295     combined = [tag, String.slice(hashtag, 1..-1)]
 296
 297     Map.put(object, "tag", combined)
 298   end
 299
 300   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 301
 302   def fix_tag(object), do: object
 303
 304   # content map usually only has one language so this will do for now.
 305   def fix_content_map(%{"contentMap" => content_map} = object) do
 306     content_groups = Map.to_list(content_map)
 307     {_, content} = Enum.at(content_groups, 0)
 308
 309     Map.put(object, "content", content)
 310   end
 311
 312   def fix_content_map(object), do: object
 313
 314   def fix_type(object, options \\ [])
 315
 316   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 317       when is_binary(reply_id) do
 318     with true <- Federator.allowed_incoming_reply_depth?(options[:depth]),
 319          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 320       Map.put(object, "type", "Answer")
 321     else
 322       _ -> object
 323     end
 324   end
 325
 326   def fix_type(object, _), do: object
 327
 328   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 329     with true <- id =~ "follows",
 330          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 331          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 332       {:ok, activity}
 333     else
 334       _ -> {:error, nil}
 335     end
 336   end
 337
 338   defp mastodon_follow_hack(_, _), do: {:error, nil}
 339
 340   defp get_follow_activity(follow_object, followed) do
 341     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 342          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 343       {:ok, activity}
 344     else
 345       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 346       {:activity, nil} ->
 347         mastodon_follow_hack(follow_object, followed)
 348
 349       _ ->
 350         {:error, nil}
 351     end
 352   end
 353
 354   # Reduce the object list to find the reported user.
 355   defp get_reported(objects) do
 356     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 357       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 358         {:halt, user}
 359       else
 360         _ -> {:cont, nil}
 361       end
 362     end)
 363   end
 364
 365   def handle_incoming(data, options \\ [])
 366
 367   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 368   # with nil ID.
 369   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 370     with context <- data["context"] || Utils.generate_context_id(),
 371          content <- data["content"] || "",
 372          %User{} = actor <- User.get_cached_by_ap_id(actor),
 373          # Reduce the object list to find the reported user.
 374          %User{} = account <- get_reported(objects),
 375          # Remove the reported user from the object list.
 376          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 377       %{
 378         actor: actor,
 379         context: context,
 380         account: account,
 381         statuses: statuses,
 382         content: content,
 383         additional: %{"cc" => [account.ap_id]}
 384       }
 385       |> ActivityPub.flag()
 386     end
 387   end
 388
 389   # disallow objects with bogus IDs
 390   def handle_incoming(%{"id" => nil}, _options), do: :error
 391   def handle_incoming(%{"id" => ""}, _options), do: :error
 392   # length of https:// = 8, should validate better, but good enough for now.
 393   def handle_incoming(%{"id" => id}, _options) when not (is_binary(id) and length(id) > 8),
 394     do: :error
 395
 396   # TODO: validate those with a Ecto scheme
 397   # - tags
 398   # - emoji
 399   def handle_incoming(
 400         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 401         options
 402       )
 403       when objtype in ["Article", "Note", "Video", "Page", "Question", "Answer"] do
 404     actor = Containment.get_actor(data)
 405
 406     data =
 407       Map.put(data, "actor", actor)
 408       |> fix_addressing
 409
 410     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 411          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 412       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 413       object = fix_object(data["object"], options)
 414
 415       params = %{
 416         to: data["to"],
 417         object: object,
 418         actor: user,
 419         context: object["conversation"],
 420         local: false,
 421         published: data["published"],
 422         additional:
 423           Map.take(data, [
 424             "cc",
 425             "directMessage",
 426             "id"
 427           ])
 428       }
 429
 430       ActivityPub.create(params)
 431     else
 432       %Activity{} = activity -> {:ok, activity}
 433       _e -> :error
 434     end
 435   end
 436
 437   def handle_incoming(
 438         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 439         options
 440       ) do
 441     actor = Containment.get_actor(data)
 442
 443     data =
 444       Map.put(data, "actor", actor)
 445       |> fix_addressing
 446
 447     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 448       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 449       object = fix_object(object, options)
 450
 451       params = %{
 452         to: data["to"],
 453         object: object,
 454         actor: user,
 455         context: nil,
 456         local: false,
 457         published: data["published"],
 458         additional: Map.take(data, ["cc", "id"])
 459       }
 460
 461       ActivityPub.listen(params)
 462     else
 463       _e -> :error
 464     end
 465   end
 466
 467   def handle_incoming(
 468         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 469         _options
 470       ) do
 471     with %User{local: true} = followed <-
 472            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 473          {:ok, %User{} = follower} <-
 474            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 475          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 476       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 477            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 478            {_, false} <- {:user_locked, User.locked?(followed)},
 479            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 480            {_, {:ok, _}} <-
 481              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 482            {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 483         ActivityPub.accept(%{
 484           to: [follower.ap_id],
 485           actor: followed,
 486           object: data,
 487           local: true
 488         })
 489       else
 490         {:user_blocked, true} ->
 491           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 492           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 493
 494           ActivityPub.reject(%{
 495             to: [follower.ap_id],
 496             actor: followed,
 497             object: data,
 498             local: true
 499           })
 500
 501         {:follow, {:error, _}} ->
 502           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 503           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "reject")
 504
 505           ActivityPub.reject(%{
 506             to: [follower.ap_id],
 507             actor: followed,
 508             object: data,
 509             local: true
 510           })
 511
 512         {:user_locked, true} ->
 513           {:ok, _relationship} = FollowingRelationship.update(follower, followed, "pending")
 514           :noop
 515       end
 516
 517       {:ok, activity}
 518     else
 519       _e ->
 520         :error
 521     end
 522   end
 523
 524   def handle_incoming(
 525         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 526         _options
 527       ) do
 528     with actor <- Containment.get_actor(data),
 529          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 530          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 531          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 532          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 533          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "accept") do
 534       ActivityPub.accept(%{
 535         to: follow_activity.data["to"],
 536         type: "Accept",
 537         actor: followed,
 538         object: follow_activity.data["id"],
 539         local: false,
 540         activity_id: id
 541       })
 542     else
 543       _e -> :error
 544     end
 545   end
 546
 547   def handle_incoming(
 548         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 549         _options
 550       ) do
 551     with actor <- Containment.get_actor(data),
 552          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 553          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 554          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 555          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 556          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, "reject"),
 557          {:ok, activity} <-
 558            ActivityPub.reject(%{
 559              to: follow_activity.data["to"],
 560              type: "Reject",
 561              actor: followed,
 562              object: follow_activity.data["id"],
 563              local: false,
 564              activity_id: id
 565            }) do
 566       {:ok, activity}
 567     else
 568       _e -> :error
 569     end
 570   end
 571
 572   def handle_incoming(%{"type" => "Like"} = data, _options) do
 573     with {_, {:ok, cast_data_sym}} <-
 574            {:casting_data,
 575             data |> LikeValidator.cast_data() |> Ecto.Changeset.apply_action(:insert)},
 576          {_, cast_data} <-
 577            {:stringify_keys, ObjectValidator.stringify_keys(cast_data_sym |> Map.from_struct())},
 578          :ok <- ObjectValidator.fetch_actor_and_object(cast_data),
 579          {_, {:ok, cast_data}} <- {:maybe_add_context, maybe_add_context_from_object(cast_data)},
 580          {_, {:ok, cast_data}} <-
 581            {:maybe_add_recipients, maybe_add_recipients_from_object(cast_data)},
 582          {_, {:ok, activity, _meta}} <-
 583            {:common_pipeline, Pipeline.common_pipeline(cast_data, local: false)} do
 584       {:ok, activity}
 585     else
 586       e -> {:error, e}
 587     end
 588   end
 589
 590   def handle_incoming(
 591         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 592         _options
 593       ) do
 594     with actor <- Containment.get_actor(data),
 595          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 596          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 597          public <- Visibility.is_public?(data),
 598          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 599       {:ok, activity}
 600     else
 601       _e -> :error
 602     end
 603   end
 604
 605   def handle_incoming(
 606         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 607           data,
 608         _options
 609       )
 610       when object_type in [
 611              "Person",
 612              "Application",
 613              "Service",
 614              "Organization"
 615            ] do
 616     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 617       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 618
 619       locked = new_user_data[:locked] || false
 620       attachment = get_in(new_user_data, [:source_data, "attachment"]) || []
 621       invisible = new_user_data[:invisible] || false
 622
 623       fields =
 624         attachment
 625         |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 626         |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 627
 628       update_data =
 629         new_user_data
 630         |> Map.take([:avatar, :banner, :bio, :name])
 631         |> Map.put(:fields, fields)
 632         |> Map.put(:locked, locked)
 633         |> Map.put(:invisible, invisible)
 634
 635       actor
 636       |> User.upgrade_changeset(update_data, true)
 637       |> User.update_and_set_cache()
 638
 639       ActivityPub.update(%{
 640         local: false,
 641         to: data["to"] || [],
 642         cc: data["cc"] || [],
 643         object: object,
 644         actor: actor_id,
 645         activity_id: data["id"]
 646       })
 647     else
 648       e ->
 649         Logger.error(e)
 650         :error
 651     end
 652   end
 653
 654   # TODO: We presently assume that any actor on the same origin domain as the object being
 655   # deleted has the rights to delete that object.  A better way to validate whether or not
 656   # the object should be deleted is to refetch the object URI, which should return either
 657   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 658   # place.
 659   def handle_incoming(
 660         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 661         _options
 662       ) do
 663     object_id = Utils.get_ap_id(object_id)
 664
 665     with actor <- Containment.get_actor(data),
 666          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 667          {:ok, object} <- get_obj_helper(object_id),
 668          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 669          {:ok, activity} <-
 670            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 671       {:ok, activity}
 672     else
 673       nil ->
 674         case User.get_cached_by_ap_id(object_id) do
 675           %User{ap_id: ^actor} = user ->
 676             User.delete(user)
 677
 678           nil ->
 679             :error
 680         end
 681
 682       _e ->
 683         :error
 684     end
 685   end
 686
 687   def handle_incoming(
 688         %{
 689           "type" => "Undo",
 690           "object" => %{"type" => "Announce", "object" => object_id},
 691           "actor" => _actor,
 692           "id" => id
 693         } = data,
 694         _options
 695       ) do
 696     with actor <- Containment.get_actor(data),
 697          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 698          {:ok, object} <- get_obj_helper(object_id),
 699          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 700       {:ok, activity}
 701     else
 702       _e -> :error
 703     end
 704   end
 705
 706   def handle_incoming(
 707         %{
 708           "type" => "Undo",
 709           "object" => %{"type" => "Follow", "object" => followed},
 710           "actor" => follower,
 711           "id" => id
 712         } = _data,
 713         _options
 714       ) do
 715     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 716          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 717          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 718       User.unfollow(follower, followed)
 719       {:ok, activity}
 720     else
 721       _e -> :error
 722     end
 723   end
 724
 725   def handle_incoming(
 726         %{
 727           "type" => "Undo",
 728           "object" => %{"type" => "Block", "object" => blocked},
 729           "actor" => blocker,
 730           "id" => id
 731         } = _data,
 732         _options
 733       ) do
 734     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 735          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 736          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 737       User.unblock(blocker, blocked)
 738       {:ok, activity}
 739     else
 740       _e -> :error
 741     end
 742   end
 743
 744   def handle_incoming(
 745         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 746         _options
 747       ) do
 748     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 749          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 750          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 751       User.unfollow(blocker, blocked)
 752       User.block(blocker, blocked)
 753       {:ok, activity}
 754     else
 755       _e -> :error
 756     end
 757   end
 758
 759   def handle_incoming(
 760         %{
 761           "type" => "Undo",
 762           "object" => %{"type" => "Like", "object" => object_id},
 763           "actor" => _actor,
 764           "id" => id
 765         } = data,
 766         _options
 767       ) do
 768     with actor <- Containment.get_actor(data),
 769          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 770          {:ok, object} <- get_obj_helper(object_id),
 771          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 772       {:ok, activity}
 773     else
 774       _e -> :error
 775     end
 776   end
 777
 778   # For Undos that don't have the complete object attached, try to find it in our database.
 779   def handle_incoming(
 780         %{
 781           "type" => "Undo",
 782           "object" => object
 783         } = activity,
 784         options
 785       )
 786       when is_binary(object) do
 787     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 788       activity
 789       |> Map.put("object", data)
 790       |> handle_incoming(options)
 791     else
 792       _e -> :error
 793     end
 794   end
 795
 796   def handle_incoming(_, _), do: :error
 797
 798   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 799   def get_obj_helper(id, options \\ []) do
 800     case Object.normalize(id, true, options) do
 801       %Object{} = object -> {:ok, object}
 802       _ -> nil
 803     end
 804   end
 805
 806   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 807   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 808         ap_id: ap_id
 809       })
 810       when attributed_to == ap_id do
 811     with {:ok, activity} <-
 812            handle_incoming(%{
 813              "type" => "Create",
 814              "to" => data["to"],
 815              "cc" => data["cc"],
 816              "actor" => attributed_to,
 817              "object" => data
 818            }) do
 819       {:ok, Object.normalize(activity)}
 820     else
 821       _ -> get_obj_helper(object_id)
 822     end
 823   end
 824
 825   def get_embedded_obj_helper(object_id, _) do
 826     get_obj_helper(object_id)
 827   end
 828
 829   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 830     with false <- String.starts_with?(in_reply_to, "http"),
 831          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 832       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 833     else
 834       _e -> object
 835     end
 836   end
 837
 838   def set_reply_to_uri(obj), do: obj
 839
 840   # Prepares the object of an outgoing create activity.
 841   def prepare_object(object) do
 842     object
 843     |> set_sensitive
 844     |> add_hashtags
 845     |> add_mention_tags
 846     |> add_emoji_tags
 847     |> add_attributed_to
 848     |> prepare_attachments
 849     |> set_conversation
 850     |> set_reply_to_uri
 851     |> strip_internal_fields
 852     |> strip_internal_tags
 853     |> set_type
 854   end
 855
 856   #  @doc
 857   #  """
 858   #  internal -> Mastodon
 859   #  """
 860
 861   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 862       when activity_type in ["Create", "Listen"] do
 863     object =
 864       object_id
 865       |> Object.normalize()
 866       |> Map.get(:data)
 867       |> prepare_object
 868
 869     data =
 870       data
 871       |> Map.put("object", object)
 872       |> Map.merge(Utils.make_json_ld_header())
 873       |> Map.delete("bcc")
 874
 875     {:ok, data}
 876   end
 877
 878   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 879     object =
 880       object_id
 881       |> Object.normalize()
 882
 883     data =
 884       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 885         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 886       else
 887         data |> maybe_fix_object_url
 888       end
 889
 890     data =
 891       data
 892       |> strip_internal_fields
 893       |> Map.merge(Utils.make_json_ld_header())
 894       |> Map.delete("bcc")
 895
 896     {:ok, data}
 897   end
 898
 899   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 900   # because of course it does.
 901   def prepare_outgoing(%{"type" => "Accept"} = data) do
 902     with follow_activity <- Activity.normalize(data["object"]) do
 903       object = %{
 904         "actor" => follow_activity.actor,
 905         "object" => follow_activity.data["object"],
 906         "id" => follow_activity.data["id"],
 907         "type" => "Follow"
 908       }
 909
 910       data =
 911         data
 912         |> Map.put("object", object)
 913         |> Map.merge(Utils.make_json_ld_header())
 914
 915       {:ok, data}
 916     end
 917   end
 918
 919   def prepare_outgoing(%{"type" => "Reject"} = data) do
 920     with follow_activity <- Activity.normalize(data["object"]) do
 921       object = %{
 922         "actor" => follow_activity.actor,
 923         "object" => follow_activity.data["object"],
 924         "id" => follow_activity.data["id"],
 925         "type" => "Follow"
 926       }
 927
 928       data =
 929         data
 930         |> Map.put("object", object)
 931         |> Map.merge(Utils.make_json_ld_header())
 932
 933       {:ok, data}
 934     end
 935   end
 936
 937   def prepare_outgoing(%{"type" => _type} = data) do
 938     data =
 939       data
 940       |> strip_internal_fields
 941       |> maybe_fix_object_url
 942       |> Map.merge(Utils.make_json_ld_header())
 943
 944     {:ok, data}
 945   end
 946
 947   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
 948     with false <- String.starts_with?(object, "http"),
 949          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
 950          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
 951            relative_object do
 952       Map.put(data, "object", external_url)
 953     else
 954       {:fetch, e} ->
 955         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
 956         data
 957
 958       _ ->
 959         data
 960     end
 961   end
 962
 963   def maybe_fix_object_url(data), do: data
 964
 965   def add_hashtags(object) do
 966     tags =
 967       (object["tag"] || [])
 968       |> Enum.map(fn
 969         # Expand internal representation tags into AS2 tags.
 970         tag when is_binary(tag) ->
 971           %{
 972             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 973             "name" => "##{tag}",
 974             "type" => "Hashtag"
 975           }
 976
 977         # Do not process tags which are already AS2 tag objects.
 978         tag when is_map(tag) ->
 979           tag
 980       end)
 981
 982     Map.put(object, "tag", tags)
 983   end
 984
 985   def add_mention_tags(object) do
 986     mentions =
 987       object
 988       |> Utils.get_notified_from_object()
 989       |> Enum.map(&build_mention_tag/1)
 990
 991     tags = object["tag"] || []
 992
 993     Map.put(object, "tag", tags ++ mentions)
 994   end
 995
 996   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
 997     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
 998   end
 999
1000   def take_emoji_tags(%User{emoji: emoji}) do
1001     emoji
1002     |> Enum.flat_map(&Map.to_list/1)
1003     |> Enum.map(&build_emoji_tag/1)
1004   end
1005
1006   # TODO: we should probably send mtime instead of unix epoch time for updated
1007   def add_emoji_tags(%{"emoji" => emoji} = object) do
1008     tags = object["tag"] || []
1009
1010     out = Enum.map(emoji, &build_emoji_tag/1)
1011
1012     Map.put(object, "tag", tags ++ out)
1013   end
1014
1015   def add_emoji_tags(object), do: object
1016
1017   defp build_emoji_tag({name, url}) do
1018     %{
1019       "icon" => %{"url" => url, "type" => "Image"},
1020       "name" => ":" <> name <> ":",
1021       "type" => "Emoji",
1022       "updated" => "1970-01-01T00:00:00Z",
1023       "id" => url
1024     }
1025   end
1026
1027   def set_conversation(object) do
1028     Map.put(object, "conversation", object["context"])
1029   end
1030
1031   def set_sensitive(object) do
1032     tags = object["tag"] || []
1033     Map.put(object, "sensitive", "nsfw" in tags)
1034   end
1035
1036   def set_type(%{"type" => "Answer"} = object) do
1037     Map.put(object, "type", "Note")
1038   end
1039
1040   def set_type(object), do: object
1041
1042   def add_attributed_to(object) do
1043     attributed_to = object["attributedTo"] || object["actor"]
1044     Map.put(object, "attributedTo", attributed_to)
1045   end
1046
1047   def prepare_attachments(object) do
1048     attachments =
1049       (object["attachment"] || [])
1050       |> Enum.map(fn data ->
1051         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1052         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1053       end)
1054
1055     Map.put(object, "attachment", attachments)
1056   end
1057
1058   defp strip_internal_fields(object) do
1059     object
1060     |> Map.drop(Pleroma.Constants.object_internal_fields())
1061   end
1062
1063   defp strip_internal_tags(%{"tag" => tags} = object) do
1064     tags = Enum.filter(tags, fn x -> is_map(x) end)
1065
1066     Map.put(object, "tag", tags)
1067   end
1068
1069   defp strip_internal_tags(object), do: object
1070
1071   def perform(:user_upgrade, user) do
1072     # we pass a fake user so that the followers collection is stripped away
1073     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1074
1075     from(
1076       a in Activity,
1077       where: ^old_follower_address in a.recipients,
1078       update: [
1079         set: [
1080           recipients:
1081             fragment(
1082               "array_replace(?,?,?)",
1083               a.recipients,
1084               ^old_follower_address,
1085               ^user.follower_address
1086             )
1087         ]
1088       ]
1089     )
1090     |> Repo.update_all([])
1091   end
1092
1093   def upgrade_user_from_ap_id(ap_id) do
1094     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1095          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1096          already_ap <- User.ap_enabled?(user),
1097          {:ok, user} <- upgrade_user(user, data) do
1098       if not already_ap do
1099         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1100       end
1101
1102       {:ok, user}
1103     else
1104       %User{} = user -> {:ok, user}
1105       e -> e
1106     end
1107   end
1108
1109   defp upgrade_user(user, data) do
1110     user
1111     |> User.upgrade_changeset(data, true)
1112     |> User.update_and_set_cache()
1113   end
1114
1115   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1116     Map.put(data, "url", url["href"])
1117   end
1118
1119   def maybe_fix_user_url(data), do: data
1120
1121   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1122
1123   defp maybe_add_context_from_object(%{"context" => context} = data) when is_binary(context),
1124     do: {:ok, data}
1125
1126   defp maybe_add_context_from_object(%{"object" => object} = data) when is_binary(object) do
1127     if object = Object.normalize(object) do
1128       data =
1129         data
1130         |> Map.put("context", object.data["context"])
1131
1132       {:ok, data}
1133     else
1134       {:error, "No context on referenced object"}
1135     end
1136   end
1137
1138   defp maybe_add_context_from_object(_) do
1139     {:error, "No referenced object"}
1140   end
1141
1142   defp maybe_add_recipients_from_object(%{"object" => object} = data) do
1143     to = data["to"] || []
1144     cc = data["cc"] || []
1145
1146     if to == [] && cc == [] do
1147       if object = Object.normalize(object) do
1148         data =
1149           data
1150           |> Map.put("to", [object.data["actor"]])
1151           |> Map.put("cc", cc)
1152
1153         {:ok, data}
1154       else
1155         {:error, "No actor on referenced object"}
1156       end
1157     else
1158       {:ok, data}
1159     end
1160   end
1161
1162   defp maybe_add_recipients_from_object(_) do
1163     {:error, "No referenced object"}
1164   end
1165 end