git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type == "Person" end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => actor}) when is_map(actor) do
  30     actor["id"]
  31   end
  32
  33   @doc """
  34   Checks that an imported AP object's actor matches the domain it came from.
  35   """
  36   def contain_origin(id, %{"actor" => actor} = params) do
  37     id_uri = URI.parse(id)
  38     actor_uri = URI.parse(get_actor(params))
  39
  40     if id_uri.host == actor_uri.host do
  41       :ok
  42     else
  43       :error
  44     end
  45   end
  46
  47   @doc """
  48   Modifies an incoming AP object (mastodon format) to our internal format.
  49   """
  50   def fix_object(object) do
  51     object
  52     |> fix_actor
  53     |> fix_attachments
  54     |> fix_context
  55     |> fix_in_reply_to
  56     |> fix_emoji
  57     |> fix_tag
  58     |> fix_content_map
  59     |> fix_likes
  60     |> fix_addressing
  61   end
  62
  63   def fix_addressing_list(map, field) do
  64     if is_binary(map[field]) do
  65       map
  66       |> Map.put(field, [map[field]])
  67     else
  68       map
  69     end
  70   end
  71
  72   def fix_addressing(map) do
  73     map
  74     |> fix_addressing_list("to")
  75     |> fix_addressing_list("cc")
  76     |> fix_addressing_list("bto")
  77     |> fix_addressing_list("bcc")
  78   end
  79
  80   def fix_actor(%{"attributedTo" => actor} = object) do
  81     object
  82     |> Map.put("actor", get_actor(%{"actor" => actor}))
  83   end
  84
  85   def fix_likes(%{"likes" => likes} = object)
  86       when is_bitstring(likes) do
  87     # Check for standardisation
  88     # This is what Peertube does
  89     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
  90     object
  91     |> Map.put("likes", [])
  92     |> Map.put("like_count", 0)
  93   end
  94
  95   def fix_likes(object) do
  96     object
  97   end
  98
  99   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
 100       when not is_nil(in_reply_to_id) do
 101     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
 102       {:ok, replied_object} ->
 103         with %Activity{} = activity <-
 104                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 105           object
 106           |> Map.put("inReplyTo", replied_object.data["id"])
 107           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 108           |> Map.put("inReplyToStatusId", activity.id)
 109           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 110           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 111         else
 112           e ->
 113             Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 114             object
 115         end
 116
 117       e ->
 118         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
 119         object
 120     end
 121   end
 122
 123   def fix_in_reply_to(object), do: object
 124
 125   def fix_context(object) do
 126     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 127
 128     object
 129     |> Map.put("context", context)
 130     |> Map.put("conversation", context)
 131   end
 132
 133   def fix_attachments(object) do
 134     attachments =
 135       (object["attachment"] || [])
 136       |> Enum.map(fn data ->
 137         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 138         Map.put(data, "url", url)
 139       end)
 140
 141     object
 142     |> Map.put("attachment", attachments)
 143   end
 144
 145   def fix_emoji(object) do
 146     tags = object["tag"] || []
 147     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 148
 149     emoji =
 150       emoji
 151       |> Enum.reduce(%{}, fn data, mapping ->
 152         name = data["name"]
 153
 154         name =
 155           if String.starts_with?(name, ":") do
 156             name |> String.slice(1..-2)
 157           else
 158             name
 159           end
 160
 161         mapping |> Map.put(name, data["icon"]["url"])
 162       end)
 163
 164     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 165     emoji = Map.merge(object["emoji"] || %{}, emoji)
 166
 167     object
 168     |> Map.put("emoji", emoji)
 169   end
 170
 171   def fix_tag(object) do
 172     tags =
 173       (object["tag"] || [])
 174       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 175       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 176
 177     combined = (object["tag"] || []) ++ tags
 178
 179     object
 180     |> Map.put("tag", combined)
 181   end
 182
 183   # content map usually only has one language so this will do for now.
 184   def fix_content_map(%{"contentMap" => content_map} = object) do
 185     content_groups = Map.to_list(content_map)
 186     {_, content} = Enum.at(content_groups, 0)
 187
 188     object
 189     |> Map.put("content", content)
 190   end
 191
 192   def fix_content_map(object), do: object
 193
 194   # disallow objects with bogus IDs
 195   def handle_incoming(%{"id" => nil}), do: :error
 196   def handle_incoming(%{"id" => ""}), do: :error
 197   # length of https:// = 8, should validate better, but good enough for now.
 198   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 199
 200   # TODO: validate those with a Ecto scheme
 201   # - tags
 202   # - emoji
 203   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 204       when objtype in ["Article", "Note", "Video"] do
 205     actor = get_actor(data)
 206
 207     data =
 208       Map.put(data, "actor", actor)
 209       |> fix_addressing
 210
 211     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 212          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 213       object = fix_object(data["object"])
 214
 215       params = %{
 216         to: data["to"],
 217         object: object,
 218         actor: user,
 219         context: object["conversation"],
 220         local: false,
 221         published: data["published"],
 222         additional:
 223           Map.take(data, [
 224             "cc",
 225             "id"
 226           ])
 227       }
 228
 229       ActivityPub.create(params)
 230     else
 231       %Activity{} = activity -> {:ok, activity}
 232       _e -> :error
 233     end
 234   end
 235
 236   def handle_incoming(
 237         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 238       ) do
 239     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 240          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 241          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 242       if not User.locked?(followed) do
 243         ActivityPub.accept(%{
 244           to: [follower.ap_id],
 245           actor: followed.ap_id,
 246           object: data,
 247           local: true
 248         })
 249
 250         User.follow(follower, followed)
 251       end
 252
 253       {:ok, activity}
 254     else
 255       _e -> :error
 256     end
 257   end
 258
 259   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 260     with true <- id =~ "follows",
 261          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 262          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 263       {:ok, activity}
 264     else
 265       _ -> {:error, nil}
 266     end
 267   end
 268
 269   defp mastodon_follow_hack(_), do: {:error, nil}
 270
 271   defp get_follow_activity(follow_object, followed) do
 272     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 273          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 274       {:ok, activity}
 275     else
 276       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 277       {:activity, nil} ->
 278         mastodon_follow_hack(follow_object, followed)
 279
 280       _ ->
 281         {:error, nil}
 282     end
 283   end
 284
 285   def handle_incoming(
 286         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 287       ) do
 288     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 289          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 290          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 291          {:ok, activity} <-
 292            ActivityPub.accept(%{
 293              to: follow_activity.data["to"],
 294              type: "Accept",
 295              actor: followed.ap_id,
 296              object: follow_activity.data["id"],
 297              local: false
 298            }) do
 299       if not User.following?(follower, followed) do
 300         {:ok, follower} = User.follow(follower, followed)
 301       end
 302
 303       {:ok, activity}
 304     else
 305       _e -> :error
 306     end
 307   end
 308
 309   def handle_incoming(
 310         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 311       ) do
 312     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 313          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 314          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 315          {:ok, activity} <-
 316            ActivityPub.accept(%{
 317              to: follow_activity.data["to"],
 318              type: "Accept",
 319              actor: followed.ap_id,
 320              object: follow_activity.data["id"],
 321              local: false
 322            }) do
 323       User.unfollow(follower, followed)
 324
 325       {:ok, activity}
 326     else
 327       _e -> :error
 328     end
 329   end
 330
 331   def handle_incoming(
 332         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 333       ) do
 334     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 335          {:ok, object} <-
 336            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 337          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 338       {:ok, activity}
 339     else
 340       _e -> :error
 341     end
 342   end
 343
 344   def handle_incoming(
 345         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 346       ) do
 347     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 348          {:ok, object} <-
 349            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 350          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 351       {:ok, activity}
 352     else
 353       _e -> :error
 354     end
 355   end
 356
 357   def handle_incoming(
 358         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 359           data
 360       )
 361       when object_type in ["Person", "Application", "Service", "Organization"] do
 362     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 363       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 364
 365       banner = new_user_data[:info]["banner"]
 366       locked = new_user_data[:info]["locked"] || false
 367
 368       update_data =
 369         new_user_data
 370         |> Map.take([:name, :bio, :avatar])
 371         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 372
 373       actor
 374       |> User.upgrade_changeset(update_data)
 375       |> User.update_and_set_cache()
 376
 377       ActivityPub.update(%{
 378         local: false,
 379         to: data["to"] || [],
 380         cc: data["cc"] || [],
 381         object: object,
 382         actor: actor_id
 383       })
 384     else
 385       e ->
 386         Logger.error(e)
 387         :error
 388     end
 389   end
 390
 391   # TODO: Make secure.
 392   def handle_incoming(
 393         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 394       ) do
 395     object_id = Utils.get_ap_id(object_id)
 396
 397     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 398          {:ok, object} <-
 399            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 400          {:ok, activity} <- ActivityPub.delete(object, false) do
 401       {:ok, activity}
 402     else
 403       _e -> :error
 404     end
 405   end
 406
 407   def handle_incoming(
 408         %{
 409           "type" => "Undo",
 410           "object" => %{"type" => "Announce", "object" => object_id},
 411           "actor" => actor,
 412           "id" => id
 413         } = _data
 414       ) do
 415     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 416          {:ok, object} <-
 417            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 418          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 419       {:ok, activity}
 420     else
 421       _e -> :error
 422     end
 423   end
 424
 425   def handle_incoming(
 426         %{
 427           "type" => "Undo",
 428           "object" => %{"type" => "Follow", "object" => followed},
 429           "actor" => follower,
 430           "id" => id
 431         } = _data
 432       ) do
 433     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 434          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 435          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 436       User.unfollow(follower, followed)
 437       {:ok, activity}
 438     else
 439       e -> :error
 440     end
 441   end
 442
 443   @ap_config Application.get_env(:pleroma, :activitypub)
 444   @accept_blocks Keyword.get(@ap_config, :accept_blocks)
 445
 446   def handle_incoming(
 447         %{
 448           "type" => "Undo",
 449           "object" => %{"type" => "Block", "object" => blocked},
 450           "actor" => blocker,
 451           "id" => id
 452         } = _data
 453       ) do
 454     with true <- @accept_blocks,
 455          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 456          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 457          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 458       User.unblock(blocker, blocked)
 459       {:ok, activity}
 460     else
 461       e -> :error
 462     end
 463   end
 464
 465   def handle_incoming(
 466         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 467       ) do
 468     with true <- @accept_blocks,
 469          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 470          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 471          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 472       User.unfollow(blocker, blocked)
 473       User.block(blocker, blocked)
 474       {:ok, activity}
 475     else
 476       e -> :error
 477     end
 478   end
 479
 480   def handle_incoming(
 481         %{
 482           "type" => "Undo",
 483           "object" => %{"type" => "Like", "object" => object_id},
 484           "actor" => actor,
 485           "id" => id
 486         } = _data
 487       ) do
 488     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 489          {:ok, object} <-
 490            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 491          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 492       {:ok, activity}
 493     else
 494       _e -> :error
 495     end
 496   end
 497
 498   def handle_incoming(_), do: :error
 499
 500   def get_obj_helper(id) do
 501     if object = Object.normalize(id), do: {:ok, object}, else: nil
 502   end
 503
 504   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 505     with false <- String.starts_with?(inReplyTo, "http"),
 506          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 507       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 508     else
 509       _e -> object
 510     end
 511   end
 512
 513   def set_reply_to_uri(obj), do: obj
 514
 515   # Prepares the object of an outgoing create activity.
 516   def prepare_object(object) do
 517     object
 518     |> set_sensitive
 519     |> add_hashtags
 520     |> add_mention_tags
 521     |> add_emoji_tags
 522     |> add_attributed_to
 523     |> prepare_attachments
 524     |> set_conversation
 525     |> set_reply_to_uri
 526   end
 527
 528   #  @doc
 529   #  """
 530   #  internal -> Mastodon
 531   #  """
 532
 533   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 534     object =
 535       object
 536       |> prepare_object
 537
 538     data =
 539       data
 540       |> Map.put("object", object)
 541       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 542
 543     {:ok, data}
 544   end
 545
 546   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 547   # because of course it does.
 548   def prepare_outgoing(%{"type" => "Accept"} = data) do
 549     with follow_activity <- Activity.normalize(data["object"]) do
 550       object = %{
 551         "actor" => follow_activity.actor,
 552         "object" => follow_activity.data["object"],
 553         "id" => follow_activity.data["id"],
 554         "type" => "Follow"
 555       }
 556
 557       data =
 558         data
 559         |> Map.put("object", object)
 560         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 561
 562       {:ok, data}
 563     end
 564   end
 565
 566   def prepare_outgoing(%{"type" => "Reject"} = data) do
 567     with follow_activity <- Activity.normalize(data["object"]) do
 568       object = %{
 569         "actor" => follow_activity.actor,
 570         "object" => follow_activity.data["object"],
 571         "id" => follow_activity.data["id"],
 572         "type" => "Follow"
 573       }
 574
 575       data =
 576         data
 577         |> Map.put("object", object)
 578         |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 579
 580       {:ok, data}
 581     end
 582   end
 583
 584   def prepare_outgoing(%{"type" => _type} = data) do
 585     data =
 586       data
 587       |> maybe_fix_object_url
 588       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 589
 590     {:ok, data}
 591   end
 592
 593   def maybe_fix_object_url(data) do
 594     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 595       case ActivityPub.fetch_object_from_id(data["object"]) do
 596         {:ok, relative_object} ->
 597           if relative_object.data["external_url"] do
 598             _data =
 599               data
 600               |> Map.put("object", relative_object.data["external_url"])
 601           else
 602             data
 603           end
 604
 605         e ->
 606           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 607           data
 608       end
 609     else
 610       data
 611     end
 612   end
 613
 614   def add_hashtags(object) do
 615     tags =
 616       (object["tag"] || [])
 617       |> Enum.map(fn tag ->
 618         %{
 619           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 620           "name" => "##{tag}",
 621           "type" => "Hashtag"
 622         }
 623       end)
 624
 625     object
 626     |> Map.put("tag", tags)
 627   end
 628
 629   def add_mention_tags(object) do
 630     recipients = object["to"] ++ (object["cc"] || [])
 631
 632     mentions =
 633       recipients
 634       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 635       |> Enum.filter(& &1)
 636       |> Enum.map(fn user ->
 637         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 638       end)
 639
 640     tags = object["tag"] || []
 641
 642     object
 643     |> Map.put("tag", tags ++ mentions)
 644   end
 645
 646   # TODO: we should probably send mtime instead of unix epoch time for updated
 647   def add_emoji_tags(object) do
 648     tags = object["tag"] || []
 649     emoji = object["emoji"] || []
 650
 651     out =
 652       emoji
 653       |> Enum.map(fn {name, url} ->
 654         %{
 655           "icon" => %{"url" => url, "type" => "Image"},
 656           "name" => ":" <> name <> ":",
 657           "type" => "Emoji",
 658           "updated" => "1970-01-01T00:00:00Z",
 659           "id" => url
 660         }
 661       end)
 662
 663     object
 664     |> Map.put("tag", tags ++ out)
 665   end
 666
 667   def set_conversation(object) do
 668     Map.put(object, "conversation", object["context"])
 669   end
 670
 671   def set_sensitive(object) do
 672     tags = object["tag"] || []
 673     Map.put(object, "sensitive", "nsfw" in tags)
 674   end
 675
 676   def add_attributed_to(object) do
 677     attributedTo = object["attributedTo"] || object["actor"]
 678
 679     object
 680     |> Map.put("attributedTo", attributedTo)
 681   end
 682
 683   def prepare_attachments(object) do
 684     attachments =
 685       (object["attachment"] || [])
 686       |> Enum.map(fn data ->
 687         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 688         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 689       end)
 690
 691     object
 692     |> Map.put("attachment", attachments)
 693   end
 694
 695   defp user_upgrade_task(user) do
 696     old_follower_address = User.ap_followers(user)
 697
 698     q =
 699       from(
 700         u in User,
 701         where: ^old_follower_address in u.following,
 702         update: [
 703           set: [
 704             following:
 705               fragment(
 706                 "array_replace(?,?,?)",
 707                 u.following,
 708                 ^old_follower_address,
 709                 ^user.follower_address
 710               )
 711           ]
 712         ]
 713       )
 714
 715     Repo.update_all(q, [])
 716
 717     maybe_retire_websub(user.ap_id)
 718
 719     # Only do this for recent activties, don't go through the whole db.
 720     # Only look at the last 1000 activities.
 721     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 722
 723     q =
 724       from(
 725         a in Activity,
 726         where: ^old_follower_address in a.recipients,
 727         where: a.id > ^since,
 728         update: [
 729           set: [
 730             recipients:
 731               fragment(
 732                 "array_replace(?,?,?)",
 733                 a.recipients,
 734                 ^old_follower_address,
 735                 ^user.follower_address
 736               )
 737           ]
 738         ]
 739       )
 740
 741     Repo.update_all(q, [])
 742   end
 743
 744   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 745     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 746          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 747       data =
 748         data
 749         |> Map.put(:info, Map.merge(user.info, data[:info]))
 750
 751       already_ap = User.ap_enabled?(user)
 752
 753       {:ok, user} =
 754         User.upgrade_changeset(user, data)
 755         |> Repo.update()
 756
 757       if !already_ap do
 758         # This could potentially take a long time, do it in the background
 759         if async do
 760           Task.start(fn ->
 761             user_upgrade_task(user)
 762           end)
 763         else
 764           user_upgrade_task(user)
 765         end
 766       end
 767
 768       {:ok, user}
 769     else
 770       e -> e
 771     end
 772   end
 773
 774   def maybe_retire_websub(ap_id) do
 775     # some sanity checks
 776     if is_binary(ap_id) && String.length(ap_id) > 8 do
 777       q =
 778         from(
 779           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 780           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 781         )
 782
 783       Repo.delete_all(q)
 784     end
 785   end
 786
 787   def maybe_fix_user_url(data) do
 788     if is_map(data["url"]) do
 789       Map.put(data, "url", data["url"]["href"])
 790     else
 791       data
 792     end
 793   end
 794
 795   def maybe_fix_user_object(data) do
 796     data
 797     |> maybe_fix_user_url
 798   end
 799 end