git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   @doc """
  17   Modifies an incoming AP object (mastodon format) to our internal format.
  18   """
  19   def fix_object(object) do
  20     object
  21     |> Map.put("actor", object["attributedTo"])
  22     |> fix_attachments
  23     |> fix_context
  24     |> fix_in_reply_to
  25     |> fix_emoji
  26     |> fix_tag
  27   end
  28
  29   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  30       when not is_nil(in_reply_to_id) do
  31     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  32       {:ok, replied_object} ->
  33         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  34
  35         object
  36         |> Map.put("inReplyTo", replied_object.data["id"])
  37         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  38         |> Map.put("inReplyToStatusId", activity.id)
  39         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  40         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  41
  42       e ->
  43         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  44         object
  45     end
  46   end
  47
  48   def fix_in_reply_to(object), do: object
  49
  50   def fix_context(object) do
  51     object
  52     |> Map.put("context", object["conversation"])
  53   end
  54
  55   def fix_attachments(object) do
  56     attachments =
  57       (object["attachment"] || [])
  58       |> Enum.map(fn data ->
  59         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  60         Map.put(data, "url", url)
  61       end)
  62
  63     object
  64     |> Map.put("attachment", attachments)
  65   end
  66
  67   def fix_emoji(object) do
  68     tags = object["tag"] || []
  69     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  70
  71     emoji =
  72       emoji
  73       |> Enum.reduce(%{}, fn data, mapping ->
  74         name = data["name"]
  75
  76         name =
  77           if String.starts_with?(name, ":") do
  78             name |> String.slice(1..-2)
  79           else
  80             name
  81           end
  82
  83         mapping |> Map.put(name, data["icon"]["url"])
  84       end)
  85
  86     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  87     emoji = Map.merge(object["emoji"] || %{}, emoji)
  88
  89     object
  90     |> Map.put("emoji", emoji)
  91   end
  92
  93   def fix_tag(object) do
  94     tags =
  95       (object["tag"] || [])
  96       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  97       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  98
  99     combined = (object["tag"] || []) ++ tags
 100
 101     object
 102     |> Map.put("tag", combined)
 103   end
 104
 105   # TODO: validate those with a Ecto scheme
 106   # - tags
 107   # - emoji
 108   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 109     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 110          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 111       object = fix_object(data["object"])
 112
 113       params = %{
 114         to: data["to"],
 115         object: object,
 116         actor: user,
 117         context: object["conversation"],
 118         local: false,
 119         published: data["published"],
 120         additional:
 121           Map.take(data, [
 122             "cc",
 123             "id"
 124           ])
 125       }
 126
 127       ActivityPub.create(params)
 128     else
 129       %Activity{} = activity -> {:ok, activity}
 130       _e -> :error
 131     end
 132   end
 133
 134   def handle_incoming(
 135         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 136       ) do
 137     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 138          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 139          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 140       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 141
 142       User.follow(follower, followed)
 143       {:ok, activity}
 144     else
 145       _e -> :error
 146     end
 147   end
 148
 149   defp get_follow_activity(follow_object) do
 150     cond do
 151       is_map(follow_object) ->
 152         {:ok, follow_object}
 153
 154       is_binary(follow_object) ->
 155         object = Activity.get_by_ap_id(follow_object)
 156
 157         if object do
 158           {:ok, object.data}
 159         else
 160           {:error, nil}
 161         end
 162
 163       true ->
 164         {:error, nil}
 165     end
 166   end
 167
 168   def handle_incoming(
 169         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 170       ) do
 171     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 172          {:ok, follow_activity} <- get_follow_activity(follow_object),
 173          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity["actor"]),
 174          follow_activity <- Utils.fetch_latest_follow(follower, followed),
 175          false <- is_nil(follow_activity),
 176          {:ok, activity} <- ActivityPub.insert(data, true) do
 177       if not User.following?(follower, followed) do
 178         {:ok, follower} = User.follow(follower, followed)
 179       end
 180
 181       {:ok, activity}
 182     else
 183       _e -> :error
 184     end
 185   end
 186
 187   def handle_incoming(
 188         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 189       ) do
 190     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 191          {:ok, follow_activity} <- get_follow_activity(follow_object),
 192          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity["actor"]),
 193          follow_activity <- Utils.fetch_latest_follow(follower, followed),
 194          false <- is_nil(follow_activity),
 195          {:ok, activity} <- ActivityPub.insert(data, true) do
 196       User.unfollow(follower, followed)
 197
 198       {:ok, activity}
 199     else
 200       _e -> :error
 201     end
 202   end
 203
 204   def handle_incoming(
 205         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 206       ) do
 207     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 208          {:ok, object} <-
 209            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 210          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 211       {:ok, activity}
 212     else
 213       _e -> :error
 214     end
 215   end
 216
 217   def handle_incoming(
 218         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 219       ) do
 220     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 221          {:ok, object} <-
 222            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 223          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 224       {:ok, activity}
 225     else
 226       _e -> :error
 227     end
 228   end
 229
 230   def handle_incoming(
 231         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 232           data
 233       ) do
 234     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 235       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 236
 237       banner = new_user_data[:info]["banner"]
 238
 239       update_data =
 240         new_user_data
 241         |> Map.take([:name, :bio, :avatar])
 242         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 243
 244       actor
 245       |> User.upgrade_changeset(update_data)
 246       |> User.update_and_set_cache()
 247
 248       ActivityPub.update(%{
 249         local: false,
 250         to: data["to"] || [],
 251         cc: data["cc"] || [],
 252         object: object,
 253         actor: actor_id
 254       })
 255     else
 256       e ->
 257         Logger.error(e)
 258         :error
 259     end
 260   end
 261
 262   # TODO: Make secure.
 263   def handle_incoming(
 264         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 265       ) do
 266     object_id = Utils.get_ap_id(object_id)
 267
 268     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 269          {:ok, object} <-
 270            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 271          {:ok, activity} <- ActivityPub.delete(object, false) do
 272       {:ok, activity}
 273     else
 274       _e -> :error
 275     end
 276   end
 277
 278   def handle_incoming(
 279         %{
 280           "type" => "Undo",
 281           "object" => %{"type" => "Announce", "object" => object_id},
 282           "actor" => actor,
 283           "id" => id
 284         } = _data
 285       ) do
 286     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 287          {:ok, object} <-
 288            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 289          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 290       {:ok, activity}
 291     else
 292       _e -> :error
 293     end
 294   end
 295
 296   def handle_incoming(
 297         %{
 298           "type" => "Undo",
 299           "object" => %{"type" => "Follow", "object" => followed},
 300           "actor" => follower,
 301           "id" => id
 302         } = _data
 303       ) do
 304     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 305          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 306          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 307       User.unfollow(follower, followed)
 308       {:ok, activity}
 309     else
 310       e -> :error
 311     end
 312   end
 313
 314   def handle_incoming(
 315         %{
 316           "type" => "Undo",
 317           "object" => %{"type" => "Block", "object" => blocked},
 318           "actor" => blocker,
 319           "id" => id
 320         } = _data
 321       ) do
 322     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 323          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 324          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 325       User.unblock(blocker, blocked)
 326       {:ok, activity}
 327     else
 328       e -> :error
 329     end
 330   end
 331
 332   def handle_incoming(
 333         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 334       ) do
 335     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 336          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 337          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 338       User.unfollow(blocker, blocked)
 339       User.block(blocker, blocked)
 340       {:ok, activity}
 341     else
 342       e -> :error
 343     end
 344   end
 345
 346   def handle_incoming(
 347         %{
 348           "type" => "Undo",
 349           "object" => %{"type" => "Like", "object" => object_id},
 350           "actor" => actor,
 351           "id" => id
 352         } = _data
 353       ) do
 354     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 355          {:ok, object} <-
 356            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 357          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 358       {:ok, activity}
 359     else
 360       _e -> :error
 361     end
 362   end
 363
 364   def handle_incoming(_), do: :error
 365
 366   def get_obj_helper(id) do
 367     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 368   end
 369
 370   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 371     with false <- String.starts_with?(inReplyTo, "http"),
 372          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 373       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 374     else
 375       _e -> object
 376     end
 377   end
 378
 379   def set_reply_to_uri(obj), do: obj
 380
 381   # Prepares the object of an outgoing create activity.
 382   def prepare_object(object) do
 383     object
 384     |> set_sensitive
 385     |> add_hashtags
 386     |> add_mention_tags
 387     |> add_emoji_tags
 388     |> add_attributed_to
 389     |> prepare_attachments
 390     |> set_conversation
 391     |> set_reply_to_uri
 392   end
 393
 394   #  @doc
 395   #  """
 396   #  internal -> Mastodon
 397   #  """
 398
 399   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 400     object =
 401       object
 402       |> prepare_object
 403
 404     data =
 405       data
 406       |> Map.put("object", object)
 407       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 408
 409     {:ok, data}
 410   end
 411
 412   def prepare_outgoing(%{"type" => _type} = data) do
 413     data =
 414       data
 415       |> maybe_fix_object_url
 416       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 417
 418     {:ok, data}
 419   end
 420
 421   def maybe_fix_object_url(data) do
 422     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 423       case ActivityPub.fetch_object_from_id(data["object"]) do
 424         {:ok, relative_object} ->
 425           if relative_object.data["external_url"] do
 426             _data =
 427               data
 428               |> Map.put("object", relative_object.data["external_url"])
 429           else
 430             data
 431           end
 432
 433         e ->
 434           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 435           data
 436       end
 437     else
 438       data
 439     end
 440   end
 441
 442   def add_hashtags(object) do
 443     tags =
 444       (object["tag"] || [])
 445       |> Enum.map(fn tag ->
 446         %{
 447           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 448           "name" => "##{tag}",
 449           "type" => "Hashtag"
 450         }
 451       end)
 452
 453     object
 454     |> Map.put("tag", tags)
 455   end
 456
 457   def add_mention_tags(object) do
 458     recipients = object["to"] ++ (object["cc"] || [])
 459
 460     mentions =
 461       recipients
 462       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 463       |> Enum.filter(& &1)
 464       |> Enum.map(fn user ->
 465         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 466       end)
 467
 468     tags = object["tag"] || []
 469
 470     object
 471     |> Map.put("tag", tags ++ mentions)
 472   end
 473
 474   # TODO: we should probably send mtime instead of unix epoch time for updated
 475   def add_emoji_tags(object) do
 476     tags = object["tag"] || []
 477     emoji = object["emoji"] || []
 478
 479     out =
 480       emoji
 481       |> Enum.map(fn {name, url} ->
 482         %{
 483           "icon" => %{"url" => url, "type" => "Image"},
 484           "name" => ":" <> name <> ":",
 485           "type" => "Emoji",
 486           "updated" => "1970-01-01T00:00:00Z",
 487           "id" => url
 488         }
 489       end)
 490
 491     object
 492     |> Map.put("tag", tags ++ out)
 493   end
 494
 495   def set_conversation(object) do
 496     Map.put(object, "conversation", object["context"])
 497   end
 498
 499   def set_sensitive(object) do
 500     tags = object["tag"] || []
 501     Map.put(object, "sensitive", "nsfw" in tags)
 502   end
 503
 504   def add_attributed_to(object) do
 505     attributedTo = object["attributedTo"] || object["actor"]
 506
 507     object
 508     |> Map.put("attributedTo", attributedTo)
 509   end
 510
 511   def prepare_attachments(object) do
 512     attachments =
 513       (object["attachment"] || [])
 514       |> Enum.map(fn data ->
 515         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 516         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 517       end)
 518
 519     object
 520     |> Map.put("attachment", attachments)
 521   end
 522
 523   defp user_upgrade_task(user) do
 524     old_follower_address = User.ap_followers(user)
 525
 526     q =
 527       from(
 528         u in User,
 529         where: ^old_follower_address in u.following,
 530         update: [
 531           set: [
 532             following:
 533               fragment(
 534                 "array_replace(?,?,?)",
 535                 u.following,
 536                 ^old_follower_address,
 537                 ^user.follower_address
 538               )
 539           ]
 540         ]
 541       )
 542
 543     Repo.update_all(q, [])
 544
 545     maybe_retire_websub(user.ap_id)
 546
 547     # Only do this for recent activties, don't go through the whole db.
 548     # Only look at the last 1000 activities.
 549     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 550
 551     q =
 552       from(
 553         a in Activity,
 554         where: ^old_follower_address in a.recipients,
 555         where: a.id > ^since,
 556         update: [
 557           set: [
 558             recipients:
 559               fragment(
 560                 "array_replace(?,?,?)",
 561                 a.recipients,
 562                 ^old_follower_address,
 563                 ^user.follower_address
 564               )
 565           ]
 566         ]
 567       )
 568
 569     Repo.update_all(q, [])
 570   end
 571
 572   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 573     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 574          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 575       data =
 576         data
 577         |> Map.put(:info, Map.merge(user.info, data[:info]))
 578
 579       already_ap = User.ap_enabled?(user)
 580
 581       {:ok, user} =
 582         User.upgrade_changeset(user, data)
 583         |> Repo.update()
 584
 585       if !already_ap do
 586         # This could potentially take a long time, do it in the background
 587         if async do
 588           Task.start(fn ->
 589             user_upgrade_task(user)
 590           end)
 591         else
 592           user_upgrade_task(user)
 593         end
 594       end
 595
 596       {:ok, user}
 597     else
 598       e -> e
 599     end
 600   end
 601
 602   def maybe_retire_websub(ap_id) do
 603     # some sanity checks
 604     if is_binary(ap_id) && String.length(ap_id) > 8 do
 605       q =
 606         from(
 607           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 608           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 609         )
 610
 611       Repo.delete_all(q)
 612     end
 613   end
 614
 615   def maybe_fix_user_url(data) do
 616     if is_map(data["url"]) do
 617       Map.put(data, "url", data["url"]["href"])
 618     else
 619       data
 620     end
 621   end
 622
 623   def maybe_fix_user_object(data) do
 624     data
 625     |> maybe_fix_user_url
 626   end
 627 end