git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/side_effects.ex

   1 defmodule Pleroma.Web.ActivityPub.SideEffects do
   2   @moduledoc """
   3   This module looks at an inserted object and executes the side effects that it
   4   implies. For example, a `Like` activity will increase the like count on the
   5   liked object, a `Follow` activity will add the user to the follower
   6   collection, and so on.
   7   """
   8   alias Pleroma.Activity
   9   alias Pleroma.Notification
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.ActivityPub.Utils
  15
  16   def handle(object, meta \\ [])
  17
  18   # Tasks this handles:
  19   # - Add like to object
  20   # - Set up notification
  21   def handle(%{data: %{"type" => "Like"}} = object, meta) do
  22     liked_object = Object.get_by_ap_id(object.data["object"])
  23     Utils.add_like_to_object(object, liked_object)
  24
  25     Notification.create_notifications(object)
  26
  27     {:ok, object, meta}
  28   end
  29
  30   # Tasks this handles:
  31   # - Add announce to object
  32   # - Set up notification
  33   def handle(%{data: %{"type" => "Announce"}} = object, meta) do
  34     announced_object = Object.get_by_ap_id(object.data["object"])
  35     Utils.add_announce_to_object(object, announced_object)
  36
  37     Notification.create_notifications(object)
  38
  39     {:ok, object, meta}
  40   end
  41
  42   def handle(%{data: %{"type" => "Undo", "object" => undone_object}} = object, meta) do
  43     with undone_object <- Activity.get_by_ap_id(undone_object),
  44          :ok <- handle_undoing(undone_object) do
  45       {:ok, object, meta}
  46     end
  47   end
  48
  49   # Tasks this handles:
  50   # - Add reaction to object
  51   # - Set up notification
  52   def handle(%{data: %{"type" => "EmojiReact"}} = object, meta) do
  53     reacted_object = Object.get_by_ap_id(object.data["object"])
  54     Utils.add_emoji_reaction_to_object(object, reacted_object)
  55
  56     Notification.create_notifications(object)
  57
  58     {:ok, object, meta}
  59   end
  60
  61   # Tasks this handles:
  62   # - Delete and unpins the create activity
  63   # - Replace object with Tombstone
  64   # - Set up notification
  65   # - Reduce the user note count
  66   # - Reduce the reply count
  67   # - Stream out the activity
  68   def handle(%{data: %{"type" => "Delete", "object" => deleted_object}} = object, meta) do
  69     deleted_object =
  70       Object.normalize(deleted_object, false) || User.get_cached_by_ap_id(deleted_object)
  71
  72     result =
  73       case deleted_object do
  74         %Object{} ->
  75           with {:ok, deleted_object, activity} <- Object.delete(deleted_object),
  76                %User{} = user <- User.get_cached_by_ap_id(deleted_object.data["actor"]) do
  77             User.remove_pinnned_activity(user, activity)
  78
  79             {:ok, user} = ActivityPub.decrease_note_count_if_public(user, deleted_object)
  80
  81             if in_reply_to = deleted_object.data["inReplyTo"] do
  82               Object.decrease_replies_count(in_reply_to)
  83             end
  84
  85             ActivityPub.stream_out(object)
  86             ActivityPub.stream_out_participations(deleted_object, user)
  87             :ok
  88           end
  89
  90         %User{} ->
  91           with {:ok, _} <- User.delete(deleted_object) do
  92             :ok
  93           end
  94       end
  95
  96     if result == :ok do
  97       Notification.create_notifications(object)
  98       {:ok, object, meta}
  99     else
 100       {:error, result}
 101     end
 102   end
 103
 104   # Nothing to do
 105   def handle(object, meta) do
 106     {:ok, object, meta}
 107   end
 108
 109   def handle_undoing(%{data: %{"type" => "Like"}} = object) do
 110     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
 111          {:ok, _} <- Utils.remove_like_from_object(object, liked_object),
 112          {:ok, _} <- Repo.delete(object) do
 113       :ok
 114     end
 115   end
 116
 117   def handle_undoing(%{data: %{"type" => "EmojiReact"}} = object) do
 118     with %Object{} = reacted_object <- Object.get_by_ap_id(object.data["object"]),
 119          {:ok, _} <- Utils.remove_emoji_reaction_from_object(object, reacted_object),
 120          {:ok, _} <- Repo.delete(object) do
 121       :ok
 122     end
 123   end
 124
 125   def handle_undoing(%{data: %{"type" => "Announce"}} = object) do
 126     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
 127          {:ok, _} <- Utils.remove_announce_from_object(object, liked_object),
 128          {:ok, _} <- Repo.delete(object) do
 129       :ok
 130     end
 131   end
 132
 133   def handle_undoing(
 134         %{data: %{"type" => "Block", "actor" => blocker, "object" => blocked}} = object
 135       ) do
 136     with %User{} = blocker <- User.get_cached_by_ap_id(blocker),
 137          %User{} = blocked <- User.get_cached_by_ap_id(blocked),
 138          {:ok, _} <- User.unblock(blocker, blocked),
 139          {:ok, _} <- Repo.delete(object) do
 140       :ok
 141     end
 142   end
 143
 144   def handle_undoing(object), do: {:error, ["don't know how to handle", object]}
 145 end