git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/relay.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Relay do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   require Logger
  11
  12   def get_actor do
  13     "#{Pleroma.Web.Endpoint.url()}/relay"
  14     |> User.get_or_create_service_actor_by_ap_id()
  15   end
  16
  17   def follow(target_instance) do
  18     with %User{} = local_user <- get_actor(),
  19          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  20          {:ok, activity} <- ActivityPub.follow(local_user, target_user) do
  21       Logger.info("relay: followed instance: #{target_instance}; id=#{activity.data["id"]}")
  22       {:ok, activity}
  23     else
  24       e ->
  25         Logger.error("error: #{inspect(e)}")
  26         {:error, e}
  27     end
  28   end
  29
  30   def unfollow(target_instance) do
  31     with %User{} = local_user <- get_actor(),
  32          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  33          {:ok, activity} <- ActivityPub.unfollow(local_user, target_user) do
  34       Logger.info("relay: unfollowed instance: #{target_instance}: id=#{activity.data["id"]}")
  35       {:ok, activity}
  36     else
  37       e ->
  38         Logger.error("error: #{inspect(e)}")
  39         {:error, e}
  40     end
  41   end
  42
  43   def publish(%Activity{data: %{"type" => "Create"}} = activity) do
  44     with %User{} = user <- get_actor(),
  45          %Object{} = object <- Object.normalize(activity) do
  46       ActivityPub.announce(user, object, nil, true, false)
  47     else
  48       e -> Logger.error("error: #{inspect(e)}")
  49     end
  50   end
  51
  52   def publish(_), do: nil
  53 end