git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/side_effects.ex

   1 defmodule Pleroma.Web.ActivityPub.SideEffects do
   2   @moduledoc """
   3   This module looks at an inserted object and executes the side effects that it
   4   implies. For example, a `Like` activity will increase the like count on the
   5   liked object, a `Follow` activity will add the user to the follower
   6   collection, and so on.
   7   """
   8   alias Pleroma.Activity
   9   alias Pleroma.Notification
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.ActivityPub.Utils
  15
  16   def handle(object, meta \\ [])
  17
  18   # Tasks this handles:
  19   # - Add like to object
  20   # - Set up notification
  21   def handle(%{data: %{"type" => "Like"}} = object, meta) do
  22     liked_object = Object.get_by_ap_id(object.data["object"])
  23     Utils.add_like_to_object(object, liked_object)
  24
  25     Notification.create_notifications(object)
  26
  27     {:ok, object, meta}
  28   end
  29
  30   def handle(%{data: %{"type" => "Undo", "object" => undone_object}} = object, meta) do
  31     with undone_object <- Activity.get_by_ap_id(undone_object),
  32          :ok <- handle_undoing(undone_object) do
  33       {:ok, object, meta}
  34     end
  35   end
  36
  37   # Tasks this handles:
  38   # - Delete and unpins the create activity
  39   # - Replace object with Tombstone
  40   # - Set up notification
  41   # - Reduce the user note count
  42   # - Reduce the reply count
  43   # - Stream out the activity
  44   def handle(%{data: %{"type" => "Delete", "object" => deleted_object}} = object, meta) do
  45     deleted_object =
  46       Object.normalize(deleted_object, false) || User.get_cached_by_ap_id(deleted_object)
  47
  48     result =
  49       case deleted_object do
  50         %Object{} ->
  51           with {:ok, deleted_object, activity} <- Object.delete(deleted_object),
  52                %User{} = user <- User.get_cached_by_ap_id(deleted_object.data["actor"]) do
  53             User.remove_pinnned_activity(user, activity)
  54
  55             {:ok, user} = ActivityPub.decrease_note_count_if_public(user, deleted_object)
  56
  57             if in_reply_to = deleted_object.data["inReplyTo"] do
  58               Object.decrease_replies_count(in_reply_to)
  59             end
  60
  61             ActivityPub.stream_out(object)
  62             ActivityPub.stream_out_participations(deleted_object, user)
  63             :ok
  64           end
  65
  66         %User{} ->
  67           with {:ok, _} <- User.delete(deleted_object) do
  68             :ok
  69           end
  70       end
  71
  72     if result == :ok do
  73       Notification.create_notifications(object)
  74       {:ok, object, meta}
  75     else
  76       {:error, result}
  77     end
  78   end
  79
  80   # Nothing to do
  81   def handle(object, meta) do
  82     {:ok, object, meta}
  83   end
  84
  85   def handle_undoing(%{data: %{"type" => "Like"}} = object) do
  86     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
  87          {:ok, _} <- Utils.remove_like_from_object(object, liked_object),
  88          {:ok, _} <- Repo.delete(object) do
  89       :ok
  90     end
  91   end
  92
  93   def handle_undoing(%{data: %{"type" => "EmojiReact"}} = object) do
  94     with %Object{} = reacted_object <- Object.get_by_ap_id(object.data["object"]),
  95          {:ok, _} <- Utils.remove_emoji_reaction_from_object(object, reacted_object),
  96          {:ok, _} <- Repo.delete(object) do
  97       :ok
  98     end
  99   end
 100
 101   def handle_undoing(%{data: %{"type" => "Announce"}} = object) do
 102     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
 103          {:ok, _} <- Utils.remove_announce_from_object(object, liked_object),
 104          {:ok, _} <- Repo.delete(object) do
 105       :ok
 106     end
 107   end
 108
 109   def handle_undoing(
 110         %{data: %{"type" => "Block", "actor" => blocker, "object" => blocked}} = object
 111       ) do
 112     with %User{} = blocker <- User.get_cached_by_ap_id(blocker),
 113          %User{} = blocked <- User.get_cached_by_ap_id(blocked),
 114          {:ok, _} <- User.unblock(blocker, blocked),
 115          {:ok, _} <- Repo.delete(object) do
 116       :ok
 117     end
 118   end
 119
 120   def handle_undoing(object), do: {:error, ["don't know how to handle", object]}
 121 end