git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/relay.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Relay do
   6   alias Pleroma.{User, Object, Activity}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   require Logger
   9
  10   def get_actor do
  11     User.get_or_create_instance_user()
  12   end
  13
  14   def follow(target_instance) do
  15     with %User{} = local_user <- get_actor(),
  16          %User{} = target_user <- User.get_or_fetch_by_ap_id(target_instance),
  17          {:ok, activity} <- ActivityPub.follow(local_user, target_user) do
  18       Logger.info("relay: followed instance: #{target_instance}; id=#{activity.data["id"]}")
  19       {:ok, activity}
  20     else
  21       e ->
  22         Logger.error("error: #{inspect(e)}")
  23         {:error, e}
  24     end
  25   end
  26
  27   def unfollow(target_instance) do
  28     with %User{} = local_user <- get_actor(),
  29          %User{} = target_user <- User.get_or_fetch_by_ap_id(target_instance),
  30          {:ok, activity} <- ActivityPub.unfollow(local_user, target_user) do
  31       Logger.info("relay: unfollowed instance: #{target_instance}: id=#{activity.data["id"]}")
  32       {:ok, activity}
  33     else
  34       e ->
  35         Logger.error("error: #{inspect(e)}")
  36         {:error, e}
  37     end
  38   end
  39
  40   def publish(%Activity{data: %{"type" => "Create"}} = activity) do
  41     with %User{} = user <- get_actor(),
  42          %Object{} = object <- Object.normalize(activity.data["object"]["id"]) do
  43       ActivityPub.announce(user, object, nil, true, false)
  44     else
  45       e -> Logger.error("error: #{inspect(e)}")
  46     end
  47   end
  48
  49   def publish(_), do: nil
  50 end