git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/relay.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Relay do
   6   alias Pleroma.User
   7   alias Pleroma.Object
   8   alias Pleroma.Activity
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   require Logger
  11
  12   def get_actor do
  13     User.get_or_create_instance_user()
  14   end
  15
  16   def follow(target_instance) do
  17     with %User{} = local_user <- get_actor(),
  18          %User{} = target_user <- User.get_or_fetch_by_ap_id(target_instance),
  19          {:ok, activity} <- ActivityPub.follow(local_user, target_user) do
  20       Logger.info("relay: followed instance: #{target_instance}; id=#{activity.data["id"]}")
  21       {:ok, activity}
  22     else
  23       e ->
  24         Logger.error("error: #{inspect(e)}")
  25         {:error, e}
  26     end
  27   end
  28
  29   def unfollow(target_instance) do
  30     with %User{} = local_user <- get_actor(),
  31          %User{} = target_user <- User.get_or_fetch_by_ap_id(target_instance),
  32          {:ok, activity} <- ActivityPub.unfollow(local_user, target_user) do
  33       Logger.info("relay: unfollowed instance: #{target_instance}: id=#{activity.data["id"]}")
  34       {:ok, activity}
  35     else
  36       e ->
  37         Logger.error("error: #{inspect(e)}")
  38         {:error, e}
  39     end
  40   end
  41
  42   def publish(%Activity{data: %{"type" => "Create"}} = activity) do
  43     with %User{} = user <- get_actor(),
  44          %Object{} = object <- Object.normalize(activity.data["object"]["id"]) do
  45       ActivityPub.announce(user, object, nil, true, false)
  46     else
  47       e -> Logger.error("error: #{inspect(e)}")
  48     end
  49   end
  50
  51   def publish(_), do: nil
  52 end