git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/pipeline.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Pipeline do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.MRF
  11   alias Pleroma.Web.ActivityPub.ObjectValidator
  12   alias Pleroma.Web.ActivityPub.SideEffects
  13   alias Pleroma.Web.Federator
  14
  15   @spec common_pipeline(map(), keyword()) ::
  16           {:ok, Activity.t() | Object.t(), keyword()} | {:error, any()}
  17   def common_pipeline(object, meta) do
  18     case Repo.transaction(fn -> do_common_pipeline(object, meta) end) do
  19       {:ok, value} ->
  20         value
  21
  22       {:error, e} ->
  23         {:error, e}
  24     end
  25   end
  26
  27   def do_common_pipeline(object, meta) do
  28     with {_, {:ok, validated_object, meta}} <-
  29            {:validate_object, ObjectValidator.validate(object, meta)},
  30          {_, {:ok, mrfd_object}} <- {:mrf_object, MRF.filter(validated_object)},
  31          {_, {:ok, activity, meta}} <-
  32            {:persist_object, ActivityPub.persist(mrfd_object, meta)},
  33          {_, {:ok, activity, meta}} <-
  34            {:execute_side_effects, SideEffects.handle(activity, meta)},
  35          {_, {:ok, _}} <- {:federation, maybe_federate(activity, meta)} do
  36       {:ok, activity, meta}
  37     else
  38       {:mrf_object, {:reject, _}} -> {:ok, nil, meta}
  39       e -> {:error, e}
  40     end
  41   end
  42
  43   defp maybe_federate(%Object{}, _), do: {:ok, :not_federated}
  44
  45   defp maybe_federate(%Activity{} = activity, meta) do
  46     with {:ok, local} <- Keyword.fetch(meta, :local) do
  47       do_not_federate = meta[:do_not_federate]
  48
  49       if !do_not_federate && local do
  50         Federator.publish(activity)
  51         {:ok, :federated}
  52       else
  53         {:ok, :not_federated}
  54       end
  55     else
  56       _e -> {:error, :badarg}
  57     end
  58   end
  59 end