git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/side_effects.ex

   1 defmodule Pleroma.Web.ActivityPub.SideEffects do
   2   @moduledoc """
   3   This module looks at an inserted object and executes the side effects that it
   4   implies. For example, a `Like` activity will increase the like count on the
   5   liked object, a `Follow` activity will add the user to the follower
   6   collection, and so on.
   7   """
   8   alias Pleroma.Activity
   9   alias Pleroma.Notification
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.ActivityPub.Utils
  14
  15   def handle(object, meta \\ [])
  16
  17   # Tasks this handles:
  18   # - Add like to object
  19   # - Set up notification
  20   def handle(%{data: %{"type" => "Like"}} = object, meta) do
  21     liked_object = Object.get_by_ap_id(object.data["object"])
  22     Utils.add_like_to_object(object, liked_object)
  23
  24     Notification.create_notifications(object)
  25
  26     {:ok, object, meta}
  27   end
  28
  29   def handle(%{data: %{"type" => "Undo", "object" => undone_object}} = object, meta) do
  30     with undone_object <- Activity.get_by_ap_id(undone_object),
  31          :ok <- handle_undoing(undone_object) do
  32       {:ok, object, meta}
  33     end
  34   end
  35
  36   # Nothing to do
  37   def handle(object, meta) do
  38     {:ok, object, meta}
  39   end
  40
  41   def handle_undoing(%{data: %{"type" => "Like"}} = object) do
  42     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
  43          {:ok, _} <- Utils.remove_like_from_object(object, liked_object),
  44          {:ok, _} <- Repo.delete(object) do
  45       :ok
  46     end
  47   end
  48
  49   def handle_undoing(%{data: %{"type" => "EmojiReact"}} = object) do
  50     with %Object{} = reacted_object <- Object.get_by_ap_id(object.data["object"]),
  51          {:ok, _} <- Utils.remove_emoji_reaction_from_object(object, reacted_object),
  52          {:ok, _} <- Repo.delete(object) do
  53       :ok
  54     end
  55   end
  56
  57   def handle_undoing(%{data: %{"type" => "Announce"}} = object) do
  58     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
  59          {:ok, _} <- Utils.remove_announce_from_object(object, liked_object),
  60          {:ok, _} <- Repo.delete(object) do
  61       :ok
  62     end
  63   end
  64
  65   def handle_undoing(
  66         %{data: %{"type" => "Block", "actor" => blocker, "object" => blocked}} = object
  67       ) do
  68     with %User{} = blocker <- User.get_cached_by_ap_id(blocker),
  69          %User{} = blocked <- User.get_cached_by_ap_id(blocked),
  70          {:ok, _} <- User.unblock(blocker, blocked),
  71          {:ok, _} <- Repo.delete(object) do
  72       :ok
  73     end
  74   end
  75
  76   def handle_undoing(object), do: {:error, ["don't know how to handle", object]}
  77 end