git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10
  11   import Ecto.Query
  12
  13   require Logger
  14
  15   @doc """
  16   Modifies an incoming AP object (mastodon format) to our internal format.
  17   """
  18   def fix_object(object) do
  19     object
  20     |> Map.put("actor", object["attributedTo"])
  21     |> fix_attachments
  22     |> fix_context
  23     |> fix_in_reply_to
  24     |> fix_emoji
  25     |> fix_tag
  26   end
  27
  28   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object) when not is_nil(in_reply_to_id) do
  29     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  30       {:ok, replied_object} ->
  31         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  32         object
  33         |> Map.put("inReplyTo", replied_object.data["id"])
  34         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  35         |> Map.put("inReplyToStatusId", activity.id)
  36         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  37         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  38       e ->
  39         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  40         object
  41     end
  42   end
  43   def fix_in_reply_to(object), do: object
  44
  45   def fix_context(object) do
  46     object
  47     |> Map.put("context", object["conversation"])
  48   end
  49
  50   def fix_attachments(object) do
  51     attachments = (object["attachment"] || [])
  52     |> Enum.map(fn (data) ->
  53       url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  54       Map.put(data, "url", url)
  55     end)
  56
  57     object
  58     |> Map.put("attachment", attachments)
  59   end
  60
  61   def fix_emoji(object) do
  62     tags = (object["tag"] || [])
  63     emoji = tags |> Enum.filter(fn (data) -> data["type"] == "Emoji" and data["icon"] end)
  64     emoji = emoji |> Enum.reduce(%{}, fn (data, mapping) ->
  65       name = data["name"]
  66       if String.starts_with?(name, ":") do
  67         name = name |> String.slice(1..-2)
  68       end
  69
  70       mapping |> Map.put(name, data["icon"]["url"])
  71     end)
  72
  73     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  74     emoji = Map.merge(object["emoji"] || %{}, emoji)
  75
  76     object
  77     |> Map.put("emoji", emoji)
  78   end
  79
  80   def fix_tag(object) do
  81     tags = (object["tag"] || [])
  82     |> Enum.filter(fn (data) -> data["type"] == "Hashtag" and data["name"] end)
  83     |> Enum.map(fn (data) -> String.slice(data["name"], 1..-1) end)
  84
  85     combined = (object["tag"] || []) ++ tags
  86
  87     object
  88     |> Map.put("tag", combined)
  89   end
  90
  91   # TODO: validate those with a Ecto scheme
  92   # - tags
  93   # - emoji
  94   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
  95     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
  96          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
  97       object = fix_object(data["object"])
  98
  99       params = %{
 100         to: data["to"],
 101         object: object,
 102         actor: user,
 103         context: object["conversation"],
 104         local: false,
 105         published: data["published"],
 106         additional: Map.take(data, [
 107               "cc",
 108               "id"
 109             ])
 110       }
 111
 112
 113       ActivityPub.create(params)
 114     else
 115       %Activity{} = activity -> {:ok, activity}
 116       _e -> :error
 117     end
 118   end
 119
 120   def handle_incoming(%{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data) do
 121     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 122          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 123          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 124       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 125       User.follow(follower, followed)
 126       {:ok, activity}
 127     else
 128       _e -> :error
 129     end
 130   end
 131
 132   def handle_incoming(%{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data) do
 133     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 134          {:ok, object} <- get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 135          {:ok, activity, object} <- ActivityPub.like(actor, object, id, false) do
 136       {:ok, activity}
 137     else
 138       _e -> :error
 139     end
 140   end
 141
 142   def handle_incoming(%{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data) do
 143     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 144          {:ok, object} <- get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 145          {:ok, activity, object} <- ActivityPub.announce(actor, object, id, false) do
 146       {:ok, activity}
 147     else
 148       _e -> :error
 149     end
 150   end
 151
 152   def handle_incoming(%{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} = data) do
 153     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 154       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 155
 156       banner = new_user_data[:info]["banner"]
 157       update_data = new_user_data
 158       |> Map.take([:name, :bio, :avatar])
 159       |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 160
 161       actor
 162       |> User.upgrade_changeset(update_data)
 163       |> User.update_and_set_cache()
 164
 165       ActivityPub.update(%{local: false, to: data["to"] || [], cc: data["cc"] || [], object: object, actor: actor_id})
 166     else
 167       e ->
 168         Logger.error(e)
 169         :error
 170     end
 171   end
 172
 173   # TODO: Make secure.
 174   def handle_incoming(%{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data) do
 175     object_id = case object_id do
 176                   %{"id" => id} -> id
 177                   id -> id
 178                 end
 179     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 180          {:ok, object} <- get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 181          {:ok, activity} <- ActivityPub.delete(object, false) do
 182       {:ok, activity}
 183     else
 184       e -> :error
 185     end
 186   end
 187
 188   # TODO
 189   # Accept
 190   # Undo
 191
 192   def handle_incoming(_), do: :error
 193
 194   def get_obj_helper(id) do
 195     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 196   end
 197
 198   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 199     with false <- String.starts_with?(inReplyTo, "http"),
 200          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 201       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 202     else
 203       _e -> object
 204     end
 205   end
 206   def set_reply_to_uri(obj), do: obj
 207
 208   # Prepares the object of an outgoing create activity.
 209   def prepare_object(object) do
 210     object
 211     |> set_sensitive
 212     |> add_hashtags
 213     |> add_mention_tags
 214     |> add_emoji_tags
 215     |> add_attributed_to
 216     |> prepare_attachments
 217     |> set_conversation
 218     |> set_reply_to_uri
 219   end
 220
 221   @doc
 222   """
 223   internal -> Mastodon
 224   """
 225   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 226     object = object
 227     |> prepare_object
 228     data = data
 229     |> Map.put("object", object)
 230     |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 231
 232     {:ok, data}
 233   end
 234
 235   def prepare_outgoing(%{"type" => type} = data) do
 236     data = data
 237     |> maybe_fix_object_url
 238     |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 239
 240     {:ok, data}
 241   end
 242
 243   def maybe_fix_object_url(data) do
 244     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 245       case ActivityPub.fetch_object_from_id(data["object"]) do
 246         {:ok, relative_object} ->
 247           if relative_object.data["external_url"] do
 248             data = data
 249             |> Map.put("object", relative_object.data["external_url"])
 250           else
 251             data
 252           end
 253         e ->
 254           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 255           data
 256       end
 257     else
 258       data
 259     end
 260   end
 261
 262   def add_hashtags(object) do
 263     tags = (object["tag"] || [])
 264     |> Enum.map fn (tag) -> %{"href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}", "name" => "##{tag}", "type" => "Hashtag"} end
 265
 266     object
 267     |> Map.put("tag", tags)
 268   end
 269
 270   def add_mention_tags(object) do
 271     recipients = object["to"] ++ (object["cc"] || [])
 272     mentions = recipients
 273     |> Enum.map(fn (ap_id) -> User.get_cached_by_ap_id(ap_id) end)
 274     |> Enum.filter(&(&1))
 275     |> Enum.map(fn(user) -> %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"} end)
 276
 277     tags = object["tag"] || []
 278
 279     object
 280     |> Map.put("tag", tags ++ mentions)
 281   end
 282
 283   # TODO: we should probably send mtime instead of unix epoch time for updated
 284   def add_emoji_tags(object) do
 285     tags = object["tag"] || []
 286     emoji = object["emoji"] || []
 287     out = emoji |> Enum.map(fn {name, url} ->
 288       %{"icon" => %{"url" => url, "type" => "Image"},
 289         "name" => ":" <> name <> ":",
 290         "type" => "Emoji",
 291         "updated" => "1970-01-01T00:00:00Z",
 292         "id" => url}
 293     end)
 294
 295     object
 296     |> Map.put("tag", tags ++ out)
 297   end
 298
 299   def set_conversation(object) do
 300     Map.put(object, "conversation", object["context"])
 301   end
 302
 303   def set_sensitive(object) do
 304     tags = object["tag"] || []
 305     Map.put(object, "sensitive", "nsfw" in tags)
 306   end
 307
 308   def add_attributed_to(object) do
 309     attributedTo = object["attributedTo"] || object["actor"]
 310
 311     object
 312     |> Map.put("attributedTo", attributedTo)
 313   end
 314
 315   def prepare_attachments(object) do
 316     attachments = (object["attachment"] || [])
 317     |> Enum.map(fn (data) ->
 318       [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 319       %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 320     end)
 321
 322     object
 323     |> Map.put("attachment", attachments)
 324   end
 325
 326   defp user_upgrade_task(user) do
 327     old_follower_address = User.ap_followers(user)
 328     q  = from u in User,
 329     where: ^old_follower_address in u.following,
 330     update: [set: [following: fragment("array_replace(?,?,?)", u.following, ^old_follower_address, ^user.follower_address)]]
 331     Repo.update_all(q, [])
 332
 333     maybe_retire_websub(user.ap_id)
 334
 335     # Only do this for recent activties, don't go through the whole db.
 336     # Only look at the last 1000 activities.
 337     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 338     q  = from a in Activity,
 339     where: ^old_follower_address in a.recipients,
 340     where: a.id > ^since,
 341     update: [set: [recipients: fragment("array_replace(?,?,?)", a.recipients, ^old_follower_address, ^user.follower_address)]]
 342     Repo.update_all(q, [])
 343   end
 344
 345   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 346     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 347          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 348       data = data
 349       |> Map.put(:info, Map.merge(user.info, data[:info]))
 350
 351       already_ap = User.ap_enabled?(user)
 352       {:ok, user} = User.upgrade_changeset(user, data)
 353       |> Repo.update()
 354
 355       if !already_ap do
 356         # This could potentially take a long time, do it in the background
 357         if async do
 358           Task.start(fn ->
 359             user_upgrade_task(user)
 360           end)
 361         else
 362           user_upgrade_task(user)
 363         end
 364       end
 365
 366       {:ok, user}
 367     else
 368       e -> e
 369     end
 370   end
 371
 372   def maybe_retire_websub(ap_id) do
 373     # some sanity checks
 374     if is_binary(ap_id) && (String.length(ap_id) > 8) do
 375       q = from ws in Pleroma.Web.Websub.WebsubClientSubscription,
 376         where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 377       Repo.delete_all(q)
 378     end
 379   end
 380 end