git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.Object
  11   alias Pleroma.Object.Containment
  12   alias Pleroma.Repo
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15   alias Pleroma.Web.ActivityPub.Utils
  16   alias Pleroma.Web.ActivityPub.Visibility
  17   alias Pleroma.Web.Federator
  18   alias Pleroma.Workers.TransmogrifierWorker
  19
  20   import Ecto.Query
  21
  22   require Logger
  23   require Pleroma.Constants
  24
  25   @doc """
  26   Modifies an incoming AP object (mastodon format) to our internal format.
  27   """
  28   def fix_object(object, options \\ []) do
  29     object
  30     |> strip_internal_fields
  31     |> fix_actor
  32     |> fix_url
  33     |> fix_attachments
  34     |> fix_context
  35     |> fix_in_reply_to(options)
  36     |> fix_emoji
  37     |> fix_tag
  38     |> fix_content_map
  39     |> fix_addressing
  40     |> fix_summary
  41     |> fix_type(options)
  42   end
  43
  44   def fix_summary(%{"summary" => nil} = object) do
  45     Map.put(object, "summary", "")
  46   end
  47
  48   def fix_summary(%{"summary" => _} = object) do
  49     # summary is present, nothing to do
  50     object
  51   end
  52
  53   def fix_summary(object), do: Map.put(object, "summary", "")
  54
  55   def fix_addressing_list(map, field) do
  56     cond do
  57       is_binary(map[field]) ->
  58         Map.put(map, field, [map[field]])
  59
  60       is_nil(map[field]) ->
  61         Map.put(map, field, [])
  62
  63       true ->
  64         map
  65     end
  66   end
  67
  68   def fix_explicit_addressing(
  69         %{"to" => to, "cc" => cc} = object,
  70         explicit_mentions,
  71         follower_collection
  72       ) do
  73     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  74
  75     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  76
  77     final_cc =
  78       (cc ++ explicit_cc)
  79       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  80       |> Enum.uniq()
  81
  82     object
  83     |> Map.put("to", explicit_to)
  84     |> Map.put("cc", final_cc)
  85   end
  86
  87   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  88
  89   # if directMessage flag is set to true, leave the addressing alone
  90   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
  91
  92   def fix_explicit_addressing(object) do
  93     explicit_mentions = Utils.determine_explicit_mentions(object)
  94
  95     %User{follower_address: follower_collection} =
  96       object
  97       |> Containment.get_actor()
  98       |> User.get_cached_by_ap_id()
  99
 100     explicit_mentions =
 101       explicit_mentions ++
 102         [
 103           Pleroma.Constants.as_public(),
 104           follower_collection
 105         ]
 106
 107     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 108   end
 109
 110   # if as:Public is addressed, then make sure the followers collection is also addressed
 111   # so that the activities will be delivered to local users.
 112   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 113     recipients = to ++ cc
 114
 115     if followers_collection not in recipients do
 116       cond do
 117         Pleroma.Constants.as_public() in cc ->
 118           to = to ++ [followers_collection]
 119           Map.put(object, "to", to)
 120
 121         Pleroma.Constants.as_public() in to ->
 122           cc = cc ++ [followers_collection]
 123           Map.put(object, "cc", cc)
 124
 125         true ->
 126           object
 127       end
 128     else
 129       object
 130     end
 131   end
 132
 133   def fix_implicit_addressing(object, _), do: object
 134
 135   def fix_addressing(object) do
 136     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 137     followers_collection = User.ap_followers(user)
 138
 139     object
 140     |> fix_addressing_list("to")
 141     |> fix_addressing_list("cc")
 142     |> fix_addressing_list("bto")
 143     |> fix_addressing_list("bcc")
 144     |> fix_explicit_addressing()
 145     |> fix_implicit_addressing(followers_collection)
 146   end
 147
 148   def fix_actor(%{"attributedTo" => actor} = object) do
 149     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 150   end
 151
 152   def fix_in_reply_to(object, options \\ [])
 153
 154   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 155       when not is_nil(in_reply_to) do
 156     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 157     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 158
 159     if Federator.allowed_incoming_reply_depth?(options[:depth]) do
 160       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 161            %Activity{} = _ <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 162         object
 163         |> Map.put("inReplyTo", replied_object.data["id"])
 164         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 165         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 166         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 167       else
 168         e ->
 169           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 170           object
 171       end
 172     else
 173       object
 174     end
 175   end
 176
 177   def fix_in_reply_to(object, _options), do: object
 178
 179   defp prepare_in_reply_to(in_reply_to) do
 180     cond do
 181       is_bitstring(in_reply_to) ->
 182         in_reply_to
 183
 184       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 185         in_reply_to["id"]
 186
 187       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 188         Enum.at(in_reply_to, 0)
 189
 190       true ->
 191         ""
 192     end
 193   end
 194
 195   def fix_context(object) do
 196     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 197
 198     object
 199     |> Map.put("context", context)
 200     |> Map.put("conversation", context)
 201   end
 202
 203   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 204     attachments =
 205       Enum.map(attachment, fn data ->
 206         media_type = data["mediaType"] || data["mimeType"]
 207         href = data["url"] || data["href"]
 208         url = [%{"type" => "Link", "mediaType" => media_type, "href" => href}]
 209
 210         data
 211         |> Map.put("mediaType", media_type)
 212         |> Map.put("url", url)
 213       end)
 214
 215     Map.put(object, "attachment", attachments)
 216   end
 217
 218   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 219     object
 220     |> Map.put("attachment", [attachment])
 221     |> fix_attachments()
 222   end
 223
 224   def fix_attachments(object), do: object
 225
 226   def fix_url(%{"url" => url} = object) when is_map(url) do
 227     Map.put(object, "url", url["href"])
 228   end
 229
 230   def fix_url(%{"type" => "Video", "url" => url} = object) when is_list(url) do
 231     first_element = Enum.at(url, 0)
 232
 233     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 234
 235     object
 236     |> Map.put("attachment", [first_element])
 237     |> Map.put("url", link_element["href"])
 238   end
 239
 240   def fix_url(%{"type" => object_type, "url" => url} = object)
 241       when object_type != "Video" and is_list(url) do
 242     first_element = Enum.at(url, 0)
 243
 244     url_string =
 245       cond do
 246         is_bitstring(first_element) -> first_element
 247         is_map(first_element) -> first_element["href"] || ""
 248         true -> ""
 249       end
 250
 251     Map.put(object, "url", url_string)
 252   end
 253
 254   def fix_url(object), do: object
 255
 256   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 257     emoji =
 258       tags
 259       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 260       |> Enum.reduce(%{}, fn data, mapping ->
 261         name = String.trim(data["name"], ":")
 262
 263         Map.put(mapping, name, data["icon"]["url"])
 264       end)
 265
 266     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 267     emoji = Map.merge(object["emoji"] || %{}, emoji)
 268
 269     Map.put(object, "emoji", emoji)
 270   end
 271
 272   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 273     name = String.trim(tag["name"], ":")
 274     emoji = %{name => tag["icon"]["url"]}
 275
 276     Map.put(object, "emoji", emoji)
 277   end
 278
 279   def fix_emoji(object), do: object
 280
 281   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 282     tags =
 283       tag
 284       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 285       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 286
 287     Map.put(object, "tag", tag ++ tags)
 288   end
 289
 290   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 291     combined = [tag, String.slice(hashtag, 1..-1)]
 292
 293     Map.put(object, "tag", combined)
 294   end
 295
 296   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 297
 298   def fix_tag(object), do: object
 299
 300   # content map usually only has one language so this will do for now.
 301   def fix_content_map(%{"contentMap" => content_map} = object) do
 302     content_groups = Map.to_list(content_map)
 303     {_, content} = Enum.at(content_groups, 0)
 304
 305     Map.put(object, "content", content)
 306   end
 307
 308   def fix_content_map(object), do: object
 309
 310   def fix_type(object, options \\ [])
 311
 312   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 313       when is_binary(reply_id) do
 314     with true <- Federator.allowed_incoming_reply_depth?(options[:depth]),
 315          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 316       Map.put(object, "type", "Answer")
 317     else
 318       _ -> object
 319     end
 320   end
 321
 322   def fix_type(object, _), do: object
 323
 324   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 325     with true <- id =~ "follows",
 326          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 327          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 328       {:ok, activity}
 329     else
 330       _ -> {:error, nil}
 331     end
 332   end
 333
 334   defp mastodon_follow_hack(_, _), do: {:error, nil}
 335
 336   defp get_follow_activity(follow_object, followed) do
 337     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 338          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 339       {:ok, activity}
 340     else
 341       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 342       {:activity, nil} ->
 343         mastodon_follow_hack(follow_object, followed)
 344
 345       _ ->
 346         {:error, nil}
 347     end
 348   end
 349
 350   # Reduce the object list to find the reported user.
 351   defp get_reported(objects) do
 352     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 353       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 354         {:halt, user}
 355       else
 356         _ -> {:cont, nil}
 357       end
 358     end)
 359   end
 360
 361   def handle_incoming(data, options \\ [])
 362
 363   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 364   # with nil ID.
 365   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 366     with context <- data["context"] || Utils.generate_context_id(),
 367          content <- data["content"] || "",
 368          %User{} = actor <- User.get_cached_by_ap_id(actor),
 369          # Reduce the object list to find the reported user.
 370          %User{} = account <- get_reported(objects),
 371          # Remove the reported user from the object list.
 372          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 373       %{
 374         actor: actor,
 375         context: context,
 376         account: account,
 377         statuses: statuses,
 378         content: content,
 379         additional: %{"cc" => [account.ap_id]}
 380       }
 381       |> ActivityPub.flag()
 382     end
 383   end
 384
 385   # disallow objects with bogus IDs
 386   def handle_incoming(%{"id" => nil}, _options), do: :error
 387   def handle_incoming(%{"id" => ""}, _options), do: :error
 388   # length of https:// = 8, should validate better, but good enough for now.
 389   def handle_incoming(%{"id" => id}, _options) when not (is_binary(id) and length(id) > 8),
 390     do: :error
 391
 392   # TODO: validate those with a Ecto scheme
 393   # - tags
 394   # - emoji
 395   def handle_incoming(
 396         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 397         options
 398       )
 399       when objtype in ["Article", "Note", "Video", "Page", "Question", "Answer"] do
 400     actor = Containment.get_actor(data)
 401
 402     data =
 403       Map.put(data, "actor", actor)
 404       |> fix_addressing
 405
 406     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 407          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 408       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 409       object = fix_object(data["object"], options)
 410
 411       params = %{
 412         to: data["to"],
 413         object: object,
 414         actor: user,
 415         context: object["conversation"],
 416         local: false,
 417         published: data["published"],
 418         additional:
 419           Map.take(data, [
 420             "cc",
 421             "directMessage",
 422             "id"
 423           ])
 424       }
 425
 426       ActivityPub.create(params)
 427     else
 428       %Activity{} = activity -> {:ok, activity}
 429       _e -> :error
 430     end
 431   end
 432
 433   def handle_incoming(
 434         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 435         options
 436       ) do
 437     actor = Containment.get_actor(data)
 438
 439     data =
 440       Map.put(data, "actor", actor)
 441       |> fix_addressing
 442
 443     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 444       options = Keyword.put(options, :depth, (options[:depth] || 0) + 1)
 445       object = fix_object(object, options)
 446
 447       params = %{
 448         to: data["to"],
 449         object: object,
 450         actor: user,
 451         context: nil,
 452         local: false,
 453         published: data["published"],
 454         additional: Map.take(data, ["cc", "id"])
 455       }
 456
 457       ActivityPub.listen(params)
 458     else
 459       _e -> :error
 460     end
 461   end
 462
 463   def handle_incoming(
 464         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 465         _options
 466       ) do
 467     with %User{local: true} = followed <-
 468            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 469          {:ok, %User{} = follower} <-
 470            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 471          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 472       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 473            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 474            {_, false} <- {:user_locked, User.locked?(followed)},
 475            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 476            {_, {:ok, _}} <-
 477              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")} do
 478         ActivityPub.accept(%{
 479           to: [follower.ap_id],
 480           actor: followed,
 481           object: data,
 482           local: true
 483         })
 484       else
 485         {:user_blocked, true} ->
 486           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 487
 488           ActivityPub.reject(%{
 489             to: [follower.ap_id],
 490             actor: followed,
 491             object: data,
 492             local: true
 493           })
 494
 495         {:follow, {:error, _}} ->
 496           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 497
 498           ActivityPub.reject(%{
 499             to: [follower.ap_id],
 500             actor: followed,
 501             object: data,
 502             local: true
 503           })
 504
 505         {:user_locked, true} ->
 506           :noop
 507       end
 508
 509       {:ok, activity}
 510     else
 511       _e ->
 512         :error
 513     end
 514   end
 515
 516   def handle_incoming(
 517         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => _id} = data,
 518         _options
 519       ) do
 520     with actor <- Containment.get_actor(data),
 521          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 522          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 523          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 524          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 525          {:ok, _follower} = User.follow(follower, followed) do
 526       ActivityPub.accept(%{
 527         to: follow_activity.data["to"],
 528         type: "Accept",
 529         actor: followed,
 530         object: follow_activity.data["id"],
 531         local: false
 532       })
 533     else
 534       _e -> :error
 535     end
 536   end
 537
 538   def handle_incoming(
 539         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => _id} = data,
 540         _options
 541       ) do
 542     with actor <- Containment.get_actor(data),
 543          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 544          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 545          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 546          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 547          {:ok, activity} <-
 548            ActivityPub.reject(%{
 549              to: follow_activity.data["to"],
 550              type: "Reject",
 551              actor: followed,
 552              object: follow_activity.data["id"],
 553              local: false
 554            }) do
 555       User.unfollow(follower, followed)
 556
 557       {:ok, activity}
 558     else
 559       _e -> :error
 560     end
 561   end
 562
 563   @misskey_reactions %{
 564     "like" => "👍",
 565     "love" => "❤️",
 566     "laugh" => "😆",
 567     "hmm" => "🤔",
 568     "surprise" => "😮",
 569     "congrats" => "🎉",
 570     "angry" => "💢",
 571     "confused" => "😥",
 572     "rip" => "😇",
 573     "pudding" => "🍮",
 574     "star" => "⭐"
 575   }
 576
 577   @doc "Rewrite misskey likes into EmojiReactions"
 578   def handle_incoming(
 579         %{
 580           "type" => "Like",
 581           "_misskey_reaction" => reaction
 582         } = data,
 583         options
 584       ) do
 585     data
 586     |> Map.put("type", "EmojiReaction")
 587     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 588     |> handle_incoming(options)
 589   end
 590
 591   def handle_incoming(
 592         %{"type" => "Like", "object" => object_id, "actor" => _actor, "id" => id} = data,
 593         _options
 594       ) do
 595     with actor <- Containment.get_actor(data),
 596          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 597          {:ok, object} <- get_obj_helper(object_id),
 598          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 599       {:ok, activity}
 600     else
 601       _e -> :error
 602     end
 603   end
 604
 605   def handle_incoming(
 606         %{
 607           "type" => "EmojiReaction",
 608           "object" => object_id,
 609           "actor" => _actor,
 610           "id" => id,
 611           "content" => emoji
 612         } = data,
 613         _options
 614       ) do
 615     with actor <- Containment.get_actor(data),
 616          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 617          {:ok, object} <- get_obj_helper(object_id),
 618          {:ok, activity, _object} <-
 619            ActivityPub.react_with_emoji(actor, object, emoji, activity_id: id, local: false) do
 620       {:ok, activity}
 621     else
 622       _e -> :error
 623     end
 624   end
 625
 626   def handle_incoming(
 627         %{"type" => "Announce", "object" => object_id, "actor" => _actor, "id" => id} = data,
 628         _options
 629       ) do
 630     with actor <- Containment.get_actor(data),
 631          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 632          {:ok, object} <- get_obj_helper(object_id),
 633          public <- Visibility.is_public?(data),
 634          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false, public) do
 635       {:ok, activity}
 636     else
 637       _e -> :error
 638     end
 639   end
 640
 641   def handle_incoming(
 642         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 643           data,
 644         _options
 645       )
 646       when object_type in ["Person", "Application", "Service", "Organization"] do
 647     with %User{ap_id: ^actor_id} = actor <- User.get_cached_by_ap_id(object["id"]) do
 648       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 649
 650       banner = new_user_data[:info][:banner]
 651       locked = new_user_data[:info][:locked] || false
 652       attachment = get_in(new_user_data, [:info, :source_data, "attachment"]) || []
 653
 654       fields =
 655         attachment
 656         |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 657         |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 658
 659       update_data =
 660         new_user_data
 661         |> Map.take([:name, :bio, :avatar])
 662         |> Map.put(:info, %{banner: banner, locked: locked, fields: fields})
 663
 664       actor
 665       |> User.upgrade_changeset(update_data, true)
 666       |> User.update_and_set_cache()
 667
 668       ActivityPub.update(%{
 669         local: false,
 670         to: data["to"] || [],
 671         cc: data["cc"] || [],
 672         object: object,
 673         actor: actor_id
 674       })
 675     else
 676       e ->
 677         Logger.error(e)
 678         :error
 679     end
 680   end
 681
 682   # TODO: We presently assume that any actor on the same origin domain as the object being
 683   # deleted has the rights to delete that object.  A better way to validate whether or not
 684   # the object should be deleted is to refetch the object URI, which should return either
 685   # an error or a tombstone.  This would allow us to verify that a deletion actually took
 686   # place.
 687   def handle_incoming(
 688         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = data,
 689         _options
 690       ) do
 691     object_id = Utils.get_ap_id(object_id)
 692
 693     with actor <- Containment.get_actor(data),
 694          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 695          {:ok, object} <- get_obj_helper(object_id),
 696          :ok <- Containment.contain_origin(actor.ap_id, object.data),
 697          {:ok, activity} <- ActivityPub.delete(object, false) do
 698       {:ok, activity}
 699     else
 700       nil ->
 701         case User.get_cached_by_ap_id(object_id) do
 702           %User{ap_id: ^actor} = user ->
 703             User.delete(user)
 704
 705           nil ->
 706             :error
 707         end
 708
 709       _e ->
 710         :error
 711     end
 712   end
 713
 714   def handle_incoming(
 715         %{
 716           "type" => "Undo",
 717           "object" => %{"type" => "Announce", "object" => object_id},
 718           "actor" => _actor,
 719           "id" => id
 720         } = data,
 721         _options
 722       ) do
 723     with actor <- Containment.get_actor(data),
 724          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 725          {:ok, object} <- get_obj_helper(object_id),
 726          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 727       {:ok, activity}
 728     else
 729       _e -> :error
 730     end
 731   end
 732
 733   def handle_incoming(
 734         %{
 735           "type" => "Undo",
 736           "object" => %{"type" => "Follow", "object" => followed},
 737           "actor" => follower,
 738           "id" => id
 739         } = _data,
 740         _options
 741       ) do
 742     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 743          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 744          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 745       User.unfollow(follower, followed)
 746       {:ok, activity}
 747     else
 748       _e -> :error
 749     end
 750   end
 751
 752   def handle_incoming(
 753         %{
 754           "type" => "Undo",
 755           "object" => %{"type" => "EmojiReaction", "id" => reaction_activity_id},
 756           "actor" => _actor,
 757           "id" => id
 758         } = data,
 759         _options
 760       ) do
 761     with actor <- Containment.get_actor(data),
 762          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 763          {:ok, activity, _} <-
 764            ActivityPub.unreact_with_emoji(actor, reaction_activity_id,
 765              activity_id: id,
 766              local: false
 767            ) do
 768       {:ok, activity}
 769     else
 770       _e -> :error
 771     end
 772   end
 773
 774   def handle_incoming(
 775         %{
 776           "type" => "Undo",
 777           "object" => %{"type" => "Block", "object" => blocked},
 778           "actor" => blocker,
 779           "id" => id
 780         } = _data,
 781         _options
 782       ) do
 783     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 784          {:ok, %User{} = blocker} <- User.get_or_fetch_by_ap_id(blocker),
 785          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 786       User.unblock(blocker, blocked)
 787       {:ok, activity}
 788     else
 789       _e -> :error
 790     end
 791   end
 792
 793   def handle_incoming(
 794         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = _data,
 795         _options
 796       ) do
 797     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 798          {:ok, %User{} = blocker} = User.get_or_fetch_by_ap_id(blocker),
 799          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 800       User.unfollow(blocker, blocked)
 801       User.block(blocker, blocked)
 802       {:ok, activity}
 803     else
 804       _e -> :error
 805     end
 806   end
 807
 808   def handle_incoming(
 809         %{
 810           "type" => "Undo",
 811           "object" => %{"type" => "Like", "object" => object_id},
 812           "actor" => _actor,
 813           "id" => id
 814         } = data,
 815         _options
 816       ) do
 817     with actor <- Containment.get_actor(data),
 818          {:ok, %User{} = actor} <- User.get_or_fetch_by_ap_id(actor),
 819          {:ok, object} <- get_obj_helper(object_id),
 820          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 821       {:ok, activity}
 822     else
 823       _e -> :error
 824     end
 825   end
 826
 827   # For Undos that don't have the complete object attached, try to find it in our database.
 828   def handle_incoming(
 829         %{
 830           "type" => "Undo",
 831           "object" => object
 832         } = activity,
 833         options
 834       )
 835       when is_binary(object) do
 836     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 837       activity
 838       |> Map.put("object", data)
 839       |> handle_incoming(options)
 840     else
 841       _e -> :error
 842     end
 843   end
 844
 845   def handle_incoming(_, _), do: :error
 846
 847   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 848   def get_obj_helper(id, options \\ []) do
 849     case Object.normalize(id, true, options) do
 850       %Object{} = object -> {:ok, object}
 851       _ -> nil
 852     end
 853   end
 854
 855   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 856     with false <- String.starts_with?(in_reply_to, "http"),
 857          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 858       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 859     else
 860       _e -> object
 861     end
 862   end
 863
 864   def set_reply_to_uri(obj), do: obj
 865
 866   # Prepares the object of an outgoing create activity.
 867   def prepare_object(object) do
 868     object
 869     |> set_sensitive
 870     |> add_hashtags
 871     |> add_mention_tags
 872     |> add_emoji_tags
 873     |> add_attributed_to
 874     |> prepare_attachments
 875     |> set_conversation
 876     |> set_reply_to_uri
 877     |> strip_internal_fields
 878     |> strip_internal_tags
 879     |> set_type
 880   end
 881
 882   #  @doc
 883   #  """
 884   #  internal -> Mastodon
 885   #  """
 886
 887   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 888       when activity_type in ["Create", "Listen"] do
 889     object =
 890       object_id
 891       |> Object.normalize()
 892       |> Map.get(:data)
 893       |> prepare_object
 894
 895     data =
 896       data
 897       |> Map.put("object", object)
 898       |> Map.merge(Utils.make_json_ld_header())
 899       |> Map.delete("bcc")
 900
 901     {:ok, data}
 902   end
 903
 904   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 905     object =
 906       object_id
 907       |> Object.normalize()
 908
 909     data =
 910       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 911         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 912       else
 913         data |> maybe_fix_object_url
 914       end
 915
 916     data =
 917       data
 918       |> strip_internal_fields
 919       |> Map.merge(Utils.make_json_ld_header())
 920       |> Map.delete("bcc")
 921
 922     {:ok, data}
 923   end
 924
 925   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 926   # because of course it does.
 927   def prepare_outgoing(%{"type" => "Accept"} = data) do
 928     with follow_activity <- Activity.normalize(data["object"]) do
 929       object = %{
 930         "actor" => follow_activity.actor,
 931         "object" => follow_activity.data["object"],
 932         "id" => follow_activity.data["id"],
 933         "type" => "Follow"
 934       }
 935
 936       data =
 937         data
 938         |> Map.put("object", object)
 939         |> Map.merge(Utils.make_json_ld_header())
 940
 941       {:ok, data}
 942     end
 943   end
 944
 945   def prepare_outgoing(%{"type" => "Reject"} = data) do
 946     with follow_activity <- Activity.normalize(data["object"]) do
 947       object = %{
 948         "actor" => follow_activity.actor,
 949         "object" => follow_activity.data["object"],
 950         "id" => follow_activity.data["id"],
 951         "type" => "Follow"
 952       }
 953
 954       data =
 955         data
 956         |> Map.put("object", object)
 957         |> Map.merge(Utils.make_json_ld_header())
 958
 959       {:ok, data}
 960     end
 961   end
 962
 963   def prepare_outgoing(%{"type" => _type} = data) do
 964     data =
 965       data
 966       |> strip_internal_fields
 967       |> maybe_fix_object_url
 968       |> Map.merge(Utils.make_json_ld_header())
 969
 970     {:ok, data}
 971   end
 972
 973   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
 974     with false <- String.starts_with?(object, "http"),
 975          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
 976          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
 977            relative_object do
 978       Map.put(data, "object", external_url)
 979     else
 980       {:fetch, e} ->
 981         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
 982         data
 983
 984       _ ->
 985         data
 986     end
 987   end
 988
 989   def maybe_fix_object_url(data), do: data
 990
 991   def add_hashtags(object) do
 992     tags =
 993       (object["tag"] || [])
 994       |> Enum.map(fn
 995         # Expand internal representation tags into AS2 tags.
 996         tag when is_binary(tag) ->
 997           %{
 998             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 999             "name" => "##{tag}",
1000             "type" => "Hashtag"
1001           }
1002
1003         # Do not process tags which are already AS2 tag objects.
1004         tag when is_map(tag) ->
1005           tag
1006       end)
1007
1008     Map.put(object, "tag", tags)
1009   end
1010
1011   def add_mention_tags(object) do
1012     mentions =
1013       object
1014       |> Utils.get_notified_from_object()
1015       |> Enum.map(&build_mention_tag/1)
1016
1017     tags = object["tag"] || []
1018
1019     Map.put(object, "tag", tags ++ mentions)
1020   end
1021
1022   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1023     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1024   end
1025
1026   def take_emoji_tags(%User{info: %{emoji: emoji} = _user_info} = _user) do
1027     emoji
1028     |> Enum.flat_map(&Map.to_list/1)
1029     |> Enum.map(&build_emoji_tag/1)
1030   end
1031
1032   # TODO: we should probably send mtime instead of unix epoch time for updated
1033   def add_emoji_tags(%{"emoji" => emoji} = object) do
1034     tags = object["tag"] || []
1035
1036     out = Enum.map(emoji, &build_emoji_tag/1)
1037
1038     Map.put(object, "tag", tags ++ out)
1039   end
1040
1041   def add_emoji_tags(object), do: object
1042
1043   defp build_emoji_tag({name, url}) do
1044     %{
1045       "icon" => %{"url" => url, "type" => "Image"},
1046       "name" => ":" <> name <> ":",
1047       "type" => "Emoji",
1048       "updated" => "1970-01-01T00:00:00Z",
1049       "id" => url
1050     }
1051   end
1052
1053   def set_conversation(object) do
1054     Map.put(object, "conversation", object["context"])
1055   end
1056
1057   def set_sensitive(object) do
1058     tags = object["tag"] || []
1059     Map.put(object, "sensitive", "nsfw" in tags)
1060   end
1061
1062   def set_type(%{"type" => "Answer"} = object) do
1063     Map.put(object, "type", "Note")
1064   end
1065
1066   def set_type(object), do: object
1067
1068   def add_attributed_to(object) do
1069     attributed_to = object["attributedTo"] || object["actor"]
1070     Map.put(object, "attributedTo", attributed_to)
1071   end
1072
1073   def prepare_attachments(object) do
1074     attachments =
1075       (object["attachment"] || [])
1076       |> Enum.map(fn data ->
1077         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1078         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
1079       end)
1080
1081     Map.put(object, "attachment", attachments)
1082   end
1083
1084   def strip_internal_fields(object) do
1085     object
1086     |> Map.drop(Pleroma.Constants.object_internal_fields())
1087   end
1088
1089   defp strip_internal_tags(%{"tag" => tags} = object) do
1090     tags = Enum.filter(tags, fn x -> is_map(x) end)
1091
1092     Map.put(object, "tag", tags)
1093   end
1094
1095   defp strip_internal_tags(object), do: object
1096
1097   def perform(:user_upgrade, user) do
1098     # we pass a fake user so that the followers collection is stripped away
1099     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1100
1101     q =
1102       from(
1103         u in User,
1104         where: ^old_follower_address in u.following,
1105         update: [
1106           set: [
1107             following:
1108               fragment(
1109                 "array_replace(?,?,?)",
1110                 u.following,
1111                 ^old_follower_address,
1112                 ^user.follower_address
1113               )
1114           ]
1115         ]
1116       )
1117
1118     Repo.update_all(q, [])
1119
1120     maybe_retire_websub(user.ap_id)
1121
1122     q =
1123       from(
1124         a in Activity,
1125         where: ^old_follower_address in a.recipients,
1126         update: [
1127           set: [
1128             recipients:
1129               fragment(
1130                 "array_replace(?,?,?)",
1131                 a.recipients,
1132                 ^old_follower_address,
1133                 ^user.follower_address
1134               )
1135           ]
1136         ]
1137       )
1138
1139     Repo.update_all(q, [])
1140   end
1141
1142   def upgrade_user_from_ap_id(ap_id) do
1143     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1144          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1145          already_ap <- User.ap_enabled?(user),
1146          {:ok, user} <- upgrade_user(user, data) do
1147       if not already_ap do
1148         TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1149       end
1150
1151       {:ok, user}
1152     else
1153       %User{} = user -> {:ok, user}
1154       e -> e
1155     end
1156   end
1157
1158   defp upgrade_user(user, data) do
1159     user
1160     |> User.upgrade_changeset(data, true)
1161     |> User.update_and_set_cache()
1162   end
1163
1164   def maybe_retire_websub(ap_id) do
1165     # some sanity checks
1166     if is_binary(ap_id) && String.length(ap_id) > 8 do
1167       q =
1168         from(
1169           ws in Pleroma.Web.Websub.WebsubClientSubscription,
1170           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
1171         )
1172
1173       Repo.delete_all(q)
1174     end
1175   end
1176
1177   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1178     Map.put(data, "url", url["href"])
1179   end
1180
1181   def maybe_fix_user_url(data), do: data
1182
1183   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1184 end