git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/pipeline.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Pipeline do
   6   alias Pleroma.Activity
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.ActivityPub.MRF
   9   alias Pleroma.Web.ActivityPub.ObjectValidator
  10   alias Pleroma.Web.ActivityPub.SideEffects
  11   alias Pleroma.Web.Federator
  12
  13   @spec common_pipeline(map(), keyword()) :: {:ok, Activity.t(), keyword()} | {:error, any()}
  14   def common_pipeline(object, meta) do
  15     with {_, {:ok, validated_object, meta}} <-
  16            {:validate_object, ObjectValidator.validate(object, meta)},
  17          {_, {:ok, mrfd_object}} <- {:mrf_object, MRF.filter(validated_object)},
  18          {_, {:ok, %Activity{} = activity, meta}} <-
  19            {:persist_object, ActivityPub.persist(mrfd_object, meta)},
  20          {_, {:ok, %Activity{} = activity, meta}} <-
  21            {:execute_side_effects, SideEffects.handle(activity, meta)},
  22          {_, {:ok, _}} <- {:federation, maybe_federate(activity, meta)} do
  23       {:ok, activity, meta}
  24     else
  25       e -> {:error, e}
  26     end
  27   end
  28
  29   defp maybe_federate(activity, meta) do
  30     with {:ok, local} <- Keyword.fetch(meta, :local) do
  31       if local do
  32         Federator.publish(activity)
  33         {:ok, :federated}
  34       else
  35         {:ok, :not_federated}
  36       end
  37     else
  38       _e -> {:error, :badarg}
  39     end
  40   end
  41 end