git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/side_effects.ex

   1 defmodule Pleroma.Web.ActivityPub.SideEffects do
   2   @moduledoc """
   3   This module looks at an inserted object and executes the side effects that it
   4   implies. For example, a `Like` activity will increase the like count on the
   5   liked object, a `Follow` activity will add the user to the follower
   6   collection, and so on.
   7   """
   8   alias Pleroma.Chat
   9   alias Pleroma.Activity
  10   alias Pleroma.Notification
  11   alias Pleroma.Object
  12   alias Pleroma.Repo
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15   alias Pleroma.Web.ActivityPub.Pipeline
  16   alias Pleroma.Web.ActivityPub.Utils
  17
  18   def handle(object, meta \\ [])
  19
  20   # Tasks this handles:
  21   # - Add like to object
  22   # - Set up notification
  23   def handle(%{data: %{"type" => "Like"}} = object, meta) do
  24     liked_object = Object.get_by_ap_id(object.data["object"])
  25     Utils.add_like_to_object(object, liked_object)
  26
  27     Notification.create_notifications(object)
  28
  29     {:ok, object, meta}
  30   end
  31
  32   # Tasks this handles
  33   # - Actually create object
  34   # - Rollback if we couldn't create it
  35   # - Set up notifications
  36   def handle(%{data: %{"type" => "Create"}} = activity, meta) do
  37     with {:ok, _object, _meta} <- handle_object_creation(meta[:object_data], meta) do
  38       Notification.create_notifications(activity)
  39       {:ok, activity, meta}
  40     else
  41       e -> Repo.rollback(e)
  42     end
  43   end
  44
  45   def handle(%{data: %{"type" => "Undo", "object" => undone_object}} = object, meta) do
  46     with undone_object <- Activity.get_by_ap_id(undone_object),
  47          :ok <- handle_undoing(undone_object) do
  48       {:ok, object, meta}
  49     end
  50   end
  51
  52   # Tasks this handles:
  53   # - Add reaction to object
  54   # - Set up notification
  55   def handle(%{data: %{"type" => "EmojiReact"}} = object, meta) do
  56     reacted_object = Object.get_by_ap_id(object.data["object"])
  57     Utils.add_emoji_reaction_to_object(object, reacted_object)
  58
  59     Notification.create_notifications(object)
  60
  61     {:ok, object, meta}
  62   end
  63
  64   # Tasks this handles:
  65   # - Delete and unpins the create activity
  66   # - Replace object with Tombstone
  67   # - Set up notification
  68   # - Reduce the user note count
  69   # - Reduce the reply count
  70   # - Stream out the activity
  71   def handle(%{data: %{"type" => "Delete", "object" => deleted_object}} = object, meta) do
  72     deleted_object =
  73       Object.normalize(deleted_object, false) || User.get_cached_by_ap_id(deleted_object)
  74
  75     result =
  76       case deleted_object do
  77         %Object{} ->
  78           with {:ok, deleted_object, activity} <- Object.delete(deleted_object),
  79                %User{} = user <- User.get_cached_by_ap_id(deleted_object.data["actor"]) do
  80             User.remove_pinnned_activity(user, activity)
  81
  82             {:ok, user} = ActivityPub.decrease_note_count_if_public(user, deleted_object)
  83
  84             if in_reply_to = deleted_object.data["inReplyTo"] do
  85               Object.decrease_replies_count(in_reply_to)
  86             end
  87
  88             ActivityPub.stream_out(object)
  89             ActivityPub.stream_out_participations(deleted_object, user)
  90             :ok
  91           end
  92
  93         %User{} ->
  94           with {:ok, _} <- User.delete(deleted_object) do
  95             :ok
  96           end
  97       end
  98
  99     if result == :ok do
 100       Notification.create_notifications(object)
 101       {:ok, object, meta}
 102     else
 103       {:error, result}
 104     end
 105   end
 106
 107   # Nothing to do
 108   def handle(object, meta) do
 109     {:ok, object, meta}
 110   end
 111
 112   def handle_object_creation(%{"type" => "ChatMessage"} = object, meta) do
 113     with {:ok, object, meta} <- Pipeline.common_pipeline(object, meta) do
 114       actor = User.get_cached_by_ap_id(object.data["actor"])
 115       recipient = User.get_cached_by_ap_id(hd(object.data["to"]))
 116
 117       [[actor, recipient], [recipient, actor]]
 118       |> Enum.each(fn [user, other_user] ->
 119         if user.local do
 120           Chat.bump_or_create(user.id, other_user.ap_id)
 121         end
 122       end)
 123
 124       {:ok, object, meta}
 125     end
 126   end
 127
 128   # Nothing to do
 129   def handle_object_creation(object) do
 130     {:ok, object}
 131   end
 132
 133   def handle_undoing(%{data: %{"type" => "Like"}} = object) do
 134     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
 135          {:ok, _} <- Utils.remove_like_from_object(object, liked_object),
 136          {:ok, _} <- Repo.delete(object) do
 137       :ok
 138     end
 139   end
 140
 141   def handle_undoing(%{data: %{"type" => "EmojiReact"}} = object) do
 142     with %Object{} = reacted_object <- Object.get_by_ap_id(object.data["object"]),
 143          {:ok, _} <- Utils.remove_emoji_reaction_from_object(object, reacted_object),
 144          {:ok, _} <- Repo.delete(object) do
 145       :ok
 146     end
 147   end
 148
 149   def handle_undoing(%{data: %{"type" => "Announce"}} = object) do
 150     with %Object{} = liked_object <- Object.get_by_ap_id(object.data["object"]),
 151          {:ok, _} <- Utils.remove_announce_from_object(object, liked_object),
 152          {:ok, _} <- Repo.delete(object) do
 153       :ok
 154     end
 155   end
 156
 157   def handle_undoing(
 158         %{data: %{"type" => "Block", "actor" => blocker, "object" => blocked}} = object
 159       ) do
 160     with %User{} = blocker <- User.get_cached_by_ap_id(blocker),
 161          %User{} = blocked <- User.get_cached_by_ap_id(blocked),
 162          {:ok, _} <- User.unblock(blocker, blocked),
 163          {:ok, _} <- Repo.delete(object) do
 164       :ok
 165     end
 166   end
 167
 168   def handle_undoing(object), do: {:error, ["don't know how to handle", object]}
 169 end