projects / akkoma / blob
? search:


4bc96b00d6053a747c850f0253223ff032a52697
[akkoma] / lib / pleroma / web / activity_pub / transmogrifier.ex
1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
2 @moduledoc """
3 A module to handle coding from internal to wire ActivityPub and back.
4 """
5 alias Pleroma.User
6 alias Pleroma.Object
7 alias Pleroma.Activity
8 alias Pleroma.Repo
9 alias Pleroma.Web.ActivityPub.ActivityPub
10 alias Pleroma.Web.ActivityPub.Utils
11
12 import Ecto.Query
13
14 require Logger
15
16 def get_actor(%{"actor" => actor}) when is_binary(actor) do
17 actor
18 end
19
20 def get_actor(%{"actor" => actor}) when is_list(actor) do
21 if is_binary(Enum.at(actor, 0)) do
22 Enum.at(actor, 0)
23 else
24 Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
25 |> Map.get("id")
26 end
27 end
28
29 def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
30 id
31 end
32
33 def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
34 get_actor(%{"actor" => actor})
35 end
36
37 @doc """
38 Checks that an imported AP object's actor matches the domain it came from.
39 """
40 def contain_origin(_id, %{"actor" => nil}), do: :error
41
42 def contain_origin(id, %{"actor" => _actor} = params) do
43 id_uri = URI.parse(id)
44 actor_uri = URI.parse(get_actor(params))
45
46 if id_uri.host == actor_uri.host do
47 :ok
48 else
49 :error
50 end
51 end
52
53 def contain_origin_from_id(_id, %{"id" => nil}), do: :error
54
55 def contain_origin_from_id(id, %{"id" => other_id} = _params) do
56 id_uri = URI.parse(id)
57 other_uri = URI.parse(other_id)
58
59 if id_uri.host == other_uri.host do
60 :ok
61 else
62 :error
63 end
64 end
65
66 @doc """
67 Modifies an incoming AP object (mastodon format) to our internal format.
68 """
69 def fix_object(object) do
70 object
71 |> fix_actor
72 |> fix_url
73 |> fix_attachments
74 |> fix_context
75 |> fix_in_reply_to
76 |> fix_emoji
77 |> fix_tag
78 |> fix_content_map
79 |> fix_likes
80 |> fix_addressing
81 end
82
83 def fix_addressing_list(map, field) do
84 if is_binary(map[field]) do
85 map
86 |> Map.put(field, [map[field]])
87 else
88 map
89 end
90 end
91
92 def fix_addressing(map) do
93 map
94 |> fix_addressing_list("to")
95 |> fix_addressing_list("cc")
96 |> fix_addressing_list("bto")
97 |> fix_addressing_list("bcc")
98 end
99
100 def fix_actor(%{"attributedTo" => actor} = object) do
101 object
102 |> Map.put("actor", get_actor(%{"actor" => actor}))
103 end
104
105 def fix_likes(%{"likes" => likes} = object)
106 when is_bitstring(likes) do
107 # Check for standardisation
108 # This is what Peertube does
109 # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
110 object
111 |> Map.put("likes", [])
112 |> Map.put("like_count", 0)
113 end
114
115 def fix_likes(object) do
116 object
117 end
118
119 def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
120 when not is_nil(in_reply_to) do
121 in_reply_to_id =
122 cond do
123 is_bitstring(in_reply_to) ->
124 in_reply_to
125
126 is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
127 in_reply_to["id"]
128
129 is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
130 Enum.at(in_reply_to, 0)
131
132 # Maybe I should output an error too?
133 true ->
134 ""
135 end
136
137 case fetch_obj_helper(in_reply_to_id) do
138 {:ok, replied_object} ->
139 with %Activity{} = activity <-
140 Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
141 object
142 |> Map.put("inReplyTo", replied_object.data["id"])
143 |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
144 |> Map.put("inReplyToStatusId", activity.id)
145 |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
146 |> Map.put("context", replied_object.data["context"] || object["conversation"])
147 else
148 e ->
149 Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
150 object
151 end
152
153 e ->
154 Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
155 object
156 end
157 end
158
159 def fix_in_reply_to(object), do: object
160
161 def fix_context(object) do
162 context = object["context"] || object["conversation"] || Utils.generate_context_id()
163
164 object
165 |> Map.put("context", context)
166 |> Map.put("conversation", context)
167 end
168
169 def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
170 attachments =
171 attachment
172 |> Enum.map(fn data ->
173 media_type = data["mediaType"] || data["mimeType"]
174 href = data["url"] || data["href"]
175
176 url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
177
178 data
179 |> Map.put("mediaType", media_type)
180 |> Map.put("url", url)
181 end)
182
183 object
184 |> Map.put("attachment", attachments)
185 end
186
187 def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
188 Map.put(object, "attachment", [attachment])
189 |> fix_attachments()
190 end
191
192 def fix_attachments(object), do: object
193
194 def fix_url(%{"url" => url} = object) when is_map(url) do
195 object
196 |> Map.put("url", url["href"])
197 end
198
199 def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
200 first_element = Enum.at(url, 0)
201
202 link_element =
203 url
204 |> Enum.filter(fn x -> is_map(x) end)
205 |> Enum.filter(fn x -> x["mimeType"] == "text/html" end)
206 |> Enum.at(0)
207
208 object
209 |> Map.put("attachment", [first_element])
210 |> Map.put("url", link_element["href"])
211 end
212
213 def fix_url(%{"type" => object_type, "url" => url} = object)
214 when object_type != "Video" and is_list(url) do
215 first_element = Enum.at(url, 0)
216
217 url_string =
218 cond do
219 is_bitstring(first_element) -> first_element
220 is_map(first_element) -> first_element["href"] || ""
221 true -> ""
222 end
223
224 object
225 |> Map.put("url", url_string)
226 end
227
228 def fix_url(object), do: object
229
230 def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
231 emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
232
233 emoji =
234 emoji
235 |> Enum.reduce(%{}, fn data, mapping ->
236 name = String.trim(data["name"], ":")
237
238 mapping |> Map.put(name, data["icon"]["url"])
239 end)
240
241 # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
242 emoji = Map.merge(object["emoji"] || %{}, emoji)
243
244 object
245 |> Map.put("emoji", emoji)
246 end
247
248 def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
249 name = String.trim(tag["name"], ":")
250 emoji = %{name => tag["icon"]["url"]}
251
252 object
253 |> Map.put("emoji", emoji)
254 end
255
256 def fix_emoji(object), do: object
257
258 def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
259 tags =
260 tag
261 |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
262 |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
263
264 combined = tag ++ tags
265
266 object
267 |> Map.put("tag", combined)
268 end
269
270 def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
271 combined = [tag, String.slice(hashtag, 1..-1)]
272
273 object
274 |> Map.put("tag", combined)
275 end
276
277 def fix_tag(object), do: object
278
279 # content map usually only has one language so this will do for now.
280 def fix_content_map(%{"contentMap" => content_map} = object) do
281 content_groups = Map.to_list(content_map)
282 {_, content} = Enum.at(content_groups, 0)
283
284 object
285 |> Map.put("content", content)
286 end
287
288 def fix_content_map(object), do: object
289
290 defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
291 with true <- id =~ "follows",
292 %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
293 %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
294 {:ok, activity}
295 else
296 _ -> {:error, nil}
297 end
298 end
299
300 defp mastodon_follow_hack(_, _), do: {:error, nil}
301
302 defp get_follow_activity(follow_object, followed) do
303 with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
304 {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
305 {:ok, activity}
306 else
307 # Can't find the activity. This might a Mastodon 2.3 "Accept"
308 {:activity, nil} ->
309 mastodon_follow_hack(follow_object, followed)
310
311 _ ->
312 {:error, nil}
313 end
314 end
315
316 # disallow objects with bogus IDs
317 def handle_incoming(%{"id" => nil}), do: :error
318 def handle_incoming(%{"id" => ""}), do: :error
319 # length of https:// = 8, should validate better, but good enough for now.
320 def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
321
322 # TODO: validate those with a Ecto scheme
323 # - tags
324 # - emoji
325 def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
326 when objtype in ["Article", "Note", "Video", "Page"] do
327 actor = get_actor(data)
328
329 data =
330 Map.put(data, "actor", actor)
331 |> fix_addressing
332
333 with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
334 %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
335 object = fix_object(data["object"])
336
337 params = %{
338 to: data["to"],
339 object: object,
340 actor: user,
341 context: object["conversation"],
342 local: false,
343 published: data["published"],
344 additional:
345 Map.take(data, [
346 "cc",
347 "id"
348 ])
349 }
350
351 ActivityPub.create(params)
352 else
353 %Activity{} = activity -> {:ok, activity}
354 _e -> :error
355 end
356 end
357
358 def handle_incoming(
359 %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
360 ) do
361 with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
362 %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
363 {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
364 if not User.locked?(followed) do
365 ActivityPub.accept(%{
366 to: [follower.ap_id],
367 actor: followed.ap_id,
368 object: data,
369 local: true
370 })
371
372 User.follow(follower, followed)
373 end
374
375 {:ok, activity}
376 else
377 _e -> :error
378 end
379 end
380
381 def handle_incoming(
382 %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data
383 ) do
384 with actor <- get_actor(data),
385 %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
386 {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
387 {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
388 %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
389 {:ok, activity} <-
390 ActivityPub.accept(%{
391 to: follow_activity.data["to"],
392 type: "Accept",
393 actor: followed.ap_id,
394 object: follow_activity.data["id"],
395 local: false
396 }) do
397 if not User.following?(follower, followed) do
398 {:ok, _follower} = User.follow(follower, followed)
399 end
400
401 {:ok, activity}
402 else
403 _e -> :error
404 end
405 end
406
407 def handle_incoming(
408 %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data
409 ) do
410 with actor <- get_actor(data),
411 %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
412 {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
413 {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
414 %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
415 {:ok, activity} <-
416 ActivityPub.accept(%{
417 to: follow_activity.data["to"],
418 type: "Accept",
419 actor: followed.ap_id,
420 object: follow_activity.data["id"],
421 local: false
422 }) do
423 User.unfollow(follower, followed)
424
425 {:ok, activity}
426 else
427 _e -> :error
428 end
429 end
430
431 def handle_incoming(
432 %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data
433 ) do
434 with actor <- get_actor(data),
435 %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
436 {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
437 {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
438 {:ok, activity}
439 else
440 _e -> :error
441 end
442 end
443
444 def handle_incoming(
445 %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data
446 ) do
447 with actor <- get_actor(data),
448 %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
449 {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
450 {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
451 {:ok, activity}
452 else
453 _e -> :error
454 end
455 end
456
457 def handle_incoming(
458 %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
459 data
460 )
461 when object_type in ["Person", "Application", "Service", "Organization"] do
462 with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
463 {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
464
465 banner = new_user_data[:info]["banner"]
466 locked = new_user_data[:info]["locked"] || false
467
468 update_data =
469 new_user_data
470 |> Map.take([:name, :bio, :avatar])
471 |> Map.put(:info, %{"banner" => banner, "locked" => locked})
472
473 actor
474 |> User.upgrade_changeset(update_data)
475 |> User.update_and_set_cache()
476
477 ActivityPub.update(%{
478 local: false,
479 to: data["to"] || [],
480 cc: data["cc"] || [],
481 object: object,
482 actor: actor_id
483 })
484 else
485 e ->
486 Logger.error(e)
487 :error
488 end
489 end
490
491 # TODO: We presently assume that any actor on the same origin domain as the object being
492 # deleted has the rights to delete that object. A better way to validate whether or not
493 # the object should be deleted is to refetch the object URI, which should return either
494 # an error or a tombstone. This would allow us to verify that a deletion actually took
495 # place.
496 def handle_incoming(
497 %{"type" => "Delete", "object" => object_id, "actor" => _actor, "id" => _id} = data
498 ) do
499 object_id = Utils.get_ap_id(object_id)
500
501 with actor <- get_actor(data),
502 %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
503 {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
504 :ok <- contain_origin(actor.ap_id, object.data),
505 {:ok, activity} <- ActivityPub.delete(object, false) do
506 {:ok, activity}
507 else
508 _e -> :error
509 end
510 end
511
512 def handle_incoming(
513 %{
514 "type" => "Undo",
515 "object" => %{"type" => "Announce", "object" => object_id},
516 "actor" => _actor,
517 "id" => id
518 } = data
519 ) do
520 with actor <- get_actor(data),
521 %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
522 {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
523 {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
524 {:ok, activity}
525 else
526 _e -> :error
527 end
528 end
529
530 def handle_incoming(
531 %{
532 "type" => "Undo",
533 "object" => %{"type" => "Follow", "object" => followed},
534 "actor" => follower,
535 "id" => id
536 } = _data
537 ) do
538 with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
539 %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
540 {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
541 User.unfollow(follower, followed)
542 {:ok, activity}
543 else
544 _e -> :error
545 end
546 end
547
548 def handle_incoming(
549 %{
550 "type" => "Undo",
551 "object" => %{"type" => "Block", "object" => blocked},
552 "actor" => blocker,
553 "id" => id
554 } = _data
555 ) do
556 with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
557 %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
558 %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
559 {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
560 User.unblock(blocker, blocked)
561 {:ok, activity}
562 else
563 _e -> :error
564 end
565 end
566
567 def handle_incoming(
568 %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data
569 ) do
570 with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
571 %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
572 %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
573 {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
574 User.unfollow(blocker, blocked)
575 User.block(blocker, blocked)
576 {:ok, activity}
577 else
578 _e -> :error
579 end
580 end
581
582 def handle_incoming(
583 %{
584 "type" => "Undo",
585 "object" => %{"type" => "Like", "object" => object_id},
586 "actor" => _actor,
587 "id" => id
588 } = data
589 ) do
590 with actor <- get_actor(data),
591 %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
592 {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
593 {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
594 {:ok, activity}
595 else
596 _e -> :error
597 end
598 end
599
600 def handle_incoming(_), do: :error
601
602 def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
603 def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
604
605 def get_obj_helper(id) do
606 if object = Object.normalize(id), do: {:ok, object}, else: nil
607 end
608
609 def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
610 with false <- String.starts_with?(inReplyTo, "http"),
611 {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
612 Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
613 else
614 _e -> object
615 end
616 end
617
618 def set_reply_to_uri(obj), do: obj
619
620 # Prepares the object of an outgoing create activity.
621 def prepare_object(object) do
622 object
623 |> set_sensitive
624 |> add_hashtags
625 |> add_mention_tags
626 |> add_emoji_tags
627 |> add_attributed_to
628 |> prepare_attachments
629 |> set_conversation
630 |> set_reply_to_uri
631 |> strip_internal_fields
632 |> strip_internal_tags
633 end
634
635 # @doc
636 # """
637 # internal -> Mastodon
638 # """
639
640 def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
641 object =
642 object
643 |> prepare_object
644
645 data =
646 data
647 |> Map.put("object", object)
648 |> Map.merge(Utils.make_json_ld_header())
649
650 {:ok, data}
651 end
652
653 # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
654 # because of course it does.
655 def prepare_outgoing(%{"type" => "Accept"} = data) do
656 with follow_activity <- Activity.normalize(data["object"]) do
657 object = %{
658 "actor" => follow_activity.actor,
659 "object" => follow_activity.data["object"],
660 "id" => follow_activity.data["id"],
661 "type" => "Follow"
662 }
663
664 data =
665 data
666 |> Map.put("object", object)
667 |> Map.merge(Utils.make_json_ld_header())
668
669 {:ok, data}
670 end
671 end
672
673 def prepare_outgoing(%{"type" => "Reject"} = data) do
674 with follow_activity <- Activity.normalize(data["object"]) do
675 object = %{
676 "actor" => follow_activity.actor,
677 "object" => follow_activity.data["object"],
678 "id" => follow_activity.data["id"],
679 "type" => "Follow"
680 }
681
682 data =
683 data
684 |> Map.put("object", object)
685 |> Map.merge(Utils.make_json_ld_header())
686
687 {:ok, data}
688 end
689 end
690
691 def prepare_outgoing(%{"type" => _type} = data) do
692 data =
693 data
694 |> maybe_fix_object_url
695 |> Map.merge(Utils.make_json_ld_header())
696
697 {:ok, data}
698 end
699
700 def maybe_fix_object_url(data) do
701 if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
702 case fetch_obj_helper(data["object"]) do
703 {:ok, relative_object} ->
704 if relative_object.data["external_url"] do
705 _data =
706 data
707 |> Map.put("object", relative_object.data["external_url"])
708 else
709 data
710 end
711
712 e ->
713 Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
714 data
715 end
716 else
717 data
718 end
719 end
720
721 def add_hashtags(object) do
722 tags =
723 (object["tag"] || [])
724 |> Enum.map(fn tag ->
725 %{
726 "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
727 "name" => "##{tag}",
728 "type" => "Hashtag"
729 }
730 end)
731
732 object
733 |> Map.put("tag", tags)
734 end
735
736 def add_mention_tags(object) do
737 mentions =
738 object
739 |> Utils.get_notified_from_object()
740 |> Enum.map(fn user ->
741 %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
742 end)
743
744 tags = object["tag"] || []
745
746 object
747 |> Map.put("tag", tags ++ mentions)
748 end
749
750 # TODO: we should probably send mtime instead of unix epoch time for updated
751 def add_emoji_tags(object) do
752 tags = object["tag"] || []
753 emoji = object["emoji"] || []
754
755 out =
756 emoji
757 |> Enum.map(fn {name, url} ->
758 %{
759 "icon" => %{"url" => url, "type" => "Image"},
760 "name" => ":" <> name <> ":",
761 "type" => "Emoji",
762 "updated" => "1970-01-01T00:00:00Z",
763 "id" => url
764 }
765 end)
766
767 object
768 |> Map.put("tag", tags ++ out)
769 end
770
771 def set_conversation(object) do
772 Map.put(object, "conversation", object["context"])
773 end
774
775 def set_sensitive(object) do
776 tags = object["tag"] || []
777 Map.put(object, "sensitive", "nsfw" in tags)
778 end
779
780 def add_attributed_to(object) do
781 attributedTo = object["attributedTo"] || object["actor"]
782
783 object
784 |> Map.put("attributedTo", attributedTo)
785 end
786
787 def prepare_attachments(object) do
788 attachments =
789 (object["attachment"] || [])
790 |> Enum.map(fn data ->
791 [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
792 %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
793 end)
794
795 object
796 |> Map.put("attachment", attachments)
797 end
798
799 defp strip_internal_fields(object) do
800 object
801 |> Map.drop([
802 "likes",
803 "like_count",
804 "announcements",
805 "announcement_count",
806 "emoji",
807 "context_id"
808 ])
809 end
810
811 defp strip_internal_tags(%{"tag" => tags} = object) do
812 tags =
813 tags
814 |> Enum.filter(fn x -> is_map(x) end)
815
816 object
817 |> Map.put("tag", tags)
818 end
819
820 defp strip_internal_tags(object), do: object
821
822 defp user_upgrade_task(user) do
823 old_follower_address = User.ap_followers(user)
824
825 q =
826 from(
827 u in User,
828 where: ^old_follower_address in u.following,
829 update: [
830 set: [
831 following:
832 fragment(
833 "array_replace(?,?,?)",
834 u.following,
835 ^old_follower_address,
836 ^user.follower_address
837 )
838 ]
839 ]
840 )
841
842 Repo.update_all(q, [])
843
844 maybe_retire_websub(user.ap_id)
845
846 # Only do this for recent activties, don't go through the whole db.
847 # Only look at the last 1000 activities.
848 since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
849
850 q =
851 from(
852 a in Activity,
853 where: ^old_follower_address in a.recipients,
854 where: a.id > ^since,
855 update: [
856 set: [
857 recipients:
858 fragment(
859 "array_replace(?,?,?)",
860 a.recipients,
861 ^old_follower_address,
862 ^user.follower_address
863 )
864 ]
865 ]
866 )
867
868 Repo.update_all(q, [])
869 end
870
871 def upgrade_user_from_ap_id(ap_id, async \\ true) do
872 with %User{local: false} = user <- User.get_by_ap_id(ap_id),
873 {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
874 already_ap = User.ap_enabled?(user)
875
876 {:ok, user} =
877 User.upgrade_changeset(user, data)
878 |> Repo.update()
879
880 if !already_ap do
881 # This could potentially take a long time, do it in the background
882 if async do
883 Task.start(fn ->
884 user_upgrade_task(user)
885 end)
886 else
887 user_upgrade_task(user)
888 end
889 end
890
891 {:ok, user}
892 else
893 e -> e
894 end
895 end
896
897 def maybe_retire_websub(ap_id) do
898 # some sanity checks
899 if is_binary(ap_id) && String.length(ap_id) > 8 do
900 q =
901 from(
902 ws in Pleroma.Web.Websub.WebsubClientSubscription,
903 where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
904 )
905
906 Repo.delete_all(q)
907 end
908 end
909
910 def maybe_fix_user_url(data) do
911 if is_map(data["url"]) do
912 Map.put(data, "url", data["url"]["href"])
913 else
914 data
915 end
916 end
917
918 def maybe_fix_user_object(data) do
919 data
920 |> maybe_fix_user_url
921 end
922 end
Fork of https://akkoma.dev/AkkomaGang/akkoma.git