git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   @doc """
  17   Modifies an incoming AP object (mastodon format) to our internal format.
  18   """
  19   def fix_object(object) do
  20     object
  21     |> Map.put("actor", object["attributedTo"])
  22     |> fix_attachments
  23     |> fix_context
  24     |> fix_in_reply_to
  25     |> fix_emoji
  26     |> fix_tag
  27   end
  28
  29   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  30       when not is_nil(in_reply_to_id) do
  31     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  32       {:ok, replied_object} ->
  33         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  34
  35         object
  36         |> Map.put("inReplyTo", replied_object.data["id"])
  37         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  38         |> Map.put("inReplyToStatusId", activity.id)
  39         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  40         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  41
  42       e ->
  43         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  44         object
  45     end
  46   end
  47
  48   def fix_in_reply_to(object), do: object
  49
  50   def fix_context(object) do
  51     object
  52     |> Map.put("context", object["conversation"])
  53   end
  54
  55   def fix_attachments(object) do
  56     attachments =
  57       (object["attachment"] || [])
  58       |> Enum.map(fn data ->
  59         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  60         Map.put(data, "url", url)
  61       end)
  62
  63     object
  64     |> Map.put("attachment", attachments)
  65   end
  66
  67   def fix_emoji(object) do
  68     tags = object["tag"] || []
  69     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  70
  71     emoji =
  72       emoji
  73       |> Enum.reduce(%{}, fn data, mapping ->
  74         name = data["name"]
  75
  76         name =
  77           if String.starts_with?(name, ":") do
  78             name |> String.slice(1..-2)
  79           else
  80             name
  81           end
  82
  83         mapping |> Map.put(name, data["icon"]["url"])
  84       end)
  85
  86     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  87     emoji = Map.merge(object["emoji"] || %{}, emoji)
  88
  89     object
  90     |> Map.put("emoji", emoji)
  91   end
  92
  93   def fix_tag(object) do
  94     tags =
  95       (object["tag"] || [])
  96       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  97       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  98
  99     combined = (object["tag"] || []) ++ tags
 100
 101     object
 102     |> Map.put("tag", combined)
 103   end
 104
 105   # TODO: validate those with a Ecto scheme
 106   # - tags
 107   # - emoji
 108   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 109     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 110          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 111       object = fix_object(data["object"])
 112
 113       params = %{
 114         to: data["to"],
 115         object: object,
 116         actor: user,
 117         context: object["conversation"],
 118         local: false,
 119         published: data["published"],
 120         additional:
 121           Map.take(data, [
 122             "cc",
 123             "id"
 124           ])
 125       }
 126
 127       ActivityPub.create(params)
 128     else
 129       %Activity{} = activity -> {:ok, activity}
 130       _e -> :error
 131     end
 132   end
 133
 134   def handle_incoming(
 135         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 136       ) do
 137     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 138          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 139          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 140       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 141
 142       User.follow(follower, followed)
 143       {:ok, activity}
 144     else
 145       _e -> :error
 146     end
 147   end
 148
 149   defp get_follow_activity(follow_object) do
 150     cond do
 151       is_map(follow_object) ->
 152         {:ok, follow_object}
 153
 154       is_binary(follow_object) ->
 155         object = get_obj_helper(follow_object) || ActivityPub.fetch_object_from_id(follow_object)
 156
 157         if object do
 158           {:ok, object}
 159         else
 160           {:error, nil}
 161         end
 162
 163       true ->
 164         {:error, nil}
 165     end
 166   end
 167
 168   def handle_incoming(
 169         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 170       ) do
 171     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 172          {:ok, follow_activity} <- get_follow_activity(follow_object),
 173          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity["actor"]) do
 174       if not User.following?(follower, followed) do
 175         User.follow(follower, followed)
 176       end
 177
 178       {:ok, data}
 179     end
 180   end
 181
 182   def handle_incoming(
 183         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 184       ) do
 185     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 186          {:ok, follow_activity} <- get_follow_activity(follow_object),
 187          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity["actor"]) do
 188       User.unfollow(follower, followed)
 189
 190       {:ok, data}
 191     end
 192   end
 193
 194   def handle_incoming(
 195         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 196       ) do
 197     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 198          {:ok, object} <-
 199            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 200          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 201       {:ok, activity}
 202     else
 203       _e -> :error
 204     end
 205   end
 206
 207   def handle_incoming(
 208         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 209       ) do
 210     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 211          {:ok, object} <-
 212            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 213          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 214       {:ok, activity}
 215     else
 216       _e -> :error
 217     end
 218   end
 219
 220   def handle_incoming(
 221         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 222           data
 223       ) do
 224     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 225       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 226
 227       banner = new_user_data[:info]["banner"]
 228
 229       update_data =
 230         new_user_data
 231         |> Map.take([:name, :bio, :avatar])
 232         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 233
 234       actor
 235       |> User.upgrade_changeset(update_data)
 236       |> User.update_and_set_cache()
 237
 238       ActivityPub.update(%{
 239         local: false,
 240         to: data["to"] || [],
 241         cc: data["cc"] || [],
 242         object: object,
 243         actor: actor_id
 244       })
 245     else
 246       e ->
 247         Logger.error(e)
 248         :error
 249     end
 250   end
 251
 252   # TODO: Make secure.
 253   def handle_incoming(
 254         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 255       ) do
 256     object_id =
 257       case object_id do
 258         %{"id" => id} -> id
 259         id -> id
 260       end
 261
 262     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 263          {:ok, object} <-
 264            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 265          {:ok, activity} <- ActivityPub.delete(object, false) do
 266       {:ok, activity}
 267     else
 268       _e -> :error
 269     end
 270   end
 271
 272   def handle_incoming(
 273         %{
 274           "type" => "Undo",
 275           "object" => %{"type" => "Announce", "object" => object_id},
 276           "actor" => actor,
 277           "id" => id
 278         } = _data
 279       ) do
 280     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 281          {:ok, object} <-
 282            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 283          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 284       {:ok, activity}
 285     else
 286       _e -> :error
 287     end
 288   end
 289
 290   def handle_incoming(
 291         %{
 292           "type" => "Undo",
 293           "object" => %{"type" => "Follow", "object" => followed},
 294           "actor" => follower,
 295           "id" => id
 296         } = _data
 297       ) do
 298     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 299          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 300          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 301       User.unfollow(follower, followed)
 302       {:ok, activity}
 303     else
 304       e -> :error
 305     end
 306   end
 307
 308   def handle_incoming(
 309         %{
 310           "type" => "Undo",
 311           "object" => %{"type" => "Block", "object" => blocked},
 312           "actor" => blocker,
 313           "id" => id
 314         } = _data
 315       ) do
 316     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 317          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 318          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 319       User.unblock(blocker, blocked)
 320       {:ok, activity}
 321     else
 322       e -> :error
 323     end
 324   end
 325
 326   def handle_incoming(
 327         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 328       ) do
 329     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 330          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 331          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 332       User.unfollow(blocker, blocked)
 333       User.block(blocker, blocked)
 334       {:ok, activity}
 335     else
 336       e -> :error
 337     end
 338   end
 339
 340   def handle_incoming(
 341         %{
 342           "type" => "Undo",
 343           "object" => %{"type" => "Like", "object" => object_id},
 344           "actor" => actor,
 345           "id" => id
 346         } = _data
 347       ) do
 348     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 349          {:ok, object} <-
 350            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 351          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 352       {:ok, activity}
 353     else
 354       _e -> :error
 355     end
 356   end
 357
 358   # TODO
 359   # Accept
 360
 361   def handle_incoming(_), do: :error
 362
 363   def get_obj_helper(id) do
 364     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 365   end
 366
 367   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 368     with false <- String.starts_with?(inReplyTo, "http"),
 369          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 370       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 371     else
 372       _e -> object
 373     end
 374   end
 375
 376   def set_reply_to_uri(obj), do: obj
 377
 378   # Prepares the object of an outgoing create activity.
 379   def prepare_object(object) do
 380     object
 381     |> set_sensitive
 382     |> add_hashtags
 383     |> add_mention_tags
 384     |> add_emoji_tags
 385     |> add_attributed_to
 386     |> prepare_attachments
 387     |> set_conversation
 388     |> set_reply_to_uri
 389   end
 390
 391   #  @doc
 392   #  """
 393   #  internal -> Mastodon
 394   #  """
 395
 396   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 397     object =
 398       object
 399       |> prepare_object
 400
 401     data =
 402       data
 403       |> Map.put("object", object)
 404       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 405
 406     {:ok, data}
 407   end
 408
 409   def prepare_outgoing(%{"type" => _type} = data) do
 410     data =
 411       data
 412       |> maybe_fix_object_url
 413       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 414
 415     {:ok, data}
 416   end
 417
 418   def maybe_fix_object_url(data) do
 419     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 420       case ActivityPub.fetch_object_from_id(data["object"]) do
 421         {:ok, relative_object} ->
 422           if relative_object.data["external_url"] do
 423             _data =
 424               data
 425               |> Map.put("object", relative_object.data["external_url"])
 426           else
 427             data
 428           end
 429
 430         e ->
 431           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 432           data
 433       end
 434     else
 435       data
 436     end
 437   end
 438
 439   def add_hashtags(object) do
 440     tags =
 441       (object["tag"] || [])
 442       |> Enum.map(fn tag ->
 443         %{
 444           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 445           "name" => "##{tag}",
 446           "type" => "Hashtag"
 447         }
 448       end)
 449
 450     object
 451     |> Map.put("tag", tags)
 452   end
 453
 454   def add_mention_tags(object) do
 455     recipients = object["to"] ++ (object["cc"] || [])
 456
 457     mentions =
 458       recipients
 459       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 460       |> Enum.filter(& &1)
 461       |> Enum.map(fn user ->
 462         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 463       end)
 464
 465     tags = object["tag"] || []
 466
 467     object
 468     |> Map.put("tag", tags ++ mentions)
 469   end
 470
 471   # TODO: we should probably send mtime instead of unix epoch time for updated
 472   def add_emoji_tags(object) do
 473     tags = object["tag"] || []
 474     emoji = object["emoji"] || []
 475
 476     out =
 477       emoji
 478       |> Enum.map(fn {name, url} ->
 479         %{
 480           "icon" => %{"url" => url, "type" => "Image"},
 481           "name" => ":" <> name <> ":",
 482           "type" => "Emoji",
 483           "updated" => "1970-01-01T00:00:00Z",
 484           "id" => url
 485         }
 486       end)
 487
 488     object
 489     |> Map.put("tag", tags ++ out)
 490   end
 491
 492   def set_conversation(object) do
 493     Map.put(object, "conversation", object["context"])
 494   end
 495
 496   def set_sensitive(object) do
 497     tags = object["tag"] || []
 498     Map.put(object, "sensitive", "nsfw" in tags)
 499   end
 500
 501   def add_attributed_to(object) do
 502     attributedTo = object["attributedTo"] || object["actor"]
 503
 504     object
 505     |> Map.put("attributedTo", attributedTo)
 506   end
 507
 508   def prepare_attachments(object) do
 509     attachments =
 510       (object["attachment"] || [])
 511       |> Enum.map(fn data ->
 512         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 513         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 514       end)
 515
 516     object
 517     |> Map.put("attachment", attachments)
 518   end
 519
 520   defp user_upgrade_task(user) do
 521     old_follower_address = User.ap_followers(user)
 522
 523     q =
 524       from(
 525         u in User,
 526         where: ^old_follower_address in u.following,
 527         update: [
 528           set: [
 529             following:
 530               fragment(
 531                 "array_replace(?,?,?)",
 532                 u.following,
 533                 ^old_follower_address,
 534                 ^user.follower_address
 535               )
 536           ]
 537         ]
 538       )
 539
 540     Repo.update_all(q, [])
 541
 542     maybe_retire_websub(user.ap_id)
 543
 544     # Only do this for recent activties, don't go through the whole db.
 545     # Only look at the last 1000 activities.
 546     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 547
 548     q =
 549       from(
 550         a in Activity,
 551         where: ^old_follower_address in a.recipients,
 552         where: a.id > ^since,
 553         update: [
 554           set: [
 555             recipients:
 556               fragment(
 557                 "array_replace(?,?,?)",
 558                 a.recipients,
 559                 ^old_follower_address,
 560                 ^user.follower_address
 561               )
 562           ]
 563         ]
 564       )
 565
 566     Repo.update_all(q, [])
 567   end
 568
 569   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 570     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 571          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 572       data =
 573         data
 574         |> Map.put(:info, Map.merge(user.info, data[:info]))
 575
 576       already_ap = User.ap_enabled?(user)
 577
 578       {:ok, user} =
 579         User.upgrade_changeset(user, data)
 580         |> Repo.update()
 581
 582       if !already_ap do
 583         # This could potentially take a long time, do it in the background
 584         if async do
 585           Task.start(fn ->
 586             user_upgrade_task(user)
 587           end)
 588         else
 589           user_upgrade_task(user)
 590         end
 591       end
 592
 593       {:ok, user}
 594     else
 595       e -> e
 596     end
 597   end
 598
 599   def maybe_retire_websub(ap_id) do
 600     # some sanity checks
 601     if is_binary(ap_id) && String.length(ap_id) > 8 do
 602       q =
 603         from(
 604           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 605           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 606         )
 607
 608       Repo.delete_all(q)
 609     end
 610   end
 611
 612   def maybe_fix_user_url(data) do
 613     if is_map(data["url"]) do
 614       Map.put(data, "url", data["url"]["href"])
 615     else
 616       data
 617     end
 618   end
 619
 620   def maybe_fix_user_object(data) do
 621     data
 622     |> maybe_fix_user_url
 623   end
 624 end