git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8
   9   @doc """
  10   Modifies an incoming AP object (mastodon format) to our internal format.
  11   """
  12   def fix_object(object) do
  13     object
  14     |> Map.put("actor", object["attributedTo"])
  15     |> fix_attachments
  16   end
  17
  18   def fix_attachments(object) do
  19     attachments = object["attachment"] || []
  20     |> Enum.map(fn (data) ->
  21       url = [%{"type" => "Link", "mediaType" => data["mediaType"], "url" => data["url"]}]
  22       Map.put(data, "url", url)
  23     end)
  24
  25     object
  26     |> Map.put("attachment", attachments)
  27   end
  28
  29   # TODO: validate those with a Ecto scheme
  30   # - tags
  31   # - emoji
  32   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
  33     with %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
  34       object = fix_object(data["object"])
  35       params = %{
  36         to: data["to"],
  37         object: object,
  38         actor: user,
  39         context: data["object"]["conversation"],
  40         local: false,
  41         published: data["published"],
  42         additional: Map.take(data, [
  43               "cc",
  44               "id"
  45             ])
  46       }
  47
  48       ActivityPub.create(params)
  49     else
  50       _e -> :error
  51     end
  52   end
  53
  54   def handle_incoming(%{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data) do
  55     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
  56          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
  57          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
  58       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
  59       User.follow(follower, followed)
  60       {:ok, activity}
  61     else
  62       _e -> :error
  63     end
  64   end
  65
  66   def handle_incoming(%{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = data) do
  67     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
  68          %Object{} = object <- Object.get_by_ap_id(object_id),
  69          {:ok, activity, object} <- ActivityPub.like(actor, object, id, false) do
  70       {:ok, activity}
  71     else
  72       _e -> :error
  73     end
  74   end
  75
  76   def handle_incoming(%{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = data) do
  77     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
  78          {:ok, object} <- ActivityPub.fetch_object_from_id(object_id),
  79          {:ok, activity, object} <- ActivityPub.announce(actor, object, id, false) do
  80       {:ok, activity}
  81     else
  82       _e -> :error
  83     end
  84   end
  85
  86   # TODO
  87   # Accept
  88   # Undo
  89
  90   def handle_incoming(_), do: :error
  91
  92   @doc
  93   """
  94   internal -> Mastodon
  95   """
  96   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
  97     object = object
  98     |> add_mention_tags
  99     |> add_attributed_to
 100     |> prepare_attachments
 101
 102     data = data
 103     |> Map.put("object", object)
 104     |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 105
 106     {:ok, data}
 107   end
 108
 109   def prepare_outgoing(%{"type" => type} = data) when type in ["Follow", "Accept", "Like", "Announce"] do
 110     data = data
 111     |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 112
 113     {:ok, data}
 114   end
 115
 116   def add_mention_tags(object) do
 117     mentions = object["to"]
 118     |> Enum.map(fn (ap_id) -> User.get_cached_by_ap_id(ap_id) end)
 119     |> Enum.filter(&(&1))
 120     |> Enum.map(fn(user) -> %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"} end)
 121
 122     tags = object["tag"] || []
 123
 124     object
 125     |> Map.put("tag", tags ++ mentions)
 126   end
 127
 128   def add_attributed_to(object) do
 129     attributedTo = object["attributedTo"] || object["actor"]
 130
 131     object
 132     |> Map.put("attributedTo", attributedTo)
 133   end
 134
 135   def prepare_attachments(object) do
 136     attachments = (object["attachment"] || [])
 137     |> Enum.map(fn (data) ->
 138       [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 139       %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 140     end)
 141
 142     object
 143     |> Map.put("attachment", attachments)
 144   end
 145 end