git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.EarmarkRenderer
  11   alias Pleroma.FollowingRelationship
  12   alias Pleroma.Object
  13   alias Pleroma.Object.Containment
  14   alias Pleroma.Repo
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ActivityPub
  17   alias Pleroma.Web.ActivityPub.Builder
  18   alias Pleroma.Web.ActivityPub.ObjectValidator
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  20   alias Pleroma.Web.ActivityPub.Pipeline
  21   alias Pleroma.Web.ActivityPub.Utils
  22   alias Pleroma.Web.ActivityPub.Visibility
  23   alias Pleroma.Web.Federator
  24   alias Pleroma.Workers.TransmogrifierWorker
  25
  26   import Ecto.Query
  27
  28   require Logger
  29   require Pleroma.Constants
  30
  31   @doc """
  32   Modifies an incoming AP object (mastodon format) to our internal format.
  33   """
  34   def fix_object(object, options \\ []) do
  35     object
  36     |> strip_internal_fields
  37     |> fix_actor
  38     |> fix_url
  39     |> fix_attachments
  40     |> fix_context
  41     |> fix_in_reply_to(options)
  42     |> fix_emoji
  43     |> fix_tag
  44     |> fix_content_map
  45     |> fix_addressing
  46     |> fix_summary
  47     |> fix_type(options)
  48     |> fix_content
  49   end
  50
  51   def fix_summary(%{"summary" => nil} = object) do
  52     Map.put(object, "summary", "")
  53   end
  54
  55   def fix_summary(%{"summary" => _} = object) do
  56     # summary is present, nothing to do
  57     object
  58   end
  59
  60   def fix_summary(object), do: Map.put(object, "summary", "")
  61
  62   def fix_addressing_list(map, field) do
  63     cond do
  64       is_binary(map[field]) ->
  65         Map.put(map, field, [map[field]])
  66
  67       is_nil(map[field]) ->
  68         Map.put(map, field, [])
  69
  70       true ->
  71         map
  72     end
  73   end
  74
  75   def fix_explicit_addressing(
  76         %{"to" => to, "cc" => cc} = object,
  77         explicit_mentions,
  78         follower_collection
  79       ) do
  80     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  81
  82     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  83
  84     final_cc =
  85       (cc ++ explicit_cc)
  86       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  87       |> Enum.uniq()
  88
  89     object
  90     |> Map.put("to", explicit_to)
  91     |> Map.put("cc", final_cc)
  92   end
  93
  94   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  95
  96   # if directMessage flag is set to true, leave the addressing alone
  97   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  98
  99   def fix_explicit_addressing(object) do
 100     explicit_mentions = Utils.determine_explicit_mentions(object)
 101
 102     %User{follower_address: follower_collection} =
 103       object
 104       |> Containment.get_actor()
 105       |> User.get_cached_by_ap_id()
 106
 107     explicit_mentions =
 108       explicit_mentions ++
 109         [
 110           Pleroma.Constants.as_public(),
 111           follower_collection
 112         ]
 113
 114     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 115   end
 116
 117   # if as:Public is addressed, then make sure the followers collection is also addressed
 118   # so that the activities will be delivered to local users.
 119   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 120     recipients = to ++ cc
 121
 122     if followers_collection not in recipients do
 123       cond do
 124         Pleroma.Constants.as_public() in cc ->
 125           to = to ++ [followers_collection]
 126           Map.put(object, "to", to)
 127
 128         Pleroma.Constants.as_public() in to ->
 129           cc = cc ++ [followers_collection]
 130           Map.put(object, "cc", cc)
 131
 132         true ->
 133           object
 134       end
 135     else
 136       object
 137     end
 138   end
 139
 140   def fix_implicit_addressing(object, _), do: object
 141
 142   def fix_addressing(object) do
 143     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 144     followers_collection = User.ap_followers(user)
 145
 146     object
 147     |> fix_addressing_list("to")
 148     |> fix_addressing_list("cc")
 149     |> fix_addressing_list("bto")
 150     |> fix_addressing_list("bcc")
 151     |> fix_explicit_addressing()
 152     |> fix_implicit_addressing(followers_collection)
 153   end
 154
 155   def fix_actor(%{"attributedTo" => actor} = object) do
 156     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 157   end
 158
 159   def fix_in_reply_to(object, options \\ [])
 160
 161   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 162       when not is_nil(in_reply_to) do
 163     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 164     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 165     depth = (options[:depth] || 0) + 1
 166
 167     if Federator.allowed_thread_distance?(depth) do
 168       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 169            %Activity{} <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 170         object
 171         |> Map.put("inReplyTo", replied_object.data["id"])
 172         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 173         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 174         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 175       else
 176         e ->
 177           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 178           object
 179       end
 180     else
 181       object
 182     end
 183   end
 184
 185   def fix_in_reply_to(object, _options), do: object
 186
 187   defp prepare_in_reply_to(in_reply_to) do
 188     cond do
 189       is_bitstring(in_reply_to) ->
 190         in_reply_to
 191
 192       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 193         in_reply_to["id"]
 194
 195       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 196         Enum.at(in_reply_to, 0)
 197
 198       true ->
 199         ""
 200     end
 201   end
 202
 203   def fix_context(object) do
 204     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 205
 206     object
 207     |> Map.put("context", context)
 208     |> Map.put("conversation", context)
 209   end
 210
 211   defp add_if_present(map, _key, nil), do: map
 212
 213   defp add_if_present(map, key, value) do
 214     Map.put(map, key, value)
 215   end
 216
 217   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 218     attachments =
 219       Enum.map(attachment, fn data ->
 220         url =
 221           cond do
 222             is_list(data["url"]) -> List.first(data["url"])
 223             is_map(data["url"]) -> data["url"]
 224             true -> nil
 225           end
 226
 227         media_type =
 228           cond do
 229             is_map(url) && is_binary(url["mediaType"]) -> url["mediaType"]
 230             is_binary(data["mediaType"]) -> data["mediaType"]
 231             is_binary(data["mimeType"]) -> data["mimeType"]
 232             true -> nil
 233           end
 234
 235         href =
 236           cond do
 237             is_map(url) && is_binary(url["href"]) -> url["href"]
 238             is_binary(data["url"]) -> data["url"]
 239             is_binary(data["href"]) -> data["href"]
 240           end
 241
 242         attachment_url =
 243           %{"href" => href}
 244           |> add_if_present("mediaType", media_type)
 245           |> add_if_present("type", Map.get(url || %{}, "type"))
 246
 247         %{"url" => [attachment_url]}
 248         |> add_if_present("mediaType", media_type)
 249         |> add_if_present("type", data["type"])
 250         |> add_if_present("name", data["name"])
 251       end)
 252
 253     Map.put(object, "attachment", attachments)
 254   end
 255
 256   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 257     object
 258     |> Map.put("attachment", [attachment])
 259     |> fix_attachments()
 260   end
 261
 262   def fix_attachments(object), do: object
 263
 264   def fix_url(%{"url" => url} = object) when is_map(url) do
 265     Map.put(object, "url", url["href"])
 266   end
 267
 268   def fix_url(%{"type" => object_type, "url" => url} = object)
 269       when object_type in ["Video", "Audio"] and is_list(url) do
 270     first_element = Enum.at(url, 0)
 271
 272     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 273
 274     object
 275     |> Map.put("attachment", [first_element])
 276     |> Map.put("url", link_element["href"])
 277   end
 278
 279   def fix_url(%{"type" => object_type, "url" => url} = object)
 280       when object_type != "Video" and is_list(url) do
 281     first_element = Enum.at(url, 0)
 282
 283     url_string =
 284       cond do
 285         is_bitstring(first_element) -> first_element
 286         is_map(first_element) -> first_element["href"] || ""
 287         true -> ""
 288       end
 289
 290     Map.put(object, "url", url_string)
 291   end
 292
 293   def fix_url(object), do: object
 294
 295   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 296     emoji =
 297       tags
 298       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 299       |> Enum.reduce(%{}, fn data, mapping ->
 300         name = String.trim(data["name"], ":")
 301
 302         Map.put(mapping, name, data["icon"]["url"])
 303       end)
 304
 305     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 306     emoji = Map.merge(object["emoji"] || %{}, emoji)
 307
 308     Map.put(object, "emoji", emoji)
 309   end
 310
 311   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 312     name = String.trim(tag["name"], ":")
 313     emoji = %{name => tag["icon"]["url"]}
 314
 315     Map.put(object, "emoji", emoji)
 316   end
 317
 318   def fix_emoji(object), do: object
 319
 320   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 321     tags =
 322       tag
 323       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 324       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 325
 326     Map.put(object, "tag", tag ++ tags)
 327   end
 328
 329   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 330     combined = [tag, String.slice(hashtag, 1..-1)]
 331
 332     Map.put(object, "tag", combined)
 333   end
 334
 335   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 336
 337   def fix_tag(object), do: object
 338
 339   # content map usually only has one language so this will do for now.
 340   def fix_content_map(%{"contentMap" => content_map} = object) do
 341     content_groups = Map.to_list(content_map)
 342     {_, content} = Enum.at(content_groups, 0)
 343
 344     Map.put(object, "content", content)
 345   end
 346
 347   def fix_content_map(object), do: object
 348
 349   def fix_type(object, options \\ [])
 350
 351   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 352       when is_binary(reply_id) do
 353     with true <- Federator.allowed_thread_distance?(options[:depth]),
 354          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 355       Map.put(object, "type", "Answer")
 356     else
 357       _ -> object
 358     end
 359   end
 360
 361   def fix_type(object, _), do: object
 362
 363   defp fix_content(%{"mediaType" => "text/markdown", "content" => content} = object)
 364        when is_binary(content) do
 365     html_content =
 366       content
 367       |> Earmark.as_html!(%Earmark.Options{renderer: EarmarkRenderer})
 368       |> Pleroma.HTML.filter_tags()
 369
 370     Map.merge(object, %{"content" => html_content, "mediaType" => "text/html"})
 371   end
 372
 373   defp fix_content(object), do: object
 374
 375   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 376     with true <- id =~ "follows",
 377          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 378          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 379       {:ok, activity}
 380     else
 381       _ -> {:error, nil}
 382     end
 383   end
 384
 385   defp mastodon_follow_hack(_, _), do: {:error, nil}
 386
 387   defp get_follow_activity(follow_object, followed) do
 388     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 389          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 390       {:ok, activity}
 391     else
 392       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 393       {:activity, nil} ->
 394         mastodon_follow_hack(follow_object, followed)
 395
 396       _ ->
 397         {:error, nil}
 398     end
 399   end
 400
 401   # Reduce the object list to find the reported user.
 402   defp get_reported(objects) do
 403     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 404       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 405         {:halt, user}
 406       else
 407         _ -> {:cont, nil}
 408       end
 409     end)
 410   end
 411
 412   def handle_incoming(data, options \\ [])
 413
 414   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 415   # with nil ID.
 416   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 417     with context <- data["context"] || Utils.generate_context_id(),
 418          content <- data["content"] || "",
 419          %User{} = actor <- User.get_cached_by_ap_id(actor),
 420          # Reduce the object list to find the reported user.
 421          %User{} = account <- get_reported(objects),
 422          # Remove the reported user from the object list.
 423          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 424       %{
 425         actor: actor,
 426         context: context,
 427         account: account,
 428         statuses: statuses,
 429         content: content,
 430         additional: %{"cc" => [account.ap_id]}
 431       }
 432       |> ActivityPub.flag()
 433     end
 434   end
 435
 436   # disallow objects with bogus IDs
 437   def handle_incoming(%{"id" => nil}, _options), do: :error
 438   def handle_incoming(%{"id" => ""}, _options), do: :error
 439   # length of https:// = 8, should validate better, but good enough for now.
 440   def handle_incoming(%{"id" => id}, _options) when is_binary(id) and byte_size(id) < 8,
 441     do: :error
 442
 443   # TODO: validate those with a Ecto scheme
 444   # - tags
 445   # - emoji
 446   def handle_incoming(
 447         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 448         options
 449       )
 450       when objtype in ["Article", "Event", "Note", "Video", "Page", "Question", "Answer", "Audio"] do
 451     actor = Containment.get_actor(data)
 452
 453     data =
 454       Map.put(data, "actor", actor)
 455       |> fix_addressing
 456
 457     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 458          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 459       object = fix_object(object, options)
 460
 461       params = %{
 462         to: data["to"],
 463         object: object,
 464         actor: user,
 465         context: object["conversation"],
 466         local: false,
 467         published: data["published"],
 468         additional:
 469           Map.take(data, [
 470             "cc",
 471             "directMessage",
 472             "id"
 473           ])
 474       }
 475
 476       with {:ok, created_activity} <- ActivityPub.create(params) do
 477         reply_depth = (options[:depth] || 0) + 1
 478
 479         if Federator.allowed_thread_distance?(reply_depth) do
 480           for reply_id <- replies(object) do
 481             Pleroma.Workers.RemoteFetcherWorker.enqueue("fetch_remote", %{
 482               "id" => reply_id,
 483               "depth" => reply_depth
 484             })
 485           end
 486         end
 487
 488         {:ok, created_activity}
 489       end
 490     else
 491       %Activity{} = activity -> {:ok, activity}
 492       _e -> :error
 493     end
 494   end
 495
 496   def handle_incoming(
 497         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 498         options
 499       ) do
 500     actor = Containment.get_actor(data)
 501
 502     data =
 503       Map.put(data, "actor", actor)
 504       |> fix_addressing
 505
 506     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 507       reply_depth = (options[:depth] || 0) + 1
 508       options = Keyword.put(options, :depth, reply_depth)
 509       object = fix_object(object, options)
 510
 511       params = %{
 512         to: data["to"],
 513         object: object,
 514         actor: user,
 515         context: nil,
 516         local: false,
 517         published: data["published"],
 518         additional: Map.take(data, ["cc", "id"])
 519       }
 520
 521       ActivityPub.listen(params)
 522     else
 523       _e -> :error
 524     end
 525   end
 526
 527   def handle_incoming(
 528         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 529         _options
 530       ) do
 531     with %User{local: true} = followed <-
 532            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 533          {:ok, %User{} = follower} <-
 534            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 535          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 536       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 537            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 538            {_, false} <- {:user_locked, User.locked?(followed)},
 539            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 540            {_, {:ok, _}} <-
 541              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 542            {:ok, _relationship} <-
 543              FollowingRelationship.update(follower, followed, :follow_accept) do
 544         ActivityPub.accept(%{
 545           to: [follower.ap_id],
 546           actor: followed,
 547           object: data,
 548           local: true
 549         })
 550       else
 551         {:user_blocked, true} ->
 552           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 553           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 554
 555           ActivityPub.reject(%{
 556             to: [follower.ap_id],
 557             actor: followed,
 558             object: data,
 559             local: true
 560           })
 561
 562         {:follow, {:error, _}} ->
 563           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 564           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 565
 566           ActivityPub.reject(%{
 567             to: [follower.ap_id],
 568             actor: followed,
 569             object: data,
 570             local: true
 571           })
 572
 573         {:user_locked, true} ->
 574           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_pending)
 575           :noop
 576       end
 577
 578       {:ok, activity}
 579     else
 580       _e ->
 581         :error
 582     end
 583   end
 584
 585   def handle_incoming(
 586         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 587         _options
 588       ) do
 589     with actor <- Containment.get_actor(data),
 590          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 591          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 592          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 593          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 594          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_accept) do
 595       User.update_follower_count(followed)
 596       User.update_following_count(follower)
 597
 598       ActivityPub.accept(%{
 599         to: follow_activity.data["to"],
 600         type: "Accept",
 601         actor: followed,
 602         object: follow_activity.data["id"],
 603         local: false,
 604         activity_id: id
 605       })
 606     else
 607       _e ->
 608         :error
 609     end
 610   end
 611
 612   def handle_incoming(
 613         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 614         _options
 615       ) do
 616     with actor <- Containment.get_actor(data),
 617          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 618          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 619          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 620          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 621          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_reject),
 622          {:ok, activity} <-
 623            ActivityPub.reject(%{
 624              to: follow_activity.data["to"],
 625              type: "Reject",
 626              actor: followed,
 627              object: follow_activity.data["id"],
 628              local: false,
 629              activity_id: id
 630            }) do
 631       {:ok, activity}
 632     else
 633       _e -> :error
 634     end
 635   end
 636
 637   @misskey_reactions %{
 638     "like" => "👍",
 639     "love" => "❤️",
 640     "laugh" => "😆",
 641     "hmm" => "🤔",
 642     "surprise" => "😮",
 643     "congrats" => "🎉",
 644     "angry" => "💢",
 645     "confused" => "😥",
 646     "rip" => "😇",
 647     "pudding" => "🍮",
 648     "star" => "⭐"
 649   }
 650
 651   @doc "Rewrite misskey likes into EmojiReacts"
 652   def handle_incoming(
 653         %{
 654           "type" => "Like",
 655           "_misskey_reaction" => reaction
 656         } = data,
 657         options
 658       ) do
 659     data
 660     |> Map.put("type", "EmojiReact")
 661     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 662     |> handle_incoming(options)
 663   end
 664
 665   def handle_incoming(%{"type" => type} = data, _options) when type in ["Like", "EmojiReact"] do
 666     with :ok <- ObjectValidator.fetch_actor_and_object(data),
 667          {:ok, activity, _meta} <-
 668            Pipeline.common_pipeline(data, local: false) do
 669       {:ok, activity}
 670     else
 671       e -> {:error, e}
 672     end
 673   end
 674
 675   def handle_incoming(
 676         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 677         _options
 678       ) do
 679     with actor <- Containment.get_actor(data),
 680          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 681          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 682          public <- Visibility.is_public?(data),
 683          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 684       {:ok, activity}
 685     else
 686       _e -> :error
 687     end
 688   end
 689
 690   def handle_incoming(
 691         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 692           data,
 693         _options
 694       )
 695       when object_type in [
 696              "Person",
 697              "Application",
 698              "Service",
 699              "Organization"
 700            ] do
 701     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 702       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 703
 704       actor
 705       |> User.remote_user_changeset(new_user_data)
 706       |> User.update_and_set_cache()
 707
 708       ActivityPub.update(%{
 709         local: false,
 710         to: data["to"] || [],
 711         cc: data["cc"] || [],
 712         object: object,
 713         actor: actor_id,
 714         activity_id: data["id"]
 715       })
 716     else
 717       e ->
 718         Logger.error(e)
 719         :error
 720     end
 721   end
 722
 723   def handle_incoming(
 724         %{"type" => "Delete"} = data,
 725         _options
 726       ) do
 727     with {:ok, activity, _} <- Pipeline.common_pipeline(data, local: false) do
 728       {:ok, activity}
 729     else
 730       {:error, {:validate_object, _}} = e ->
 731         # Check if we have a create activity for this
 732         with {:ok, object_id} <- Types.ObjectID.cast(data["object"]),
 733              %Activity{data: %{"actor" => actor}} <-
 734                Activity.create_by_object_ap_id(object_id) |> Repo.one(),
 735              # We have one, insert a tombstone and retry
 736              {:ok, tombstone_data, _} <- Builder.tombstone(actor, object_id),
 737              {:ok, _tombstone} <- Object.create(tombstone_data) do
 738           handle_incoming(data)
 739         else
 740           _ -> e
 741         end
 742     end
 743   end
 744
 745   def handle_incoming(
 746         %{
 747           "type" => "Undo",
 748           "object" => %{"type" => "Follow", "object" => followed},
 749           "actor" => follower,
 750           "id" => id
 751         } = _data,
 752         _options
 753       ) do
 754     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 755          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 756          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 757       User.unfollow(follower, followed)
 758       {:ok, activity}
 759     else
 760       _e -> :error
 761     end
 762   end
 763
 764   def handle_incoming(
 765         %{
 766           "type" => "Undo",
 767           "object" => %{"type" => type}
 768         } = data,
 769         _options
 770       )
 771       when type in ["Like", "EmojiReact", "Announce", "Block"] do
 772     with {:ok, activity, _} <- Pipeline.common_pipeline(data, local: false) do
 773       {:ok, activity}
 774     end
 775   end
 776
 777   # For Undos that don't have the complete object attached, try to find it in our database.
 778   def handle_incoming(
 779         %{
 780           "type" => "Undo",
 781           "object" => object
 782         } = activity,
 783         options
 784       )
 785       when is_binary(object) do
 786     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 787       activity
 788       |> Map.put("object", data)
 789       |> handle_incoming(options)
 790     else
 791       _e -> :error
 792     end
 793   end
 794
 795   def handle_incoming(
 796         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 797         _options
 798       ) do
 799     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 800          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 801          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 802       User.unfollow(blocker, blocked)
 803       User.block(blocker, blocked)
 804       {:ok, activity}
 805     else
 806       _e -> :error
 807     end
 808   end
 809
 810   def handle_incoming(
 811         %{
 812           "type" => "Move",
 813           "actor" => origin_actor,
 814           "object" => origin_actor,
 815           "target" => target_actor
 816         },
 817         _options
 818       ) do
 819     with %User{} = origin_user <- User.get_cached_by_ap_id(origin_actor),
 820          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_actor),
 821          true <- origin_actor in target_user.also_known_as do
 822       ActivityPub.move(origin_user, target_user, false)
 823     else
 824       _e -> :error
 825     end
 826   end
 827
 828   def handle_incoming(_, _), do: :error
 829
 830   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 831   def get_obj_helper(id, options \\ []) do
 832     case Object.normalize(id, true, options) do
 833       %Object{} = object -> {:ok, object}
 834       _ -> nil
 835     end
 836   end
 837
 838   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 839   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 840         ap_id: ap_id
 841       })
 842       when attributed_to == ap_id do
 843     with {:ok, activity} <-
 844            handle_incoming(%{
 845              "type" => "Create",
 846              "to" => data["to"],
 847              "cc" => data["cc"],
 848              "actor" => attributed_to,
 849              "object" => data
 850            }) do
 851       {:ok, Object.normalize(activity)}
 852     else
 853       _ -> get_obj_helper(object_id)
 854     end
 855   end
 856
 857   def get_embedded_obj_helper(object_id, _) do
 858     get_obj_helper(object_id)
 859   end
 860
 861   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 862     with false <- String.starts_with?(in_reply_to, "http"),
 863          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 864       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 865     else
 866       _e -> object
 867     end
 868   end
 869
 870   def set_reply_to_uri(obj), do: obj
 871
 872   @doc """
 873   Serialized Mastodon-compatible `replies` collection containing _self-replies_.
 874   Based on Mastodon's ActivityPub::NoteSerializer#replies.
 875   """
 876   def set_replies(obj_data) do
 877     replies_uris =
 878       with limit when limit > 0 <-
 879              Pleroma.Config.get([:activitypub, :note_replies_output_limit], 0),
 880            %Object{} = object <- Object.get_cached_by_ap_id(obj_data["id"]) do
 881         object
 882         |> Object.self_replies()
 883         |> select([o], fragment("?->>'id'", o.data))
 884         |> limit(^limit)
 885         |> Repo.all()
 886       else
 887         _ -> []
 888       end
 889
 890     set_replies(obj_data, replies_uris)
 891   end
 892
 893   defp set_replies(obj, []) do
 894     obj
 895   end
 896
 897   defp set_replies(obj, replies_uris) do
 898     replies_collection = %{
 899       "type" => "Collection",
 900       "items" => replies_uris
 901     }
 902
 903     Map.merge(obj, %{"replies" => replies_collection})
 904   end
 905
 906   def replies(%{"replies" => %{"first" => %{"items" => items}}}) when not is_nil(items) do
 907     items
 908   end
 909
 910   def replies(%{"replies" => %{"items" => items}}) when not is_nil(items) do
 911     items
 912   end
 913
 914   def replies(_), do: []
 915
 916   # Prepares the object of an outgoing create activity.
 917   def prepare_object(object) do
 918     object
 919     |> set_sensitive
 920     |> add_hashtags
 921     |> add_mention_tags
 922     |> add_emoji_tags
 923     |> add_attributed_to
 924     |> prepare_attachments
 925     |> set_conversation
 926     |> set_reply_to_uri
 927     |> set_replies
 928     |> strip_internal_fields
 929     |> strip_internal_tags
 930     |> set_type
 931   end
 932
 933   #  @doc
 934   #  """
 935   #  internal -> Mastodon
 936   #  """
 937
 938   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 939       when activity_type in ["Create", "Listen"] do
 940     object =
 941       object_id
 942       |> Object.normalize()
 943       |> Map.get(:data)
 944       |> prepare_object
 945
 946     data =
 947       data
 948       |> Map.put("object", object)
 949       |> Map.merge(Utils.make_json_ld_header())
 950       |> Map.delete("bcc")
 951
 952     {:ok, data}
 953   end
 954
 955   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 956     object =
 957       object_id
 958       |> Object.normalize()
 959
 960     data =
 961       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 962         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 963       else
 964         data |> maybe_fix_object_url
 965       end
 966
 967     data =
 968       data
 969       |> strip_internal_fields
 970       |> Map.merge(Utils.make_json_ld_header())
 971       |> Map.delete("bcc")
 972
 973     {:ok, data}
 974   end
 975
 976   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 977   # because of course it does.
 978   def prepare_outgoing(%{"type" => "Accept"} = data) do
 979     with follow_activity <- Activity.normalize(data["object"]) do
 980       object = %{
 981         "actor" => follow_activity.actor,
 982         "object" => follow_activity.data["object"],
 983         "id" => follow_activity.data["id"],
 984         "type" => "Follow"
 985       }
 986
 987       data =
 988         data
 989         |> Map.put("object", object)
 990         |> Map.merge(Utils.make_json_ld_header())
 991
 992       {:ok, data}
 993     end
 994   end
 995
 996   def prepare_outgoing(%{"type" => "Reject"} = data) do
 997     with follow_activity <- Activity.normalize(data["object"]) do
 998       object = %{
 999         "actor" => follow_activity.actor,
1000         "object" => follow_activity.data["object"],
1001         "id" => follow_activity.data["id"],
1002         "type" => "Follow"
1003       }
1004
1005       data =
1006         data
1007         |> Map.put("object", object)
1008         |> Map.merge(Utils.make_json_ld_header())
1009
1010       {:ok, data}
1011     end
1012   end
1013
1014   def prepare_outgoing(%{"type" => _type} = data) do
1015     data =
1016       data
1017       |> strip_internal_fields
1018       |> maybe_fix_object_url
1019       |> Map.merge(Utils.make_json_ld_header())
1020
1021     {:ok, data}
1022   end
1023
1024   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
1025     with false <- String.starts_with?(object, "http"),
1026          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
1027          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
1028            relative_object do
1029       Map.put(data, "object", external_url)
1030     else
1031       {:fetch, e} ->
1032         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
1033         data
1034
1035       _ ->
1036         data
1037     end
1038   end
1039
1040   def maybe_fix_object_url(data), do: data
1041
1042   def add_hashtags(object) do
1043     tags =
1044       (object["tag"] || [])
1045       |> Enum.map(fn
1046         # Expand internal representation tags into AS2 tags.
1047         tag when is_binary(tag) ->
1048           %{
1049             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
1050             "name" => "##{tag}",
1051             "type" => "Hashtag"
1052           }
1053
1054         # Do not process tags which are already AS2 tag objects.
1055         tag when is_map(tag) ->
1056           tag
1057       end)
1058
1059     Map.put(object, "tag", tags)
1060   end
1061
1062   def add_mention_tags(object) do
1063     {enabled_receivers, disabled_receivers} = Utils.get_notified_from_object(object)
1064     potential_receivers = enabled_receivers ++ disabled_receivers
1065     mentions = Enum.map(potential_receivers, &build_mention_tag/1)
1066
1067     tags = object["tag"] || []
1068     Map.put(object, "tag", tags ++ mentions)
1069   end
1070
1071   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1072     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1073   end
1074
1075   def take_emoji_tags(%User{emoji: emoji}) do
1076     emoji
1077     |> Map.to_list()
1078     |> Enum.map(&build_emoji_tag/1)
1079   end
1080
1081   # TODO: we should probably send mtime instead of unix epoch time for updated
1082   def add_emoji_tags(%{"emoji" => emoji} = object) do
1083     tags = object["tag"] || []
1084
1085     out = Enum.map(emoji, &build_emoji_tag/1)
1086
1087     Map.put(object, "tag", tags ++ out)
1088   end
1089
1090   def add_emoji_tags(object), do: object
1091
1092   defp build_emoji_tag({name, url}) do
1093     %{
1094       "icon" => %{"url" => url, "type" => "Image"},
1095       "name" => ":" <> name <> ":",
1096       "type" => "Emoji",
1097       "updated" => "1970-01-01T00:00:00Z",
1098       "id" => url
1099     }
1100   end
1101
1102   def set_conversation(object) do
1103     Map.put(object, "conversation", object["context"])
1104   end
1105
1106   def set_sensitive(%{"sensitive" => true} = object) do
1107     object
1108   end
1109
1110   def set_sensitive(object) do
1111     tags = object["tag"] || []
1112     Map.put(object, "sensitive", "nsfw" in tags)
1113   end
1114
1115   def set_type(%{"type" => "Answer"} = object) do
1116     Map.put(object, "type", "Note")
1117   end
1118
1119   def set_type(object), do: object
1120
1121   def add_attributed_to(object) do
1122     attributed_to = object["attributedTo"] || object["actor"]
1123     Map.put(object, "attributedTo", attributed_to)
1124   end
1125
1126   def prepare_attachments(object) do
1127     attachments =
1128       object
1129       |> Map.get("attachment", [])
1130       |> Enum.map(fn data ->
1131         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1132
1133         %{
1134           "url" => href,
1135           "mediaType" => media_type,
1136           "name" => data["name"],
1137           "type" => "Document"
1138         }
1139       end)
1140
1141     Map.put(object, "attachment", attachments)
1142   end
1143
1144   def strip_internal_fields(object) do
1145     Map.drop(object, Pleroma.Constants.object_internal_fields())
1146   end
1147
1148   defp strip_internal_tags(%{"tag" => tags} = object) do
1149     tags = Enum.filter(tags, fn x -> is_map(x) end)
1150
1151     Map.put(object, "tag", tags)
1152   end
1153
1154   defp strip_internal_tags(object), do: object
1155
1156   def perform(:user_upgrade, user) do
1157     # we pass a fake user so that the followers collection is stripped away
1158     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1159
1160     from(
1161       a in Activity,
1162       where: ^old_follower_address in a.recipients,
1163       update: [
1164         set: [
1165           recipients:
1166             fragment(
1167               "array_replace(?,?,?)",
1168               a.recipients,
1169               ^old_follower_address,
1170               ^user.follower_address
1171             )
1172         ]
1173       ]
1174     )
1175     |> Repo.update_all([])
1176   end
1177
1178   def upgrade_user_from_ap_id(ap_id) do
1179     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1180          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1181          {:ok, user} <- update_user(user, data) do
1182       TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1183       {:ok, user}
1184     else
1185       %User{} = user -> {:ok, user}
1186       e -> e
1187     end
1188   end
1189
1190   defp update_user(user, data) do
1191     user
1192     |> User.remote_user_changeset(data)
1193     |> User.update_and_set_cache()
1194   end
1195
1196   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1197     Map.put(data, "url", url["href"])
1198   end
1199
1200   def maybe_fix_user_url(data), do: data
1201
1202   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1203 end