git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type == "Person" end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => actor}) when is_map(actor) do
  30     actor["id"]
  31   end
  32
  33   @doc """
  34   Checks that an imported AP object's actor matches the domain it came from.
  35   """
  36   def contain_origin(id, %{"actor" => actor} = params) do
  37     id_uri = URI.parse(id)
  38     actor_uri = URI.parse(get_actor(params))
  39
  40     if id_uri.host == actor_uri.host do
  41       :ok
  42     else
  43       :error
  44     end
  45   end
  46
  47   @doc """
  48   Modifies an incoming AP object (mastodon format) to our internal format.
  49   """
  50   def fix_object(object) do
  51     object
  52     |> fix_actor
  53     |> fix_attachments
  54     |> fix_context
  55     |> fix_in_reply_to
  56     |> fix_emoji
  57     |> fix_tag
  58     |> fix_content_map
  59     |> fix_likes
  60     |> fix_addressing
  61   end
  62
  63   def fix_addressing_list(map, field) do
  64     if is_binary(map[field]) do
  65       map
  66       |> Map.put(field, [map[field]])
  67     else
  68       map
  69     end
  70   end
  71
  72   def fix_addressing(map) do
  73     map
  74     |> fix_addressing_list("to")
  75     |> fix_addressing_list("cc")
  76     |> fix_addressing_list("bto")
  77     |> fix_addressing_list("bcc")
  78   end
  79
  80   def fix_actor(%{"attributedTo" => actor} = object) do
  81     object
  82     |> Map.put("actor", get_actor(%{"actor" => actor}))
  83   end
  84
  85   def fix_likes(%{"likes" => likes} = object)
  86       when is_bitstring(likes) do
  87     # Check for standardisation
  88     # This is what Peertube does
  89     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
  90     object
  91     |> Map.put("likes", [])
  92     |> Map.put("like_count", 0)
  93   end
  94
  95   def fix_likes(object) do
  96     object
  97   end
  98
  99   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 100       when not is_nil(in_reply_to) do
 101     in_reply_to_id =
 102       if is_bitstring(in_reply_to) do
 103         in_reply_to
 104       else
 105         if is_map(in_reply_to) && in_reply_to["id"] do
 106           in_reply_to["id"]
 107         end
 108       end
 109
 110     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
 111       {:ok, replied_object} ->
 112         with %Activity{} = activity <-
 113                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 114           object
 115           |> Map.put("inReplyTo", replied_object.data["id"])
 116           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 117           |> Map.put("inReplyToStatusId", activity.id)
 118           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 119           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 120         else
 121           e ->
 122             Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 123             object
 124         end
 125
 126       e ->
 127         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 128         object
 129     end
 130   end
 131
 132   def fix_in_reply_to(object), do: object
 133
 134   def fix_context(object) do
 135     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 136
 137     object
 138     |> Map.put("context", context)
 139     |> Map.put("conversation", context)
 140   end
 141
 142   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 143     attachments =
 144       attachment
 145       |> Enum.map(fn data ->
 146         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 147         Map.put(data, "url", url)
 148       end)
 149
 150     object
 151     |> Map.put("attachment", attachments)
 152   end
 153
 154   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 155     attachment =
 156       Map.put(attachment, "url", [
 157         %{"type" => "Link", "mediaType" => attachment["mediaType"], "href" => attachment["url"]}
 158       ])
 159
 160     Map.put(object, "attachment", attachment)
 161   end
 162
 163   def fix_attachments(object) do
 164     object
 165   end
 166
 167   def fix_emoji(object) do
 168     tags = object["tag"] || []
 169     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 170
 171     emoji =
 172       emoji
 173       |> Enum.reduce(%{}, fn data, mapping ->
 174         name = data["name"]
 175
 176         name =
 177           if String.starts_with?(name, ":") do
 178             name |> String.slice(1..-2)
 179           else
 180             name
 181           end
 182
 183         mapping |> Map.put(name, data["icon"]["url"])
 184       end)
 185
 186     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 187     emoji = Map.merge(object["emoji"] || %{}, emoji)
 188
 189     object
 190     |> Map.put("emoji", emoji)
 191   end
 192
 193   def fix_tag(object) do
 194     tags =
 195       (object["tag"] || [])
 196       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 197       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 198
 199     combined = (object["tag"] || []) ++ tags
 200
 201     object
 202     |> Map.put("tag", combined)
 203   end
 204
 205   # content map usually only has one language so this will do for now.
 206   def fix_content_map(%{"contentMap" => content_map} = object) do
 207     content_groups = Map.to_list(content_map)
 208     {_, content} = Enum.at(content_groups, 0)
 209
 210     object
 211     |> Map.put("content", content)
 212   end
 213
 214   def fix_content_map(object), do: object
 215
 216   # disallow objects with bogus IDs
 217   def handle_incoming(%{"id" => nil}), do: :error
 218   def handle_incoming(%{"id" => ""}), do: :error
 219   # length of https:// = 8, should validate better, but good enough for now.
 220   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 221
 222   # TODO: validate those with a Ecto scheme
 223   # - tags
 224   # - emoji
 225   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 226       when objtype in ["Article", "Note", "Video"] do
 227     actor = get_actor(data)
 228
 229     data =
 230       Map.put(data, "actor", actor)
 231       |> fix_addressing
 232
 233     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 234          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 235       object = fix_object(data["object"])
 236
 237       params = %{
 238         to: data["to"],
 239         object: object,
 240         actor: user,
 241         context: object["conversation"],
 242         local: false,
 243         published: data["published"],
 244         additional:
 245           Map.take(data, [
 246             "cc",
 247             "id"
 248           ])
 249       }
 250
 251       ActivityPub.create(params)
 252     else
 253       %Activity{} = activity -> {:ok, activity}
 254       _e -> :error
 255     end
 256   end
 257
 258   def handle_incoming(
 259         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 260       ) do
 261     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 262          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 263          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 264       if not User.locked?(followed) do
 265         ActivityPub.accept(%{
 266           to: [follower.ap_id],
 267           actor: followed.ap_id,
 268           object: data,
 269           local: true
 270         })
 271
 272         User.follow(follower, followed)
 273       end
 274
 275       {:ok, activity}
 276     else
 277       _e -> :error
 278     end
 279   end
 280
 281   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 282     with true <- id =~ "follows",
 283          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 284          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 285       {:ok, activity}
 286     else
 287       _ -> {:error, nil}
 288     end
 289   end
 290
 291   defp mastodon_follow_hack(_), do: {:error, nil}
 292
 293   defp get_follow_activity(follow_object, followed) do
 294     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 295          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 296       {:ok, activity}
 297     else
 298       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 299       {:activity, nil} ->
 300         mastodon_follow_hack(follow_object, followed)
 301
 302       _ ->
 303         {:error, nil}
 304     end
 305   end
 306
 307   def handle_incoming(
 308         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 309       ) do
 310     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 311          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 312          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 313          {:ok, activity} <-
 314            ActivityPub.accept(%{
 315              to: follow_activity.data["to"],
 316              type: "Accept",
 317              actor: followed.ap_id,
 318              object: follow_activity.data["id"],
 319              local: false
 320            }) do
 321       if not User.following?(follower, followed) do
 322         {:ok, follower} = User.follow(follower, followed)
 323       end
 324
 325       {:ok, activity}
 326     else
 327       _e -> :error
 328     end
 329   end
 330
 331   def handle_incoming(
 332         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 333       ) do
 334     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 335          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 336          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 337          {:ok, activity} <-
 338            ActivityPub.accept(%{
 339              to: follow_activity.data["to"],
 340              type: "Accept",
 341              actor: followed.ap_id,
 342              object: follow_activity.data["id"],
 343              local: false
 344            }) do
 345       User.unfollow(follower, followed)
 346
 347       {:ok, activity}
 348     else
 349       _e -> :error
 350     end
 351   end
 352
 353   def handle_incoming(
 354         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 355       ) do
 356     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 357          {:ok, object} <-
 358            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 359          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 360       {:ok, activity}
 361     else
 362       _e -> :error
 363     end
 364   end
 365
 366   def handle_incoming(
 367         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 368       ) do
 369     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 370          {:ok, object} <-
 371            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 372          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 373       {:ok, activity}
 374     else
 375       _e -> :error
 376     end
 377   end
 378
 379   def handle_incoming(
 380         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 381           data
 382       )
 383       when object_type in ["Person", "Application", "Service", "Organization"] do
 384     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 385       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 386
 387       banner = new_user_data[:info]["banner"]
 388       locked = new_user_data[:info]["locked"] || false
 389
 390       update_data =
 391         new_user_data
 392         |> Map.take([:name, :bio, :avatar])
 393         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 394
 395       actor
 396       |> User.upgrade_changeset(update_data)
 397       |> User.update_and_set_cache()
 398
 399       ActivityPub.update(%{
 400         local: false,
 401         to: data["to"] || [],
 402         cc: data["cc"] || [],
 403         object: object,
 404         actor: actor_id
 405       })
 406     else
 407       e ->
 408         Logger.error(e)
 409         :error
 410     end
 411   end
 412
 413   # TODO: Make secure.
 414   def handle_incoming(
 415         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 416       ) do
 417     object_id = Utils.get_ap_id(object_id)
 418
 419     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 420          {:ok, object} <-
 421            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 422          {:ok, activity} <- ActivityPub.delete(object, false) do
 423       {:ok, activity}
 424     else
 425       _e -> :error
 426     end
 427   end
 428
 429   def handle_incoming(
 430         %{
 431           "type" => "Undo",
 432           "object" => %{"type" => "Announce", "object" => object_id},
 433           "actor" => actor,
 434           "id" => id
 435         } = _data
 436       ) do
 437     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 438          {:ok, object} <-
 439            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 440          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 441       {:ok, activity}
 442     else
 443       _e -> :error
 444     end
 445   end
 446
 447   def handle_incoming(
 448         %{
 449           "type" => "Undo",
 450           "object" => %{"type" => "Follow", "object" => followed},
 451           "actor" => follower,
 452           "id" => id
 453         } = _data
 454       ) do
 455     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 456          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 457          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 458       User.unfollow(follower, followed)
 459       {:ok, activity}
 460     else
 461       e -> :error
 462     end
 463   end
 464
 465   @ap_config Application.get_env(:pleroma, :activitypub)
 466   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 467
 468   def handle_incoming(
 469         %{
 470           "type" => "Undo",
 471           "object" => %{"type" => "Block", "object" => blocked},
 472           "actor" => blocker,
 473           "id" => id
 474         } = _data
 475       ) do
 476     with true <- @accept_blocks,
 477          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 478          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 479          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 480       User.unblock(blocker, blocked)
 481       {:ok, activity}
 482     else
 483       e -> :error
 484     end
 485   end
 486
 487   def handle_incoming(
 488         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 489       ) do
 490     with true <- @accept_blocks,
 491          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 492          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 493          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 494       User.unfollow(blocker, blocked)
 495       User.block(blocker, blocked)
 496       {:ok, activity}
 497     else
 498       e -> :error
 499     end
 500   end
 501
 502   def handle_incoming(
 503         %{
 504           "type" => "Undo",
 505           "object" => %{"type" => "Like", "object" => object_id},
 506           "actor" => actor,
 507           "id" => id
 508         } = _data
 509       ) do
 510     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 511          {:ok, object} <-
 512            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 513          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 514       {:ok, activity}
 515     else
 516       _e -> :error
 517     end
 518   end
 519
 520   def handle_incoming(_), do: :error
 521
 522   def get_obj_helper(id) do
 523     if object = Object.normalize(id), do: {:ok, object}, else: nil
 524   end
 525
 526   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 527     with false <- String.starts_with?(inReplyTo, "http"),
 528          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 529       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 530     else
 531       _e -> object
 532     end
 533   end
 534
 535   def set_reply_to_uri(obj), do: obj
 536
 537   # Prepares the object of an outgoing create activity.
 538   def prepare_object(object) do
 539     object
 540     |> set_sensitive
 541     |> add_hashtags
 542     |> add_mention_tags
 543     |> add_emoji_tags
 544     |> add_attributed_to
 545     |> prepare_attachments
 546     |> set_conversation
 547     |> set_reply_to_uri
 548   end
 549
 550   #  @doc
 551   #  """
 552   #  internal -> Mastodon
 553   #  """
 554
 555   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 556     object =
 557       object
 558       |> prepare_object
 559
 560     data =
 561       data
 562       |> Map.put("object", object)
 563       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 564
 565     {:ok, data}
 566   end
 567
 568   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 569   # because of course it does.
 570   def prepare_outgoing(%{"type" => "Accept"} = data) do
 571     with follow_activity <- Activity.normalize(data["object"]) do
 572       object = %{
 573         "actor" => follow_activity.actor,
 574         "object" => follow_activity.data["object"],
 575         "id" => follow_activity.data["id"],
 576         "type" => "Follow"
 577       }
 578
 579       data =
 580         data
 581         |> Map.put("object", object)
 582         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 583
 584       {:ok, data}
 585     end
 586   end
 587
 588   def prepare_outgoing(%{"type" => "Reject"} = data) do
 589     with follow_activity <- Activity.normalize(data["object"]) do
 590       object = %{
 591         "actor" => follow_activity.actor,
 592         "object" => follow_activity.data["object"],
 593         "id" => follow_activity.data["id"],
 594         "type" => "Follow"
 595       }
 596
 597       data =
 598         data
 599         |> Map.put("object", object)
 600         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 601
 602       {:ok, data}
 603     end
 604   end
 605
 606   def prepare_outgoing(%{"type" => _type} = data) do
 607     data =
 608       data
 609       |> maybe_fix_object_url
 610       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 611
 612     {:ok, data}
 613   end
 614
 615   def maybe_fix_object_url(data) do
 616     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 617       case ActivityPub.fetch_object_from_id(data["object"]) do
 618         {:ok, relative_object} ->
 619           if relative_object.data["external_url"] do
 620             _data =
 621               data
 622               |> Map.put("object", relative_object.data["external_url"])
 623           else
 624             data
 625           end
 626
 627         e ->
 628           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 629           data
 630       end
 631     else
 632       data
 633     end
 634   end
 635
 636   def add_hashtags(object) do
 637     tags =
 638       (object["tag"] || [])
 639       |> Enum.map(fn tag ->
 640         %{
 641           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 642           "name" => "##{tag}",
 643           "type" => "Hashtag"
 644         }
 645       end)
 646
 647     object
 648     |> Map.put("tag", tags)
 649   end
 650
 651   def add_mention_tags(object) do
 652     recipients = object["to"] ++ (object["cc"] || [])
 653
 654     mentions =
 655       recipients
 656       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 657       |> Enum.filter(& &1)
 658       |> Enum.map(fn user ->
 659         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 660       end)
 661
 662     tags = object["tag"] || []
 663
 664     object
 665     |> Map.put("tag", tags ++ mentions)
 666   end
 667
 668   # TODO: we should probably send mtime instead of unix epoch time for updated
 669   def add_emoji_tags(object) do
 670     tags = object["tag"] || []
 671     emoji = object["emoji"] || []
 672
 673     out =
 674       emoji
 675       |> Enum.map(fn {name, url} ->
 676         %{
 677           "icon" => %{"url" => url, "type" => "Image"},
 678           "name" => ":" <> name <> ":",
 679           "type" => "Emoji",
 680           "updated" => "1970-01-01T00:00:00Z",
 681           "id" => url
 682         }
 683       end)
 684
 685     object
 686     |> Map.put("tag", tags ++ out)
 687   end
 688
 689   def set_conversation(object) do
 690     Map.put(object, "conversation", object["context"])
 691   end
 692
 693   def set_sensitive(object) do
 694     tags = object["tag"] || []
 695     Map.put(object, "sensitive", "nsfw" in tags)
 696   end
 697
 698   def add_attributed_to(object) do
 699     attributedTo = object["attributedTo"] || object["actor"]
 700
 701     object
 702     |> Map.put("attributedTo", attributedTo)
 703   end
 704
 705   def prepare_attachments(object) do
 706     attachments =
 707       (object["attachment"] || [])
 708       |> Enum.map(fn data ->
 709         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 710         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 711       end)
 712
 713     object
 714     |> Map.put("attachment", attachments)
 715   end
 716
 717   defp user_upgrade_task(user) do
 718     old_follower_address = User.ap_followers(user)
 719
 720     q =
 721       from(
 722         u in User,
 723         where: ^old_follower_address in u.following,
 724         update: [
 725           set: [
 726             following:
 727               fragment(
 728                 "array_replace(?,?,?)",
 729                 u.following,
 730                 ^old_follower_address,
 731                 ^user.follower_address
 732               )
 733           ]
 734         ]
 735       )
 736
 737     Repo.update_all(q, [])
 738
 739     maybe_retire_websub(user.ap_id)
 740
 741     # Only do this for recent activties, don't go through the whole db.
 742     # Only look at the last 1000 activities.
 743     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 744
 745     q =
 746       from(
 747         a in Activity,
 748         where: ^old_follower_address in a.recipients,
 749         where: a.id > ^since,
 750         update: [
 751           set: [
 752             recipients:
 753               fragment(
 754                 "array_replace(?,?,?)",
 755                 a.recipients,
 756                 ^old_follower_address,
 757                 ^user.follower_address
 758               )
 759           ]
 760         ]
 761       )
 762
 763     Repo.update_all(q, [])
 764   end
 765
 766   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 767     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 768          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 769       data =
 770         data
 771         |> Map.put(:info, Map.merge(user.info, data[:info]))
 772
 773       already_ap = User.ap_enabled?(user)
 774
 775       {:ok, user} =
 776         User.upgrade_changeset(user, data)
 777         |> Repo.update()
 778
 779       if !already_ap do
 780         # This could potentially take a long time, do it in the background
 781         if async do
 782           Task.start(fn ->
 783             user_upgrade_task(user)
 784           end)
 785         else
 786           user_upgrade_task(user)
 787         end
 788       end
 789
 790       {:ok, user}
 791     else
 792       e -> e
 793     end
 794   end
 795
 796   def maybe_retire_websub(ap_id) do
 797     # some sanity checks
 798     if is_binary(ap_id) && String.length(ap_id) > 8 do
 799       q =
 800         from(
 801           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 802           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 803         )
 804
 805       Repo.delete_all(q)
 806     end
 807   end
 808
 809   def maybe_fix_user_url(data) do
 810     if is_map(data["url"]) do
 811       Map.put(data, "url", data["url"]["href"])
 812     else
 813       data
 814     end
 815   end
 816
 817   def maybe_fix_user_object(data) do
 818     data
 819     |> maybe_fix_user_url
 820   end
 821 end