git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.Object
  12   alias Pleroma.Object.Containment
  13   alias Pleroma.Repo
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16   alias Pleroma.Web.ActivityPub.ObjectValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  18   alias Pleroma.Web.ActivityPub.Pipeline
  19   alias Pleroma.Web.ActivityPub.Utils
  20   alias Pleroma.Web.ActivityPub.Visibility
  21   alias Pleroma.Web.Federator
  22   alias Pleroma.Workers.TransmogrifierWorker
  23
  24   import Ecto.Query
  25
  26   require Logger
  27   require Pleroma.Constants
  28
  29   @doc """
  30   Modifies an incoming AP object (mastodon format) to our internal format.
  31   """
  32   def fix_object(object, options \\ []) do
  33     object
  34     |> strip_internal_fields
  35     |> fix_actor
  36     |> fix_url
  37     |> fix_attachments
  38     |> fix_context
  39     |> fix_in_reply_to(options)
  40     |> fix_emoji
  41     |> fix_tag
  42     |> fix_content_map
  43     |> fix_addressing
  44     |> fix_summary
  45     |> fix_type(options)
  46   end
  47
  48   def fix_summary(%{"summary" => nil} = object) do
  49     Map.put(object, "summary", "")
  50   end
  51
  52   def fix_summary(%{"summary" => _} = object) do
  53     # summary is present, nothing to do
  54     object
  55   end
  56
  57   def fix_summary(object), do: Map.put(object, "summary", "")
  58
  59   def fix_addressing_list(map, field) do
  60     cond do
  61       is_binary(map[field]) ->
  62         Map.put(map, field, [map[field]])
  63
  64       is_nil(map[field]) ->
  65         Map.put(map, field, [])
  66
  67       true ->
  68         map
  69     end
  70   end
  71
  72   def fix_explicit_addressing(
  73         %{"to" => to, "cc" => cc} = object,
  74         explicit_mentions,
  75         follower_collection
  76       ) do
  77     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  78
  79     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  80
  81     final_cc =
  82       (cc ++ explicit_cc)
  83       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  84       |> Enum.uniq()
  85
  86     object
  87     |> Map.put("to", explicit_to)
  88     |> Map.put("cc", final_cc)
  89   end
  90
  91   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  92
  93   # if directMessage flag is set to true, leave the addressing alone
  94   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  95
  96   def fix_explicit_addressing(object) do
  97     explicit_mentions = Utils.determine_explicit_mentions(object)
  98
  99     %User{follower_address: follower_collection} =
 100       object
 101       |> Containment.get_actor()
 102       |> User.get_cached_by_ap_id()
 103
 104     explicit_mentions =
 105       explicit_mentions ++
 106         [
 107           Pleroma.Constants.as_public(),
 108           follower_collection
 109         ]
 110
 111     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 112   end
 113
 114   # if as:Public is addressed, then make sure the followers collection is also addressed
 115   # so that the activities will be delivered to local users.
 116   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 117     recipients = to ++ cc
 118
 119     if followers_collection not in recipients do
 120       cond do
 121         Pleroma.Constants.as_public() in cc ->
 122           to = to ++ [followers_collection]
 123           Map.put(object, "to", to)
 124
 125         Pleroma.Constants.as_public() in to ->
 126           cc = cc ++ [followers_collection]
 127           Map.put(object, "cc", cc)
 128
 129         true ->
 130           object
 131       end
 132     else
 133       object
 134     end
 135   end
 136
 137   def fix_implicit_addressing(object, _), do: object
 138
 139   def fix_addressing(object) do
 140     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 141     followers_collection = User.ap_followers(user)
 142
 143     object
 144     |> fix_addressing_list("to")
 145     |> fix_addressing_list("cc")
 146     |> fix_addressing_list("bto")
 147     |> fix_addressing_list("bcc")
 148     |> fix_explicit_addressing()
 149     |> fix_implicit_addressing(followers_collection)
 150   end
 151
 152   def fix_actor(%{"attributedTo" => actor} = object) do
 153     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 154   end
 155
 156   def fix_in_reply_to(object, options \\ [])
 157
 158   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 159       when not is_nil(in_reply_to) do
 160     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 161     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 162     depth = (options[:depth] || 0) + 1
 163
 164     if Federator.allowed_thread_distance?(depth) do
 165       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 166            %Activity{} <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 167         object
 168         |> Map.put("inReplyTo", replied_object.data["id"])
 169         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 170         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 171         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 172       else
 173         e ->
 174           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 175           object
 176       end
 177     else
 178       object
 179     end
 180   end
 181
 182   def fix_in_reply_to(object, _options), do: object
 183
 184   defp prepare_in_reply_to(in_reply_to) do
 185     cond do
 186       is_bitstring(in_reply_to) ->
 187         in_reply_to
 188
 189       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 190         in_reply_to["id"]
 191
 192       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 193         Enum.at(in_reply_to, 0)
 194
 195       true ->
 196         ""
 197     end
 198   end
 199
 200   def fix_context(object) do
 201     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 202
 203     object
 204     |> Map.put("context", context)
 205     |> Map.put("conversation", context)
 206   end
 207
 208   defp add_if_present(map, _key, nil), do: map
 209
 210   defp add_if_present(map, key, value) do
 211     Map.put(map, key, value)
 212   end
 213
 214   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 215     attachments =
 216       Enum.map(attachment, fn data ->
 217         url =
 218           cond do
 219             is_list(data["url"]) -> List.first(data["url"])
 220             is_map(data["url"]) -> data["url"]
 221             true -> nil
 222           end
 223
 224         media_type =
 225           cond do
 226             is_map(url) && is_binary(url["mediaType"]) -> url["mediaType"]
 227             is_binary(data["mediaType"]) -> data["mediaType"]
 228             is_binary(data["mimeType"]) -> data["mimeType"]
 229             true -> nil
 230           end
 231
 232         href =
 233           cond do
 234             is_map(url) && is_binary(url["href"]) -> url["href"]
 235             is_binary(data["url"]) -> data["url"]
 236             is_binary(data["href"]) -> data["href"]
 237           end
 238
 239         attachment_url =
 240           %{"href" => href}
 241           |> add_if_present("mediaType", media_type)
 242           |> add_if_present("type", Map.get(url || %{}, "type"))
 243
 244         %{"url" => [attachment_url]}
 245         |> add_if_present("mediaType", media_type)
 246         |> add_if_present("type", data["type"])
 247         |> add_if_present("name", data["name"])
 248       end)
 249
 250     Map.put(object, "attachment", attachments)
 251   end
 252
 253   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 254     object
 255     |> Map.put("attachment", [attachment])
 256     |> fix_attachments()
 257   end
 258
 259   def fix_attachments(object), do: object
 260
 261   def fix_url(%{"url" => url} = object) when is_map(url) do
 262     Map.put(object, "url", url["href"])
 263   end
 264
 265   def fix_url(%{"type" => object_type, "url" => url} = object)
 266       when object_type in ["Video", "Audio"] and is_list(url) do
 267     first_element = Enum.at(url, 0)
 268
 269     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 270
 271     object
 272     |> Map.put("attachment", [first_element])
 273     |> Map.put("url", link_element["href"])
 274   end
 275
 276   def fix_url(%{"type" => object_type, "url" => url} = object)
 277       when object_type != "Video" and is_list(url) do
 278     first_element = Enum.at(url, 0)
 279
 280     url_string =
 281       cond do
 282         is_bitstring(first_element) -> first_element
 283         is_map(first_element) -> first_element["href"] || ""
 284         true -> ""
 285       end
 286
 287     Map.put(object, "url", url_string)
 288   end
 289
 290   def fix_url(object), do: object
 291
 292   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 293     emoji =
 294       tags
 295       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 296       |> Enum.reduce(%{}, fn data, mapping ->
 297         name = String.trim(data["name"], ":")
 298
 299         Map.put(mapping, name, data["icon"]["url"])
 300       end)
 301
 302     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 303     emoji = Map.merge(object["emoji"] || %{}, emoji)
 304
 305     Map.put(object, "emoji", emoji)
 306   end
 307
 308   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 309     name = String.trim(tag["name"], ":")
 310     emoji = %{name => tag["icon"]["url"]}
 311
 312     Map.put(object, "emoji", emoji)
 313   end
 314
 315   def fix_emoji(object), do: object
 316
 317   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 318     tags =
 319       tag
 320       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 321       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 322
 323     Map.put(object, "tag", tag ++ tags)
 324   end
 325
 326   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 327     combined = [tag, String.slice(hashtag, 1..-1)]
 328
 329     Map.put(object, "tag", combined)
 330   end
 331
 332   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 333
 334   def fix_tag(object), do: object
 335
 336   # content map usually only has one language so this will do for now.
 337   def fix_content_map(%{"contentMap" => content_map} = object) do
 338     content_groups = Map.to_list(content_map)
 339     {_, content} = Enum.at(content_groups, 0)
 340
 341     Map.put(object, "content", content)
 342   end
 343
 344   def fix_content_map(object), do: object
 345
 346   def fix_type(object, options \\ [])
 347
 348   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 349       when is_binary(reply_id) do
 350     with true <- Federator.allowed_thread_distance?(options[:depth]),
 351          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 352       Map.put(object, "type", "Answer")
 353     else
 354       _ -> object
 355     end
 356   end
 357
 358   def fix_type(object, _), do: object
 359
 360   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 361     with true <- id =~ "follows",
 362          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 363          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 364       {:ok, activity}
 365     else
 366       _ -> {:error, nil}
 367     end
 368   end
 369
 370   defp mastodon_follow_hack(_, _), do: {:error, nil}
 371
 372   defp get_follow_activity(follow_object, followed) do
 373     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 374          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 375       {:ok, activity}
 376     else
 377       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 378       {:activity, nil} ->
 379         mastodon_follow_hack(follow_object, followed)
 380
 381       _ ->
 382         {:error, nil}
 383     end
 384   end
 385
 386   # Reduce the object list to find the reported user.
 387   defp get_reported(objects) do
 388     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 389       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 390         {:halt, user}
 391       else
 392         _ -> {:cont, nil}
 393       end
 394     end)
 395   end
 396
 397   def handle_incoming(data, options \\ [])
 398
 399   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 400   # with nil ID.
 401   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 402     with context <- data["context"] || Utils.generate_context_id(),
 403          content <- data["content"] || "",
 404          %User{} = actor <- User.get_cached_by_ap_id(actor),
 405          # Reduce the object list to find the reported user.
 406          %User{} = account <- get_reported(objects),
 407          # Remove the reported user from the object list.
 408          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 409       %{
 410         actor: actor,
 411         context: context,
 412         account: account,
 413         statuses: statuses,
 414         content: content,
 415         additional: %{"cc" => [account.ap_id]}
 416       }
 417       |> ActivityPub.flag()
 418     end
 419   end
 420
 421   # disallow objects with bogus IDs
 422   def handle_incoming(%{"id" => nil}, _options), do: :error
 423   def handle_incoming(%{"id" => ""}, _options), do: :error
 424   # length of https:// = 8, should validate better, but good enough for now.
 425   def handle_incoming(%{"id" => id}, _options) when is_binary(id) and byte_size(id) < 8,
 426     do: :error
 427
 428   # TODO: validate those with a Ecto scheme
 429   # - tags
 430   # - emoji
 431   def handle_incoming(
 432         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 433         options
 434       )
 435       when objtype in ["Article", "Event", "Note", "Video", "Page", "Question", "Answer", "Audio"] do
 436     actor = Containment.get_actor(data)
 437
 438     data =
 439       Map.put(data, "actor", actor)
 440       |> fix_addressing
 441
 442     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 443          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 444       object = fix_object(object, options)
 445
 446       params = %{
 447         to: data["to"],
 448         object: object,
 449         actor: user,
 450         context: object["conversation"],
 451         local: false,
 452         published: data["published"],
 453         additional:
 454           Map.take(data, [
 455             "cc",
 456             "directMessage",
 457             "id"
 458           ])
 459       }
 460
 461       with {:ok, created_activity} <- ActivityPub.create(params) do
 462         reply_depth = (options[:depth] || 0) + 1
 463
 464         if Federator.allowed_thread_distance?(reply_depth) do
 465           for reply_id <- replies(object) do
 466             Pleroma.Workers.RemoteFetcherWorker.enqueue("fetch_remote", %{
 467               "id" => reply_id,
 468               "depth" => reply_depth
 469             })
 470           end
 471         end
 472
 473         {:ok, created_activity}
 474       end
 475     else
 476       %Activity{} = activity -> {:ok, activity}
 477       _e -> :error
 478     end
 479   end
 480
 481   def handle_incoming(
 482         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 483         options
 484       ) do
 485     actor = Containment.get_actor(data)
 486
 487     data =
 488       Map.put(data, "actor", actor)
 489       |> fix_addressing
 490
 491     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 492       reply_depth = (options[:depth] || 0) + 1
 493       options = Keyword.put(options, :depth, reply_depth)
 494       object = fix_object(object, options)
 495
 496       params = %{
 497         to: data["to"],
 498         object: object,
 499         actor: user,
 500         context: nil,
 501         local: false,
 502         published: data["published"],
 503         additional: Map.take(data, ["cc", "id"])
 504       }
 505
 506       ActivityPub.listen(params)
 507     else
 508       _e -> :error
 509     end
 510   end
 511
 512   def handle_incoming(
 513         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 514         _options
 515       ) do
 516     with %User{local: true} = followed <-
 517            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 518          {:ok, %User{} = follower} <-
 519            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 520          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 521       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 522            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 523            {_, false} <- {:user_locked, User.locked?(followed)},
 524            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 525            {_, {:ok, _}} <-
 526              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 527            {:ok, _relationship} <-
 528              FollowingRelationship.update(follower, followed, :follow_accept) do
 529         ActivityPub.accept(%{
 530           to: [follower.ap_id],
 531           actor: followed,
 532           object: data,
 533           local: true
 534         })
 535       else
 536         {:user_blocked, true} ->
 537           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 538           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 539
 540           ActivityPub.reject(%{
 541             to: [follower.ap_id],
 542             actor: followed,
 543             object: data,
 544             local: true
 545           })
 546
 547         {:follow, {:error, _}} ->
 548           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 549           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 550
 551           ActivityPub.reject(%{
 552             to: [follower.ap_id],
 553             actor: followed,
 554             object: data,
 555             local: true
 556           })
 557
 558         {:user_locked, true} ->
 559           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_pending)
 560           :noop
 561       end
 562
 563       {:ok, activity}
 564     else
 565       _e ->
 566         :error
 567     end
 568   end
 569
 570   def handle_incoming(
 571         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 572         _options
 573       ) do
 574     with actor <- Containment.get_actor(data),
 575          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 576          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 577          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 578          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 579          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_accept) do
 580       ActivityPub.accept(%{
 581         to: follow_activity.data["to"],
 582         type: "Accept",
 583         actor: followed,
 584         object: follow_activity.data["id"],
 585         local: false,
 586         activity_id: id
 587       })
 588     else
 589       _e -> :error
 590     end
 591   end
 592
 593   def handle_incoming(
 594         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 595         _options
 596       ) do
 597     with actor <- Containment.get_actor(data),
 598          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 599          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 600          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 601          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 602          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_reject),
 603          {:ok, activity} <-
 604            ActivityPub.reject(%{
 605              to: follow_activity.data["to"],
 606              type: "Reject",
 607              actor: followed,
 608              object: follow_activity.data["id"],
 609              local: false,
 610              activity_id: id
 611            }) do
 612       {:ok, activity}
 613     else
 614       _e -> :error
 615     end
 616   end
 617
 618   @misskey_reactions %{
 619     "like" => "👍",
 620     "love" => "❤️",
 621     "laugh" => "😆",
 622     "hmm" => "🤔",
 623     "surprise" => "😮",
 624     "congrats" => "🎉",
 625     "angry" => "💢",
 626     "confused" => "😥",
 627     "rip" => "😇",
 628     "pudding" => "🍮",
 629     "star" => "⭐"
 630   }
 631
 632   @doc "Rewrite misskey likes into EmojiReacts"
 633   def handle_incoming(
 634         %{
 635           "type" => "Like",
 636           "_misskey_reaction" => reaction
 637         } = data,
 638         options
 639       ) do
 640     data
 641     |> Map.put("type", "EmojiReact")
 642     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 643     |> handle_incoming(options)
 644   end
 645
 646   def handle_incoming(
 647         %{"type" => "Create", "object" => %{"type" => "ChatMessage"}} = data,
 648         _options
 649       ) do
 650     case Pipeline.common_pipeline(data, local: false) do
 651       {:ok, activity, _} ->
 652         {:ok, activity}
 653
 654       e ->
 655         e
 656     end
 657   end
 658
 659   def handle_incoming(%{"type" => "Like"} = data, _options) do
 660     with {_, {:ok, cast_data_sym}} <-
 661            {:casting_data,
 662             data |> LikeValidator.cast_data() |> Ecto.Changeset.apply_action(:insert)},
 663          cast_data = ObjectValidator.stringify_keys(Map.from_struct(cast_data_sym)),
 664          :ok <- ObjectValidator.fetch_actor_and_object(cast_data),
 665          {_, {:ok, cast_data}} <- {:ensure_context_presence, ensure_context_presence(cast_data)},
 666          {_, {:ok, cast_data}} <-
 667            {:ensure_recipients_presence, ensure_recipients_presence(cast_data)},
 668          {_, {:ok, activity, _meta}} <-
 669            {:common_pipeline, Pipeline.common_pipeline(cast_data, local: false)} do
 670       {:ok, activity}
 671     else
 672       e -> {:error, e}
 673     end
 674   end
 675
 676   def handle_incoming(
 677         %{
 678           "type" => "EmojiReact",
 679           "object" => object_id,
 680           "actor" => _actor,
 681           "id" => id,
 682           "content" => emoji
 683         } = data,
 684         _options
 685       ) do
 686     with actor <- Containment.get_actor(data),
 687          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 688          {:ok, object} <- get_obj_helper(object_id),
 689          {:ok, activity, _object} <-
 690            ActivityPub.react_with_emoji(actor, object, emoji, activity_id: id, local: false) do
 691       {:ok, activity}
 692     else
 693       _e -> :error
 694     end
 695   end
 696
 697   def handle_incoming(
 698         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 699         _options
 700       ) do
 701     with actor <- Containment.get_actor(data),
 702          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 703          {:ok, object} <- get_embedded_obj_helper(object_id, actor),
 704          public <- Visibility.is_public?(data),
 705          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 706       {:ok, activity}
 707     else
 708       _e -> :error
 709     end
 710   end
 711
 712   def handle_incoming(
 713         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 714           data,
 715         _options
 716       )
 717       when object_type in [
 718              "Person",
 719              "Application",
 720              "Service",
 721              "Organization"
 722            ] do
 723     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 724       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 725
 726       actor
 727       |> User.remote_user_changeset(new_user_data)
 728       |> User.update_and_set_cache()
 729
 730       ActivityPub.update(%{
 731         local: false,
 732         to: data["to"] || [],
 733         cc: data["cc"] || [],
 734         object: object,
 735         actor: actor_id,
 736         activity_id: data["id"]
 737       })
 738     else
 739       e ->
 740         Logger.error(e)
 741         :error
 742     end
 743   end
 744
 745   # TODO: We presently assume that any actor on the same origin domain as the object being
 746   # deleted has the rights to delete that object.  A better way to validate whether or not
 747   # the object should be deleted is to refetch the object URI, which should return either
 748   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 749   # place.
 750   def handle_incoming(
 751         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => id} = data,
 752         _options
 753       ) do
 754     object_id = Utils.get_ap_id(object_id)
 755
 756     with actor <- Containment.get_actor(data),
 757          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 758          {:ok, object} <- get_obj_helper(object_id),
 759          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 760          {:ok, activity} <-
 761            ActivityPub.delete(object, local: false, activity_id: id, actor: actor.ap_id) do
 762       {:ok, activity}
 763     else
 764       nil ->
 765         case User.get_cached_by_ap_id(object_id) do
 766           %User{ap_id: ^actor} = user ->
 767             User.delete(user)
 768
 769           nil ->
 770             :error
 771         end
 772
 773       _e ->
 774         :error
 775     end
 776   end
 777
 778   def handle_incoming(
 779         %{
 780           "type" => "Undo",
 781           "object" => %{"type" => "Announce", "object" => object_id},
 782           "actor" => _actor,
 783           "id" => id
 784         } = data,
 785         _options
 786       ) do
 787     with actor <- Containment.get_actor(data),
 788          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 789          {:ok, object} <- get_obj_helper(object_id),
 790          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 791       {:ok, activity}
 792     else
 793       _e -> :error
 794     end
 795   end
 796
 797   def handle_incoming(
 798         %{
 799           "type" => "Undo",
 800           "object" => %{"type" => "Follow", "object" => followed},
 801           "actor" => follower,
 802           "id" => id
 803         } = _data,
 804         _options
 805       ) do
 806     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 807          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 808          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 809       User.unfollow(follower, followed)
 810       {:ok, activity}
 811     else
 812       _e -> :error
 813     end
 814   end
 815
 816   def handle_incoming(
 817         %{
 818           "type" => "Undo",
 819           "object" => %{"type" => "EmojiReact", "id" => reaction_activity_id},
 820           "actor" => _actor,
 821           "id" => id
 822         } = data,
 823         _options
 824       ) do
 825     with actor <- Containment.get_actor(data),
 826          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 827          {:ok, activity, _} <-
 828            ActivityPub.unreact_with_emoji(actor, reaction_activity_id,
 829              activity_id: id,
 830              local: false
 831            ) do
 832       {:ok, activity}
 833     else
 834       _e -> :error
 835     end
 836   end
 837
 838   def handle_incoming(
 839         %{
 840           "type" => "Undo",
 841           "object" => %{"type" => "Block", "object" => blocked},
 842           "actor" => blocker,
 843           "id" => id
 844         } = _data,
 845         _options
 846       ) do
 847     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 848          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 849          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 850       User.unblock(blocker, blocked)
 851       {:ok, activity}
 852     else
 853       _e -> :error
 854     end
 855   end
 856
 857   def handle_incoming(
 858         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 859         _options
 860       ) do
 861     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 862          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 863          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 864       User.unfollow(blocker, blocked)
 865       User.block(blocker, blocked)
 866       {:ok, activity}
 867     else
 868       _e -> :error
 869     end
 870   end
 871
 872   def handle_incoming(
 873         %{
 874           "type" => "Undo",
 875           "object" => %{"type" => "Like", "object" => object_id},
 876           "actor" => _actor,
 877           "id" => id
 878         } = data,
 879         _options
 880       ) do
 881     with actor <- Containment.get_actor(data),
 882          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 883          {:ok, object} <- get_obj_helper(object_id),
 884          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 885       {:ok, activity}
 886     else
 887       _e -> :error
 888     end
 889   end
 890
 891   # For Undos that don't have the complete object attached, try to find it in our database.
 892   def handle_incoming(
 893         %{
 894           "type" => "Undo",
 895           "object" => object
 896         } = activity,
 897         options
 898       )
 899       when is_binary(object) do
 900     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 901       activity
 902       |> Map.put("object", data)
 903       |> handle_incoming(options)
 904     else
 905       _e -> :error
 906     end
 907   end
 908
 909   def handle_incoming(
 910         %{
 911           "type" => "Move",
 912           "actor" => origin_actor,
 913           "object" => origin_actor,
 914           "target" => target_actor
 915         },
 916         _options
 917       ) do
 918     with %User{} = origin_user <- User.get_cached_by_ap_id(origin_actor),
 919          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_actor),
 920          true <- origin_actor in target_user.also_known_as do
 921       ActivityPub.move(origin_user, target_user, false)
 922     else
 923       _e -> :error
 924     end
 925   end
 926
 927   def handle_incoming(_, _), do: :error
 928
 929   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 930   def get_obj_helper(id, options \\ []) do
 931     case Object.normalize(id, true, options) do
 932       %Object{} = object -> {:ok, object}
 933       _ -> nil
 934     end
 935   end
 936
 937   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 938   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 939         ap_id: ap_id
 940       })
 941       when attributed_to == ap_id do
 942     with {:ok, activity} <-
 943            handle_incoming(%{
 944              "type" => "Create",
 945              "to" => data["to"],
 946              "cc" => data["cc"],
 947              "actor" => attributed_to,
 948              "object" => data
 949            }) do
 950       {:ok, Object.normalize(activity)}
 951     else
 952       _ -> get_obj_helper(object_id)
 953     end
 954   end
 955
 956   def get_embedded_obj_helper(object_id, _) do
 957     get_obj_helper(object_id)
 958   end
 959
 960   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 961     with false <- String.starts_with?(in_reply_to, "http"),
 962          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 963       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 964     else
 965       _e -> object
 966     end
 967   end
 968
 969   def set_reply_to_uri(obj), do: obj
 970
 971   @doc """
 972   Serialized Mastodon-compatible `replies` collection containing _self-replies_.
 973   Based on Mastodon's ActivityPub::NoteSerializer#replies.
 974   """
 975   def set_replies(obj_data) do
 976     replies_uris =
 977       with limit when limit > 0 <-
 978              Pleroma.Config.get([:activitypub, :note_replies_output_limit], 0),
 979            %Object{} = object <- Object.get_cached_by_ap_id(obj_data["id"]) do
 980         object
 981         |> Object.self_replies()
 982         |> select([o], fragment("?->>'id'", o.data))
 983         |> limit(^limit)
 984         |> Repo.all()
 985       else
 986         _ -> []
 987       end
 988
 989     set_replies(obj_data, replies_uris)
 990   end
 991
 992   defp set_replies(obj, []) do
 993     obj
 994   end
 995
 996   defp set_replies(obj, replies_uris) do
 997     replies_collection = %{
 998       "type" => "Collection",
 999       "items" => replies_uris
1000     }
1001
1002     Map.merge(obj, %{"replies" => replies_collection})
1003   end
1004
1005   def replies(%{"replies" => %{"first" => %{"items" => items}}}) when not is_nil(items) do
1006     items
1007   end
1008
1009   def replies(%{"replies" => %{"items" => items}}) when not is_nil(items) do
1010     items
1011   end
1012
1013   def replies(_), do: []
1014
1015   # Prepares the object of an outgoing create activity.
1016   def prepare_object(object) do
1017     object
1018     |> set_sensitive
1019     |> add_hashtags
1020     |> add_mention_tags
1021     |> add_emoji_tags
1022     |> add_attributed_to
1023     |> prepare_attachments
1024     |> set_conversation
1025     |> set_reply_to_uri
1026     |> set_replies
1027     |> strip_internal_fields
1028     |> strip_internal_tags
1029     |> set_type
1030   end
1031
1032   #  @doc
1033   #  """
1034   #  internal -> Mastodon
1035   #  """
1036
1037   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
1038       when activity_type in ["Create", "Listen"] do
1039     object =
1040       object_id
1041       |> Object.normalize()
1042       |> Map.get(:data)
1043       |> prepare_object
1044
1045     data =
1046       data
1047       |> Map.put("object", object)
1048       |> Map.merge(Utils.make_json_ld_header())
1049       |> Map.delete("bcc")
1050
1051     {:ok, data}
1052   end
1053
1054   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
1055     object =
1056       object_id
1057       |> Object.normalize()
1058
1059     data =
1060       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
1061         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
1062       else
1063         data |> maybe_fix_object_url
1064       end
1065
1066     data =
1067       data
1068       |> strip_internal_fields
1069       |> Map.merge(Utils.make_json_ld_header())
1070       |> Map.delete("bcc")
1071
1072     {:ok, data}
1073   end
1074
1075   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
1076   # because of course it does.
1077   def prepare_outgoing(%{"type" => "Accept"} = data) do
1078     with follow_activity <- Activity.normalize(data["object"]) do
1079       object = %{
1080         "actor" => follow_activity.actor,
1081         "object" => follow_activity.data["object"],
1082         "id" => follow_activity.data["id"],
1083         "type" => "Follow"
1084       }
1085
1086       data =
1087         data
1088         |> Map.put("object", object)
1089         |> Map.merge(Utils.make_json_ld_header())
1090
1091       {:ok, data}
1092     end
1093   end
1094
1095   def prepare_outgoing(%{"type" => "Reject"} = data) do
1096     with follow_activity <- Activity.normalize(data["object"]) do
1097       object = %{
1098         "actor" => follow_activity.actor,
1099         "object" => follow_activity.data["object"],
1100         "id" => follow_activity.data["id"],
1101         "type" => "Follow"
1102       }
1103
1104       data =
1105         data
1106         |> Map.put("object", object)
1107         |> Map.merge(Utils.make_json_ld_header())
1108
1109       {:ok, data}
1110     end
1111   end
1112
1113   def prepare_outgoing(%{"type" => _type} = data) do
1114     data =
1115       data
1116       |> strip_internal_fields
1117       |> maybe_fix_object_url
1118       |> Map.merge(Utils.make_json_ld_header())
1119
1120     {:ok, data}
1121   end
1122
1123   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
1124     with false <- String.starts_with?(object, "http"),
1125          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
1126          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
1127            relative_object do
1128       Map.put(data, "object", external_url)
1129     else
1130       {:fetch, e} ->
1131         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
1132         data
1133
1134       _ ->
1135         data
1136     end
1137   end
1138
1139   def maybe_fix_object_url(data), do: data
1140
1141   def add_hashtags(object) do
1142     tags =
1143       (object["tag"] || [])
1144       |> Enum.map(fn
1145         # Expand internal representation tags into AS2 tags.
1146         tag when is_binary(tag) ->
1147           %{
1148             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
1149             "name" => "##{tag}",
1150             "type" => "Hashtag"
1151           }
1152
1153         # Do not process tags which are already AS2 tag objects.
1154         tag when is_map(tag) ->
1155           tag
1156       end)
1157
1158     Map.put(object, "tag", tags)
1159   end
1160
1161   def add_mention_tags(object) do
1162     {enabled_receivers, disabled_receivers} = Utils.get_notified_from_object(object)
1163     potential_receivers = enabled_receivers ++ disabled_receivers
1164     mentions = Enum.map(potential_receivers, &build_mention_tag/1)
1165
1166     tags = object["tag"] || []
1167     Map.put(object, "tag", tags ++ mentions)
1168   end
1169
1170   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1171     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1172   end
1173
1174   def take_emoji_tags(%User{emoji: emoji}) do
1175     emoji
1176     |> Map.to_list()
1177     |> Enum.map(&build_emoji_tag/1)
1178   end
1179
1180   # TODO: we should probably send mtime instead of unix epoch time for updated
1181   def add_emoji_tags(%{"emoji" => emoji} = object) do
1182     tags = object["tag"] || []
1183
1184     out = Enum.map(emoji, &build_emoji_tag/1)
1185
1186     Map.put(object, "tag", tags ++ out)
1187   end
1188
1189   def add_emoji_tags(object), do: object
1190
1191   defp build_emoji_tag({name, url}) do
1192     %{
1193       "icon" => %{"url" => url, "type" => "Image"},
1194       "name" => ":" <> name <> ":",
1195       "type" => "Emoji",
1196       "updated" => "1970-01-01T00:00:00Z",
1197       "id" => url
1198     }
1199   end
1200
1201   def set_conversation(object) do
1202     Map.put(object, "conversation", object["context"])
1203   end
1204
1205   def set_sensitive(object) do
1206     tags = object["tag"] || []
1207     Map.put(object, "sensitive", "nsfw" in tags)
1208   end
1209
1210   def set_type(%{"type" => "Answer"} = object) do
1211     Map.put(object, "type", "Note")
1212   end
1213
1214   def set_type(object), do: object
1215
1216   def add_attributed_to(object) do
1217     attributed_to = object["attributedTo"] || object["actor"]
1218     Map.put(object, "attributedTo", attributed_to)
1219   end
1220
1221   def prepare_attachments(object) do
1222     attachments =
1223       (object["attachment"] || [])
1224       |> Enum.map(fn data ->
1225         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1226         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1227       end)
1228
1229     Map.put(object, "attachment", attachments)
1230   end
1231
1232   def strip_internal_fields(object) do
1233     object
1234     |> Map.drop(Pleroma.Constants.object_internal_fields())
1235   end
1236
1237   defp strip_internal_tags(%{"tag" => tags} = object) do
1238     tags = Enum.filter(tags, fn x -> is_map(x) end)
1239
1240     Map.put(object, "tag", tags)
1241   end
1242
1243   defp strip_internal_tags(object), do: object
1244
1245   def perform(:user_upgrade, user) do
1246     # we pass a fake user so that the followers collection is stripped away
1247     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1248
1249     from(
1250       a in Activity,
1251       where: ^old_follower_address in a.recipients,
1252       update: [
1253         set: [
1254           recipients:
1255             fragment(
1256               "array_replace(?,?,?)",
1257               a.recipients,
1258               ^old_follower_address,
1259               ^user.follower_address
1260             )
1261         ]
1262       ]
1263     )
1264     |> Repo.update_all([])
1265   end
1266
1267   def upgrade_user_from_ap_id(ap_id) do
1268     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1269          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1270          {:ok, user} <- update_user(user, data) do
1271       TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1272       {:ok, user}
1273     else
1274       %User{} = user -> {:ok, user}
1275       e -> e
1276     end
1277   end
1278
1279   defp update_user(user, data) do
1280     user
1281     |> User.remote_user_changeset(data)
1282     |> User.update_and_set_cache()
1283   end
1284
1285   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1286     Map.put(data, "url", url["href"])
1287   end
1288
1289   def maybe_fix_user_url(data), do: data
1290
1291   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1292
1293   defp ensure_context_presence(%{"context" => context} = data) when is_binary(context),
1294     do: {:ok, data}
1295
1296   defp ensure_context_presence(%{"object" => object} = data) when is_binary(object) do
1297     with %{data: %{"context" => context}} when is_binary(context) <- Object.normalize(object) do
1298       {:ok, Map.put(data, "context", context)}
1299     else
1300       _ ->
1301         {:error, :no_context}
1302     end
1303   end
1304
1305   defp ensure_context_presence(_) do
1306     {:error, :no_context}
1307   end
1308
1309   defp ensure_recipients_presence(%{"to" => [_ | _], "cc" => [_ | _]} = data),
1310     do: {:ok, data}
1311
1312   defp ensure_recipients_presence(%{"object" => object} = data) do
1313     case Object.normalize(object) do
1314       %{data: %{"actor" => actor}} ->
1315         data =
1316           data
1317           |> Map.put("to", [actor])
1318           |> Map.put("cc", data["cc"] || [])
1319
1320         {:ok, data}
1321
1322       nil ->
1323         {:error, :no_object}
1324
1325       _ ->
1326         {:error, :no_actor}
1327     end
1328   end
1329
1330   defp ensure_recipients_presence(_) do
1331     {:error, :no_object}
1332   end
1333 end