git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10
  11   import Ecto.Query
  12
  13   require Logger
  14
  15   @doc """
  16   Modifies an incoming AP object (mastodon format) to our internal format.
  17   """
  18   def fix_object(object) do
  19     object
  20     |> Map.put("actor", object["attributedTo"])
  21     |> fix_attachments
  22     |> fix_context
  23     |> fix_in_reply_to
  24     |> fix_emoji
  25     |> fix_tag
  26   end
  27
  28   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  29       when not is_nil(in_reply_to_id) do
  30     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  31       {:ok, replied_object} ->
  32         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  33
  34         object
  35         |> Map.put("inReplyTo", replied_object.data["id"])
  36         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  37         |> Map.put("inReplyToStatusId", activity.id)
  38         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  39         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  40
  41       e ->
  42         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  43         object
  44     end
  45   end
  46
  47   def fix_in_reply_to(object), do: object
  48
  49   def fix_context(object) do
  50     object
  51     |> Map.put("context", object["conversation"])
  52   end
  53
  54   def fix_attachments(object) do
  55     attachments =
  56       (object["attachment"] || [])
  57       |> Enum.map(fn data ->
  58         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  59         Map.put(data, "url", url)
  60       end)
  61
  62     object
  63     |> Map.put("attachment", attachments)
  64   end
  65
  66   def fix_emoji(object) do
  67     tags = object["tag"] || []
  68     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  69
  70     emoji =
  71       emoji
  72       |> Enum.reduce(%{}, fn data, mapping ->
  73         name = data["name"]
  74
  75         if String.starts_with?(name, ":") do
  76           name = name |> String.slice(1..-2)
  77         end
  78
  79         mapping |> Map.put(name, data["icon"]["url"])
  80       end)
  81
  82     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  83     emoji = Map.merge(object["emoji"] || %{}, emoji)
  84
  85     object
  86     |> Map.put("emoji", emoji)
  87   end
  88
  89   def fix_tag(object) do
  90     tags =
  91       (object["tag"] || [])
  92       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  93       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  94
  95     combined = (object["tag"] || []) ++ tags
  96
  97     object
  98     |> Map.put("tag", combined)
  99   end
 100
 101   # TODO: validate those with a Ecto scheme
 102   # - tags
 103   # - emoji
 104   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 105     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 106          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 107       object = fix_object(data["object"])
 108
 109       params = %{
 110         to: data["to"],
 111         object: object,
 112         actor: user,
 113         context: object["conversation"],
 114         local: false,
 115         published: data["published"],
 116         additional:
 117           Map.take(data, [
 118             "cc",
 119             "id"
 120           ])
 121       }
 122
 123       ActivityPub.create(params)
 124     else
 125       %Activity{} = activity -> {:ok, activity}
 126       _e -> :error
 127     end
 128   end
 129
 130   def handle_incoming(
 131         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 132       ) do
 133     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 134          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 135          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 136       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 137
 138       User.follow(follower, followed)
 139       {:ok, activity}
 140     else
 141       _e -> :error
 142     end
 143   end
 144
 145   def handle_incoming(
 146         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data
 147       ) do
 148     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 149          {:ok, object} <-
 150            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 151          {:ok, activity, object} <- ActivityPub.like(actor, object, id, false) do
 152       {:ok, activity}
 153     else
 154       _e -> :error
 155     end
 156   end
 157
 158   def handle_incoming(
 159         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data
 160       ) do
 161     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 162          {:ok, object} <-
 163            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 164          {:ok, activity, object} <- ActivityPub.announce(actor, object, id, false) do
 165       {:ok, activity}
 166     else
 167       _e -> :error
 168     end
 169   end
 170
 171   def handle_incoming(
 172         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 173           data
 174       ) do
 175     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 176       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 177
 178       banner = new_user_data[:info]["banner"]
 179
 180       update_data =
 181         new_user_data
 182         |> Map.take([:name, :bio, :avatar])
 183         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 184
 185       actor
 186       |> User.upgrade_changeset(update_data)
 187       |> User.update_and_set_cache()
 188
 189       ActivityPub.update(%{
 190         local: false,
 191         to: data["to"] || [],
 192         cc: data["cc"] || [],
 193         object: object,
 194         actor: actor_id
 195       })
 196     else
 197       e ->
 198         Logger.error(e)
 199         :error
 200     end
 201   end
 202
 203   # TODO: Make secure.
 204   def handle_incoming(
 205         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data
 206       ) do
 207     object_id =
 208       case object_id do
 209         %{"id" => id} -> id
 210         id -> id
 211       end
 212
 213     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 214          {:ok, object} <-
 215            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 216          {:ok, activity} <- ActivityPub.delete(object, false) do
 217       {:ok, activity}
 218     else
 219       e -> :error
 220     end
 221   end
 222
 223   def handle_incoming(
 224         %{
 225           "type" => "Undo",
 226           "object" => %{"type" => "Announce", "id" => object_id},
 227           "actor" => actor,
 228           "id" => id
 229         } = data
 230       ) do
 231     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 232          {:ok, object} <-
 233            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 234          {:ok, activity} <- ActivityPub.unannounce(object, false) do
 235       {:ok, activity}
 236     else
 237       e -> :error
 238     end
 239   end
 240
 241   # TODO
 242   # Accept
 243   # Undo for non-Announce
 244
 245   def handle_incoming(_), do: :error
 246
 247   def get_obj_helper(id) do
 248     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 249   end
 250
 251   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 252     with false <- String.starts_with?(inReplyTo, "http"),
 253          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 254       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 255     else
 256       _e -> object
 257     end
 258   end
 259
 260   def set_reply_to_uri(obj), do: obj
 261
 262   # Prepares the object of an outgoing create activity.
 263   def prepare_object(object) do
 264     object
 265     |> set_sensitive
 266     |> add_hashtags
 267     |> add_mention_tags
 268     |> add_emoji_tags
 269     |> add_attributed_to
 270     |> prepare_attachments
 271     |> set_conversation
 272     |> set_reply_to_uri
 273   end
 274
 275   @doc
 276   """
 277   internal -> Mastodon
 278   """
 279
 280   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 281     object =
 282       object
 283       |> prepare_object
 284
 285     data =
 286       data
 287       |> Map.put("object", object)
 288       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 289
 290     {:ok, data}
 291   end
 292
 293   def prepare_outgoing(%{"type" => type} = data) do
 294     data =
 295       data
 296       |> maybe_fix_object_url
 297       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 298
 299     {:ok, data}
 300   end
 301
 302   def maybe_fix_object_url(data) do
 303     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 304       case ActivityPub.fetch_object_from_id(data["object"]) do
 305         {:ok, relative_object} ->
 306           if relative_object.data["external_url"] do
 307             data =
 308               data
 309               |> Map.put("object", relative_object.data["external_url"])
 310           else
 311             data
 312           end
 313
 314         e ->
 315           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 316           data
 317       end
 318     else
 319       data
 320     end
 321   end
 322
 323   def add_hashtags(object) do
 324     tags =
 325       (object["tag"] || [])
 326       |> Enum.map(fn tag ->
 327         %{
 328           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 329           "name" => "##{tag}",
 330           "type" => "Hashtag"
 331         }
 332       end)
 333
 334     object
 335     |> Map.put("tag", tags)
 336   end
 337
 338   def add_mention_tags(object) do
 339     recipients = object["to"] ++ (object["cc"] || [])
 340
 341     mentions =
 342       recipients
 343       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 344       |> Enum.filter(& &1)
 345       |> Enum.map(fn user ->
 346         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 347       end)
 348
 349     tags = object["tag"] || []
 350
 351     object
 352     |> Map.put("tag", tags ++ mentions)
 353   end
 354
 355   # TODO: we should probably send mtime instead of unix epoch time for updated
 356   def add_emoji_tags(object) do
 357     tags = object["tag"] || []
 358     emoji = object["emoji"] || []
 359
 360     out =
 361       emoji
 362       |> Enum.map(fn {name, url} ->
 363         %{
 364           "icon" => %{"url" => url, "type" => "Image"},
 365           "name" => ":" <> name <> ":",
 366           "type" => "Emoji",
 367           "updated" => "1970-01-01T00:00:00Z",
 368           "id" => url
 369         }
 370       end)
 371
 372     object
 373     |> Map.put("tag", tags ++ out)
 374   end
 375
 376   def set_conversation(object) do
 377     Map.put(object, "conversation", object["context"])
 378   end
 379
 380   def set_sensitive(object) do
 381     tags = object["tag"] || []
 382     Map.put(object, "sensitive", "nsfw" in tags)
 383   end
 384
 385   def add_attributed_to(object) do
 386     attributedTo = object["attributedTo"] || object["actor"]
 387
 388     object
 389     |> Map.put("attributedTo", attributedTo)
 390   end
 391
 392   def prepare_attachments(object) do
 393     attachments =
 394       (object["attachment"] || [])
 395       |> Enum.map(fn data ->
 396         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 397         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 398       end)
 399
 400     object
 401     |> Map.put("attachment", attachments)
 402   end
 403
 404   defp user_upgrade_task(user) do
 405     old_follower_address = User.ap_followers(user)
 406
 407     q =
 408       from(
 409         u in User,
 410         where: ^old_follower_address in u.following,
 411         update: [
 412           set: [
 413             following:
 414               fragment(
 415                 "array_replace(?,?,?)",
 416                 u.following,
 417                 ^old_follower_address,
 418                 ^user.follower_address
 419               )
 420           ]
 421         ]
 422       )
 423
 424     Repo.update_all(q, [])
 425
 426     maybe_retire_websub(user.ap_id)
 427
 428     # Only do this for recent activties, don't go through the whole db.
 429     # Only look at the last 1000 activities.
 430     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 431
 432     q =
 433       from(
 434         a in Activity,
 435         where: ^old_follower_address in a.recipients,
 436         where: a.id > ^since,
 437         update: [
 438           set: [
 439             recipients:
 440               fragment(
 441                 "array_replace(?,?,?)",
 442                 a.recipients,
 443                 ^old_follower_address,
 444                 ^user.follower_address
 445               )
 446           ]
 447         ]
 448       )
 449
 450     Repo.update_all(q, [])
 451   end
 452
 453   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 454     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 455          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 456       data =
 457         data
 458         |> Map.put(:info, Map.merge(user.info, data[:info]))
 459
 460       already_ap = User.ap_enabled?(user)
 461
 462       {:ok, user} =
 463         User.upgrade_changeset(user, data)
 464         |> Repo.update()
 465
 466       if !already_ap do
 467         # This could potentially take a long time, do it in the background
 468         if async do
 469           Task.start(fn ->
 470             user_upgrade_task(user)
 471           end)
 472         else
 473           user_upgrade_task(user)
 474         end
 475       end
 476
 477       {:ok, user}
 478     else
 479       e -> e
 480     end
 481   end
 482
 483   def maybe_retire_websub(ap_id) do
 484     # some sanity checks
 485     if is_binary(ap_id) && String.length(ap_id) > 8 do
 486       q =
 487         from(
 488           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 489           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 490         )
 491
 492       Repo.delete_all(q)
 493     end
 494   end
 495 end