git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  30     id
  31   end
  32
  33   @doc """
  34   Checks that an imported AP object's actor matches the domain it came from.
  35   """
  36   def contain_origin(id, %{"actor" => actor} = params) do
  37     id_uri = URI.parse(id)
  38     actor_uri = URI.parse(get_actor(params))
  39
  40     if id_uri.host == actor_uri.host do
  41       :ok
  42     else
  43       :error
  44     end
  45   end
  46
  47   @doc """
  48   Modifies an incoming AP object (mastodon format) to our internal format.
  49   """
  50   def fix_object(object) do
  51     object
  52     |> fix_actor
  53     |> fix_attachments
  54     |> fix_context
  55     |> fix_in_reply_to
  56     |> fix_emoji
  57     |> fix_tag
  58     |> fix_content_map
  59     |> fix_likes
  60     |> fix_addressing
  61   end
  62
  63   def fix_addressing_list(map, field) do
  64     if is_binary(map[field]) do
  65       map
  66       |> Map.put(field, [map[field]])
  67     else
  68       map
  69     end
  70   end
  71
  72   def fix_addressing(map) do
  73     map
  74     |> fix_addressing_list("to")
  75     |> fix_addressing_list("cc")
  76     |> fix_addressing_list("bto")
  77     |> fix_addressing_list("bcc")
  78   end
  79
  80   def fix_actor(%{"attributedTo" => actor} = object) do
  81     object
  82     |> Map.put("actor", get_actor(%{"actor" => actor}))
  83   end
  84
  85   def fix_likes(%{"likes" => likes} = object)
  86       when is_bitstring(likes) do
  87     # Check for standardisation
  88     # This is what Peertube does
  89     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
  90     object
  91     |> Map.put("likes", [])
  92     |> Map.put("like_count", 0)
  93   end
  94
  95   def fix_likes(object) do
  96     object
  97   end
  98
  99   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 100       when not is_nil(in_reply_to) do
 101     in_reply_to_id =
 102       cond do
 103         is_bitstring(in_reply_to) ->
 104           in_reply_to
 105
 106         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 107           in_reply_to["id"]
 108
 109         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 110           Enum.at(in_reply_to, 0)
 111
 112         # Maybe I should output an error too?
 113         true ->
 114           ""
 115       end
 116
 117     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
 118       {:ok, replied_object} ->
 119         with %Activity{} = activity <-
 120                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 121           object
 122           |> Map.put("inReplyTo", replied_object.data["id"])
 123           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 124           |> Map.put("inReplyToStatusId", activity.id)
 125           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 126           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 127         else
 128           e ->
 129             Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 130             object
 131         end
 132
 133       e ->
 134         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 135         object
 136     end
 137   end
 138
 139   def fix_in_reply_to(object), do: object
 140
 141   def fix_context(object) do
 142     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 143
 144     object
 145     |> Map.put("context", context)
 146     |> Map.put("conversation", context)
 147   end
 148
 149   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 150     attachments =
 151       attachment
 152       |> Enum.map(fn data ->
 153         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 154         Map.put(data, "url", url)
 155       end)
 156
 157     object
 158     |> Map.put("attachment", attachments)
 159   end
 160
 161   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 162     attachment =
 163       Map.put(attachment, "url", [
 164         %{"type" => "Link", "mediaType" => attachment["mediaType"], "href" => attachment["url"]}
 165       ])
 166
 167     Map.put(object, "attachment", attachment)
 168   end
 169
 170   def fix_attachments(object) do
 171     object
 172   end
 173
 174   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 175     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 176
 177     emoji =
 178       emoji
 179       |> Enum.reduce(%{}, fn data, mapping ->
 180         name = String.trim(data["name"], ":")
 181
 182         mapping |> Map.put(name, data["icon"]["url"])
 183       end)
 184
 185     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 186     emoji = Map.merge(object["emoji"] || %{}, emoji)
 187
 188     object
 189     |> Map.put("emoji", emoji)
 190   end
 191
 192   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 193     name = String.trim(tag["name"], ":")
 194     emoji = %{name => tag["icon"]["url"]}
 195
 196     object
 197     |> Map.put("emoji", emoji)
 198   end
 199
 200   def fix_emoji(object) do
 201     object
 202   end
 203
 204   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 205     tags =
 206       tag
 207       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 208       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 209
 210     combined = tag ++ tags
 211
 212     object
 213     |> Map.put("tag", combined)
 214   end
 215
 216   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 217     combined = [tag, String.slice(hashtag, 1..-1)]
 218
 219     object
 220     |> Map.put("tag", combined)
 221   end
 222
 223   def fix_tag(object) do
 224     object
 225   end
 226
 227   # content map usually only has one language so this will do for now.
 228   def fix_content_map(%{"contentMap" => content_map} = object) do
 229     content_groups = Map.to_list(content_map)
 230     {_, content} = Enum.at(content_groups, 0)
 231
 232     object
 233     |> Map.put("content", content)
 234   end
 235
 236   def fix_content_map(object), do: object
 237
 238   # disallow objects with bogus IDs
 239   def handle_incoming(%{"id" => nil}), do: :error
 240   def handle_incoming(%{"id" => ""}), do: :error
 241   # length of https:// = 8, should validate better, but good enough for now.
 242   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 243
 244   # TODO: validate those with a Ecto scheme
 245   # - tags
 246   # - emoji
 247   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 248       when objtype in ["Article", "Note", "Video"] do
 249     actor = get_actor(data)
 250
 251     data =
 252       Map.put(data, "actor", actor)
 253       |> fix_addressing
 254
 255     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 256          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 257       object = fix_object(data["object"])
 258
 259       params = %{
 260         to: data["to"],
 261         object: object,
 262         actor: user,
 263         context: object["conversation"],
 264         local: false,
 265         published: data["published"],
 266         additional:
 267           Map.take(data, [
 268             "cc",
 269             "id"
 270           ])
 271       }
 272
 273       ActivityPub.create(params)
 274     else
 275       %Activity{} = activity -> {:ok, activity}
 276       _e -> :error
 277     end
 278   end
 279
 280   def handle_incoming(
 281         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 282       ) do
 283     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 284          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 285          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 286       if not User.locked?(followed) do
 287         ActivityPub.accept(%{
 288           to: [follower.ap_id],
 289           actor: followed.ap_id,
 290           object: data,
 291           local: true
 292         })
 293
 294         User.follow(follower, followed)
 295       end
 296
 297       {:ok, activity}
 298     else
 299       _e -> :error
 300     end
 301   end
 302
 303   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 304     with true <- id =~ "follows",
 305          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 306          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 307       {:ok, activity}
 308     else
 309       _ -> {:error, nil}
 310     end
 311   end
 312
 313   defp mastodon_follow_hack(_), do: {:error, nil}
 314
 315   defp get_follow_activity(follow_object, followed) do
 316     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 317          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 318       {:ok, activity}
 319     else
 320       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 321       {:activity, nil} ->
 322         mastodon_follow_hack(follow_object, followed)
 323
 324       _ ->
 325         {:error, nil}
 326     end
 327   end
 328
 329   def handle_incoming(
 330         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 331       ) do
 332     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 333          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 334          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 335          {:ok, activity} <-
 336            ActivityPub.accept(%{
 337              to: follow_activity.data["to"],
 338              type: "Accept",
 339              actor: followed.ap_id,
 340              object: follow_activity.data["id"],
 341              local: false
 342            }) do
 343       if not User.following?(follower, followed) do
 344         {:ok, follower} = User.follow(follower, followed)
 345       end
 346
 347       {:ok, activity}
 348     else
 349       _e -> :error
 350     end
 351   end
 352
 353   def handle_incoming(
 354         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 355       ) do
 356     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 357          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 358          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 359          {:ok, activity} <-
 360            ActivityPub.accept(%{
 361              to: follow_activity.data["to"],
 362              type: "Accept",
 363              actor: followed.ap_id,
 364              object: follow_activity.data["id"],
 365              local: false
 366            }) do
 367       User.unfollow(follower, followed)
 368
 369       {:ok, activity}
 370     else
 371       _e -> :error
 372     end
 373   end
 374
 375   def handle_incoming(
 376         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 377       ) do
 378     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 379          {:ok, object} <-
 380            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 381          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 382       {:ok, activity}
 383     else
 384       _e -> :error
 385     end
 386   end
 387
 388   def handle_incoming(
 389         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 390       ) do
 391     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 392          {:ok, object} <-
 393            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 394          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 395       {:ok, activity}
 396     else
 397       _e -> :error
 398     end
 399   end
 400
 401   def handle_incoming(
 402         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 403           data
 404       )
 405       when object_type in ["Person", "Application", "Service", "Organization"] do
 406     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 407       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 408
 409       banner = new_user_data[:info]["banner"]
 410       locked = new_user_data[:info]["locked"] || false
 411
 412       update_data =
 413         new_user_data
 414         |> Map.take([:name, :bio, :avatar])
 415         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 416
 417       actor
 418       |> User.upgrade_changeset(update_data)
 419       |> User.update_and_set_cache()
 420
 421       ActivityPub.update(%{
 422         local: false,
 423         to: data["to"] || [],
 424         cc: data["cc"] || [],
 425         object: object,
 426         actor: actor_id
 427       })
 428     else
 429       e ->
 430         Logger.error(e)
 431         :error
 432     end
 433   end
 434
 435   # TODO: Make secure.
 436   def handle_incoming(
 437         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 438       ) do
 439     object_id = Utils.get_ap_id(object_id)
 440
 441     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 442          {:ok, object} <-
 443            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 444          {:ok, activity} <- ActivityPub.delete(object, false) do
 445       {:ok, activity}
 446     else
 447       _e -> :error
 448     end
 449   end
 450
 451   def handle_incoming(
 452         %{
 453           "type" => "Undo",
 454           "object" => %{"type" => "Announce", "object" => object_id},
 455           "actor" => actor,
 456           "id" => id
 457         } = _data
 458       ) do
 459     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 460          {:ok, object} <-
 461            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 462          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 463       {:ok, activity}
 464     else
 465       _e -> :error
 466     end
 467   end
 468
 469   def handle_incoming(
 470         %{
 471           "type" => "Undo",
 472           "object" => %{"type" => "Follow", "object" => followed},
 473           "actor" => follower,
 474           "id" => id
 475         } = _data
 476       ) do
 477     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 478          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 479          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 480       User.unfollow(follower, followed)
 481       {:ok, activity}
 482     else
 483       e -> :error
 484     end
 485   end
 486
 487   @ap_config Application.get_env(:pleroma, :activitypub)
 488   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 489
 490   def handle_incoming(
 491         %{
 492           "type" => "Undo",
 493           "object" => %{"type" => "Block", "object" => blocked},
 494           "actor" => blocker,
 495           "id" => id
 496         } = _data
 497       ) do
 498     with true <- @accept_blocks,
 499          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 500          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 501          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 502       User.unblock(blocker, blocked)
 503       {:ok, activity}
 504     else
 505       e -> :error
 506     end
 507   end
 508
 509   def handle_incoming(
 510         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 511       ) do
 512     with true <- @accept_blocks,
 513          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 514          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 515          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 516       User.unfollow(blocker, blocked)
 517       User.block(blocker, blocked)
 518       {:ok, activity}
 519     else
 520       e -> :error
 521     end
 522   end
 523
 524   def handle_incoming(
 525         %{
 526           "type" => "Undo",
 527           "object" => %{"type" => "Like", "object" => object_id},
 528           "actor" => actor,
 529           "id" => id
 530         } = _data
 531       ) do
 532     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 533          {:ok, object} <-
 534            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 535          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 536       {:ok, activity}
 537     else
 538       _e -> :error
 539     end
 540   end
 541
 542   def handle_incoming(_), do: :error
 543
 544   def get_obj_helper(id) do
 545     if object = Object.normalize(id), do: {:ok, object}, else: nil
 546   end
 547
 548   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 549     with false <- String.starts_with?(inReplyTo, "http"),
 550          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 551       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 552     else
 553       _e -> object
 554     end
 555   end
 556
 557   def set_reply_to_uri(obj), do: obj
 558
 559   # Prepares the object of an outgoing create activity.
 560   def prepare_object(object) do
 561     object
 562     |> set_sensitive
 563     |> add_hashtags
 564     |> add_mention_tags
 565     |> add_emoji_tags
 566     |> add_attributed_to
 567     |> prepare_attachments
 568     |> set_conversation
 569     |> set_reply_to_uri
 570   end
 571
 572   #  @doc
 573   #  """
 574   #  internal -> Mastodon
 575   #  """
 576
 577   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 578     object =
 579       object
 580       |> prepare_object
 581
 582     data =
 583       data
 584       |> Map.put("object", object)
 585       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 586
 587     {:ok, data}
 588   end
 589
 590   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 591   # because of course it does.
 592   def prepare_outgoing(%{"type" => "Accept"} = data) do
 593     with follow_activity <- Activity.normalize(data["object"]) do
 594       object = %{
 595         "actor" => follow_activity.actor,
 596         "object" => follow_activity.data["object"],
 597         "id" => follow_activity.data["id"],
 598         "type" => "Follow"
 599       }
 600
 601       data =
 602         data
 603         |> Map.put("object", object)
 604         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 605
 606       {:ok, data}
 607     end
 608   end
 609
 610   def prepare_outgoing(%{"type" => "Reject"} = data) do
 611     with follow_activity <- Activity.normalize(data["object"]) do
 612       object = %{
 613         "actor" => follow_activity.actor,
 614         "object" => follow_activity.data["object"],
 615         "id" => follow_activity.data["id"],
 616         "type" => "Follow"
 617       }
 618
 619       data =
 620         data
 621         |> Map.put("object", object)
 622         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 623
 624       {:ok, data}
 625     end
 626   end
 627
 628   def prepare_outgoing(%{"type" => _type} = data) do
 629     data =
 630       data
 631       |> maybe_fix_object_url
 632       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 633
 634     {:ok, data}
 635   end
 636
 637   def maybe_fix_object_url(data) do
 638     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 639       case ActivityPub.fetch_object_from_id(data["object"]) do
 640         {:ok, relative_object} ->
 641           if relative_object.data["external_url"] do
 642             _data =
 643               data
 644               |> Map.put("object", relative_object.data["external_url"])
 645           else
 646             data
 647           end
 648
 649         e ->
 650           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 651           data
 652       end
 653     else
 654       data
 655     end
 656   end
 657
 658   def add_hashtags(object) do
 659     tags =
 660       (object["tag"] || [])
 661       |> Enum.map(fn tag ->
 662         %{
 663           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 664           "name" => "##{tag}",
 665           "type" => "Hashtag"
 666         }
 667       end)
 668
 669     object
 670     |> Map.put("tag", tags)
 671   end
 672
 673   def add_mention_tags(object) do
 674     recipients = object["to"] ++ (object["cc"] || [])
 675
 676     mentions =
 677       recipients
 678       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 679       |> Enum.filter(& &1)
 680       |> Enum.map(fn user ->
 681         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 682       end)
 683
 684     tags = object["tag"] || []
 685
 686     object
 687     |> Map.put("tag", tags ++ mentions)
 688   end
 689
 690   # TODO: we should probably send mtime instead of unix epoch time for updated
 691   def add_emoji_tags(object) do
 692     tags = object["tag"] || []
 693     emoji = object["emoji"] || []
 694
 695     out =
 696       emoji
 697       |> Enum.map(fn {name, url} ->
 698         %{
 699           "icon" => %{"url" => url, "type" => "Image"},
 700           "name" => ":" <> name <> ":",
 701           "type" => "Emoji",
 702           "updated" => "1970-01-01T00:00:00Z",
 703           "id" => url
 704         }
 705       end)
 706
 707     object
 708     |> Map.put("tag", tags ++ out)
 709   end
 710
 711   def set_conversation(object) do
 712     Map.put(object, "conversation", object["context"])
 713   end
 714
 715   def set_sensitive(object) do
 716     tags = object["tag"] || []
 717     Map.put(object, "sensitive", "nsfw" in tags)
 718   end
 719
 720   def add_attributed_to(object) do
 721     attributedTo = object["attributedTo"] || object["actor"]
 722
 723     object
 724     |> Map.put("attributedTo", attributedTo)
 725   end
 726
 727   def prepare_attachments(object) do
 728     attachments =
 729       (object["attachment"] || [])
 730       |> Enum.map(fn data ->
 731         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 732         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 733       end)
 734
 735     object
 736     |> Map.put("attachment", attachments)
 737   end
 738
 739   defp user_upgrade_task(user) do
 740     old_follower_address = User.ap_followers(user)
 741
 742     q =
 743       from(
 744         u in User,
 745         where: ^old_follower_address in u.following,
 746         update: [
 747           set: [
 748             following:
 749               fragment(
 750                 "array_replace(?,?,?)",
 751                 u.following,
 752                 ^old_follower_address,
 753                 ^user.follower_address
 754               )
 755           ]
 756         ]
 757       )
 758
 759     Repo.update_all(q, [])
 760
 761     maybe_retire_websub(user.ap_id)
 762
 763     # Only do this for recent activties, don't go through the whole db.
 764     # Only look at the last 1000 activities.
 765     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 766
 767     q =
 768       from(
 769         a in Activity,
 770         where: ^old_follower_address in a.recipients,
 771         where: a.id > ^since,
 772         update: [
 773           set: [
 774             recipients:
 775               fragment(
 776                 "array_replace(?,?,?)",
 777                 a.recipients,
 778                 ^old_follower_address,
 779                 ^user.follower_address
 780               )
 781           ]
 782         ]
 783       )
 784
 785     Repo.update_all(q, [])
 786   end
 787
 788   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 789     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 790          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 791       data =
 792         data
 793         |> Map.put(:info, Map.merge(user.info, data[:info]))
 794
 795       already_ap = User.ap_enabled?(user)
 796
 797       {:ok, user} =
 798         User.upgrade_changeset(user, data)
 799         |> Repo.update()
 800
 801       if !already_ap do
 802         # This could potentially take a long time, do it in the background
 803         if async do
 804           Task.start(fn ->
 805             user_upgrade_task(user)
 806           end)
 807         else
 808           user_upgrade_task(user)
 809         end
 810       end
 811
 812       {:ok, user}
 813     else
 814       e -> e
 815     end
 816   end
 817
 818   def maybe_retire_websub(ap_id) do
 819     # some sanity checks
 820     if is_binary(ap_id) && String.length(ap_id) > 8 do
 821       q =
 822         from(
 823           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 824           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 825         )
 826
 827       Repo.delete_all(q)
 828     end
 829   end
 830
 831   def maybe_fix_user_url(data) do
 832     if is_map(data["url"]) do
 833       Map.put(data, "url", data["url"]["href"])
 834     else
 835       data
 836     end
 837   end
 838
 839   def maybe_fix_user_object(data) do
 840     data
 841     |> maybe_fix_user_url
 842   end
 843 end