git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  17     actor
  18   end
  19
  20   def get_actor(%{"actor" => actor}) when is_list(actor) do
  21     if is_binary(Enum.at(actor, 0)) do
  22       Enum.at(actor, 0)
  23     else
  24       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  25       |> Map.get("id")
  26     end
  27   end
  28
  29   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  30     id
  31   end
  32
  33   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  34     get_actor(%{"actor" => actor})
  35   end
  36
  37   @doc """
  38   Checks that an imported AP object's actor matches the domain it came from.
  39   """
  40   def contain_origin(id, %{"actor" => nil}), do: :error
  41
  42   def contain_origin(id, %{"actor" => actor} = params) do
  43     id_uri = URI.parse(id)
  44     actor_uri = URI.parse(get_actor(params))
  45
  46     if id_uri.host == actor_uri.host do
  47       :ok
  48     else
  49       :error
  50     end
  51   end
  52
  53   def contain_origin_from_id(id, %{"id" => nil}), do: :error
  54
  55   def contain_origin_from_id(id, %{"id" => other_id} = params) do
  56     id_uri = URI.parse(id)
  57     other_uri = URI.parse(other_id)
  58
  59     if id_uri.host == other_uri.host do
  60       :ok
  61     else
  62       :error
  63     end
  64   end
  65
  66   @doc """
  67   Modifies an incoming AP object (mastodon format) to our internal format.
  68   """
  69   def fix_object(object) do
  70     object
  71     |> fix_actor
  72     |> fix_attachments
  73     |> fix_url
  74     |> fix_context
  75     |> fix_in_reply_to
  76     |> fix_emoji
  77     |> fix_tag
  78     |> fix_content_map
  79     |> fix_likes
  80     |> fix_addressing
  81   end
  82
  83   def fix_addressing_list(map, field) do
  84     if is_binary(map[field]) do
  85       map
  86       |> Map.put(field, [map[field]])
  87     else
  88       map
  89     end
  90   end
  91
  92   def fix_addressing(map) do
  93     map
  94     |> fix_addressing_list("to")
  95     |> fix_addressing_list("cc")
  96     |> fix_addressing_list("bto")
  97     |> fix_addressing_list("bcc")
  98   end
  99
 100   def fix_actor(%{"attributedTo" => actor} = object) do
 101     object
 102     |> Map.put("actor", get_actor(%{"actor" => actor}))
 103   end
 104
 105   def fix_likes(%{"likes" => likes} = object)
 106       when is_bitstring(likes) do
 107     # Check for standardisation
 108     # This is what Peertube does
 109     # curl -H 'Accept: application/activity+json' $likes | jq .totalItems
 110     object
 111     |> Map.put("likes", [])
 112     |> Map.put("like_count", 0)
 113   end
 114
 115   def fix_likes(object) do
 116     object
 117   end
 118
 119   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object)
 120       when not is_nil(in_reply_to) do
 121     in_reply_to_id =
 122       cond do
 123         is_bitstring(in_reply_to) ->
 124           in_reply_to
 125
 126         is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 127           in_reply_to["id"]
 128
 129         is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 130           Enum.at(in_reply_to, 0)
 131
 132         # Maybe I should output an error too?
 133         true ->
 134           ""
 135       end
 136
 137     case fetch_obj_helper(in_reply_to_id) do
 138       {:ok, replied_object} ->
 139         with %Activity{} = activity <-
 140                Activity.get_create_activity_by_object_ap_id(replied_object.data["id"]) do
 141           object
 142           |> Map.put("inReplyTo", replied_object.data["id"])
 143           |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 144           |> Map.put("inReplyToStatusId", activity.id)
 145           |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
 146           |> Map.put("context", replied_object.data["context"] || object["conversation"])
 147         else
 148           e ->
 149             Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 150             object
 151         end
 152
 153       e ->
 154         Logger.error("Couldn't fetch \"#{inspect(in_reply_to_id)}\", error: #{inspect(e)}")
 155         object
 156     end
 157   end
 158
 159   def fix_in_reply_to(object), do: object
 160
 161   def fix_context(object) do
 162     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 163
 164     object
 165     |> Map.put("context", context)
 166     |> Map.put("conversation", context)
 167   end
 168
 169   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 170     attachments =
 171       attachment
 172       |> Enum.map(fn data ->
 173         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
 174         Map.put(data, "url", url)
 175       end)
 176
 177     object
 178     |> Map.put("attachment", attachments)
 179   end
 180
 181   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 182     Map.put(object, "attachment", [attachment])
 183     |> fix_attachments()
 184   end
 185
 186   def fix_attachments(object), do: object
 187
 188   def fix_url(%{"url" => url} = object) when is_map(url) do
 189     object
 190     |> Map.put("url", url["href"])
 191   end
 192
 193   def fix_url(%{"url" => url} = object) when is_list(url) do
 194     first_element = Enum.at(url, 0)
 195
 196     url_string =
 197       cond do
 198         is_bitstring(first_element) -> first_element
 199         is_map(first_element) -> first_element["href"] || ""
 200         true -> ""
 201       end
 202
 203     object
 204     |> Map.put("url", url_string)
 205   end
 206
 207   def fix_url(object), do: object
 208
 209   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 210     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 211
 212     emoji =
 213       emoji
 214       |> Enum.reduce(%{}, fn data, mapping ->
 215         name = String.trim(data["name"], ":")
 216
 217         mapping |> Map.put(name, data["icon"]["url"])
 218       end)
 219
 220     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 221     emoji = Map.merge(object["emoji"] || %{}, emoji)
 222
 223     object
 224     |> Map.put("emoji", emoji)
 225   end
 226
 227   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 228     name = String.trim(tag["name"], ":")
 229     emoji = %{name => tag["icon"]["url"]}
 230
 231     object
 232     |> Map.put("emoji", emoji)
 233   end
 234
 235   def fix_emoji(object), do: object
 236
 237   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 238     tags =
 239       tag
 240       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 241       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 242
 243     combined = tag ++ tags
 244
 245     object
 246     |> Map.put("tag", combined)
 247   end
 248
 249   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 250     combined = [tag, String.slice(hashtag, 1..-1)]
 251
 252     object
 253     |> Map.put("tag", combined)
 254   end
 255
 256   def fix_tag(object), do: object
 257
 258   # content map usually only has one language so this will do for now.
 259   def fix_content_map(%{"contentMap" => content_map} = object) do
 260     content_groups = Map.to_list(content_map)
 261     {_, content} = Enum.at(content_groups, 0)
 262
 263     object
 264     |> Map.put("content", content)
 265   end
 266
 267   def fix_content_map(object), do: object
 268
 269   # disallow objects with bogus IDs
 270   def handle_incoming(%{"id" => nil}), do: :error
 271   def handle_incoming(%{"id" => ""}), do: :error
 272   # length of https:// = 8, should validate better, but good enough for now.
 273   def handle_incoming(%{"id" => id}) when not (is_binary(id) and length(id) > 8), do: :error
 274
 275   # TODO: validate those with a Ecto scheme
 276   # - tags
 277   # - emoji
 278   def handle_incoming(%{"type" => "Create", "object" => %{"type" => objtype} = object} = data)
 279       when objtype in ["Article", "Note", "Video", "Page"] do
 280     actor = get_actor(data)
 281
 282     data =
 283       Map.put(data, "actor", actor)
 284       |> fix_addressing
 285
 286     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 287          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 288       object = fix_object(data["object"])
 289
 290       params = %{
 291         to: data["to"],
 292         object: object,
 293         actor: user,
 294         context: object["conversation"],
 295         local: false,
 296         published: data["published"],
 297         additional:
 298           Map.take(data, [
 299             "cc",
 300             "id"
 301           ])
 302       }
 303
 304       ActivityPub.create(params)
 305     else
 306       %Activity{} = activity -> {:ok, activity}
 307       _e -> :error
 308     end
 309   end
 310
 311   def handle_incoming(
 312         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 313       ) do
 314     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 315          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 316          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 317       if not User.locked?(followed) do
 318         ActivityPub.accept(%{
 319           to: [follower.ap_id],
 320           actor: followed.ap_id,
 321           object: data,
 322           local: true
 323         })
 324
 325         User.follow(follower, followed)
 326       end
 327
 328       {:ok, activity}
 329     else
 330       _e -> :error
 331     end
 332   end
 333
 334   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 335     with true <- id =~ "follows",
 336          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 337          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 338       {:ok, activity}
 339     else
 340       _ -> {:error, nil}
 341     end
 342   end
 343
 344   defp mastodon_follow_hack(_), do: {:error, nil}
 345
 346   defp get_follow_activity(follow_object, followed) do
 347     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 348          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 349       {:ok, activity}
 350     else
 351       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 352       {:activity, nil} ->
 353         mastodon_follow_hack(follow_object, followed)
 354
 355       _ ->
 356         {:error, nil}
 357     end
 358   end
 359
 360   def handle_incoming(
 361         %{"type" => "Accept", "object" => follow_object, "actor" => actor, "id" => id} = data
 362       ) do
 363     with actor <- get_actor(data),
 364          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 365          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 366          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 367          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 368          {:ok, activity} <-
 369            ActivityPub.accept(%{
 370              to: follow_activity.data["to"],
 371              type: "Accept",
 372              actor: followed.ap_id,
 373              object: follow_activity.data["id"],
 374              local: false
 375            }) do
 376       if not User.following?(follower, followed) do
 377         {:ok, follower} = User.follow(follower, followed)
 378       end
 379
 380       {:ok, activity}
 381     else
 382       _e -> :error
 383     end
 384   end
 385
 386   def handle_incoming(
 387         %{"type" => "Reject", "object" => follow_object, "actor" => actor, "id" => id} = data
 388       ) do
 389     with actor <- get_actor(data),
 390          %User{} = followed <- User.get_or_fetch_by_ap_id(actor),
 391          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 392          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 393          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 394          {:ok, activity} <-
 395            ActivityPub.accept(%{
 396              to: follow_activity.data["to"],
 397              type: "Accept",
 398              actor: followed.ap_id,
 399              object: follow_activity.data["id"],
 400              local: false
 401            }) do
 402       User.unfollow(follower, followed)
 403
 404       {:ok, activity}
 405     else
 406       _e -> :error
 407     end
 408   end
 409
 410   def handle_incoming(
 411         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data
 412       ) do
 413     with actor <- get_actor(data),
 414          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 415          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 416          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 417       {:ok, activity}
 418     else
 419       _e -> :error
 420     end
 421   end
 422
 423   def handle_incoming(
 424         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data
 425       ) do
 426     with actor <- get_actor(data),
 427          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 428          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 429          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 430       {:ok, activity}
 431     else
 432       _e -> :error
 433     end
 434   end
 435
 436   def handle_incoming(
 437         %{"type" => "Update", "object" => %{"type" => object_type} = object, "actor" => actor_id} =
 438           data
 439       )
 440       when object_type in ["Person", "Application", "Service", "Organization"] do
 441     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 442       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 443
 444       banner = new_user_data[:info]["banner"]
 445       locked = new_user_data[:info]["locked"] || false
 446
 447       update_data =
 448         new_user_data
 449         |> Map.take([:name, :bio, :avatar])
 450         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner, "locked" => locked}))
 451
 452       actor
 453       |> User.upgrade_changeset(update_data)
 454       |> User.update_and_set_cache()
 455
 456       ActivityPub.update(%{
 457         local: false,
 458         to: data["to"] || [],
 459         cc: data["cc"] || [],
 460         object: object,
 461         actor: actor_id
 462       })
 463     else
 464       e ->
 465         Logger.error(e)
 466         :error
 467     end
 468   end
 469
 470   # TODO: Make secure.
 471   def handle_incoming(
 472         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = data
 473       ) do
 474     object_id = Utils.get_ap_id(object_id)
 475
 476     with actor <- get_actor(data),
 477          %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 478          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 479          {:ok, activity} <- ActivityPub.delete(object, false) do
 480       {:ok, activity}
 481     else
 482       _e -> :error
 483     end
 484   end
 485
 486   def handle_incoming(
 487         %{
 488           "type" => "Undo",
 489           "object" => %{"type" => "Announce", "object" => object_id},
 490           "actor" => actor,
 491           "id" => id
 492         } = data
 493       ) do
 494     with actor <- get_actor(data),
 495          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 496          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 497          {:ok, activity, _} <- ActivityPub.unannounce(actor, object, id, false) do
 498       {:ok, activity}
 499     else
 500       _e -> :error
 501     end
 502   end
 503
 504   def handle_incoming(
 505         %{
 506           "type" => "Undo",
 507           "object" => %{"type" => "Follow", "object" => followed},
 508           "actor" => follower,
 509           "id" => id
 510         } = _data
 511       ) do
 512     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 513          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 514          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 515       User.unfollow(follower, followed)
 516       {:ok, activity}
 517     else
 518       e -> :error
 519     end
 520   end
 521
 522   def handle_incoming(
 523         %{
 524           "type" => "Undo",
 525           "object" => %{"type" => "Block", "object" => blocked},
 526           "actor" => blocker,
 527           "id" => id
 528         } = _data
 529       ) do
 530     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 531          %User{local: true} = blocked <- User.get_cached_by_ap_id(blocked),
 532          %User{} = blocker <- User.get_or_fetch_by_ap_id(blocker),
 533          {:ok, activity} <- ActivityPub.unblock(blocker, blocked, id, false) do
 534       User.unblock(blocker, blocked)
 535       {:ok, activity}
 536     else
 537       e -> :error
 538     end
 539   end
 540
 541   def handle_incoming(
 542         %{"type" => "Block", "object" => blocked, "actor" => blocker, "id" => id} = data
 543       ) do
 544     with true <- Pleroma.Config.get([:activitypub, :accept_blocks]),
 545          %User{local: true} = blocked = User.get_cached_by_ap_id(blocked),
 546          %User{} = blocker = User.get_or_fetch_by_ap_id(blocker),
 547          {:ok, activity} <- ActivityPub.block(blocker, blocked, id, false) do
 548       User.unfollow(blocker, blocked)
 549       User.block(blocker, blocked)
 550       {:ok, activity}
 551     else
 552       e -> :error
 553     end
 554   end
 555
 556   def handle_incoming(
 557         %{
 558           "type" => "Undo",
 559           "object" => %{"type" => "Like", "object" => object_id},
 560           "actor" => actor,
 561           "id" => id
 562         } = data
 563       ) do
 564     with actor <- get_actor(data),
 565          %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 566          {:ok, object} <- get_obj_helper(object_id) || fetch_obj_helper(object_id),
 567          {:ok, activity, _, _} <- ActivityPub.unlike(actor, object, id, false) do
 568       {:ok, activity}
 569     else
 570       _e -> :error
 571     end
 572   end
 573
 574   def handle_incoming(_), do: :error
 575
 576   def fetch_obj_helper(id) when is_bitstring(id), do: ActivityPub.fetch_object_from_id(id)
 577   def fetch_obj_helper(obj) when is_map(obj), do: ActivityPub.fetch_object_from_id(obj["id"])
 578
 579   def get_obj_helper(id) do
 580     if object = Object.normalize(id), do: {:ok, object}, else: nil
 581   end
 582
 583   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 584     with false <- String.starts_with?(inReplyTo, "http"),
 585          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 586       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 587     else
 588       _e -> object
 589     end
 590   end
 591
 592   def set_reply_to_uri(obj), do: obj
 593
 594   # Prepares the object of an outgoing create activity.
 595   def prepare_object(object) do
 596     object
 597     |> set_sensitive
 598     |> add_hashtags
 599     |> add_mention_tags
 600     |> add_emoji_tags
 601     |> add_attributed_to
 602     |> prepare_attachments
 603     |> set_conversation
 604     |> set_reply_to_uri
 605     |> strip_internal_fields
 606     |> strip_internal_tags
 607   end
 608
 609   #  @doc
 610   #  """
 611   #  internal -> Mastodon
 612   #  """
 613
 614   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 615     object =
 616       object
 617       |> prepare_object
 618
 619     data =
 620       data
 621       |> Map.put("object", object)
 622       |> Map.merge(Utils.make_json_ld_header())
 623
 624     {:ok, data}
 625   end
 626
 627   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 628   # because of course it does.
 629   def prepare_outgoing(%{"type" => "Accept"} = data) do
 630     with follow_activity <- Activity.normalize(data["object"]) do
 631       object = %{
 632         "actor" => follow_activity.actor,
 633         "object" => follow_activity.data["object"],
 634         "id" => follow_activity.data["id"],
 635         "type" => "Follow"
 636       }
 637
 638       data =
 639         data
 640         |> Map.put("object", object)
 641         |> Map.merge(Utils.make_json_ld_header())
 642
 643       {:ok, data}
 644     end
 645   end
 646
 647   def prepare_outgoing(%{"type" => "Reject"} = data) do
 648     with follow_activity <- Activity.normalize(data["object"]) do
 649       object = %{
 650         "actor" => follow_activity.actor,
 651         "object" => follow_activity.data["object"],
 652         "id" => follow_activity.data["id"],
 653         "type" => "Follow"
 654       }
 655
 656       data =
 657         data
 658         |> Map.put("object", object)
 659         |> Map.merge(Utils.make_json_ld_header())
 660
 661       {:ok, data}
 662     end
 663   end
 664
 665   def prepare_outgoing(%{"type" => _type} = data) do
 666     data =
 667       data
 668       |> maybe_fix_object_url
 669       |> Map.merge(Utils.make_json_ld_header())
 670
 671     {:ok, data}
 672   end
 673
 674   def maybe_fix_object_url(data) do
 675     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 676       case fetch_obj_helper(data["object"]) do
 677         {:ok, relative_object} ->
 678           if relative_object.data["external_url"] do
 679             _data =
 680               data
 681               |> Map.put("object", relative_object.data["external_url"])
 682           else
 683             data
 684           end
 685
 686         e ->
 687           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 688           data
 689       end
 690     else
 691       data
 692     end
 693   end
 694
 695   def add_hashtags(object) do
 696     tags =
 697       (object["tag"] || [])
 698       |> Enum.map(fn tag ->
 699         %{
 700           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 701           "name" => "##{tag}",
 702           "type" => "Hashtag"
 703         }
 704       end)
 705
 706     object
 707     |> Map.put("tag", tags)
 708   end
 709
 710   def add_mention_tags(object) do
 711     mentions =
 712       object
 713       |> Utils.get_notified_from_object()
 714       |> Enum.map(fn user ->
 715         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 716       end)
 717
 718     tags = object["tag"] || []
 719
 720     object
 721     |> Map.put("tag", tags ++ mentions)
 722   end
 723
 724   # TODO: we should probably send mtime instead of unix epoch time for updated
 725   def add_emoji_tags(object) do
 726     tags = object["tag"] || []
 727     emoji = object["emoji"] || []
 728
 729     out =
 730       emoji
 731       |> Enum.map(fn {name, url} ->
 732         %{
 733           "icon" => %{"url" => url, "type" => "Image"},
 734           "name" => ":" <> name <> ":",
 735           "type" => "Emoji",
 736           "updated" => "1970-01-01T00:00:00Z",
 737           "id" => url
 738         }
 739       end)
 740
 741     object
 742     |> Map.put("tag", tags ++ out)
 743   end
 744
 745   def set_conversation(object) do
 746     Map.put(object, "conversation", object["context"])
 747   end
 748
 749   def set_sensitive(object) do
 750     tags = object["tag"] || []
 751     Map.put(object, "sensitive", "nsfw" in tags)
 752   end
 753
 754   def add_attributed_to(object) do
 755     attributedTo = object["attributedTo"] || object["actor"]
 756
 757     object
 758     |> Map.put("attributedTo", attributedTo)
 759   end
 760
 761   def prepare_attachments(object) do
 762     attachments =
 763       (object["attachment"] || [])
 764       |> Enum.map(fn data ->
 765         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 766         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 767       end)
 768
 769     object
 770     |> Map.put("attachment", attachments)
 771   end
 772
 773   defp strip_internal_fields(object) do
 774     object
 775     |> Map.drop([
 776       "likes",
 777       "like_count",
 778       "announcements",
 779       "announcement_count",
 780       "emoji",
 781       "context_id"
 782     ])
 783   end
 784
 785   defp strip_internal_tags(%{"tag" => tags} = object) do
 786     tags =
 787       tags
 788       |> Enum.filter(fn x -> is_map(x) end)
 789
 790     object
 791     |> Map.put("tag", tags)
 792   end
 793
 794   defp strip_internal_tags(object), do: object
 795
 796   defp user_upgrade_task(user) do
 797     old_follower_address = User.ap_followers(user)
 798
 799     q =
 800       from(
 801         u in User,
 802         where: ^old_follower_address in u.following,
 803         update: [
 804           set: [
 805             following:
 806               fragment(
 807                 "array_replace(?,?,?)",
 808                 u.following,
 809                 ^old_follower_address,
 810                 ^user.follower_address
 811               )
 812           ]
 813         ]
 814       )
 815
 816     Repo.update_all(q, [])
 817
 818     maybe_retire_websub(user.ap_id)
 819
 820     # Only do this for recent activties, don't go through the whole db.
 821     # Only look at the last 1000 activities.
 822     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 823
 824     q =
 825       from(
 826         a in Activity,
 827         where: ^old_follower_address in a.recipients,
 828         where: a.id > ^since,
 829         update: [
 830           set: [
 831             recipients:
 832               fragment(
 833                 "array_replace(?,?,?)",
 834                 a.recipients,
 835                 ^old_follower_address,
 836                 ^user.follower_address
 837               )
 838           ]
 839         ]
 840       )
 841
 842     Repo.update_all(q, [])
 843   end
 844
 845   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 846     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 847          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 848       data =
 849         data
 850         |> Map.put(:info, Map.merge(user.info, data[:info]))
 851
 852       already_ap = User.ap_enabled?(user)
 853
 854       {:ok, user} =
 855         User.upgrade_changeset(user, data)
 856         |> Repo.update()
 857
 858       if !already_ap do
 859         # This could potentially take a long time, do it in the background
 860         if async do
 861           Task.start(fn ->
 862             user_upgrade_task(user)
 863           end)
 864         else
 865           user_upgrade_task(user)
 866         end
 867       end
 868
 869       {:ok, user}
 870     else
 871       e -> e
 872     end
 873   end
 874
 875   def maybe_retire_websub(ap_id) do
 876     # some sanity checks
 877     if is_binary(ap_id) && String.length(ap_id) > 8 do
 878       q =
 879         from(
 880           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 881           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 882         )
 883
 884       Repo.delete_all(q)
 885     end
 886   end
 887
 888   def maybe_fix_user_url(data) do
 889     if is_map(data["url"]) do
 890       Map.put(data, "url", data["url"]["href"])
 891     else
 892       data
 893     end
 894   end
 895
 896   def maybe_fix_user_object(data) do
 897     data
 898     |> maybe_fix_user_url
 899   end
 900 end