git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/side_effects.ex

   1 defmodule Pleroma.Web.ActivityPub.SideEffects do
   2   @moduledoc """
   3   This module looks at an inserted object and executes the side effects that it
   4   implies. For example, a `Like` activity will increase the like count on the
   5   liked object, a `Follow` activity will add the user to the follower
   6   collection, and so on.
   7   """
   8   alias Pleroma.Activity
   9   alias Pleroma.Notification
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.ActivityPub.Utils
  15
  16   def handle(object, meta \\ [])
  17
  18   # Tasks this handles:
  19   # - Add like to object
  20   # - Set up notification
  21   def handle(%{data: %{"type" => "Like"}} = object, meta) do
  22     liked_object = Object.get_by_ap_id(object.data["object"])
  23     Utils.add_like_to_object(object, liked_object)
  24
  25     Notification.create_notifications(object)
  26
  27     {:ok, object, meta}
  28   end
  29
  30   # Tasks this handles:
  31   # - Add announce to object
  32   # - Set up notification
  33   # - Stream out the announce
  34   def handle(%{data: %{"type" => "Announce"}} = object, meta) do
  35     announced_object = Object.get_by_ap_id(object.data["object"])
  36
  37     Utils.add_announce_to_object(object, announced_object)
  38
  39     Notification.create_notifications(object)
  40     ActivityPub.stream_out(object)
  41
  42     {:ok, object, meta}
  43   end
  44
  45   def handle(%{data: %{"type" => "Undo", "object" => undone_object}} = object, meta) do
  46     with undone_object <- Activity.get_by_ap_id(undone_object),
  47          :ok <- handle_undoing(undone_object) do
  48       {:ok, object, meta}
  49     end
  50   end
  51
  52   # Tasks this handles:
  53   # - Add reaction to object
  54   # - Set up notification
  55   def handle(%{data: %{"type" => "EmojiReact"}} = object, meta) do
  56     reacted_object = Object.get_by_ap_id(object.data["object"])
  57     Utils.add_emoji_reaction_to_object(object, reacted_object)
  58
  59     Notification.create_notifications(object)
  60
  61     {:ok, object, meta}
  62   end
  63
  64   # Tasks this handles:
  65   # - Delete and unpins the create activity
  66   # - Replace object with Tombstone
  67   # - Set up notification
  68   # - Reduce the user note count
  69   # - Reduce the reply count
  70   # - Stream out the activity
  71   def handle(%{data: %{"type" => "Delete", "object" => deleted_object}} = object, meta) do
  72     deleted_object =
  73       Object.normalize(deleted_object, false) || User.get_cached_by_ap_id(deleted_object)
  74
  75     result =
  76       case deleted_object do
  77         %Object{} ->
  78           with {:ok, deleted_object, activity} <- Object.delete(deleted_object),
  79                %User{} = user <- User.get_cached_by_ap_id(deleted_object.data["actor"]) do
  80             User.remove_pinnned_activity(user, activity)
  81
  82             {:ok, user} = ActivityPub.decrease_note_count_if_public(user, deleted_object)
  83
  84             if in_reply_to = deleted_object.data["inReplyTo"] do
  85               Object.decrease_replies_count(in_reply_to)
  86             end
  87
  88             ActivityPub.stream_out(object)
  89             ActivityPub.stream_out_participations(deleted_object, user)
  90             :ok
  91           end
  92
  93         %User{} ->
  94           with {:ok, _} <- User.delete(deleted_object) do
  95             :ok
  96           end
  97       end
  98
  99     if result == :ok do
 100       Notification.create_notifications(object)
 101       {:ok, object, meta}
 102     else
 103       {:error, result}
 104     end
 105   end
 106
 107   # Nothing to do
 108   def handle(object, meta) do
 109     {:ok, object, meta}
 110   end
 111
 112   def handle_undoing(%{data: %{"type" => "Like"}} = object) do
 113     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
 114          {:ok, _} <- Utils.remove_like_from_object(object, liked_object),
 115          {:ok, _} <- Repo.delete(object) do
 116       :ok
 117     end
 118   end
 119
 120   def handle_undoing(%{data: %{"type" => "EmojiReact"}} = object) do
 121     with %Object{} = reacted_object <- Object.get_by_ap_id(object.data["object"]),
 122          {:ok, _} <- Utils.remove_emoji_reaction_from_object(object, reacted_object),
 123          {:ok, _} <- Repo.delete(object) do
 124       :ok
 125     end
 126   end
 127
 128   def handle_undoing(%{data: %{"type" => "Announce"}} = object) do
 129     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
 130          {:ok, _} <- Utils.remove_announce_from_object(object, liked_object),
 131          {:ok, _} <- Repo.delete(object) do
 132       :ok
 133     end
 134   end
 135
 136   def handle_undoing(
 137         %{data: %{"type" => "Block", "actor" => blocker, "object" => blocked}} = object
 138       ) do
 139     with %User{} = blocker <- User.get_cached_by_ap_id(blocker),
 140          %User{} = blocked <- User.get_cached_by_ap_id(blocked),
 141          {:ok, _} <- User.unblock(blocker, blocked),
 142          {:ok, _} <- Repo.delete(object) do
 143       :ok
 144     end
 145   end
 146
 147   def handle_undoing(object), do: {:error, ["don't know how to handle", object]}
 148 end