git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/relay.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Relay do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   require Logger
  11
  12   def get_actor do
  13     "#{Pleroma.Web.Endpoint.url()}/relay"
  14     |> User.get_or_create_service_actor_by_ap_id()
  15   end
  16
  17   @spec follow(String.t()) :: {:ok, Activity.t()} | {:error, any()}
  18   def follow(target_instance) do
  19     with %User{} = local_user <- get_actor(),
  20          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  21          {:ok, activity} <- ActivityPub.follow(local_user, target_user) do
  22       Logger.info("relay: followed instance: #{target_instance}; id=#{activity.data["id"]}")
  23       {:ok, activity}
  24     else
  25       {:error, _} = error ->
  26         Logger.error("error: #{inspect(error)}")
  27         error
  28
  29       e ->
  30         Logger.error("error: #{inspect(e)}")
  31         {:error, e}
  32     end
  33   end
  34
  35   @spec unfollow(String.t()) :: {:ok, Activity.t()} | {:error, any()}
  36   def unfollow(target_instance) do
  37     with %User{} = local_user <- get_actor(),
  38          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  39          {:ok, activity} <- ActivityPub.unfollow(local_user, target_user) do
  40       User.unfollow(local_user, target_user)
  41       Logger.info("relay: unfollowed instance: #{target_instance}: id=#{activity.data["id"]}")
  42       {:ok, activity}
  43     else
  44       {:error, _} = error ->
  45         Logger.error("error: #{inspect(error)}")
  46         error
  47
  48       e ->
  49         Logger.error("error: #{inspect(e)}")
  50         {:error, e}
  51     end
  52   end
  53
  54   @spec publish(any()) :: {:ok, Activity.t(), Object.t()} | {:error, any()}
  55   def publish(%Activity{data: %{"type" => "Create"}} = activity) do
  56     with %User{} = user <- get_actor(),
  57          %Object{} = object <- Object.normalize(activity) do
  58       ActivityPub.announce(user, object, nil, true, false)
  59     else
  60       e ->
  61         Logger.error("error: #{inspect(e)}")
  62         {:error, inspect(e)}
  63     end
  64   end
  65
  66   def publish(_), do: {:error, "Not implemented"}
  67 end