git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10
  11   import Ecto.Query
  12
  13   require Logger
  14
  15   @doc """
  16   Modifies an incoming AP object (mastodon format) to our internal format.
  17   """
  18   def fix_object(object) do
  19     object
  20     |> Map.put("actor", object["attributedTo"])
  21     |> fix_attachments
  22     |> fix_context
  23     |> fix_in_reply_to
  24     |> fix_emoji
  25     |> fix_tag
  26   end
  27
  28   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  29       when not is_nil(in_reply_to_id) do
  30     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  31       {:ok, replied_object} ->
  32         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  33
  34         object
  35         |> Map.put("inReplyTo", replied_object.data["id"])
  36         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  37         |> Map.put("inReplyToStatusId", activity.id)
  38         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  39         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  40
  41       e ->
  42         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  43         object
  44     end
  45   end
  46
  47   def fix_in_reply_to(object), do: object
  48
  49   def fix_context(object) do
  50     object
  51     |> Map.put("context", object["conversation"])
  52   end
  53
  54   def fix_attachments(object) do
  55     attachments =
  56       (object["attachment"] || [])
  57       |> Enum.map(fn data ->
  58         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  59         Map.put(data, "url", url)
  60       end)
  61
  62     object
  63     |> Map.put("attachment", attachments)
  64   end
  65
  66   def fix_emoji(object) do
  67     tags = object["tag"] || []
  68     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  69
  70     emoji =
  71       emoji
  72       |> Enum.reduce(%{}, fn data, mapping ->
  73         name = data["name"]
  74
  75         name =
  76           if String.starts_with?(name, ":") do
  77             name |> String.slice(1..-2)
  78           else
  79             name
  80           end
  81
  82         mapping |> Map.put(name, data["icon"]["url"])
  83       end)
  84
  85     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  86     emoji = Map.merge(object["emoji"] || %{}, emoji)
  87
  88     object
  89     |> Map.put("emoji", emoji)
  90   end
  91
  92   def fix_tag(object) do
  93     tags =
  94       (object["tag"] || [])
  95       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  96       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  97
  98     combined = (object["tag"] || []) ++ tags
  99
 100     object
 101     |> Map.put("tag", combined)
 102   end
 103
 104   # TODO: validate those with a Ecto scheme
 105   # - tags
 106   # - emoji
 107   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 108     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 109          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 110       object = fix_object(data["object"])
 111
 112       params = %{
 113         to: data["to"],
 114         object: object,
 115         actor: user,
 116         context: object["conversation"],
 117         local: false,
 118         published: data["published"],
 119         additional:
 120           Map.take(data, [
 121             "cc",
 122             "id"
 123           ])
 124       }
 125
 126       ActivityPub.create(params)
 127     else
 128       %Activity{} = activity -> {:ok, activity}
 129       _e -> :error
 130     end
 131   end
 132
 133   def handle_incoming(
 134         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 135       ) do
 136     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 137          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 138          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 139       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 140
 141       User.follow(follower, followed)
 142       {:ok, activity}
 143     else
 144       _e -> :error
 145     end
 146   end
 147
 148   def handle_incoming(
 149         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 150       ) do
 151     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 152          {:ok, object} <-
 153            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 154          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 155       {:ok, activity}
 156     else
 157       _e -> :error
 158     end
 159   end
 160
 161   def handle_incoming(
 162         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 163       ) do
 164     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 165          {:ok, object} <-
 166            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 167          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 168       {:ok, activity}
 169     else
 170       _e -> :error
 171     end
 172   end
 173
 174   def handle_incoming(
 175         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 176           data
 177       ) do
 178     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 179       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 180
 181       banner = new_user_data[:info]["banner"]
 182
 183       update_data =
 184         new_user_data
 185         |> Map.take([:name, :bio, :avatar])
 186         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 187
 188       actor
 189       |> User.upgrade_changeset(update_data)
 190       |> User.update_and_set_cache()
 191
 192       ActivityPub.update(%{
 193         local: false,
 194         to: data["to"] || [],
 195         cc: data["cc"] || [],
 196         object: object,
 197         actor: actor_id
 198       })
 199     else
 200       e ->
 201         Logger.error(e)
 202         :error
 203     end
 204   end
 205
 206   # TODO: Make secure.
 207   def handle_incoming(
 208         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 209       ) do
 210     object_id =
 211       case object_id do
 212         %{"id" => id} -> id
 213         id -> id
 214       end
 215
 216     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 217          {:ok, object} <-
 218            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 219          {:ok, activity} <- ActivityPub.delete(object, false) do
 220       {:ok, activity}
 221     else
 222       _e -> :error
 223     end
 224   end
 225
 226   def handle_incoming(
 227         %{
 228           "type" => "Undo",
 229           "object" => %{"type" => "Announce", "object" => object_id},
 230           "actor" => actor,
 231           "id" => id
 232         } = data
 233       ) do
 234     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 235          {:ok, object} <-
 236            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 237          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 238       {:ok, activity}
 239     else
 240       e -> :error
 241     end
 242   end
 243
 244   def handle_incoming(
 245         %{
 246           "type" => "Undo",
 247           "object" => %{"type" => "Follow", "object" => followed},
 248           "actor" => follower,
 249           "id" => id
 250         } = _data
 251       ) do
 252     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 253          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 254          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 255       User.unfollow(follower, followed)
 256       {:ok, activity}
 257     else
 258       e -> :error
 259     end
 260   end
 261
 262   def handle_incoming(
 263         %{
 264           "type" => "Undo",
 265           "object" => %{"type" => "Block", "object" => blocked},
 266           "actor" => blocker,
 267           "id" => id
 268         } = _data
 269       ) do
 270     with %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 271          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 272          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 273       {:ok, activity}
 274     else
 275       e -> :error
 276     end
 277   end
 278
 279   def handle_incoming(
 280         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 281       ) do
 282     with %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 283          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 284          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 285       User.unfollow(blocker, blocked)
 286       User.block(blocker, blocked)
 287       {:ok, activity}
 288     else
 289       e -> :error
 290     end
 291   end
 292
 293   def handle_incoming(
 294         %{
 295           "type" => "Undo",
 296           "object" => %{"type" => "Like", "object" => object_id},
 297           "actor" => actor,
 298           "id" => id
 299         } = data
 300       ) do
 301     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 302          {:ok, object} <-
 303            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 304          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 305       {:ok, activity}
 306     else
 307       e -> :error
 308     end
 309   end
 310
 311   # TODO
 312   # Accept
 313
 314   def handle_incoming(_), do: :error
 315
 316   def get_obj_helper(id) do
 317     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 318   end
 319
 320   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 321     with false <- String.starts_with?(inReplyTo, "http"),
 322          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 323       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 324     else
 325       _e -> object
 326     end
 327   end
 328
 329   def set_reply_to_uri(obj), do: obj
 330
 331   # Prepares the object of an outgoing create activity.
 332   def prepare_object(object) do
 333     object
 334     |> set_sensitive
 335     |> add_hashtags
 336     |> add_mention_tags
 337     |> add_emoji_tags
 338     |> add_attributed_to
 339     |> prepare_attachments
 340     |> set_conversation
 341     |> set_reply_to_uri
 342   end
 343
 344   #  @doc
 345   #  """
 346   #  internal -> Mastodon
 347   #  """
 348
 349   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 350     object =
 351       object
 352       |> prepare_object
 353
 354     data =
 355       data
 356       |> Map.put("object", object)
 357       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 358
 359     {:ok, data}
 360   end
 361
 362   def prepare_outgoing(%{"type" => _type} = data) do
 363     data =
 364       data
 365       |> maybe_fix_object_url
 366       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 367
 368     {:ok, data}
 369   end
 370
 371   def maybe_fix_object_url(data) do
 372     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 373       case ActivityPub.fetch_object_from_id(data["object"]) do
 374         {:ok, relative_object} ->
 375           if relative_object.data["external_url"] do
 376             _data =
 377               data
 378               |> Map.put("object", relative_object.data["external_url"])
 379           else
 380             data
 381           end
 382
 383         e ->
 384           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 385           data
 386       end
 387     else
 388       data
 389     end
 390   end
 391
 392   def add_hashtags(object) do
 393     tags =
 394       (object["tag"] || [])
 395       |> Enum.map(fn tag ->
 396         %{
 397           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 398           "name" => "##{tag}",
 399           "type" => "Hashtag"
 400         }
 401       end)
 402
 403     object
 404     |> Map.put("tag", tags)
 405   end
 406
 407   def add_mention_tags(object) do
 408     recipients = object["to"] ++ (object["cc"] || [])
 409
 410     mentions =
 411       recipients
 412       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 413       |> Enum.filter(& &1)
 414       |> Enum.map(fn user ->
 415         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 416       end)
 417
 418     tags = object["tag"] || []
 419
 420     object
 421     |> Map.put("tag", tags ++ mentions)
 422   end
 423
 424   # TODO: we should probably send mtime instead of unix epoch time for updated
 425   def add_emoji_tags(object) do
 426     tags = object["tag"] || []
 427     emoji = object["emoji"] || []
 428
 429     out =
 430       emoji
 431       |> Enum.map(fn {name, url} ->
 432         %{
 433           "icon" => %{"url" => url, "type" => "Image"},
 434           "name" => ":" <> name <> ":",
 435           "type" => "Emoji",
 436           "updated" => "1970-01-01T00:00:00Z",
 437           "id" => url
 438         }
 439       end)
 440
 441     object
 442     |> Map.put("tag", tags ++ out)
 443   end
 444
 445   def set_conversation(object) do
 446     Map.put(object, "conversation", object["context"])
 447   end
 448
 449   def set_sensitive(object) do
 450     tags = object["tag"] || []
 451     Map.put(object, "sensitive", "nsfw" in tags)
 452   end
 453
 454   def add_attributed_to(object) do
 455     attributedTo = object["attributedTo"] || object["actor"]
 456
 457     object
 458     |> Map.put("attributedTo", attributedTo)
 459   end
 460
 461   def prepare_attachments(object) do
 462     attachments =
 463       (object["attachment"] || [])
 464       |> Enum.map(fn data ->
 465         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 466         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 467       end)
 468
 469     object
 470     |> Map.put("attachment", attachments)
 471   end
 472
 473   defp user_upgrade_task(user) do
 474     old_follower_address = User.ap_followers(user)
 475
 476     q =
 477       from(
 478         u in User,
 479         where: ^old_follower_address in u.following,
 480         update: [
 481           set: [
 482             following:
 483               fragment(
 484                 "array_replace(?,?,?)",
 485                 u.following,
 486                 ^old_follower_address,
 487                 ^user.follower_address
 488               )
 489           ]
 490         ]
 491       )
 492
 493     Repo.update_all(q, [])
 494
 495     maybe_retire_websub(user.ap_id)
 496
 497     # Only do this for recent activties, don't go through the whole db.
 498     # Only look at the last 1000 activities.
 499     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 500
 501     q =
 502       from(
 503         a in Activity,
 504         where: ^old_follower_address in a.recipients,
 505         where: a.id > ^since,
 506         update: [
 507           set: [
 508             recipients:
 509               fragment(
 510                 "array_replace(?,?,?)",
 511                 a.recipients,
 512                 ^old_follower_address,
 513                 ^user.follower_address
 514               )
 515           ]
 516         ]
 517       )
 518
 519     Repo.update_all(q, [])
 520   end
 521
 522   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 523     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 524          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 525       data =
 526         data
 527         |> Map.put(:info, Map.merge(user.info, data[:info]))
 528
 529       already_ap = User.ap_enabled?(user)
 530
 531       {:ok, user} =
 532         User.upgrade_changeset(user, data)
 533         |> Repo.update()
 534
 535       if !already_ap do
 536         # This could potentially take a long time, do it in the background
 537         if async do
 538           Task.start(fn ->
 539             user_upgrade_task(user)
 540           end)
 541         else
 542           user_upgrade_task(user)
 543         end
 544       end
 545
 546       {:ok, user}
 547     else
 548       e -> e
 549     end
 550   end
 551
 552   def maybe_retire_websub(ap_id) do
 553     # some sanity checks
 554     if is_binary(ap_id) && String.length(ap_id) > 8 do
 555       q =
 556         from(
 557           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 558           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 559         )
 560
 561       Repo.delete_all(q)
 562     end
 563   end
 564
 565   def maybe_fix_user_url(data) do
 566     if is_map(data["url"]) do
 567       data = Map.put(data, "url", data["url"]["href"])
 568     end
 569
 570     data
 571   end
 572
 573   def maybe_fix_user_object(data) do
 574     data
 575     |> maybe_fix_user_url
 576   end
 577 end