git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   @doc """
  17   Modifies an incoming AP object (mastodon format) to our internal format.
  18   """
  19   def fix_object(object) do
  20     object
  21     |> Map.put("actor", object["attributedTo"])
  22     |> fix_attachments
  23     |> fix_context
  24     |> fix_in_reply_to
  25     |> fix_emoji
  26     |> fix_tag
  27   end
  28
  29   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  30       when not is_nil(in_reply_to_id) do
  31     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  32       {:ok, replied_object} ->
  33         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  34
  35         object
  36         |> Map.put("inReplyTo", replied_object.data["id"])
  37         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  38         |> Map.put("inReplyToStatusId", activity.id)
  39         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  40         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  41
  42       e ->
  43         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  44         object
  45     end
  46   end
  47
  48   def fix_in_reply_to(object), do: object
  49
  50   def fix_context(object) do
  51     object
  52     |> Map.put("context", object["conversation"])
  53   end
  54
  55   def fix_attachments(object) do
  56     attachments =
  57       (object["attachment"] || [])
  58       |> Enum.map(fn data ->
  59         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  60         Map.put(data, "url", url)
  61       end)
  62
  63     object
  64     |> Map.put("attachment", attachments)
  65   end
  66
  67   def fix_emoji(object) do
  68     tags = object["tag"] || []
  69     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  70
  71     emoji =
  72       emoji
  73       |> Enum.reduce(%{}, fn data, mapping ->
  74         name = data["name"]
  75
  76         name =
  77           if String.starts_with?(name, ":") do
  78             name |> String.slice(1..-2)
  79           else
  80             name
  81           end
  82
  83         mapping |> Map.put(name, data["icon"]["url"])
  84       end)
  85
  86     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  87     emoji = Map.merge(object["emoji"] || %{}, emoji)
  88
  89     object
  90     |> Map.put("emoji", emoji)
  91   end
  92
  93   def fix_tag(object) do
  94     tags =
  95       (object["tag"] || [])
  96       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  97       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  98
  99     combined = (object["tag"] || []) ++ tags
 100
 101     object
 102     |> Map.put("tag", combined)
 103   end
 104
 105   # TODO: validate those with a Ecto scheme
 106   # - tags
 107   # - emoji
 108   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 109     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 110          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 111       object = fix_object(data["object"])
 112
 113       params = %{
 114         to: data["to"],
 115         object: object,
 116         actor: user,
 117         context: object["conversation"],
 118         local: false,
 119         published: data["published"],
 120         additional:
 121           Map.take(data, [
 122             "cc",
 123             "id"
 124           ])
 125       }
 126
 127       ActivityPub.create(params)
 128     else
 129       %Activity{} = activity -> {:ok, activity}
 130       _e -> :error
 131     end
 132   end
 133
 134   def handle_incoming(
 135         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 136       ) do
 137     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 138          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 139          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 140       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 141
 142       User.follow(follower, followed)
 143       {:ok, activity}
 144     else
 145       _e -> :error
 146     end
 147   end
 148
 149   defp get_follow_activity(follow_object) do
 150     cond do
 151       is_map(follow_object) ->
 152         {:ok, follow_object}
 153
 154       is_binary(follow_object) ->
 155         object = Activity.get_by_ap_id(follow_object)
 156
 157         if object do
 158           {:ok, object.data}
 159         else
 160           {:error, nil}
 161         end
 162
 163       true ->
 164         {:error, nil}
 165     end
 166   end
 167
 168   def handle_incoming(
 169         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 170       ) do
 171     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 172          {:ok, follow_activity} <- get_follow_activity(follow_object),
 173          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity["actor"]),
 174          {:ok, activity} <- ActivityPub.insert(data, true) do
 175       if not User.following?(follower, followed) do
 176         {:ok, follower} = User.follow(follower, followed)
 177       end
 178
 179       {:ok, activity}
 180     end
 181   end
 182
 183   def handle_incoming(
 184         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 185       ) do
 186     with %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 187          {:ok, follow_activity} <- get_follow_activity(follow_object),
 188          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity["actor"]),
 189          {:ok, activity} <- ActivityPub.insert(data, true) do
 190       User.unfollow(follower, followed)
 191
 192       {:ok, activity}
 193     end
 194   end
 195
 196   def handle_incoming(
 197         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 198       ) do
 199     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 200          {:ok, object} <-
 201            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 202          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 203       {:ok, activity}
 204     else
 205       _e -> :error
 206     end
 207   end
 208
 209   def handle_incoming(
 210         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 211       ) do
 212     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 213          {:ok, object} <-
 214            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 215          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 216       {:ok, activity}
 217     else
 218       _e -> :error
 219     end
 220   end
 221
 222   def handle_incoming(
 223         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 224           data
 225       ) do
 226     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 227       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 228
 229       banner = new_user_data[:info]["banner"]
 230
 231       update_data =
 232         new_user_data
 233         |> Map.take([:name, :bio, :avatar])
 234         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 235
 236       actor
 237       |> User.upgrade_changeset(update_data)
 238       |> User.update_and_set_cache()
 239
 240       ActivityPub.update(%{
 241         local: false,
 242         to: data["to"] || [],
 243         cc: data["cc"] || [],
 244         object: object,
 245         actor: actor_id
 246       })
 247     else
 248       e ->
 249         Logger.error(e)
 250         :error
 251     end
 252   end
 253
 254   # TODO: Make secure.
 255   def handle_incoming(
 256         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 257       ) do
 258     object_id =
 259       case object_id do
 260         %{"id" => id} -> id
 261         id -> id
 262       end
 263
 264     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 265          {:ok, object} <-
 266            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 267          {:ok, activity} <- ActivityPub.delete(object, false) do
 268       {:ok, activity}
 269     else
 270       _e -> :error
 271     end
 272   end
 273
 274   def handle_incoming(
 275         %{
 276           "type" => "Undo",
 277           "object" => %{"type" => "Announce", "object" => object_id},
 278           "actor" => actor,
 279           "id" => id
 280         } = _data
 281       ) do
 282     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 283          {:ok, object} <-
 284            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 285          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 286       {:ok, activity}
 287     else
 288       _e -> :error
 289     end
 290   end
 291
 292   def handle_incoming(
 293         %{
 294           "type" => "Undo",
 295           "object" => %{"type" => "Follow", "object" => followed},
 296           "actor" => follower,
 297           "id" => id
 298         } = _data
 299       ) do
 300     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 301          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 302          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 303       User.unfollow(follower, followed)
 304       {:ok, activity}
 305     else
 306       e -> :error
 307     end
 308   end
 309
 310   def handle_incoming(
 311         %{
 312           "type" => "Undo",
 313           "object" => %{"type" => "Block", "object" => blocked},
 314           "actor" => blocker,
 315           "id" => id
 316         } = _data
 317       ) do
 318     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 319          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 320          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 321       User.unblock(blocker, blocked)
 322       {:ok, activity}
 323     else
 324       e -> :error
 325     end
 326   end
 327
 328   def handle_incoming(
 329         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 330       ) do
 331     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 332          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 333          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 334       User.unfollow(blocker, blocked)
 335       User.block(blocker, blocked)
 336       {:ok, activity}
 337     else
 338       e -> :error
 339     end
 340   end
 341
 342   def handle_incoming(
 343         %{
 344           "type" => "Undo",
 345           "object" => %{"type" => "Like", "object" => object_id},
 346           "actor" => actor,
 347           "id" => id
 348         } = _data
 349       ) do
 350     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 351          {:ok, object} <-
 352            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 353          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 354       {:ok, activity}
 355     else
 356       _e -> :error
 357     end
 358   end
 359
 360   # TODO
 361   # Accept
 362
 363   def handle_incoming(_), do: :error
 364
 365   def get_obj_helper(id) do
 366     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 367   end
 368
 369   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 370     with false <- String.starts_with?(inReplyTo, "http"),
 371          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 372       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 373     else
 374       _e -> object
 375     end
 376   end
 377
 378   def set_reply_to_uri(obj), do: obj
 379
 380   # Prepares the object of an outgoing create activity.
 381   def prepare_object(object) do
 382     object
 383     |> set_sensitive
 384     |> add_hashtags
 385     |> add_mention_tags
 386     |> add_emoji_tags
 387     |> add_attributed_to
 388     |> prepare_attachments
 389     |> set_conversation
 390     |> set_reply_to_uri
 391   end
 392
 393   #  @doc
 394   #  """
 395   #  internal -> Mastodon
 396   #  """
 397
 398   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 399     object =
 400       object
 401       |> prepare_object
 402
 403     data =
 404       data
 405       |> Map.put("object", object)
 406       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 407
 408     {:ok, data}
 409   end
 410
 411   def prepare_outgoing(%{"type" => _type} = data) do
 412     data =
 413       data
 414       |> maybe_fix_object_url
 415       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 416
 417     {:ok, data}
 418   end
 419
 420   def maybe_fix_object_url(data) do
 421     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 422       case ActivityPub.fetch_object_from_id(data["object"]) do
 423         {:ok, relative_object} ->
 424           if relative_object.data["external_url"] do
 425             _data =
 426               data
 427               |> Map.put("object", relative_object.data["external_url"])
 428           else
 429             data
 430           end
 431
 432         e ->
 433           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 434           data
 435       end
 436     else
 437       data
 438     end
 439   end
 440
 441   def add_hashtags(object) do
 442     tags =
 443       (object["tag"] || [])
 444       |> Enum.map(fn tag ->
 445         %{
 446           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 447           "name" => "##{tag}",
 448           "type" => "Hashtag"
 449         }
 450       end)
 451
 452     object
 453     |> Map.put("tag", tags)
 454   end
 455
 456   def add_mention_tags(object) do
 457     recipients = object["to"] ++ (object["cc"] || [])
 458
 459     mentions =
 460       recipients
 461       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 462       |> Enum.filter(& &1)
 463       |> Enum.map(fn user ->
 464         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 465       end)
 466
 467     tags = object["tag"] || []
 468
 469     object
 470     |> Map.put("tag", tags ++ mentions)
 471   end
 472
 473   # TODO: we should probably send mtime instead of unix epoch time for updated
 474   def add_emoji_tags(object) do
 475     tags = object["tag"] || []
 476     emoji = object["emoji"] || []
 477
 478     out =
 479       emoji
 480       |> Enum.map(fn {name, url} ->
 481         %{
 482           "icon" => %{"url" => url, "type" => "Image"},
 483           "name" => ":" <> name <> ":",
 484           "type" => "Emoji",
 485           "updated" => "1970-01-01T00:00:00Z",
 486           "id" => url
 487         }
 488       end)
 489
 490     object
 491     |> Map.put("tag", tags ++ out)
 492   end
 493
 494   def set_conversation(object) do
 495     Map.put(object, "conversation", object["context"])
 496   end
 497
 498   def set_sensitive(object) do
 499     tags = object["tag"] || []
 500     Map.put(object, "sensitive", "nsfw" in tags)
 501   end
 502
 503   def add_attributed_to(object) do
 504     attributedTo = object["attributedTo"] || object["actor"]
 505
 506     object
 507     |> Map.put("attributedTo", attributedTo)
 508   end
 509
 510   def prepare_attachments(object) do
 511     attachments =
 512       (object["attachment"] || [])
 513       |> Enum.map(fn data ->
 514         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 515         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 516       end)
 517
 518     object
 519     |> Map.put("attachment", attachments)
 520   end
 521
 522   defp user_upgrade_task(user) do
 523     old_follower_address = User.ap_followers(user)
 524
 525     q =
 526       from(
 527         u in User,
 528         where: ^old_follower_address in u.following,
 529         update: [
 530           set: [
 531             following:
 532               fragment(
 533                 "array_replace(?,?,?)",
 534                 u.following,
 535                 ^old_follower_address,
 536                 ^user.follower_address
 537               )
 538           ]
 539         ]
 540       )
 541
 542     Repo.update_all(q, [])
 543
 544     maybe_retire_websub(user.ap_id)
 545
 546     # Only do this for recent activties, don't go through the whole db.
 547     # Only look at the last 1000 activities.
 548     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 549
 550     q =
 551       from(
 552         a in Activity,
 553         where: ^old_follower_address in a.recipients,
 554         where: a.id > ^since,
 555         update: [
 556           set: [
 557             recipients:
 558               fragment(
 559                 "array_replace(?,?,?)",
 560                 a.recipients,
 561                 ^old_follower_address,
 562                 ^user.follower_address
 563               )
 564           ]
 565         ]
 566       )
 567
 568     Repo.update_all(q, [])
 569   end
 570
 571   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 572     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 573          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 574       data =
 575         data
 576         |> Map.put(:info, Map.merge(user.info, data[:info]))
 577
 578       already_ap = User.ap_enabled?(user)
 579
 580       {:ok, user} =
 581         User.upgrade_changeset(user, data)
 582         |> Repo.update()
 583
 584       if !already_ap do
 585         # This could potentially take a long time, do it in the background
 586         if async do
 587           Task.start(fn ->
 588             user_upgrade_task(user)
 589           end)
 590         else
 591           user_upgrade_task(user)
 592         end
 593       end
 594
 595       {:ok, user}
 596     else
 597       e -> e
 598     end
 599   end
 600
 601   def maybe_retire_websub(ap_id) do
 602     # some sanity checks
 603     if is_binary(ap_id) && String.length(ap_id) > 8 do
 604       q =
 605         from(
 606           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 607           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 608         )
 609
 610       Repo.delete_all(q)
 611     end
 612   end
 613
 614   def maybe_fix_user_url(data) do
 615     if is_map(data["url"]) do
 616       Map.put(data, "url", data["url"]["href"])
 617     else
 618       data
 619     end
 620   end
 621
 622   def maybe_fix_user_object(data) do
 623     data
 624     |> maybe_fix_user_url
 625   end
 626 end