git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.User
  10   alias Pleroma.Object
  11   alias Pleroma.Activity
  12   alias Pleroma.Repo
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.ActivityPub.Utils
  15
  16   import Ecto.Query
  17
  18   require Logger
  19
  20   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  21     actor
  22   end
  23
  24   def get_actor(%{"actor" => actor}) when is_list(actor) do
  25     if is_binary(Enum.at(actor, 0)) do
  26       Enum.at(actor, 0)
  27     else
  28       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  29       |> Map.get("id")
  30     end
  31   end
  32
  33   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  34     id
  35   end
  36
  37   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  38     get_actor(%{"actor" => actor})
  39   end
  40
  41   @doc """
  42   Checks that an imported AP object's actor matches the domain it came from.
  43   """
  44   def contain_origin(_id, %{"actor" => nil}), do: :error
  45
  46   def contain_origin(id, %{"actor" => _actor} = params) do
  47     id_uri = URI.parse(id)
  48     actor_uri = URI.parse(get_actor(params))
  49
  50     if id_uri.host == actor_uri.host do
  51       :ok
  52     else
  53       :error
  54     end
  55   end
  56
  57   def contain_origin_from_id(_id, %{"id" => nil}), do: :error
  58
  59   def contain_origin_from_id(id, %{"id" => other_id} = _params) do
  60     id_uri = URI.parse(id)
  61     other_uri = URI.parse(other_id)
  62
  63     if id_uri.host == other_uri.host do
  64       :ok
  65     else
  66       :error
  67     end
  68   end
  69
  70   @doc """
  71   Modifies an incoming AP object (mastodon format) to our internal format.
  72   """
  73   def fix_object(object) do
  74     object
  75     |> fix_actor
  76     |> fix_url
  77     |> fix_attachments
  78     |> fix_context
  79     |> fix_in_reply_to
  80     |> fix_emoji
  81     |> fix_tag
  82     |> fix_content_map
  83     |> fix_likes
  84     |> fix_addressing
  85   end
  86
  87   def fix_addressing_list(map, field) do
  88     if is_binary(map[field]) do
  89       map
  90       |> Map.put(field, [map[field]])
  91     else
  92       map
  93     end
  94   end
  95
  96   def fix_addressing(map) do
  97     map
  98     |> fix_addressing_list("to")
  99     |> fix_addressing_list("cc")
 100     |> fix_addressing_list("bto")
 101     |> fix_addressing_list("bcc")
 102   end
 103
 104   def fix_actor(%{"attributedTo" => actor} = object) do
 105     object
 106     |> Map.put("actor", get_actor(%{"actor" => actor}))
 107   end
 108
 109   def fix_likes(%{"likes" => likes} = object)
 110       when is_bitstring(likes) do
 111     # Check for standardisation
 112     # This is what Peertube does
 113     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
 114     object
 115     |> Map.put("likes", [])
 116     |> Map.put("like_count", 0)
 117   end
 118
 119   def fix_likes(object) do
 120     object
 121   end
 122
 123   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 124       when not is_nil(in_reply_to) do
 125     in_reply_to_id =
 126       cond do
 127         is_bitstring(in_reply_to) ->
 128           in_reply_to
 129
 130         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 131           in_reply_to["id"]
 132
 133         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 134           Enum.at(in_reply_to, 0)
 135
 136         # Maybe I should output an error too?
 137         true ->
 138           ""
 139       end
 140
 141     case fetch_obj_helper(in_reply_to_id) do
 142       {:ok, replied_object} ->
 143         with %Activity{} = activity <-
 144                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 145           object
 146           |> Map.put("inReplyTo", replied_object.data["id"])
 147           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 148           |> Map.put("inReplyToStatusId", activity.id)
 149           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 150           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 151         else
 152           e ->
 153             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 154             object
 155         end
 156
 157       e ->
 158         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 159         object
 160     end
 161   end
 162
 163   def fix_in_reply_to(object), do: object
 164
 165   def fix_context(object) do
 166     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 167
 168     object
 169     |> Map.put("context", context)
 170     |> Map.put("conversation", context)
 171   end
 172
 173   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 174     attachments =
 175       attachment
 176       |> Enum.map(fn data ->
 177         media_type = data["mediaType"] || data["mimeType"]
 178         href = data["url"] || data["href"]
 179
 180         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 181
 182         data
 183         |> Map.put("mediaType", media_type)
 184         |> Map.put("url", url)
 185       end)
 186
 187     object
 188     |> Map.put("attachment", attachments)
 189   end
 190
 191   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 192     Map.put(object, "attachment", [attachment])
 193     |> fix_attachments()
 194   end
 195
 196   def fix_attachments(object), do: object
 197
 198   def fix_url(%{"url" => url} = object) when is_map(url) do
 199     object
 200     |> Map.put("url", url["href"])
 201   end
 202
 203   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 204     first_element = Enum.at(url, 0)
 205
 206     link_element =
 207       url
 208       |> Enum.filter(fn x -> is_map(x) end)
 209       |> Enum.filter(fn x -> x["mimeType"] == "text/html" end)
 210       |> Enum.at(0)
 211
 212     object
 213     |> Map.put("attachment", [first_element])
 214     |> Map.put("url", link_element["href"])
 215   end
 216
 217   def fix_url(%{"type" => object_type, "url" => url} = object)
 218       when object_type != "Video" and is_list(url) do
 219     first_element = Enum.at(url, 0)
 220
 221     url_string =
 222       cond do
 223         is_bitstring(first_element) -> first_element
 224         is_map(first_element) -> first_element["href"] || ""
 225         true -> ""
 226       end
 227
 228     object
 229     |> Map.put("url", url_string)
 230   end
 231
 232   def fix_url(object), do: object
 233
 234   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 235     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 236
 237     emoji =
 238       emoji
 239       |> Enum.reduce(%{}, fn data, mapping ->
 240         name = String.trim(data["name"], ":")
 241
 242         mapping |> Map.put(name, data["icon"]["url"])
 243       end)
 244
 245     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 246     emoji = Map.merge(object["emoji"] || %{}, emoji)
 247
 248     object
 249     |> Map.put("emoji", emoji)
 250   end
 251
 252   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 253     name = String.trim(tag["name"], ":")
 254     emoji = %{name => tag["icon"]["url"]}
 255
 256     object
 257     |> Map.put("emoji", emoji)
 258   end
 259
 260   def fix_emoji(object), do: object
 261
 262   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 263     tags =
 264       tag
 265       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 266       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 267
 268     combined = tag ++ tags
 269
 270     object
 271     |> Map.put("tag", combined)
 272   end
 273
 274   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 275     combined = [tag, String.slice(hashtag, 1..-1)]
 276
 277     object
 278     |> Map.put("tag", combined)
 279   end
 280
 281   def fix_tag(object), do: object
 282
 283   # content map usually only has one language so this will do for now.
 284   def fix_content_map(%{"contentMap" => content_map} = object) do
 285     content_groups = Map.to_list(content_map)
 286     {_, content} = Enum.at(content_groups, 0)
 287
 288     object
 289     |> Map.put("content", content)
 290   end
 291
 292   def fix_content_map(object), do: object
 293
 294   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 295     with true <- id =~ "follows",
 296          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 297          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 298       {:ok, activity}
 299     else
 300       _ -> {:error, nil}
 301     end
 302   end
 303
 304   defp mastodon_follow_hack(_, _), do: {:error, nil}
 305
 306   defp get_follow_activity(follow_object, followed) do
 307     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 308          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 309       {:ok, activity}
 310     else
 311       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 312       {:activity, nil} ->
 313         mastodon_follow_hack(follow_object, followed)
 314
 315       _ ->
 316         {:error, nil}
 317     end
 318   end
 319
 320   # disallow objects with bogus IDs
 321   def handle_incoming(%{"id" => nil}), do: :error
 322   def handle_incoming(%{"id" => ""}), do: :error
 323   # length of https:// = 8, should validate better, but good enough for now.
 324   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 325
 326   # TODO: validate those with a Ecto scheme
 327   # - tags
 328   # - emoji
 329   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 330       when objtype in ["Article", "Note", "Video", "Page"] do
 331     actor = get_actor(data)
 332
 333     data =
 334       Map.put(data, "actor", actor)
 335       |> fix_addressing
 336
 337     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 338          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 339       object = fix_object(data["object"])
 340
 341       params = %{
 342         to: data["to"],
 343         object: object,
 344         actor: user,
 345         context: object["conversation"],
 346         local: false,
 347         published: data["published"],
 348         additional:
 349           Map.take(data, [
 350             "cc",
 351             "id"
 352           ])
 353       }
 354
 355       ActivityPub.create(params)
 356     else
 357       %Activity{} = activity -> {:ok, activity}
 358       _e -> :error
 359     end
 360   end
 361
 362   def handle_incoming(
 363         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 364       ) do
 365     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 366          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 367          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 368       if not User.locked?(followed) do
 369         ActivityPub.accept(%{
 370           to: [follower.ap_id],
 371           actor: followed.ap_id,
 372           object: data,
 373           local: true
 374         })
 375
 376         User.follow(follower, followed)
 377       end
 378
 379       {:ok, activity}
 380     else
 381       _e -> :error
 382     end
 383   end
 384
 385   def handle_incoming(
 386         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 387       ) do
 388     with actor <- get_actor(data),
 389          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 390          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 391          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 392          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 393          {:ok, activity} <-
 394            ActivityPub.accept(%{
 395              to: follow_activity.data["to"],
 396              type: "Accept",
 397              actor: followed.ap_id,
 398              object: follow_activity.data["id"],
 399              local: false
 400            }) do
 401       if not User.following?(follower, followed) do
 402         {:ok, _follower} = User.follow(follower, followed)
 403       end
 404
 405       {:ok, activity}
 406     else
 407       _e -> :error
 408     end
 409   end
 410
 411   def handle_incoming(
 412         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data
 413       ) do
 414     with actor <- get_actor(data),
 415          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 416          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 417          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 418          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 419          {:ok, activity} <-
 420            ActivityPub.accept(%{
 421              to: follow_activity.data["to"],
 422              type: "Accept",
 423              actor: followed.ap_id,
 424              object: follow_activity.data["id"],
 425              local: false
 426            }) do
 427       User.unfollow(follower, followed)
 428
 429       {:ok, activity}
 430     else
 431       _e -> :error
 432     end
 433   end
 434
 435   def handle_incoming(
 436         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data
 437       ) do
 438     with actor <- get_actor(data),
 439          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 440          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 441          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 442       {:ok, activity}
 443     else
 444       _e -> :error
 445     end
 446   end
 447
 448   def handle_incoming(
 449         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data
 450       ) do
 451     with actor <- get_actor(data),
 452          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 453          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 454          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 455       {:ok, activity}
 456     else
 457       _e -> :error
 458     end
 459   end
 460
 461   def handle_incoming(
 462         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 463           data
 464       )
 465       when object_type in ["Person", "Application", "Service", "Organization"] do
 466     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 467       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 468
 469       banner = new_user_data[:info]["banner"]
 470       locked = new_user_data[:info]["locked"] || false
 471
 472       update_data =
 473         new_user_data
 474         |> Map.take([:name, :bio, :avatar])
 475         |> Map.put(:info, %{"banner" => banner, "locked" => locked})
 476
 477       actor
 478       |> User.upgrade_changeset(update_data)
 479       |> User.update_and_set_cache()
 480
 481       ActivityPub.update(%{
 482         local: false,
 483         to: data["to"] || [],
 484         cc: data["cc"] || [],
 485         object: object,
 486         actor: actor_id
 487       })
 488     else
 489       e ->
 490         Logger.error(e)
 491         :error
 492     end
 493   end
 494
 495   # TODO: We presently assume that any actor on the same origin domain as the object being
 496   # deleted has the rights to delete that object.  A better way to validate whether or not
 497   # the object should be deleted is to refetch the object URI, which should return either
 498   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 499   # place.
 500   def handle_incoming(
 501         %{"type" => "Delete", "object" => object_id, "actor" => _actor, "id" => _id} = data
 502       ) do
 503     object_id = Utils.get_ap_id(object_id)
 504
 505     with actor <- get_actor(data),
 506          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 507          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 508          :ok <- contain_origin(actor.ap_id, object.data),
 509          {:ok, activity} <- ActivityPub.delete(object, false) do
 510       {:ok, activity}
 511     else
 512       _e -> :error
 513     end
 514   end
 515
 516   def handle_incoming(
 517         %{
 518           "type" => "Undo",
 519           "object" => %{"type" => "Announce", "object" => object_id},
 520           "actor" => _actor,
 521           "id" => id
 522         } = data
 523       ) do
 524     with actor <- get_actor(data),
 525          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 526          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 527          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 528       {:ok, activity}
 529     else
 530       _e -> :error
 531     end
 532   end
 533
 534   def handle_incoming(
 535         %{
 536           "type" => "Undo",
 537           "object" => %{"type" => "Follow", "object" => followed},
 538           "actor" => follower,
 539           "id" => id
 540         } = _data
 541       ) do
 542     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 543          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 544          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 545       User.unfollow(follower, followed)
 546       {:ok, activity}
 547     else
 548       _e -> :error
 549     end
 550   end
 551
 552   def handle_incoming(
 553         %{
 554           "type" => "Undo",
 555           "object" => %{"type" => "Block", "object" => blocked},
 556           "actor" => blocker,
 557           "id" => id
 558         } = _data
 559       ) do
 560     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 561          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 562          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 563          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 564       User.unblock(blocker, blocked)
 565       {:ok, activity}
 566     else
 567       _e -> :error
 568     end
 569   end
 570
 571   def handle_incoming(
 572         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data
 573       ) do
 574     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 575          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 576          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 577          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 578       User.unfollow(blocker, blocked)
 579       User.block(blocker, blocked)
 580       {:ok, activity}
 581     else
 582       _e -> :error
 583     end
 584   end
 585
 586   def handle_incoming(
 587         %{
 588           "type" => "Undo",
 589           "object" => %{"type" => "Like", "object" => object_id},
 590           "actor" => _actor,
 591           "id" => id
 592         } = data
 593       ) do
 594     with actor <- get_actor(data),
 595          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 596          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 597          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 598       {:ok, activity}
 599     else
 600       _e -> :error
 601     end
 602   end
 603
 604   def handle_incoming(_), do: :error
 605
 606   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 607   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 608
 609   def get_obj_helper(id) do
 610     if object = Object.normalize(id), do: {:ok, object}, else: nil
 611   end
 612
 613   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 614     with false <- String.starts_with?(inReplyTo, "http"),
 615          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 616       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 617     else
 618       _e -> object
 619     end
 620   end
 621
 622   def set_reply_to_uri(obj), do: obj
 623
 624   # Prepares the object of an outgoing create activity.
 625   def prepare_object(object) do
 626     object
 627     |> set_sensitive
 628     |> add_hashtags
 629     |> add_mention_tags
 630     |> add_emoji_tags
 631     |> add_attributed_to
 632     |> prepare_attachments
 633     |> set_conversation
 634     |> set_reply_to_uri
 635     |> strip_internal_fields
 636     |> strip_internal_tags
 637   end
 638
 639   #  @doc
 640   #  """
 641   #  internal -> Mastodon
 642   #  """
 643
 644   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 645     object =
 646       object
 647       |> prepare_object
 648
 649     data =
 650       data
 651       |> Map.put("object", object)
 652       |> Map.merge(Utils.make_json_ld_header())
 653
 654     {:ok, data}
 655   end
 656
 657   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 658   # because of course it does.
 659   def prepare_outgoing(%{"type" => "Accept"} = data) do
 660     with follow_activity <- Activity.normalize(data["object"]) do
 661       object = %{
 662         "actor" => follow_activity.actor,
 663         "object" => follow_activity.data["object"],
 664         "id" => follow_activity.data["id"],
 665         "type" => "Follow"
 666       }
 667
 668       data =
 669         data
 670         |> Map.put("object", object)
 671         |> Map.merge(Utils.make_json_ld_header())
 672
 673       {:ok, data}
 674     end
 675   end
 676
 677   def prepare_outgoing(%{"type" => "Reject"} = data) do
 678     with follow_activity <- Activity.normalize(data["object"]) do
 679       object = %{
 680         "actor" => follow_activity.actor,
 681         "object" => follow_activity.data["object"],
 682         "id" => follow_activity.data["id"],
 683         "type" => "Follow"
 684       }
 685
 686       data =
 687         data
 688         |> Map.put("object", object)
 689         |> Map.merge(Utils.make_json_ld_header())
 690
 691       {:ok, data}
 692     end
 693   end
 694
 695   def prepare_outgoing(%{"type" => _type} = data) do
 696     data =
 697       data
 698       |> maybe_fix_object_url
 699       |> Map.merge(Utils.make_json_ld_header())
 700
 701     {:ok, data}
 702   end
 703
 704   def maybe_fix_object_url(data) do
 705     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 706       case fetch_obj_helper(data["object"]) do
 707         {:ok, relative_object} ->
 708           if relative_object.data["external_url"] do
 709             _data =
 710               data
 711               |> Map.put("object", relative_object.data["external_url"])
 712           else
 713             data
 714           end
 715
 716         e ->
 717           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 718           data
 719       end
 720     else
 721       data
 722     end
 723   end
 724
 725   def add_hashtags(object) do
 726     tags =
 727       (object["tag"] || [])
 728       |> Enum.map(fn tag ->
 729         %{
 730           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 731           "name" => "##{tag}",
 732           "type" => "Hashtag"
 733         }
 734       end)
 735
 736     object
 737     |> Map.put("tag", tags)
 738   end
 739
 740   def add_mention_tags(object) do
 741     mentions =
 742       object
 743       |> Utils.get_notified_from_object()
 744       |> Enum.map(fn user ->
 745         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 746       end)
 747
 748     tags = object["tag"] || []
 749
 750     object
 751     |> Map.put("tag", tags ++ mentions)
 752   end
 753
 754   # TODO: we should probably send mtime instead of unix epoch time for updated
 755   def add_emoji_tags(object) do
 756     tags = object["tag"] || []
 757     emoji = object["emoji"] || []
 758
 759     out =
 760       emoji
 761       |> Enum.map(fn {name, url} ->
 762         %{
 763           "icon" => %{"url" => url, "type" => "Image"},
 764           "name" => ":" <> name <> ":",
 765           "type" => "Emoji",
 766           "updated" => "1970-01-01T00:00:00Z",
 767           "id" => url
 768         }
 769       end)
 770
 771     object
 772     |> Map.put("tag", tags ++ out)
 773   end
 774
 775   def set_conversation(object) do
 776     Map.put(object, "conversation", object["context"])
 777   end
 778
 779   def set_sensitive(object) do
 780     tags = object["tag"] || []
 781     Map.put(object, "sensitive", "nsfw" in tags)
 782   end
 783
 784   def add_attributed_to(object) do
 785     attributedTo = object["attributedTo"] || object["actor"]
 786
 787     object
 788     |> Map.put("attributedTo", attributedTo)
 789   end
 790
 791   def prepare_attachments(object) do
 792     attachments =
 793       (object["attachment"] || [])
 794       |> Enum.map(fn data ->
 795         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 796         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 797       end)
 798
 799     object
 800     |> Map.put("attachment", attachments)
 801   end
 802
 803   defp strip_internal_fields(object) do
 804     object
 805     |> Map.drop([
 806       "likes",
 807       "like_count",
 808       "announcements",
 809       "announcement_count",
 810       "emoji",
 811       "context_id"
 812     ])
 813   end
 814
 815   defp strip_internal_tags(%{"tag" => tags} = object) do
 816     tags =
 817       tags
 818       |> Enum.filter(fn x -> is_map(x) end)
 819
 820     object
 821     |> Map.put("tag", tags)
 822   end
 823
 824   defp strip_internal_tags(object), do: object
 825
 826   defp user_upgrade_task(user) do
 827     old_follower_address = User.ap_followers(user)
 828
 829     q =
 830       from(
 831         u in User,
 832         where: ^old_follower_address in u.following,
 833         update: [
 834           set: [
 835             following:
 836               fragment(
 837                 "array_replace(?,?,?)",
 838                 u.following,
 839                 ^old_follower_address,
 840                 ^user.follower_address
 841               )
 842           ]
 843         ]
 844       )
 845
 846     Repo.update_all(q, [])
 847
 848     maybe_retire_websub(user.ap_id)
 849
 850     # Only do this for recent activties, don't go through the whole db.
 851     # Only look at the last 1000 activities.
 852     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 853
 854     q =
 855       from(
 856         a in Activity,
 857         where: ^old_follower_address in a.recipients,
 858         where: a.id > ^since,
 859         update: [
 860           set: [
 861             recipients:
 862               fragment(
 863                 "array_replace(?,?,?)",
 864                 a.recipients,
 865                 ^old_follower_address,
 866                 ^user.follower_address
 867               )
 868           ]
 869         ]
 870       )
 871
 872     Repo.update_all(q, [])
 873   end
 874
 875   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 876     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 877          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 878       already_ap = User.ap_enabled?(user)
 879
 880       {:ok, user} =
 881         User.upgrade_changeset(user, data)
 882         |> Repo.update()
 883
 884       if !already_ap do
 885         # This could potentially take a long time, do it in the background
 886         if async do
 887           Task.start(fn ->
 888             user_upgrade_task(user)
 889           end)
 890         else
 891           user_upgrade_task(user)
 892         end
 893       end
 894
 895       {:ok, user}
 896     else
 897       e -> e
 898     end
 899   end
 900
 901   def maybe_retire_websub(ap_id) do
 902     # some sanity checks
 903     if is_binary(ap_id) && String.length(ap_id) > 8 do
 904       q =
 905         from(
 906           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 907           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 908         )
 909
 910       Repo.delete_all(q)
 911     end
 912   end
 913
 914   def maybe_fix_user_url(data) do
 915     if is_map(data["url"]) do
 916       Map.put(data, "url", data["url"]["href"])
 917     else
 918       data
 919     end
 920   end
 921
 922   def maybe_fix_user_object(data) do
 923     data
 924     |> maybe_fix_user_url
 925   end
 926 end